CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.12)
   2 set(CMAKE_CONFIGURATION_TYPES "Release;Debug;ASAN")
   3 project(openvpn)
   4
   5 # This CMake file implements building OpenVPN with CMAKE
   6 #
   7 # Note that this is *NOT* the official way to build openvpn on anything
   8 # other than Windows/mingw despite working on other platforms too. You will need
   9 # to add -DUNSUPPORTED_BUILDS=true to build on non Windows platforms.
  10 #
  11 # This cmake also makes a few assertions like lzo, lz4 being used
  12 # and OpenSSL having version 1.1.1+ and generally does not offer the same
  13 # configurability like autoconf
  14
  15 find_package(PkgConfig REQUIRED)
  16 include(CheckSymbolExists)
  17 include(CheckIncludeFiles)
  18 include(CheckCCompilerFlag)
  19 include(CheckLinkerFlag OPTIONAL)
  20 include(CheckTypeSize)
  21 include(CheckStructHasMember)
  22 include(CTest)
  23
  24 option(UNSUPPORTED_BUILDS "Allow unsupported builds" OFF)
  25
  26 if (NOT WIN32 AND NOT ${UNSUPPORTED_BUILDS})
  27     message(FATAL_ERROR "Note: on Unix platform the official and supported build method is using autoconfig. CMake based build should be only used for Windows and internal testing/development.")
  28 endif()
  29
  30 if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/config.h")
  31     message(FATAL_ERROR "The top level source directory has a config.h file. Note that you can't mix in-tree autoconfig builds with out-of-tree cmake builds.")
  32 endif ()
  33
  34 option(MBED "BUILD with mbed" OFF)
  35 option(WOLFSSL "BUILD with wolfSSL" OFF)
  36 option(ENABLE_LZ4 "BUILD with lz4" ON)
  37 option(ENABLE_LZO "BUILD with lzo" ON)
  38 option(ENABLE_PKCS11 "BUILD with pkcs11-helper" ON)
  39 option(USE_WERROR "Treat compiler warnings as errors (-Werror)" ON)
  40
  41 set(PLUGIN_DIR /usr/local/lib/openvpn/plugins CACHE FILEPATH "Location of the plugin directory")
  42
  43 # AddressSanitize - use CXX=clang++ CC=clang cmake -DCMAKE_BUILD_TYPE=asan to build with ASAN
  44 set(CMAKE_C_FLAGS_ASAN
  45     "-fsanitize=address,undefined -fno-sanitize-recover=all -fno-optimize-sibling-calls -fsanitize-address-use-after-scope -fno-omit-frame-pointer -g -O1"
  46     CACHE STRING "Flags used by the C compiler during AddressSanitizer builds."
  47     FORCE)
  48 set(CMAKE_CXX_FLAGS_ASAN
  49     "-fsanitize=address,undefined -fno-sanitize-recover=all -fno-optimize-sibling-calls -fsanitize-address-use-after-scope -fno-omit-frame-pointer -g -O1"
  50     CACHE STRING "Flags used by the C++ compiler during AddressSanitizer builds."
  51     FORCE)
  52
  53 if (MSVC)
  54     add_definitions(-D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_DEPRECATE -D_WINSOCK_DEPRECATED_NO_WARNINGS)
  55     if (USE_WERROR)
  56         add_compile_options(/WX)
  57     endif ()
  58     add_compile_options(
  59         /MP
  60         /W2
  61         /sdl
  62         /Qspectre
  63         /guard:cf
  64         /FC
  65         /ZH:SHA_256
  66         "$<$<CONFIG:Release>:/GL>"
  67         "$<$<CONFIG:Release>:/Oi>"
  68         "$<$<CONFIG:Release>:/Gy>"
  69         "$<$<CONFIG:Release>:/Zi>"
  70         )
  71     add_link_options(
  72         /Brepro
  73         "$<$<CONFIG:Release>:/LTCG:incremental>"
  74         "$<$<CONFIG:Release>:/DEBUG:FULL>"
  75         "$<$<CONFIG:Release>:/OPT:REF>"
  76         "$<$<CONFIG:Release>:/OPT:ICF>"
  77         )
  78     if (${CMAKE_GENERATOR_PLATFORM} STREQUAL "x64" OR ${CMAKE_GENERATOR_PLATFORM} STREQUAL "x86")
  79         add_link_options("$<$<CONFIG:Release>:/CETCOMPAT>")
  80     endif()
  81 else ()
  82     add_compile_options(-Wall -Wuninitialized)
  83     check_c_compiler_flag(-Wno-stringop-truncation NoStringOpTruncation)
  84
  85     if (${NoStringOpTruncation})
  86         add_compile_options(-Wno-stringop-truncation)
  87     endif()
  88     # We are not ready for this
  89     #add_compile_options(-Wconversion -Wno-sign-conversion -Wsign-compare)
  90     if (USE_WERROR)
  91         add_compile_options(-Werror)
  92     endif ()
  93 endif ()
  94
  95 find_program(PYTHON NAMES python3 python)
  96 execute_process(
  97     COMMAND ${PYTHON} ${CMAKE_CURRENT_SOURCE_DIR}/contrib/cmake/parse-version.m4.py ${CMAKE_CURRENT_SOURCE_DIR}/version.m4
  98     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  99     )
 100 include(${CMAKE_CURRENT_BINARY_DIR}/version.cmake)
 101
 102 set(OPENVPN_VERSION_MAJOR ${PRODUCT_VERSION_MAJOR})
 103 set(OPENVPN_VERSION_MINOR ${PRODUCT_VERSION_MINOR})
 104 set(OPENVPN_VERSION_PATCH ${PRODUCT_VERSION_PATCH})
 105 set(OPENVPN_VERSION_RESOURCE ${PRODUCT_VERSION_RESOURCE})
 106
 107 set(CMAKE_C_STANDARD 99)
 108
 109 # Set the various defines for config.h.cmake.in
 110 if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
 111     set(TARGET_LINUX YES)
 112     set(ENABLE_ASYNC_PUSH YES)
 113     set(ENABLE_LINUXDCO YES)
 114     set(ENABLE_SITNL YES)
 115     set(HAVE_DECL_SO_MARK YES)
 116     set(ENABLE_FEATURE_TUN_PERSIST 1)
 117     set(HAVE_LINUX_TYPES_H 1)
 118     set(ENABLE_DCO YES)
 119     set(HAVE_CMSGHDR YES)
 120 elseif (${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 121     set(TARGET_FREEBSD YES)
 122     set(ENABLE_DCO YES)
 123     link_libraries(-lnv)
 124 elseif (WIN32)
 125     set(ENABLE_DCO YES)
 126 elseif (APPLE)
 127     set(TARGET_DARWIN YES)
 128     set(HAVE_NET_IF_UTUN_H YES)
 129 endif ()
 130
 131 if (UNIX)
 132     set(PATH_SEPARATOR /)
 133     set(ENABLE_PORT_SHARE YES)
 134     set(HAVE_SA_FAMILY_T YES)
 135 elseif (WIN32)
 136     set(PATH_SEPARATOR \\\\)
 137     set(TARGET_WIN32 YES)
 138 endif ()
 139
 140 check_symbol_exists(chroot unistd.h HAVE_CHROOT)
 141 check_symbol_exists(chdir unistd.h HAVE_CHDIR)
 142 check_symbol_exists(dup unistd.h HAVE_DUP)
 143 check_symbol_exists(dup2 unistd.h HAVE_DUP2)
 144 check_symbol_exists(fork unistd.h HAVE_FORK)
 145 check_symbol_exists(execve unistd.h HAVE_EXECVE)
 146 check_symbol_exists(ftruncate unistd.h HAVE_FTRUNCATE)
 147 check_symbol_exists(setgid unistd.h HAVE_SETGID)
 148 check_symbol_exists(setuid unistd.h HAVE_SETUID)
 149 check_symbol_exists(setsid unistd.h HAVE_SETSID)
 150 check_symbol_exists(getpeereid unistd.h HAVE_GETPEEREID)
 151
 152 check_symbol_exists(epoll_create sys/epoll.h HAVE_EPOLL_CREATE)
 153
 154 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 155 check_symbol_exists(basename libgen.h HAVE_BASENAME)
 156 check_symbol_exists(chsize io.h HAVE_CHSIZE)
 157 check_symbol_exists(daemon "unistd.h;stdlib.h" HAVE_DAEMON)
 158 check_symbol_exists(dirname libgen.h HAVE_DIRNAME)
 159 check_symbol_exists(getrlimit sys/resource.h HAVE_GETRLIMIT)
 160 check_symbol_exists(mlockall sys/mman.h HAVE_MLOCKALL)
 161
 162 check_symbol_exists(sendmsg sys/socket.h HAVE_SENDMSG)
 163 check_symbol_exists(recvmsg sys/socket.h HAVE_RECVMSG)
 164 check_symbol_exists(cmsghdr sys/socket.h HAVE_CMSGHDR)
 165 check_symbol_exists(openlog syslog.h HAVE_OPENLOG)
 166 check_symbol_exists(syslog syslog.h HAVE_SYSLOG)
 167 check_symbol_exists(getgrnam grp.h HAVE_GETGRNAM)
 168 check_symbol_exists(getpwnam pwd.h HAVE_GETPWNAM)
 169 check_symbol_exists(getsockname sys/socket.h HAVE_GETSOCKNAME)
 170
 171 # Some OS (e.g. FreeBSD) need some basic headers to allow
 172 # including network headers
 173 set(NETEXTRA sys/types.h)
 174 check_include_files("${NETEXTRA};netinet/in.h" HAVE_NETINET_IN_H)
 175
 176 if (HAVE_NETINET_IN_H)
 177     list(APPEND NETEXTRA netinet/in.h)
 178 endif ()
 179
 180 check_include_files("${NETEXTRA};netinet/in6.h" HAVE_NETINET_IN_H)
 181 check_include_files(linux/if_tun.h HAVE_LINUX_IF_TUN_H)
 182 check_include_files(linux/sockios.h HAVE_LINUX_SOCKIOS_H)
 183 check_include_files(dlfcn.h HAVE_DLFCN_H)
 184 check_include_files(fcntl.h HAVE_FCNTL_H)
 185 check_include_files(dmalloc.h HAVE_DMALLOC_H)
 186 check_include_files(err.h HAVE_ERR_H)
 187 check_include_files(sys/epoll.h HAVE_SYS_EPOLL_H)
 188 check_include_files(poll.h HAVE_POLL_H)
 189 check_include_files(sys/socket.h HAVE_SYS_SOCKET_H)
 190 check_include_files(sys/time.h HAVE_SYS_TIME_H)
 191 check_include_files(netdb.h HAVE_NETDB_H)
 192 check_include_files(unistd.h HAVE_UNISTD_H)
 193 check_include_files(sys/un.h HAVE_SYS_UN_H)
 194 check_include_files(libgen.h HAVE_LIBGEN_H)
 195 check_include_files(net/if.h HAVE_NET_IF_H)
 196 check_include_files("${NETEXTRA};netinet/ip.h" HAVE_NETINET_IP_H)
 197 check_include_files(arpa/inet.h HAVE_ARPA_INET_H)
 198 check_include_files(net/if_utun.h HAVE_NET_UTUN_H)
 199 check_include_files(sys/ioctl.h HAVE_SYS_IOCTL_H)
 200 check_include_files(sys/inotify.h HAVE_SYS_INOTIFY_H)
 201 check_include_files("${NETEXTRA};sys/uio.h" HAVE_SYS_UIO_H)
 202 check_include_files(syslog.h HAVE_SYSLOG_H)
 203 check_include_files(sys/wait.h HAVE_SYS_WAIT_H)
 204 check_include_files(grp.h HAVE_GRP_H)
 205 check_include_files(pwd.h HAVE_PWD_H)
 206 check_include_files(sys/mman.h HAVE_SYS_MMAN_H)
 207
 208
 209 check_include_files("${NETEXTRA};resolv.h" HAVE_RESOLV_H)
 210 check_include_files("${NETEXTRA};net/if_tun.h" HAVE_NET_IF_TUN_H)
 211
 212 set(CMAKE_EXTRA_INCLUDE_FILES netinet/ip.h)
 213 check_type_size("struct in_pktinfo" IN_PKTINFO)
 214 check_struct_has_member("struct in_pktinfo" ipi_spec_dst netinet/ip.h HAVE_IPI_SPEC_DST)
 215 check_type_size("struct msghdr" MSGHDR)
 216 set(CMAKE_EXTRA_INCLUDE_FILES)
 217
 218 find_program(IFCONFIG_PATH ifconfig)
 219 find_program(IPROUTE_PATH ip)
 220 find_program(ROUTE_PATH route)
 221
 222 if (${ENABLE_LZ4})
 223     pkg_search_module(liblz4 liblz4 REQUIRED IMPORTED_TARGET)
 224 endif ()
 225
 226 if (${ENABLE_LZO})
 227     pkg_search_module(lzo2 lzo2 REQUIRED IMPORTED_TARGET)
 228 endif ()
 229
 230 if (${ENABLE_PKCS11})
 231     pkg_search_module(pkcs11-helper libpkcs11-helper-1 REQUIRED IMPORTED_TARGET)
 232 endif ()
 233
 234 function(add_library_deps target)
 235     if (${MBED})
 236         target_link_libraries(${target} -lmbedtls -lmbedx509 -lmbedcrypto)
 237     elseif (${WOLFSSL})
 238         pkg_search_module(wolfssl wolfssl REQUIRED)
 239         target_link_libraries(${target} PUBLIC ${wolfssl_LINK_LIBRARIES})
 240         target_include_directories(${target} PRIVATE ${wolfssl_INCLUDE_DIRS}/wolfssl)
 241     else ()
 242         set(ENABLE_X509ALTUSERNAME YES)
 243
 244         find_package(OpenSSL REQUIRED)
 245         target_link_libraries(${target} PUBLIC OpenSSL::SSL OpenSSL::Crypto)
 246         if (WIN32)
 247             target_link_libraries(${target} PUBLIC
 248                 ws2_32.lib crypt32.lib fwpuclnt.lib iphlpapi.lib
 249                 wininet.lib setupapi.lib rpcrt4.lib wtsapi32.lib ncrypt.lib bcrypt.lib)
 250         endif ()
 251
 252     endif ()
 253
 254     # optional dependencies
 255     target_link_libraries(${target} PUBLIC
 256         $<TARGET_NAME_IF_EXISTS:PkgConfig::liblz4>
 257         $<TARGET_NAME_IF_EXISTS:PkgConfig::lzo2>
 258         $<TARGET_NAME_IF_EXISTS:PkgConfig::pkcs11-helper>
 259         )
 260
 261     if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
 262         pkg_search_module(libcapng REQUIRED libcap-ng IMPORTED_TARGET)
 263         pkg_search_module(libnl REQUIRED libnl-genl-3.0 IMPORTED_TARGET)
 264
 265         target_link_libraries(${target} PUBLIC PkgConfig::libcapng PkgConfig::libnl)
 266     endif ()
 267
 268 endfunction()
 269
 270 if (${MBED})
 271     set(ENABLE_CRYPTO_MBEDTLS YES)
 272 elseif (${WOLFSSL})
 273     set(ENABLE_CRYPTO_OPENSSL YES)
 274     set(ENABLE_CRYPTO_WOLFSSL YES)
 275     set(ENABLE_X509ALTUSERNAME YES)
 276 else ()
 277     set(ENABLE_CRYPTO_OPENSSL YES)
 278     set(ENABLE_X509ALTUSERNAME YES)
 279 endif ()
 280
 281 include_directories(${CMAKE_CURRENT_SOURCE_DIR} src/compat include)
 282
 283 add_custom_command(
 284     OUTPUT always_rebuild config-version.h
 285     COMMAND ${PYTHON} ${CMAKE_CURRENT_SOURCE_DIR}/contrib/cmake/git-version.py
 286     )
 287 set(HAVE_CONFIG_VERSION_H YES)
 288
 289 configure_file(config.h.cmake.in config.h)
 290 configure_file(include/openvpn-plugin.h.in openvpn-plugin.h)
 291 # TODO we should remove the need for this, and always include config.h
 292 add_definitions(-DHAVE_CONFIG_H)
 293
 294 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 295
 296 add_subdirectory(doc)
 297 add_subdirectory(src/openvpnmsica)
 298 add_subdirectory(src/openvpnserv)
 299 add_subdirectory(src/tapctl)
 300
 301 set(SOURCE_FILES
 302     ${CMAKE_CURRENT_BINARY_DIR}/config.h
 303     ${CMAKE_CURRENT_BINARY_DIR}/config-version.h
 304     ${CMAKE_CURRENT_BINARY_DIR}/openvpn-plugin.h
 305
 306     src/compat/compat-basename.c
 307     src/compat/compat-daemon.c
 308     src/compat/compat-dirname.c
 309     src/compat/compat-gettimeofday.c
 310     src/compat/compat-strsep.c
 311     src/compat/compat-versionhelpers.h
 312     src/openvpn/argv.c
 313     src/openvpn/argv.h
 314     src/openvpn/base64.c
 315     src/openvpn/base64.h
 316     src/openvpn/basic.h
 317     src/openvpn/block_dns.h
 318     src/openvpn/block_dns.c
 319     src/openvpn/buffer.c
 320     src/openvpn/buffer.h
 321     src/openvpn/circ_list.h
 322     src/openvpn/clinat.c
 323     src/openvpn/clinat.h
 324     src/openvpn/common.h
 325     src/openvpn/comp-lz4.c
 326     src/openvpn/comp-lz4.h
 327     src/openvpn/comp.c
 328     src/openvpn/comp.h
 329     src/openvpn/compstub.c
 330     src/openvpn/console.c
 331     src/openvpn/console_builtin.c
 332     src/openvpn/console.h
 333     src/openvpn/crypto.c
 334     src/openvpn/crypto.h
 335     src/openvpn/crypto_backend.h
 336     src/openvpn/crypto_openssl.c
 337     src/openvpn/crypto_openssl.h
 338     src/openvpn/crypto_mbedtls.c
 339     src/openvpn/crypto_mbedtls.h
 340     src/openvpn/cryptoapi.c
 341     src/openvpn/cryptoapi.h
 342     src/openvpn/dco.c
 343     src/openvpn/dco.h
 344     src/openvpn/dco_win.c
 345     src/openvpn/dco_win.h
 346     src/openvpn/dco_linux.c
 347     src/openvpn/dco_linux.h
 348     src/openvpn/dco_freebsd.c
 349     src/openvpn/dco_freebsd.h
 350     src/openvpn/dhcp.c
 351     src/openvpn/dhcp.h
 352     src/openvpn/dns.c
 353     src/openvpn/dns.h
 354     src/openvpn/errlevel.h
 355     src/openvpn/env_set.c
 356     src/openvpn/env_set.h
 357     src/openvpn/error.c
 358     src/openvpn/error.h
 359     src/openvpn/event.c
 360     src/openvpn/event.h
 361     src/openvpn/fdmisc.c
 362     src/openvpn/fdmisc.h
 363     src/openvpn/forward.c
 364     src/openvpn/forward.h
 365     src/openvpn/fragment.c
 366     src/openvpn/fragment.h
 367     src/openvpn/gremlin.c
 368     src/openvpn/gremlin.h
 369     src/openvpn/helper.c
 370     src/openvpn/helper.h
 371     src/openvpn/httpdigest.c
 372     src/openvpn/httpdigest.h
 373     src/openvpn/init.c
 374     src/openvpn/init.h
 375     src/openvpn/integer.h
 376     src/openvpn/interval.c
 377     src/openvpn/interval.h
 378     src/openvpn/list.c
 379     src/openvpn/list.h
 380     src/openvpn/lladdr.c
 381     src/openvpn/lladdr.h
 382     src/openvpn/lzo.c
 383     src/openvpn/lzo.h
 384     src/openvpn/manage.c
 385     src/openvpn/manage.h
 386     src/openvpn/mbuf.c
 387     src/openvpn/mbuf.h
 388     src/openvpn/memdbg.h
 389     src/openvpn/misc.c
 390     src/openvpn/misc.h
 391     src/openvpn/mroute.c
 392     src/openvpn/mroute.h
 393     src/openvpn/mss.c
 394     src/openvpn/mss.h
 395     src/openvpn/mstats.c
 396     src/openvpn/mstats.h
 397     src/openvpn/mtcp.c
 398     src/openvpn/mtcp.h
 399     src/openvpn/mtu.c
 400     src/openvpn/mtu.h
 401     src/openvpn/mudp.c
 402     src/openvpn/mudp.h
 403     src/openvpn/multi.c
 404     src/openvpn/multi.h
 405     src/openvpn/ntlm.c
 406     src/openvpn/ntlm.h
 407     src/openvpn/occ.c
 408     src/openvpn/occ.h
 409     src/openvpn/openvpn.c
 410     src/openvpn/openvpn.h
 411     src/openvpn/openvpn_win32_resources.rc
 412     src/openvpn/options.c
 413     src/openvpn/options.h
 414     src/openvpn/options_util.c
 415     src/openvpn/options_util.h
 416     src/openvpn/otime.c
 417     src/openvpn/otime.h
 418     src/openvpn/ovpn_dco_win.h
 419     src/openvpn/packet_id.c
 420     src/openvpn/packet_id.h
 421     src/openvpn/perf.c
 422     src/openvpn/perf.h
 423     src/openvpn/ping.c
 424     src/openvpn/ping.h
 425     src/openvpn/pkcs11.c
 426     src/openvpn/pkcs11.h
 427     src/openvpn/pkcs11_backend.h
 428     src/openvpn/pkcs11_openssl.c
 429     src/openvpn/pkcs11_mbedtls.c
 430     src/openvpn/platform.c
 431     src/openvpn/platform.h
 432     src/openvpn/plugin.c
 433     src/openvpn/plugin.h
 434     src/openvpn/pool.c
 435     src/openvpn/pool.h
 436     src/openvpn/proto.c
 437     src/openvpn/proto.h
 438     src/openvpn/proxy.c
 439     src/openvpn/proxy.h
 440     src/openvpn/ps.c
 441     src/openvpn/ps.h
 442     src/openvpn/push.c
 443     src/openvpn/push.h
 444     src/openvpn/pushlist.h
 445     src/openvpn/reflect_filter.c
 446     src/openvpn/reflect_filter.h
 447     src/openvpn/reliable.c
 448     src/openvpn/reliable.h
 449     src/openvpn/route.c
 450     src/openvpn/route.h
 451     src/openvpn/run_command.c
 452     src/openvpn/run_command.h
 453     src/openvpn/schedule.c
 454     src/openvpn/schedule.h
 455     src/openvpn/session_id.c
 456     src/openvpn/session_id.h
 457     src/openvpn/shaper.c
 458     src/openvpn/shaper.h
 459     src/openvpn/sig.c
 460     src/openvpn/sig.h
 461     src/openvpn/socket.c
 462     src/openvpn/socket.h
 463     src/openvpn/socks.c
 464     src/openvpn/socks.h
 465     src/openvpn/ssl.c
 466     src/openvpn/ssl.h
 467     src/openvpn/ssl_backend.h
 468     src/openvpn/ssl_common.h
 469     src/openvpn/ssl_openssl.c
 470     src/openvpn/ssl_openssl.h
 471     src/openvpn/ssl_mbedtls.c
 472     src/openvpn/ssl_mbedtls.h
 473     src/openvpn/ssl_verify.c
 474     src/openvpn/ssl_verify.h
 475     src/openvpn/ssl_verify_backend.h
 476     src/openvpn/ssl_verify_openssl.c
 477     src/openvpn/ssl_verify_openssl.h
 478     src/openvpn/ssl_verify_mbedtls.c
 479     src/openvpn/ssl_verify_mbedtls.h
 480     src/openvpn/status.c
 481     src/openvpn/status.h
 482     src/openvpn/syshead.h
 483     src/openvpn/tls_crypt.c
 484     src/openvpn/tun.c
 485     src/openvpn/tun.h
 486     src/openvpn/networking_sitnl.c
 487     src/openvpn/networking_freebsd.c
 488     src/openvpn/auth_token.c
 489     src/openvpn/auth_token.h
 490     src/openvpn/ssl_ncp.c
 491     src/openvpn/ssl_ncp.h
 492     src/openvpn/ssl_pkt.c
 493     src/openvpn/ssl_pkt.h
 494     src/openvpn/ssl_util.c
 495     src/openvpn/ssl_util.h
 496     src/openvpn/vlan.c
 497     src/openvpn/vlan.h
 498     src/openvpn/win32.c
 499     src/openvpn/win32-util.c
 500     src/openvpn/win32.h
 501     src/openvpn/win32-util.h
 502     src/openvpn/xkey_helper.c
 503     src/openvpn/xkey_provider.c
 504     )
 505
 506 add_executable(openvpn ${SOURCE_FILES})
 507
 508 add_library_deps(openvpn)
 509
 510 if (MINGW)
 511     target_compile_options(openvpn PRIVATE
 512         -DWIN32_LEAN_AND_MEAN
 513         -DNTDDI_VERSION=NTDDI_VISTA -D_WIN32_WINNT=_WIN32_WINNT_VISTA
 514         )
 515     target_compile_options(openvpn PRIVATE -municode -UUNICODE)
 516     target_link_options(openvpn PRIVATE -municode)
 517 endif()
 518
 519 if (MSVC)
 520     # we have our own manifest
 521     target_link_options(openvpn PRIVATE /MANIFEST:NO)
 522 endif()
 523
 524 if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
 525     target_link_libraries(openvpn PUBLIC -ldl)
 526 endif ()
 527
 528 if (NOT WIN32)
 529     target_compile_options(openvpn PRIVATE -DPLUGIN_LIBDIR=\"${PLUGIN_DIR}\")
 530
 531     find_library(resolv resolv)
 532     # some platform like BSDs already include resolver functionality in the libc and not have an extra resolv library
 533     if (${resolv} OR APPLE)
 534         target_link_libraries(openvpn PUBLIC -lresolv)
 535     endif ()
 536 endif ()
 537
 538
 539 if (BUILD_TESTING)
 540     find_package(cmocka CONFIG)
 541     if (TARGET cmocka::cmocka)
 542         set(CMOCKA_LIBRARIES cmocka::cmocka)
 543     else ()
 544         pkg_search_module(cmocka cmocka REQUIRED IMPORTED_TARGET)
 545         set(CMOCKA_LIBRARIES PkgConfig::cmocka)
 546     endif ()
 547
 548     set(unit_tests
 549         "test_auth_token"
 550         "test_buffer"
 551         "test_crypto"
 552         "test_misc"
 553         "test_ncp"
 554         "test_packet_id"
 555         "test_pkt"
 556         "test_provider"
 557         )
 558
 559     if (WIN32)
 560         list(APPEND unit_tests
 561             "test_cryptoapi"
 562             )
 563     endif ()
 564
 565     # MSVC and Apple's LLVM ld do not support --wrap
 566     # This test requires cmake >= 3.18, so check if check_linker_flag is
 567     # available
 568     if (COMMAND check_linker_flag)
 569         check_linker_flag(C -Wl,--wrap=parse_line LD_SUPPORTS_WRAP)
 570     endif()
 571
 572     if (${LD_SUPPORTS_WRAP})
 573         list(APPEND unit_tests
 574             "test_argv"
 575             "test_tls_crypt"
 576             )
 577     endif ()
 578
 579     # These tests work on only on Linux since they depend on special Linux features
 580     if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
 581         list(APPEND unit_tests
 582             "test_networking"
 583             )
 584     endif ()
 585
 586     if (NOT WIN32 AND ${ENABLE_PKCS11})
 587         set(_HAVE_SOFTHSM2 YES)
 588         find_program(P11TOOL p11tool)
 589         find_program(SOFTHSM2_UTIL softhsm2-util)
 590         find_library(SOFTHSM2_MODULE softhsm2 PATH_SUFFIXES softhsm)
 591
 592         if (P11TOOL STREQUAL "P11TOOL-NOTFOUND")
 593             message(STATUS "p11tool not found, pkcs11 UT disabled")
 594             set(_HAVE_SOFTHSM2 NO)
 595         elseif (SOFTHSM2_UTIL STREQUAL "SOFTHSM2_UTIL-NOTFOUND")
 596             message(STATUS "softhsm2-util not found, pkcs11 UT disabled")
 597             set(_HAVE_SOFTHSM2 NO)
 598         elseif (SOFTHSM2_MODULE STREQUAL "SOFTHSM2_MODULE-NOTFOUND")
 599             message(STATUS "softhsm2 module not found, pkcs11 UT disabled")
 600             set(_HAVE_SOFTHSM2 NO)
 601         endif ()
 602
 603         if (_HAVE_SOFTHSM2)
 604             message(VERBOSE "pkcs11 UT enabled")
 605             list(APPEND unit_tests
 606                 "test_pkcs11"
 607                 )
 608         endif ()
 609     endif ()
 610
 611     foreach (test_name ${unit_tests})
 612         # test_networking needs special environment
 613         if (NOT ${test_name} STREQUAL "test_networking")
 614             add_test(${test_name} ${test_name})
 615         endif ()
 616         add_executable(${test_name}
 617             tests/unit_tests/openvpn/${test_name}.c
 618             tests/unit_tests/openvpn/mock_msg.c
 619             tests/unit_tests/openvpn/mock_msg.h
 620             src/openvpn/platform.c
 621             src/openvpn/win32-util.c
 622             src/compat/compat-gettimeofday.c
 623             )
 624
 625         add_library_deps(${test_name})
 626         target_link_libraries(${test_name} PUBLIC ${CMOCKA_LIBRARIES})
 627
 628         target_include_directories(${test_name} PRIVATE src/openvpn)
 629
 630         if (NOT ${test_name} STREQUAL "test_buffer")
 631             target_sources(${test_name} PRIVATE
 632                 src/openvpn/buffer.c
 633                 )
 634         endif ()
 635
 636     endforeach()
 637
 638     target_sources(test_auth_token PRIVATE
 639         src/openvpn/base64.c
 640         src/openvpn/crypto_mbedtls.c
 641         src/openvpn/crypto_openssl.c
 642         src/openvpn/crypto.c
 643         src/openvpn/otime.c
 644         src/openvpn/packet_id.c
 645         )
 646
 647     target_sources(test_buffer PRIVATE
 648         tests/unit_tests/openvpn/mock_get_random.c
 649         )
 650
 651     target_sources(test_crypto PRIVATE
 652         src/openvpn/crypto_mbedtls.c
 653         src/openvpn/crypto_openssl.c
 654         src/openvpn/crypto.c
 655         src/openvpn/otime.c
 656         src/openvpn/packet_id.c
 657         src/openvpn/mtu.c
 658         src/openvpn/mss.c
 659         )
 660
 661     target_sources(test_misc PRIVATE
 662         tests/unit_tests/openvpn/mock_get_random.c
 663         src/openvpn/options_util.c
 664         src/openvpn/ssl_util.c
 665         )
 666
 667     target_sources(test_ncp PRIVATE
 668         src/openvpn/crypto_mbedtls.c
 669         src/openvpn/crypto_openssl.c
 670         src/openvpn/crypto.c
 671         src/openvpn/otime.c
 672         src/openvpn/packet_id.c
 673         src/openvpn/ssl_util.c
 674         src/compat/compat-strsep.c
 675         )
 676
 677     target_sources(test_packet_id PRIVATE
 678         tests/unit_tests/openvpn/mock_get_random.c
 679         src/openvpn/otime.c
 680         src/openvpn/packet_id.c
 681         src/openvpn/reliable.c
 682         src/openvpn/session_id.c
 683         )
 684
 685     target_sources(test_pkt PRIVATE
 686         tests/unit_tests/openvpn/mock_win32_execve.c
 687         src/openvpn/argv.c
 688         src/openvpn/base64.c
 689         src/openvpn/crypto_mbedtls.c
 690         src/openvpn/crypto_openssl.c
 691         src/openvpn/crypto.c
 692         src/openvpn/env_set.c
 693         src/openvpn/otime.c
 694         src/openvpn/packet_id.c
 695         src/openvpn/reliable.c
 696         src/openvpn/run_command.c
 697         src/openvpn/session_id.c
 698         src/openvpn/ssl_pkt.c
 699         src/openvpn/tls_crypt.c
 700         )
 701
 702     target_sources(test_provider PRIVATE
 703         tests/unit_tests/openvpn/mock_get_random.c
 704         src/openvpn/xkey_provider.c
 705         src/openvpn/xkey_helper.c
 706         src/openvpn/base64.c
 707         )
 708
 709     if (TARGET test_argv)
 710         target_link_options(test_argv PRIVATE -Wl,--wrap=parse_line)
 711         target_sources(test_argv PRIVATE
 712             tests/unit_tests/openvpn/mock_get_random.c
 713             src/openvpn/argv.c
 714             )
 715     endif ()
 716
 717     if (TARGET test_cryptoapi)
 718         target_sources(test_cryptoapi PRIVATE
 719             tests/unit_tests/openvpn/mock_get_random.c
 720             tests/unit_tests/openvpn/cert_data.h
 721             tests/unit_tests/openvpn/pkey_test_utils.c
 722             src/openvpn/xkey_provider.c
 723             src/openvpn/xkey_helper.c
 724             src/openvpn/base64.c
 725             )
 726     endif ()
 727
 728     if (TARGET test_networking)
 729         target_link_options(test_networking PRIVATE -Wl,--wrap=parse_line)
 730         target_compile_options(test_networking PRIVATE -UNDEBUG)
 731         target_sources(test_networking PRIVATE
 732             src/openvpn/networking_sitnl.c
 733             src/openvpn/crypto_mbedtls.c
 734             src/openvpn/crypto_openssl.c
 735             src/openvpn/crypto.c
 736             src/openvpn/otime.c
 737             src/openvpn/packet_id.c
 738             )
 739     endif ()
 740
 741     if (TARGET test_tls_crypt)
 742         target_link_options(test_tls_crypt PRIVATE -Wl,--wrap=parse_line)
 743         target_link_options(test_tls_crypt PRIVATE
 744             -Wl,--wrap=buffer_read_from_file
 745             -Wl,--wrap=buffer_write_file
 746             -Wl,--wrap=rand_bytes)
 747         target_sources(test_tls_crypt PRIVATE
 748             tests/unit_tests/openvpn/mock_win32_execve.c
 749             src/openvpn/argv.c
 750             src/openvpn/base64.c
 751             src/openvpn/crypto_mbedtls.c
 752             src/openvpn/crypto_openssl.c
 753             src/openvpn/crypto.c
 754             src/openvpn/env_set.c
 755             src/openvpn/otime.c
 756             src/openvpn/packet_id.c
 757             src/openvpn/run_command.c
 758             )
 759     endif ()
 760
 761     if (TARGET test_pkcs11)
 762         target_compile_options(test_pkcs11 PRIVATE
 763             -DP11TOOL_PATH=\"${P11TOOL}\"
 764             -DSOFTHSM2_MODULE_PATH=\"${SOFTHSM2_MODULE}\"
 765             -DSOFTHSM2_UTIL_PATH=\"${SOFTHSM2_UTIL}\"
 766             )
 767         target_sources(test_pkcs11 PRIVATE
 768             tests/unit_tests/openvpn/mock_get_random.c
 769             tests/unit_tests/openvpn/pkey_test_utils.c
 770             src/openvpn/argv.c
 771             src/openvpn/base64.c
 772             src/openvpn/env_set.c
 773             src/openvpn/otime.c
 774             src/openvpn/pkcs11.c
 775             src/openvpn/pkcs11_openssl.c
 776             src/openvpn/run_command.c
 777             src/openvpn/xkey_helper.c
 778             src/openvpn/xkey_provider.c
 779             )
 780     endif ()
 781
 782 endif (BUILD_TESTING)