configure.ac

   1 AC_PREREQ([2.61])
   2
   3 AC_INIT([pdns], m4_esyscmd([build-aux/gen-version]))
   4
   5 AC_CONFIG_SRCDIR([pdns/receiver.cc])
   6 AC_CONFIG_MACRO_DIR([m4])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_AUX_DIR([build-aux])
   9
  10 AC_SUBST([pdns_configure_args], ["$ac_configure_args"])
  11 AC_DEFINE_UNQUOTED([PDNS_CONFIG_ARGS],
  12   ["$pdns_configure_args"],
  13   [pdns configure arguments]
  14 )
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar -Wno-portability subdir-objects parallel-tests 1.11])
  17 AM_SILENT_RULES([yes])
  18
  19 AC_CANONICAL_HOST
  20 : ${CFLAGS="-Wall -g -O2"}
  21 : ${CXXFLAGS="-Wall -g -O2"}
  22
  23 AC_PROG_CC
  24 AM_PROG_CC_C_O
  25 PDNS_CHECK_BISON
  26 PDNS_CHECK_FLEX
  27 AC_PROG_INSTALL
  28 AC_PROG_MAKE_SET
  29
  30 AC_PROG_CXX
  31 AS_IF([test "x$CXX" = "xno" || test "x$CXX:x$GXX" = "xg++:x"],
  32   AC_MSG_ERROR([no C++ compiler found])
  33 )
  34
  35 AC_LANG([C++])
  36
  37 AC_DEFINE([_GNU_SOURCE], [1],
  38   [Define _GNU_SOURCE so that we get all necessary prototypes]
  39 )
  40
  41 # Warn when pkg.m4 is missing
  42 m4_pattern_forbid([^_?PKG_[A-Z_]+$], [*** pkg.m4 missing, please install pkg-config])
  43
  44 PDNS_CHECK_OS
  45
  46 PDNS_WITH_LUAJIT
  47 AS_IF([test "x$with_luajit" = "xno"], [
  48   PDNS_WITH_LUA
  49 ])
  50 PDNS_CHECK_LUA_HPP
  51
  52 AX_CXX_COMPILE_STDCXX_11
  53
  54 AC_MSG_CHECKING([whether we will enable compiler security checks])
  55 AC_ARG_ENABLE([hardening],
  56   [AS_HELP_STRING([--disable-hardening], [disable compiler security checks @<:@default=no@:>@])],
  57   [enable_hardening=$enableval],
  58   [enable_hardening=yes]
  59 )
  60 AC_MSG_RESULT([$enable_hardening])
  61
  62 AS_IF([test "x$enable_hardening" != "xno"], [
  63   AC_CC_PIE
  64   AC_CC_STACK_PROTECTOR
  65   AC_CC_PARAM_SSP_BUFFER_SIZE([4])
  66   AC_CC_D_FORTIFY_SOURCE
  67   AC_LD_RELRO
  68 ])
  69
  70 PDNS_CHECK_NETWORK_LIBS
  71
  72 LT_PREREQ([2.2.2])
  73 LT_INIT([disable-static dlopen])
  74
  75
  76 MC_TM_GMTOFF
  77
  78 # Define full_libdir to be the fully expanded (${exec_prefix}, etc.)
  79 # "system" library path.
  80 # We use this to search for other libraries.
  81 eval full_libdir="\"$libdir\""
  82
  83 # detect pkg-config explicitly
  84 PKG_PROG_PKG_CONFIG
  85
  86 AC_CHECK_HEADERS(
  87         [sys/mman.h],
  88         [AC_CHECK_FUNC(
  89                 [mmap],
  90                 [AC_DEFINE(HAVE_MMAP, [1], [Define to 1 if you have mmap])],
  91                 [have_mmap=no]
  92         )],
  93         [have_mmap=no]
  94 )
  95
  96 PDNS_ENABLE_BOTAN
  97 PDNS_CHECK_LIBSODIUM
  98 PDNS_CHECK_LIBDECAF
  99 PDNS_CHECK_LIBCRYPTO([
 100 ],[
 101    AC_MSG_ERROR([OpenSSL/libcrypto not found])
 102   ]
 103 )
 104 PDNS_CHECK_LIBCRYPTO_ECDSA
 105
 106 PDNS_CHECK_RAGEL([pdns/dnslabeltext.cc], [www.powerdns.com])
 107 PDNS_CHECK_CLOCK_GETTIME
 108
 109 BOOST_REQUIRE([1.35])
 110 # Boost accumulators, as used by dnsbulktest and dnstcpbench, need 1.48+
 111 # to be compatible with C++11
 112 AM_CONDITIONAL([HAVE_BOOST_GE_148], [test "$boost_major_version" -ge 148])
 113
 114 BOOST_PROGRAM_OPTIONS([mt])
 115 AS_IF([test "$boost_cv_lib_program_options" = "no"], [
 116   AC_MSG_ERROR([Boost Program Options library not found])
 117 ])
 118 PDNS_ENABLE_UNIT_TESTS
 119 PDNS_ENABLE_BACKEND_UNIT_TESTS
 120 PDNS_ENABLE_REPRODUCIBLE
 121
 122 PDNS_WITH_SQLITE3
 123
 124 PDNS_CHECK_VIRTUALENV
 125 PDNS_FROM_GIT
 126
 127 dnl Checks for library functions.
 128 AC_CHECK_FUNCS_ONCE([strcasestr localtime_r recvmmsg])
 129
 130 AM_CONDITIONAL([HAVE_RECVMMSG], [test "x$ac_cv_func_recvmmsg" = "xyes"])
 131
 132 AS_IF([test "x$lt_cv_dlopen" = "xno"],
 133   [AC_MSG_ERROR([Your system does not support dlopen])]
 134 )
 135
 136 AC_SUBST([LIBDL], [$lt_cv_dlopen_libs])
 137
 138 PDNS_ENABLE_VERBOSE_LOGGING
 139 PDNS_ENABLE_PKCS11
 140 PDNS_ENABLE_GSS_TSIG
 141
 142 AC_SUBST([socketdir])
 143 socketdir="/var/run"
 144 AC_ARG_WITH([socketdir],
 145   [AS_HELP_STRING([--with-socketdir], [where the controlsocket lives @<:@default=/var/run@:>@])],
 146   [socketdir="$withval"]
 147 )
 148
 149 modules="bind gmysql random"
 150 AC_ARG_WITH([modules],
 151   [AS_HELP_STRING([--with-modules], [which backends to compile with @<:@default=bind gmysql random@:>@])],
 152   [modules="$withval"]
 153 )
 154
 155 dynmodules="pipe"
 156 AC_ARG_WITH([dynmodules],
 157   [AS_HELP_STRING([--with-dynmodules], [which backends to build for dynamic loading @<:@default=pipe@:>@])],
 158   [dynmodules="$withval"]
 159 )
 160
 161 AC_SUBST([moduledirs])
 162 AC_SUBST([moduleobjects])
 163 AC_SUBST([modulelibs])
 164 AC_DEFINE_UNQUOTED([PDNS_MODULES], "$modules", [Built-in modules])
 165
 166 AS_IF([test x"$modules" = "xno"], [modules=""])
 167 AS_IF([test x"$dynmodules" = "xno"], [dynmodules=""])
 168
 169 for a in $modules $dynmodules; do
 170   case "$a" in
 171     oracle|goracle)
 172       PDNS_WITH_ORACLE
 173       needoracle=yes
 174       ;;
 175     godbc)
 176       PDNS_WITH_UNIXODBC
 177       ;;
 178     mydns|gmysql|pdns)
 179       PDNS_WITH_MYSQL
 180       ;;
 181     gpgsql)
 182       PDNS_WITH_POSTGRESQL
 183       ;;
 184     gsqlite3)
 185       needsqlite3=yes
 186       ;;
 187     ldap)
 188       PDNS_CHECK_LDAP
 189       needldap=yes
 190       ;;
 191     opendbx)
 192       PDNS_CHECK_OPENDBX
 193       ;;
 194     remote)
 195       AS_IF([test "x$enable_unit_tests" = "xyes"],
 196         [PDNS_CHECK_CURL_PROGRAM]
 197       )
 198       have_remotebackend=yes
 199       ;;
 200     tinydns)
 201       PDNS_CHECK_CDB
 202       ;;
 203     geoip)
 204       PDNS_CHECK_GEOIP
 205       ;;
 206     lua)
 207       AS_IF([test "x$with_lua" = "xno"],
 208         AC_MSG_ERROR([Lua backend needs lua, run ./configure --with-lua])
 209       )
 210       AS_IF([test "x$LUAPC" = "x" -a "x$LUAJITPC" = "x"],
 211         AC_MSG_ERROR([Lua backend needs lua but we cannot find it])
 212       )
 213       ;;
 214   esac
 215 done
 216
 217 PDNS_ENABLE_REMOTEBACKEND_ZEROMQ
 218
 219 AC_MSG_CHECKING([whether we will be building and installing the extra tools])
 220 AC_ARG_ENABLE([tools],
 221   [AS_HELP_STRING([--enable-tools], [if we should build and install the tools @<:@default=no@:>@])],
 222   [enable_tools=$enableval],
 223   [enable_tools=no]
 224 )
 225
 226 AC_MSG_RESULT([$enable_tools])
 227 AM_CONDITIONAL([TOOLS], [test "x$enable_tools" != "xno"])
 228
 229 PDNS_WITH_PROTOBUF
 230
 231
 232 AM_CONDITIONAL([ORACLE], [test "x$needoracle" = "xyes"])
 233
 234 AM_CONDITIONAL([LDAP], [test "x$needldap" = "xyes"])
 235
 236 PDNS_CHECK_SQLITE3
 237 AM_CONDITIONAL([SQLITE3], [test "x$needsqlite3" = "xyes"])
 238
 239 for a in $modules; do
 240   AC_MSG_CHECKING([whether we can build module "${a}"])
 241   if [[ -d "$srcdir/modules/${a}backend" ]]; then
 242     AC_MSG_RESULT([yes])
 243     moduledirs="$moduledirs ${a}backend"
 244
 245     for b in `cat $srcdir/modules/${a}backend/OBJECTFILES`; do
 246       moduleobjects="$moduleobjects ../modules/${a}backend/$b"
 247     done
 248     modulelibs="$modulelibs `cat $srcdir/modules/${a}backend/OBJECTLIBS`"
 249   else
 250     AC_MSG_RESULT([no])
 251     AC_MSG_ERROR([Do not know how to build module "$a", "$srcdir/modules/${a}backend" does not exist! Please review --with-modules parameter for supported values.])
 252   fi
 253 done
 254
 255 for a in $dynmodules; do
 256   AC_MSG_CHECKING([whether we can build dynamic module "${a}"])
 257   if [[ -d "$srcdir/modules/${a}backend" ]]; then
 258     AC_MSG_RESULT([yes])
 259     moduledirs="$moduledirs ${a}backend"
 260   else
 261     AC_MSG_RESULT([no])
 262     AC_MSG_ERROR([Do not know how to build module "$a", "$srcdir/modules/${a}backend" does not exist! Please review --with-dynmodules parameter for supported values.])
 263   fi
 264 done
 265
 266 AX_AVAILABLE_SYSTEMD
 267 AM_CONDITIONAL([HAVE_SYSTEMD], [ test x"$systemd" = "xy" ])
 268
 269 LDFLAGS="$RELRO_LDFLAGS $LDFLAGS"
 270
 271 CFLAGS="$PIE_CFLAGS $CFLAGS"
 272 CXXFLAGS="$PIE_CFLAGS $CXXFLAGS"
 273 PROGRAM_LDFLAGS="$PIE_LDFLAGS $PROGRAM_LDFLAGS"
 274 AC_SUBST([PROGRAM_LDFLAGS])
 275
 276 PDNS_ENABLE_COVERAGE
 277 PDNS_ENABLE_SANITIZERS
 278 PDNS_ENABLE_MALLOC_TRACE
 279
 280 AC_SUBST(LIBS)
 281
 282 AC_SUBST([AM_CPPFLAGS],
 283   ["AS_ESCAPE([-I$(top_builddir) -I$(top_srcdir)]) $THREADFLAGS $BOOST_CPPFLAGS"]
 284 )
 285
 286 AC_SUBST([YAHTTP_CFLAGS], ['-I$(top_srcdir)/ext/yahttp'])
 287 AC_SUBST([YAHTTP_LIBS], ['$(top_builddir)/ext/yahttp/yahttp/libyahttp.la'])
 288
 289 CXXFLAGS="$SANITIZER_FLAGS $CXXFLAGS"
 290
 291 AC_ARG_VAR(PACKAGEVERSION, [The version used in secpoll queries])
 292 AS_IF([test "x$PACKAGEVERSION" != "x"],
 293   [AC_DEFINE_UNQUOTED([PACKAGEVERSION], "$PACKAGEVERSION", [Set to the package version used for secpoll])]
 294 )
 295
 296 export moduledirs moduleobjects modulelibs
 297
 298 AC_CONFIG_FILES([
 299   Makefile
 300   modules/Makefile
 301   pdns/Makefile
 302   codedocs/Makefile
 303   docs/Makefile
 304   pdns/pdns.init
 305   ext/Makefile
 306   ext/yahttp/Makefile
 307   ext/yahttp/yahttp/Makefile
 308   ext/json11/Makefile
 309   modules/bindbackend/Makefile
 310   modules/geoipbackend/Makefile
 311   modules/gmysqlbackend/Makefile
 312   modules/godbcbackend/Makefile
 313   modules/goraclebackend/Makefile
 314   modules/gpgsqlbackend/Makefile
 315   modules/gsqlite3backend/Makefile
 316   modules/ldapbackend/Makefile
 317   modules/luabackend/Makefile
 318   modules/mydnsbackend/Makefile
 319   modules/opendbxbackend/Makefile
 320   modules/oraclebackend/Makefile
 321   modules/pipebackend/Makefile
 322   modules/randombackend/Makefile
 323   modules/remotebackend/Makefile
 324   modules/tinydnsbackend/Makefile
 325 ])
 326 AC_OUTPUT
 327
 328 AC_MSG_NOTICE([])
 329 AC_MSG_NOTICE([Configuration summary])
 330 AC_MSG_NOTICE([=====================])
 331 AC_MSG_NOTICE([])
 332 AC_MSG_NOTICE([Configured with: $pdns_configure_args])
 333 AC_MSG_NOTICE([])
 334 AC_MSG_NOTICE([CC: $CC])
 335 AC_MSG_NOTICE([CXX: $CXX])
 336 AC_MSG_NOTICE([LD: $LD])
 337 AC_MSG_NOTICE([CFLAGS: $CFLAGS])
 338 AC_MSG_NOTICE([CPPFLAGS: $CPPFLAGS])
 339 AC_MSG_NOTICE([CXXFLAGS: $CXXFLAGS])
 340 AC_MSG_NOTICE([LDFLAGS: $LDFLAGS])
 341 AC_MSG_NOTICE([LIBS: $LIBS])
 342 AC_MSG_NOTICE([BOOST_CPPFLAGS: $BOOST_CPPFLAGS])
 343 AC_MSG_NOTICE([])
 344 AC_MSG_NOTICE([Features enabled])
 345 AC_MSG_NOTICE([----------------])
 346 AC_MSG_NOTICE([Built-in modules: $modules])
 347 AC_MSG_NOTICE([Dynamic modules: $dynmodules])
 348 AC_MSG_NOTICE([])
 349 AS_IF([test "x$libcrypto_ecdsa" = "xyes"],
 350   [AC_MSG_NOTICE([OpenSSL ecdsa: yes])],
 351   [AC_MSG_NOTICE([OpenSSL ecdsa: no])]
 352 )
 353 AS_IF([test "x$LIBSODIUM_LIBS" != "x" || test "x$LIBDECAF_LIBS" != "x"],
 354   [AC_MSG_NOTICE([ed25519: yes])],
 355   [AC_MSG_NOTICE([ed25519: no])]
 356 )
 357 AS_IF([test "x$LIBDECAF_LIBS" != "x"],
 358   [AC_MSG_NOTICE([ed448: yes])],
 359   [AC_MSG_NOTICE([ed448: no])]
 360 )
 361 AS_IF([test "x$BOTAN_LIBS" != "x"],
 362   [AC_MSG_NOTICE([gost: yes])],
 363   [AC_MSG_NOTICE([gost: no])]
 364 )
 365 AS_IF([test "x$needsqlite3" != "x"],
 366   [AC_MSG_NOTICE([SQLite3: yes])],
 367   [AC_MSG_NOTICE([SQLite3: no])]
 368 )
 369 AS_IF([test "x$LUAPC" != "x"],
 370   [AC_MSG_NOTICE([Lua: $LUAPC])],
 371   [AS_IF([test "x$LUAJITPC" != "x"],
 372     [AC_MSG_NOTICE([LuaJit: $LUAJITPC])],
 373     [AC_MSG_NOTICE([Lua/LuaJit: no])])
 374 ])
 375 AS_IF([test "x$enable_experimental_pkcs11" = "xyes"],
 376   [AC_MSG_NOTICE([PKCS-11: yes])]
 377 )
 378 AS_IF([test "x$enable_experimental_gss_tsig" = "xyes"],
 379   [AC_MSG_NOTICE([GSS-TSIG: yes])]
 380 )
 381 AS_IF([test "x$systemd" != "xn"],
 382   [AC_MSG_NOTICE([systemd: yes])],
 383   [AC_MSG_NOTICE([systemd: no])]
 384 )
 385 AS_IF([test "x$enable_remotebackend_zeromq" != "xno"],
 386   [AC_MSG_NOTICE([ZeroMQ connector for remotebackend: yes])]
 387 )
 388 AC_MSG_NOTICE([])