configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bugtracking.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 PACKAGE_VERSION=`sed 's/.*"\(.*\)".*/\1/' <$srcdir/version.h`
  11
  12 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_HOST
  17
  18 dnl define the directory for replacement function since AC_LIBOBJ does not
  19 dnl officially support subdirs and fails with automake
  20 AC_CONFIG_LIBOBJ_DIR([lib])
  21
  22 # We must decide this before testing the compiler.
  23
  24 # Please allow this to default to yes, so that your users have more
  25 # chance of getting a useful stack trace if problems occur.
  26
  27 AC_MSG_CHECKING([whether to include debugging symbols])
  28 AC_ARG_ENABLE(debug,
  29         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  30
  31 if test x"$enable_debug" = x"no"; then
  32     AC_MSG_RESULT(no)
  33     ac_cv_prog_cc_g=no
  34 else
  35     AC_MSG_RESULT([yes])
  36     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  37     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  38 fi
  39
  40 dnl Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CPP
  43 AC_PROG_CXX
  44 AC_PROG_AWK
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51 AC_PATH_PROG([PYTHON3], [python3])
  52
  53 AC_DEFINE([_GNU_SOURCE], 1,
  54           [Define _GNU_SOURCE so that we get all necessary prototypes])
  55
  56 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  57         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  58 fi
  59
  60 AC_ARG_ENABLE(profile,
  61         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  62 if test x"$enable_profile" = x"yes"; then
  63         CFLAGS="$CFLAGS -pg"
  64 fi
  65
  66 AC_MSG_CHECKING([if md2man can create man pages])
  67 if test x"$ac_cv_path_PYTHON3" = x; then
  68     AC_MSG_RESULT(no - python3 not found)
  69     md2man_works=no
  70 else
  71     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  72     if test $? = 0; then
  73         AC_MSG_RESULT(yes)
  74         md2man_works=yes
  75     else
  76         AC_MSG_RESULT(no)
  77         md2man_works=no
  78         echo "$md2man_out"
  79     fi
  80 fi
  81
  82 AC_MSG_CHECKING([if we require man-page building])
  83 AC_ARG_ENABLE([md2man],
  84         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  85 if test x"$enable_md2man" != x"no"; then
  86     if test -f "$srcdir/rsync.1"; then
  87         AC_MSG_RESULT(optional)
  88     else
  89         AC_MSG_RESULT(required)
  90         if test x"$md2man_works" = x"no"; then
  91             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  92 You can specify --disable-md2man if you want to skip building them.)
  93         fi
  94     fi
  95     MAKE_MAN=man
  96 else
  97     AC_MSG_RESULT(no)
  98     MAKE_MAN=''
  99 fi
 100
 101 # Specifically, this turns on panic_action handling.
 102 AC_ARG_ENABLE(maintainer-mode,
 103         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 104 if test x"$enable_maintainer_mode" = x"yes"; then
 105         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 106 fi
 107
 108 # This is needed for our included version of popt.  Kind of silly, but
 109 # I don't want our version too far out of sync.
 110 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 111
 112 # If GCC, turn on warnings.
 113 if test x"$GCC" = x"yes"; then
 114         CFLAGS="$CFLAGS -Wall -W"
 115 fi
 116
 117 AC_ARG_WITH(included-popt,
 118         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 119
 120 AC_ARG_WITH(included-zlib,
 121         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 122
 123 AC_ARG_WITH(protected-args,
 124         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 125 if test x"$with_protected_args" = x"yes"; then
 126         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 127 fi
 128
 129 AC_ARG_WITH(rsync-path,
 130         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 131         [ RSYNC_PATH="$with_rsync_path" ],
 132         [ RSYNC_PATH="rsync" ])
 133
 134 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 135
 136 AC_ARG_WITH(rsyncd-conf,
 137         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 138         [ if test ! -z "$with_rsyncd_conf" ; then
 139                 case $with_rsyncd_conf in
 140                         yes|no)
 141                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 142                                 ;;
 143                         /*)
 144                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 145                                 ;;
 146                         *)
 147                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 148                                 ;;
 149                 esac
 150         else
 151                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 152         fi ],
 153         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 154
 155 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 156
 157 AC_ARG_WITH(rsh,
 158         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 159
 160 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 161 if test x$HAVE_REMSH = x1; then
 162         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 163 fi
 164
 165 if test x"$with_rsh" != x; then
 166         RSYNC_RSH="$with_rsh"
 167 else
 168         RSYNC_RSH="ssh"
 169 fi
 170 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 171
 172 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 173 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 174 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175
 176 AC_ARG_WITH(nobody-group,
 177     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 178     [ NOBODY_GROUP="$with_nobody_group" ])
 179
 180 if test x"$with_nobody_group" = x; then
 181     AC_MSG_CHECKING([the group for user "nobody"])
 182     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 183         NOBODY_GROUP=nobody
 184     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 185         NOBODY_GROUP=nogroup
 186     else
 187         NOBODY_GROUP=nobody # test for others?
 188     fi
 189     AC_MSG_RESULT($NOBODY_GROUP)
 190 fi
 191
 192 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 193 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 194
 195 # SIMD optimizations
 196 SIMD=
 197
 198 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 199 AC_ARG_ENABLE(simd,
 200     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 201
 202 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 203 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 204
 205 if test x"$enable_simd" != x"no"; then
 206     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 207     if test x"$build_cpu" = x"x86_64"; then
 208         AC_LANG(C++)
 209         AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 210 #include <immintrin.h>
 211 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 212 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 213 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 214 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 215 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 216 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 217 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 218 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 219 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 220 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 221 {
 222     int i;
 223     for (i = 0; i < (len-32); i+=32) {
 224         __m128i in8_1, in8_2;
 225         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 226         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 227     }
 228 }
 229 ]], [[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],[CXX_OK=yes],[CXX_OK=no])
 230         AC_LANG(C)
 231         if test x"$CXX_OK" = x"yes"; then
 232             # AC_MSG_RESULT() is called below.
 233             SIMD="x86_64"
 234         elif test x"$enable_simd" = x"yes"; then
 235             AC_MSG_RESULT(error)
 236             AC_MSG_ERROR(The SIMD compilation test failed.
 237 Omit --enable-simd to continue without it.)
 238         fi
 239     elif test x"$enable_simd" = x"yes"; then
 240         AC_MSG_RESULT(unavailable)
 241         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 242 Omit --enable-simd to continue without it.)
 243     fi
 244 fi
 245
 246 if test x"$SIMD" != x""; then
 247     AC_MSG_RESULT([yes ($SIMD)])
 248     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 249     SIMD='$(SIMD_'"$SIMD)"
 250     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 251     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 252     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 253     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 254     case "$CXX_VERSION" in
 255     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 256     esac
 257 else
 258     AC_MSG_RESULT(no)
 259 fi
 260
 261 AC_SUBST(SIMD)
 262
 263 AC_MSG_CHECKING([if assembler accepts noexecstack])
 264 OLD_CFLAGS="$CFLAGS"
 265 CFLAGS="$CFLAGS -Wa,--noexecstack"
 266 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 267 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 268 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 269 CFLAGS="$OLD_CFLAGS"
 270 AC_SUBST(NOEXECSTACK)
 271
 272 ASM=
 273
 274 AC_MSG_CHECKING([whether to enable ASM optimizations])
 275 AC_ARG_ENABLE(asm,
 276     AS_HELP_STRING([--disable-asm],[disable ASM optimizations]))
 277
 278 if test x"$enable_asm" != x"no"; then
 279     if test x"$build_cpu" = x"x86_64"; then
 280         ASM="$build_cpu"
 281     elif test x"$enable_asm" = x"yes"; then
 282         AC_MSG_RESULT(unavailable)
 283         AC_MSG_ERROR(The ASM optimizations are currently x86_64 only.
 284 Omit --enable-asm to continue without it.)
 285     fi
 286 fi
 287
 288 if test x"$ASM" != x""; then
 289     AC_MSG_RESULT([yes ($ASM)])
 290     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 291     ASM='$(ASM_'"$ASM)"
 292 else
 293     AC_MSG_RESULT(no)
 294 fi
 295
 296 AC_SUBST(ASM)
 297
 298 # arrgh. libc in some old debian version screwed up the largefile
 299 # stuff, getting byte range locking wrong
 300 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 301 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 302 #define _FILE_OFFSET_BITS 64
 303 #include <stdio.h>
 304 #include <fcntl.h>
 305 #include <sys/types.h>
 306 #include <sys/wait.h>
 307 #if HAVE_UNISTD_H
 308 #include <unistd.h>
 309 #endif
 310
 311 int main(void)
 312 {
 313         struct flock lock;
 314         int status;
 315         char tpl[32] = "/tmp/locktest.XXXXXX";
 316         int fd = mkstemp(tpl);
 317         if (fd < 0) {
 318                 strcpy(tpl, "conftest.dat");
 319                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 320         }
 321
 322         lock.l_type = F_WRLCK;
 323         lock.l_whence = SEEK_SET;
 324         lock.l_start = 0;
 325         lock.l_len = 1;
 326         lock.l_pid = 0;
 327         fcntl(fd,F_SETLK,&lock);
 328         if (fork() == 0) {
 329                 lock.l_start = 1;
 330                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 331         }
 332         wait(&status);
 333         unlink(tpl);
 334         return WEXITSTATUS(status);
 335 }
 336 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 337 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 338    AC_SYS_LARGEFILE
 339 fi
 340
 341 ipv6type=unknown
 342 ipv6lib=none
 343 ipv6trylibc=yes
 344
 345 AC_ARG_ENABLE(ipv6,
 346         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 347 if test x"$enable_ipv6" != x"no"; then
 348         AC_MSG_CHECKING([ipv6 stack type])
 349         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin TANDEM; do
 350                 case $i in
 351                 inria)
 352                         # http://www.kame.net/
 353                         AC_EGREP_CPP(yes, [
 354 #include <netinet/in.h>
 355 #ifdef IPV6_INRIA_VERSION
 356 yes
 357 #endif],
 358                                 [ipv6type=$i;
 359                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 360                                 ])
 361                         ;;
 362                 kame)
 363                         # http://www.kame.net/
 364                         AC_EGREP_CPP(yes, [
 365 #include <netinet/in.h>
 366 #ifdef __KAME__
 367 yes
 368 #endif],
 369                                 [ipv6type=$i;
 370                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 371                         ;;
 372                 linux-glibc)
 373                         # http://www.v6.linux.or.jp/
 374                         AC_EGREP_CPP(yes, [
 375 #include <features.h>
 376 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 377 yes
 378 #endif],
 379                                 [ipv6type=$i;
 380 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 381                         ;;
 382                 linux-inet6)
 383                         # http://www.v6.linux.or.jp/
 384                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 385                                 ipv6type=$i
 386                                 ipv6lib=inet6
 387                                 ipv6libdir=/usr/inet6/lib
 388                                 ipv6trylibc=yes;
 389                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 390                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 391                         fi
 392                         ;;
 393                 solaris)
 394                         # http://www.sun.com
 395                         AC_EGREP_CPP(yes, [
 396 #include <netinet/ip6.h>
 397 #ifdef __sun
 398 yes
 399 #endif],
 400                                 [ipv6type=$i;
 401                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 402                         ;;
 403                 toshiba)
 404                         AC_EGREP_CPP(yes, [
 405 #include <sys/param.h>
 406 #ifdef _TOSHIBA_INET6
 407 yes
 408 #endif],
 409                                 [ipv6type=$i;
 410                                 ipv6lib=inet6;
 411                                 ipv6libdir=/usr/local/v6/lib;
 412                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 413                         ;;
 414                 v6d)
 415                         AC_EGREP_CPP(yes, [
 416 #include </usr/local/v6/include/sys/v6config.h>
 417 #ifdef __V6D__
 418 yes
 419 #endif],
 420                                 [ipv6type=$i;
 421                                 ipv6lib=v6;
 422                                 ipv6libdir=/usr/local/v6/lib;
 423                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 424                         ;;
 425                 zeta)
 426                         AC_EGREP_CPP(yes, [
 427 #include <sys/param.h>
 428 #ifdef _ZETA_MINAMI_INET6
 429 yes
 430 #endif],
 431                                 [ipv6type=$i;
 432                                 ipv6lib=inet6;
 433                                 ipv6libdir=/usr/local/v6/lib;
 434                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 435                         ;;
 436                 cygwin)
 437                         AC_EGREP_CPP(yes, [
 438 #include <netinet/in.h>
 439 #ifdef _CYGWIN_IN6_H
 440 yes
 441 #endif],
 442                                 [ipv6type=$i;
 443                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 444                         ;;
 445                 TANDEM)
 446                         AC_EGREP_CPP(yes, [
 447 #include <netinet/ip6.h>
 448 #ifdef __TANDEM
 449 yes
 450 #endif],
 451                                 [ipv6type=$i;
 452                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 453                         ;;
 454                 esac
 455                 if test "$ipv6type" != "unknown"; then
 456                         break
 457                 fi
 458         done
 459         AC_MSG_RESULT($ipv6type)
 460
 461         AC_SEARCH_LIBS(getaddrinfo, inet6)
 462 fi
 463
 464 dnl Do you want to disable use of locale functions
 465 AC_ARG_ENABLE([locale],
 466         AS_HELP_STRING([--disable-locale],[disable locale features]))
 467 AH_TEMPLATE([CONFIG_LOCALE],
 468 [Undefine if you do not want locale features.  By default this is defined.])
 469 if test x"$enable_locale" != x"no"; then
 470         AC_DEFINE(CONFIG_LOCALE)
 471 fi
 472
 473 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 474 case $host_os in
 475         *cygwin* ) AC_MSG_RESULT(yes)
 476                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 477                             [Define to 1 if sockets need to be shutdown])
 478                    ;;
 479                * ) AC_MSG_RESULT(no);;
 480 esac
 481
 482 AC_C_BIGENDIAN
 483 AC_HEADER_DIRENT
 484 AC_HEADER_TIME
 485 AC_HEADER_SYS_WAIT
 486 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 487     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 488     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 489     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 490     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 491     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
 492     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 493     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h)
 494 AC_HEADER_MAJOR_FIXED
 495
 496 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 497 AC_ARG_ENABLE([openssl],
 498         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 499 AH_TEMPLATE([USE_OPENSSL],
 500 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 501 if test x"$enable_openssl" != x"no"; then
 502     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 503       AC_MSG_RESULT(yes)
 504       AC_SEARCH_LIBS(MD5_Init, crypto,
 505           [AC_DEFINE(USE_OPENSSL)],
 506           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 507 Use --disable-openssl to continue without openssl crypto lib support.)])
 508     else
 509         AC_MSG_RESULT(no)
 510         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 511 Use --disable-openssl to continue without it.)
 512     fi
 513 else
 514     AC_MSG_RESULT(no)
 515 fi
 516
 517 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 518 AC_ARG_ENABLE([xxhash],
 519         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 520 AH_TEMPLATE([SUPPORT_XXHASH],
 521 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 522 if test x"$enable_xxhash" != x"no"; then
 523     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 524         AC_MSG_RESULT(yes)
 525         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 526             [AC_DEFINE(SUPPORT_XXHASH)],
 527             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 528 Use --disable-xxhash to continue without xxhash checksums.)])
 529     else
 530         AC_MSG_RESULT(no)
 531         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 532 Use --disable-xxhash to continue without it.)
 533     fi
 534 else
 535     AC_MSG_RESULT(no)
 536 fi
 537
 538 AC_MSG_CHECKING([whether to enable zstd compression])
 539 AC_ARG_ENABLE([zstd],
 540         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 541 AH_TEMPLATE([SUPPORT_ZSTD],
 542 [Undefine if you do not want zstd compression.  By default this is defined.])
 543 if test x"$enable_zstd" != x"no"; then
 544     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 545         AC_MSG_RESULT(yes)
 546         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 547             [AC_DEFINE(SUPPORT_ZSTD)],
 548             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 549 Use --disable-zstd to continue without zstd compression.)])
 550     else
 551         AC_MSG_RESULT(no)
 552         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 553 Use --disable-zstd to continue without it.)
 554     fi
 555 else
 556     AC_MSG_RESULT(no)
 557 fi
 558
 559 AC_MSG_CHECKING([whether to enable LZ4 compression])
 560 AC_ARG_ENABLE([lz4],
 561         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 562 AH_TEMPLATE([SUPPORT_LZ4],
 563 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 564 if test x"$enable_lz4" != x"no"; then
 565     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 566         AC_MSG_RESULT(yes)
 567         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 568             [AC_DEFINE(SUPPORT_LZ4)],
 569             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 570 Use --disable-lz4 to continue without lz4 compression.)])
 571     else
 572         AC_MSG_RESULT(no)
 573         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 574 Use --disable-lz4 to continue without it.)
 575     fi
 576 else
 577     AC_MSG_RESULT(no)
 578 fi
 579
 580 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 581 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 582 #include <sys/types.h>
 583 #ifdef MAJOR_IN_MKDEV
 584 #include <sys/mkdev.h>
 585 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 586 #  define makedev mkdev
 587 # endif
 588 #elif defined MAJOR_IN_SYSMACROS
 589 #include <sys/sysmacros.h>
 590 #endif
 591
 592 int main(void)
 593 {
 594         dev_t dev = makedev(0, 5, 7);
 595         if (major(dev) != 5 || minor(dev) != 7)
 596                 return 1;
 597         return 0;
 598 }
 599 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 600 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 601    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 602 fi
 603
 604 AC_CHECK_SIZEOF(int)
 605 AC_CHECK_SIZEOF(long)
 606 AC_CHECK_SIZEOF(long long)
 607 AC_CHECK_SIZEOF(short)
 608 AC_CHECK_SIZEOF(int16_t)
 609 AC_CHECK_SIZEOF(uint16_t)
 610 AC_CHECK_SIZEOF(int32_t)
 611 AC_CHECK_SIZEOF(uint32_t)
 612 AC_CHECK_SIZEOF(int64_t)
 613 AC_CHECK_SIZEOF(off_t)
 614 AC_CHECK_SIZEOF(off64_t)
 615 AC_CHECK_SIZEOF(time_t)
 616 AC_CHECK_SIZEOF(char*)
 617
 618 AC_C_INLINE
 619
 620 AC_TYPE_LONG_DOUBLE_WIDER
 621 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 622 if test $ac_cv_c_long_double = yes; then
 623   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 624 fi
 625
 626 AC_TYPE_UID_T
 627 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 628 AC_TYPE_GETGROUPS
 629 AC_CHECK_MEMBERS([struct stat.st_rdev,
 630                   struct stat.st_mtimensec,
 631                   struct stat.st_mtimespec.tv_nsec,
 632                   struct stat.st_mtim.tv_nsec],,,[
 633 #ifdef HAVE_SYS_TYPES_H
 634 #include <sys/types.h>
 635 #endif
 636 #ifdef HAVE_SYS_STAT_H
 637 #include <sys/stat.h>
 638 #endif
 639 #ifdef HAVE_UNISTD_H
 640 #include <unistd.h>
 641 #endif])
 642
 643 TYPE_SOCKLEN_T
 644
 645 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 646     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 647 if test x"$rsync_cv_errno" = x"yes"; then
 648    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 649 fi
 650
 651 # The following test taken from the cvs sources
 652 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 653 # These need checks to be before checks for any other functions that
 654 #    might be in the same libraries.
 655 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 656 # libsocket.so which has a bad implementation of gethostbyname (it
 657 # only looks in /etc/hosts), so we only look for -lsocket if we need
 658 # it.
 659 AC_CHECK_FUNCS(connect)
 660 if test x"$ac_cv_func_connect" = x"no"; then
 661     case "$LIBS" in
 662     *-lnsl*) ;;
 663     *) AC_CHECK_LIB(nsl_s, printf) ;;
 664     esac
 665     case "$LIBS" in
 666     *-lnsl*) ;;
 667     *) AC_CHECK_LIB(nsl, printf) ;;
 668     esac
 669     case "$LIBS" in
 670     *-lsocket*) ;;
 671     *) AC_CHECK_LIB(socket, connect) ;;
 672     esac
 673     case "$LIBS" in
 674     *-linet*) ;;
 675     *) AC_CHECK_LIB(inet, connect) ;;
 676     esac
 677     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 678     dnl has been cached.
 679     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 680        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 681         # ac_cv_func_connect=yes
 682         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 683         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 684     fi
 685 fi
 686
 687 AC_SEARCH_LIBS(inet_ntop, resolv)
 688
 689 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 690 # accept either iconv_open or libiconv_open, since some include files map
 691 # the former to the latter.
 692 AC_SEARCH_LIBS(iconv_open, iconv)
 693 AC_SEARCH_LIBS(libiconv_open, iconv)
 694
 695 AC_MSG_CHECKING([for iconv declaration])
 696 AC_CACHE_VAL(am_cv_proto_iconv, [
 697     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 698 #include <stdlib.h>
 699 #include <iconv.h>
 700 extern
 701 #ifdef __cplusplus
 702 "C"
 703 #endif
 704 #if defined(__STDC__) || defined(__cplusplus)
 705 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 706 #else
 707 size_t iconv();
 708 #endif
 709 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 710       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 711     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 712 AC_MSG_RESULT([$]{ac_t:-
 713          }[$]am_cv_proto_iconv)
 714 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 715                    [Define as const if the declaration of iconv() needs const.])
 716
 717 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 718
 719 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 720
 721 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 722 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 723 #include <sys/socket.h>])
 724
 725 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 726 #   builtin getaddrinfo if one of the defines don't exist
 727 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 728                rsync_cv_HAVE_GETADDR_DEFINES,[
 729                         AC_EGREP_CPP(yes, [
 730                         #include <sys/types.h>
 731                         #include <sys/socket.h>
 732                         #include <netdb.h>
 733                         #ifdef AI_PASSIVE
 734                         yes
 735                         #endif],
 736                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 737                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 738 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 739         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 740         # something else so we must include <netdb.h> to get the
 741         # redefinition.
 742         AC_CHECK_FUNCS(getaddrinfo, ,
 743                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 744                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 745                 #include <sys/socket.h>
 746                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 747                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 748                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 749                         AC_LIBOBJ([getaddrinfo])])])
 750     ],[AC_LIBOBJ([getaddrinfo])])
 751
 752 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 753                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 754                 [],
 755                 [
 756 #include <sys/types.h>
 757 #include <sys/socket.h>
 758 ])
 759
 760 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 761                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 762                 [],
 763                 [
 764 #include <sys/types.h>
 765 #include <sys/socket.h>
 766 #include <netinet/in.h>
 767 ])
 768
 769 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 770                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 771                 [],
 772                 [
 773 #include <sys/types.h>
 774 #include <sys/socket.h>
 775 #include <netinet/in.h>
 776 ])
 777
 778 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 779                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 780                 [],
 781                 [
 782 #include <sys/types.h>
 783 #include <sys/socket.h>
 784 #include <netinet/in.h>
 785 ])
 786
 787 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 788 #if HAVE_SYS_TYPES_H
 789 # include <sys/types.h>
 790 #endif
 791 #if HAVE_SYS_STAT_H
 792 # include <sys/stat.h>
 793 #endif
 794 #if STDC_HEADERS
 795 # include <stdlib.h>
 796 # include <stddef.h>
 797 #else
 798 # if HAVE_STDLIB_H
 799 #  include <stdlib.h>
 800 # endif
 801 #endif
 802 ])
 803
 804 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 805 #
 806 AC_CHECK_FUNCS(strcasecmp)
 807 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 808     AC_CHECK_LIB(resolv, strcasecmp)
 809 fi
 810
 811 AC_CHECK_FUNCS(aclsort)
 812 if test x"$ac_cv_func_aclsort" = x"no"; then
 813     AC_CHECK_LIB(sec, aclsort)
 814 fi
 815
 816 dnl At the moment we don't test for a broken memcmp(), because all we
 817 dnl need to do is test for equality, not comparison, and it seems that
 818 dnl every platform has a memcmp that can do at least that.
 819 dnl AC_FUNC_MEMCMP
 820
 821 AC_FUNC_UTIME_NULL
 822 AC_FUNC_ALLOCA
 823 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 824     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 825     chflags getattrlist mktime innetgr \
 826     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 827     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 828     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 829     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 830     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 831     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 832
 833 dnl cygwin iconv.h defines iconv_open as libiconv_open
 834 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 835     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 836 fi
 837
 838 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 839
 840 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 841 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 842 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 843 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 844     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 845 fi
 846
 847 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 848 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 849         #define _GNU_SOURCE 1
 850         #include <linux/falloc.h>
 851         #ifndef FALLOC_FL_PUNCH_HOLE
 852         #error FALLOC_FL_PUNCH_HOLE is missing
 853         #endif
 854     ]])], [
 855         AC_MSG_RESULT([yes])
 856         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 857     ], [
 858         AC_MSG_RESULT([no])
 859     ]
 860 )
 861
 862 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 863 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 864         #define _GNU_SOURCE 1
 865         #include <linux/falloc.h>
 866         #ifndef FALLOC_FL_ZERO_RANGE
 867         #error FALLOC_FL_ZERO_RANGE is missing
 868         #endif
 869     ]])], [
 870         AC_MSG_RESULT([yes])
 871         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 872     ], [
 873         AC_MSG_RESULT([no])
 874     ]
 875 )
 876
 877 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 878 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 879 #include <unistd.h>
 880 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 881 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 882     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 883 fi
 884
 885 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 886     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 887     case $host_os in
 888     *cygwin*)
 889         AC_MSG_RESULT(yes)
 890         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 891                   [Define if posix_fallocate is efficient (Cygwin)])
 892         ;;
 893     *)
 894         AC_MSG_RESULT(no)
 895         ;;
 896     esac
 897 fi
 898
 899 dnl End of preallocation stuff
 900
 901 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 902 if test $ac_cv_func_getpgrp = yes; then
 903     AC_FUNC_GETPGRP
 904 fi
 905
 906 AC_ARG_ENABLE(iconv-open,
 907     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 908     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 909
 910 if test x"$enable_iconv_open" != x"no"; then
 911     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 912 fi
 913
 914 AC_ARG_ENABLE(iconv,
 915     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 916     [], [enable_iconv=$enable_iconv_open])
 917 AH_TEMPLATE([ICONV_OPTION],
 918 [Define if you want the --iconv option.  Specifying a value will set the
 919 default iconv setting (a NULL means no --iconv processing by default).])
 920 if test x"$enable_iconv" != x"no"; then
 921         if test x"$enable_iconv" = x"yes"; then
 922                 AC_DEFINE(ICONV_OPTION, NULL)
 923         else
 924                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 925         fi
 926         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 927 fi
 928
 929 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 930   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 931 #if HAVE_UNISTD_H
 932 # include <unistd.h>
 933 #endif
 934 #include <stdlib.h>
 935 #include <errno.h>
 936 int main(void) {
 937         char const *dangling_symlink = "conftest.dangle";
 938         unlink(dangling_symlink);
 939         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 940         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 941         return 0;
 942     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 943 if test $rsync_cv_chown_modifies_symlink = yes; then
 944   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 945 fi
 946
 947 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 948   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 949 #if HAVE_UNISTD_H
 950 # include <unistd.h>
 951 #endif
 952 #include <stdlib.h>
 953 #include <errno.h>
 954 #define FILENAME "conftest.dangle"
 955 int main(void) {
 956         unlink(FILENAME);
 957         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 958         unlink(FILENAME "2");
 959         if (link(FILENAME, FILENAME "2") < 0) return 1;
 960         return 0;
 961     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 962 if test $rsync_cv_can_hardlink_symlink = yes; then
 963   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 964 fi
 965
 966 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 967   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 968 #if HAVE_UNISTD_H
 969 # include <unistd.h>
 970 #endif
 971 #ifdef HAVE_SYS_STAT_H
 972 #include <sys/stat.h>
 973 #endif
 974 #include <stdlib.h>
 975 #include <errno.h>
 976 #define FILENAME "conftest.fifi"
 977 int main(void) {
 978         unlink(FILENAME);
 979         if (mkfifo(FILENAME, 0777) < 0) abort();
 980         unlink(FILENAME "2");
 981         if (link(FILENAME, FILENAME "2") < 0) return 1;
 982         return 0;
 983     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 984 if test $rsync_cv_can_hardlink_special = yes; then
 985     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 986 fi
 987
 988 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 989 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 990 #include <sys/types.h>
 991 #include <sys/socket.h>
 992
 993 int main(void) {
 994        int fd[2];
 995        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 996 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 997 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 998     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 999 fi
1000
1001 AC_REPLACE_FUNCS([getpass])
1002
1003 if test x"$with_included_popt" != x"yes"; then
1004     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1005 fi
1006 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1007     # If the system has /usr/include/popt/popt.h, we enable the
1008     # included popt because an attempt to "#include <popt/popt.h>"
1009     # would use our included header file anyway (due to -I.), and
1010     # might conflict with the system popt.
1011     with_included_popt=yes
1012 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1013     with_included_popt=yes
1014 fi
1015
1016 AC_MSG_CHECKING([whether to use included libpopt])
1017 if test x"$with_included_popt" = x"yes"; then
1018     AC_MSG_RESULT($srcdir/popt)
1019     BUILD_POPT='$(popt_OBJS)'
1020     CFLAGS="-I$srcdir/popt $CFLAGS"
1021     if test x"$ALLOCA" != x
1022     then
1023         # this can be removed when/if we add an included alloca.c;
1024         #  see autoconf documentation on AC_FUNC_ALLOCA
1025         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1026     fi
1027 else
1028     AC_MSG_RESULT(no)
1029 fi
1030
1031 # We default to using our zlib unless --with-included-zlib=no is given.
1032 if test x"$with_included_zlib" != x"no"; then
1033     with_included_zlib=yes
1034 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1035     with_included_zlib=yes
1036 fi
1037 if test x"$with_included_zlib" != x"yes"; then
1038     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1039 fi
1040
1041 AC_MSG_CHECKING([whether to use included zlib])
1042 if test x"$with_included_zlib" = x"yes"; then
1043     AC_MSG_RESULT($srcdir/zlib)
1044     BUILD_ZLIB='$(zlib_OBJS)'
1045     CFLAGS="-I$srcdir/zlib $CFLAGS"
1046 else
1047     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1048     AC_MSG_RESULT(no)
1049 fi
1050
1051 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1052 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1053 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1054     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1055 fi
1056
1057 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1058 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1059 #include <dirent.h>
1060 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1061 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1062 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1063 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1064     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1065 fi
1066
1067 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1068 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1069 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1070 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1071     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1072 fi
1073
1074 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1075 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1076 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1077 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1078     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1079 fi
1080
1081 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1082 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1083 #include <sys/types.h>
1084 #include <stdarg.h>
1085 #include <stdio.h>
1086 #include <stdlib.h>
1087 #include <string.h>
1088 void foo(const char *format, ...) {
1089        va_list ap;
1090        int len;
1091        static char buf[] = "12345678901234567890";
1092
1093        va_start(ap, format);
1094        len = vsnprintf(0, 0, format, ap);
1095        va_end(ap);
1096        if (len != 5) exit(1);
1097
1098        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1099 }
1100 int main(void) { foo("hello"); return 0; }
1101 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1102 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1103     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1104 fi
1105
1106
1107 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1108 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1109 #include <sys/types.h>
1110 #include <sys/stat.h>
1111 #include <unistd.h>
1112 int main(void) {
1113   struct stat st;
1114   char tpl[20]="/tmp/test.XXXXXX";
1115   int fd = mkstemp(tpl);
1116   if (fd == -1) return 1;
1117   unlink(tpl);
1118   if (fstat(fd, &st) != 0) return 1;
1119   if ((st.st_mode & 0777) != 0600) return 1;
1120   return 0;
1121 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1122 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1123     case $host_os in
1124     hpux*)
1125         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1126         dnl so we noisily skip using it.  See HP change request JAGaf34426
1127         dnl for details. (sbonds)
1128         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1129         ;;
1130     *)
1131         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1132         ;;
1133     esac
1134 fi
1135
1136
1137 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1138 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1139 #include <stdio.h>
1140 #include <sys/stat.h>
1141 #include <errno.h>
1142 #if HAVE_UNISTD_H
1143 # include <unistd.h>
1144 #endif
1145 int main(void) { int rc, ec; char *fn = "fifo-test";
1146 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1147 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1148 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1149 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1150     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1151 fi
1152
1153 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1154 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1155 #include <stdio.h>
1156 #include <sys/stat.h>
1157 #include <errno.h>
1158 #if HAVE_UNISTD_H
1159 # include <unistd.h>
1160 #endif
1161 int main(void) { int rc, ec; char *fn = "sock-test";
1162 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1163 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1164 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1165 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1166     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1167 fi
1168
1169 #
1170 # The following test was mostly taken from the tcl/tk plus patches
1171 #
1172 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1173 rm -rf conftest*
1174 cat > conftest.$ac_ext <<EOF
1175 int main(void) { return 0; }
1176 EOF
1177 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1178 if test -f conftest..o; then
1179     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1180 else
1181     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1182 fi
1183 rm -rf conftest*
1184 ])
1185 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1186     OBJ_SAVE="#"
1187     OBJ_RESTORE="#"
1188     CC_SHOBJ_FLAG='-o $@'
1189 else
1190     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1191     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1192     CC_SHOBJ_FLAG=""
1193 fi
1194
1195 AC_SUBST(OBJ_SAVE)
1196 AC_SUBST(OBJ_RESTORE)
1197 AC_SUBST(CC_SHOBJ_FLAG)
1198 AC_SUBST(BUILD_POPT)
1199 AC_SUBST(BUILD_ZLIB)
1200 AC_SUBST(MAKE_MAN)
1201
1202 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1203 #################################################
1204 # check for ACL support
1205
1206 AC_MSG_CHECKING([whether to support ACLs])
1207 AC_ARG_ENABLE(acl-support,
1208         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1209
1210 if test x"$enable_acl_support" = x"no"; then
1211     AC_MSG_RESULT(no)
1212 else
1213     case "$host_os" in
1214     *sysv5*)
1215         AC_MSG_RESULT(Using UnixWare ACLs)
1216         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1217         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1218         ;;
1219     solaris*)
1220         AC_MSG_RESULT(Using solaris ACLs)
1221         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1222         AC_DEFINE(SUPPORT_ACLS, 1)
1223         ;;
1224     *irix*)
1225         AC_MSG_RESULT(Using IRIX ACLs)
1226         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1227         AC_DEFINE(SUPPORT_ACLS, 1)
1228         ;;
1229     *aix*)
1230         AC_MSG_RESULT(Using AIX ACLs)
1231         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1232         AC_DEFINE(SUPPORT_ACLS, 1)
1233         ;;
1234     *osf*)
1235         AC_MSG_RESULT(Using Tru64 ACLs)
1236         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1237         AC_DEFINE(SUPPORT_ACLS, 1)
1238         LIBS="$LIBS -lpacl"
1239         ;;
1240     darwin*)
1241         AC_MSG_RESULT(Using OS X ACLs)
1242         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1243         AC_DEFINE(SUPPORT_ACLS, 1)
1244         ;;
1245     *hpux*|*nsk*)
1246         AC_MSG_RESULT(Using HPUX ACLs)
1247         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1248         AC_DEFINE(SUPPORT_ACLS, 1)
1249         ;;
1250     *)
1251         AC_MSG_RESULT(running tests:)
1252         AC_CHECK_LIB(acl,acl_get_file)
1253         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1254             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1255 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1256         AC_MSG_CHECKING(ACL test results)
1257         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1258             AC_MSG_RESULT(Using posix ACLs)
1259             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1260             AC_DEFINE(SUPPORT_ACLS, 1)
1261             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1262                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1263 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1264             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1265                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1266             fi
1267         else
1268             if test x"$enable_acl_support" = x"yes"; then
1269                 AC_MSG_ERROR(Failed to find ACL support)
1270             else
1271                 AC_MSG_RESULT(No ACL support found)
1272             fi
1273         fi
1274         ;;
1275     esac
1276 fi
1277
1278 #################################################
1279 # check for extended attribute support
1280 AC_MSG_CHECKING(whether to support extended attributes)
1281 AC_ARG_ENABLE(xattr-support,
1282     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1283     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1284         *yes*) enable_xattr_support=maybe ;;
1285         *) enable_xattr_support=no ;;
1286         esac])
1287 AH_TEMPLATE([SUPPORT_XATTRS],
1288 [Define to 1 to add support for extended attributes])
1289 if test x"$enable_xattr_support" = x"no"; then
1290     AC_MSG_RESULT(no)
1291 else
1292     case "$host_os" in
1293     *linux*|*netbsd*|*cygwin*)
1294         AC_MSG_RESULT(Using Linux xattrs)
1295         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1296         AC_DEFINE(SUPPORT_XATTRS, 1)
1297         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1298         AC_CHECK_LIB(attr,getxattr)
1299         ;;
1300     darwin*)
1301         AC_MSG_RESULT(Using OS X xattrs)
1302         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1303         AC_DEFINE(SUPPORT_XATTRS, 1)
1304         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1305         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1306         ;;
1307     freebsd*)
1308         AC_MSG_RESULT(Using FreeBSD extattrs)
1309         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1310         AC_DEFINE(SUPPORT_XATTRS, 1)
1311         ;;
1312     solaris*)
1313         AC_MSG_RESULT(Using Solaris xattrs)
1314         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1315         AC_DEFINE(SUPPORT_XATTRS, 1)
1316         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1317         ;;
1318     *)
1319         if test x"$enable_xattr_support" = x"yes"; then
1320             AC_MSG_ERROR(Failed to find extended attribute support)
1321         else
1322             AC_MSG_RESULT(No extended attribute support found)
1323         fi
1324         ;;
1325     esac
1326 fi
1327
1328 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1329     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1330     OLD_CFLAGS="$CFLAGS"
1331     CFLAGS="$CFLAGS -Wno-unused-parameter"
1332     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1333     AC_MSG_RESULT([$rsync_warn_flag])
1334     if test x"$rsync_warn_flag" = x"no"; then
1335         CFLAGS="$OLD_CFLAGS"
1336     fi
1337 fi
1338
1339 case "$CC" in
1340 ' checker'*|checker*)
1341     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1342     ;;
1343 esac
1344
1345 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1346 AC_OUTPUT
1347
1348 AC_MSG_RESULT()
1349 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1350 AC_MSG_RESULT()