m4/pdns_with_gnutls.m4

   1 AC_DEFUN([PDNS_WITH_GNUTLS], [
   2   AC_MSG_CHECKING([whether we will be linking in GnuTLS])
   3   HAVE_GNUTLS=0
   4   AC_ARG_WITH([gnutls],
   5     AS_HELP_STRING([--with-gnutls],[use GnuTLS @<:@default=auto@:>@]),
   6     [with_gnutls=$withval],
   7     [with_gnutls=auto],
   8   )
   9   AC_MSG_RESULT([$with_gnutls])
  10
  11   AS_IF([test "x$with_gnutls" != "xno"], [
  12     AS_IF([test "x$with_gnutls" = "xyes" -o "x$with_gnutls" = "xauto"], [
  13       # we require gnutls_certificate_set_x509_key_file, added in 3.1.11
  14       PKG_CHECK_MODULES([GNUTLS], [gnutls >= 3.1.11], [
  15         [HAVE_GNUTLS=1]
  16         AC_DEFINE([HAVE_GNUTLS], [1], [Define to 1 if you have GnuTLS])
  17         save_CFLAGS=$CFLAGS
  18         save_LIBS=$LIBS
  19         CFLAGS="$GNUTLS_CFLAGS $CFLAGS"
  20         LIBS="$GNUTLS_LIBS $LIBS"
  21         AC_CHECK_FUNCS([gnutls_memset gnutls_session_set_verify_cert gnutls_session_get_verify_cert_status gnutls_alpn_set_protocols])
  22         CFLAGS=$save_CFLAGS
  23         LIBS=$save_LIBS
  24
  25       ], [ : ])
  26     ])
  27   ])
  28   AM_CONDITIONAL([HAVE_GNUTLS], [test "x$GNUTLS_LIBS" != "x"])
  29   AS_IF([test "x$with_gnutls" = "xyes"], [
  30     AS_IF([test x"$GNUTLS_LIBS" = "x"], [
  31       AC_MSG_ERROR([GnuTLS requested but libraries were not found])
  32     ])
  33   ])
  34 ])