configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.1dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 204 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 205
 206 if test x"$enable_simd" != x"no"; then
 207     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 208     if test x"$build_cpu" = x"x86_64"; then
 209         AC_LANG(C++)
 210         AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 211 #include <immintrin.h>
 212 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 213 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 214 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 215 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 216 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 217 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 218 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 219 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 220 inline void more_testing(char* buf, int len)
 221 {
 222     int i;
 223     for (i = 0; i < (len-32); i+=32) {
 224         __m128i in8_1, in8_2;
 225         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 226         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 227     }
 228 }
 229 ]], [[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],[CXX_OK=yes],[CXX_OK=no])
 230         AC_LANG(C)
 231         if test x"$CXX_OK" = x"yes"; then
 232             # AC_MSG_RESULT() is called below.
 233             SIMD="x86_64"
 234         elif test x"$enable_simd" = x"yes"; then
 235             AC_MSG_RESULT(error)
 236             AC_MSG_ERROR(The SIMD compilation test failed.
 237 Omit --enable-simd to continue without it.)
 238         fi
 239     elif test x"$enable_simd" = x"yes"; then
 240         AC_MSG_RESULT(unavailable)
 241         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 242 Omit --enable-simd to continue without it.)
 243     fi
 244 fi
 245
 246 if test x"$SIMD" != x""; then
 247     AC_MSG_RESULT([yes ($SIMD)])
 248     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 249     SIMD='$(SIMD_'"$SIMD)"
 250     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 251     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 252 else
 253     AC_MSG_RESULT(no)
 254 fi
 255
 256 AC_SUBST(SIMD)
 257
 258 AC_MSG_CHECKING([if assembler accepts noexecstack])
 259 OLD_CFLAGS="$CFLAGS"
 260 CFLAGS="$CFLAGS -Wa,--noexecstack"
 261 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 262 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 263 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 264 CFLAGS="$OLD_CFLAGS"
 265 AC_SUBST(NOEXECSTACK)
 266
 267 ASM=
 268
 269 AC_MSG_CHECKING([whether to enable ASM optimizations])
 270 AC_ARG_ENABLE(asm,
 271     AS_HELP_STRING([--disable-asm],[disable ASM optimizations]))
 272
 273 if test x"$enable_asm" != x"no"; then
 274     if test x"$build_cpu" = x"x86_64"; then
 275         ASM="$build_cpu"
 276     elif test x"$enable_asm" = x"yes"; then
 277         AC_MSG_RESULT(unavailable)
 278         AC_MSG_ERROR(The ASM optimizations are currently x86_64 only.
 279 Omit --enable-asm to continue without it.)
 280     fi
 281 fi
 282
 283 if test x"$ASM" != x""; then
 284     AC_MSG_RESULT([yes ($ASM)])
 285     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 286     ASM='$(ASM_'"$ASM)"
 287 else
 288     AC_MSG_RESULT(no)
 289 fi
 290
 291 AC_SUBST(ASM)
 292
 293 # arrgh. libc in some old debian version screwed up the largefile
 294 # stuff, getting byte range locking wrong
 295 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 296 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 297 #define _FILE_OFFSET_BITS 64
 298 #include <stdio.h>
 299 #include <fcntl.h>
 300 #include <sys/types.h>
 301 #include <sys/wait.h>
 302 #if HAVE_UNISTD_H
 303 #include <unistd.h>
 304 #endif
 305
 306 int main(void)
 307 {
 308         struct flock lock;
 309         int status;
 310         char tpl[32] = "/tmp/locktest.XXXXXX";
 311         int fd = mkstemp(tpl);
 312         if (fd < 0) {
 313                 strcpy(tpl, "conftest.dat");
 314                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 315         }
 316
 317         lock.l_type = F_WRLCK;
 318         lock.l_whence = SEEK_SET;
 319         lock.l_start = 0;
 320         lock.l_len = 1;
 321         lock.l_pid = 0;
 322         fcntl(fd,F_SETLK,&lock);
 323         if (fork() == 0) {
 324                 lock.l_start = 1;
 325                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 326         }
 327         wait(&status);
 328         unlink(tpl);
 329         return WEXITSTATUS(status);
 330 }
 331 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 332 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 333    AC_SYS_LARGEFILE
 334 fi
 335
 336 ipv6type=unknown
 337 ipv6lib=none
 338 ipv6trylibc=yes
 339
 340 AC_ARG_ENABLE(ipv6,
 341         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 342 if test x"$enable_ipv6" != x"no"; then
 343         AC_MSG_CHECKING([ipv6 stack type])
 344         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 345                 case $i in
 346                 inria)
 347                         # http://www.kame.net/
 348                         AC_EGREP_CPP(yes, [
 349 #include <netinet/in.h>
 350 #ifdef IPV6_INRIA_VERSION
 351 yes
 352 #endif],
 353                                 [ipv6type=$i;
 354                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 355                                 ])
 356                         ;;
 357                 kame)
 358                         # http://www.kame.net/
 359                         AC_EGREP_CPP(yes, [
 360 #include <netinet/in.h>
 361 #ifdef __KAME__
 362 yes
 363 #endif],
 364                                 [ipv6type=$i;
 365                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 366                         ;;
 367                 linux-glibc)
 368                         # http://www.v6.linux.or.jp/
 369                         AC_EGREP_CPP(yes, [
 370 #include <features.h>
 371 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 372 yes
 373 #endif],
 374                                 [ipv6type=$i;
 375 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 376                         ;;
 377                 linux-inet6)
 378                         # http://www.v6.linux.or.jp/
 379                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 380                                 ipv6type=$i
 381                                 ipv6lib=inet6
 382                                 ipv6libdir=/usr/inet6/lib
 383                                 ipv6trylibc=yes;
 384                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 385                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 386                         fi
 387                         ;;
 388                 solaris)
 389                         # http://www.sun.com
 390                         AC_EGREP_CPP(yes, [
 391 #include <netinet/ip6.h>
 392 #ifdef __sun
 393 yes
 394 #endif],
 395                                 [ipv6type=$i;
 396                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 397                         ;;
 398                 toshiba)
 399                         AC_EGREP_CPP(yes, [
 400 #include <sys/param.h>
 401 #ifdef _TOSHIBA_INET6
 402 yes
 403 #endif],
 404                                 [ipv6type=$i;
 405                                 ipv6lib=inet6;
 406                                 ipv6libdir=/usr/local/v6/lib;
 407                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 408                         ;;
 409                 v6d)
 410                         AC_EGREP_CPP(yes, [
 411 #include </usr/local/v6/include/sys/v6config.h>
 412 #ifdef __V6D__
 413 yes
 414 #endif],
 415                                 [ipv6type=$i;
 416                                 ipv6lib=v6;
 417                                 ipv6libdir=/usr/local/v6/lib;
 418                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 419                         ;;
 420                 zeta)
 421                         AC_EGREP_CPP(yes, [
 422 #include <sys/param.h>
 423 #ifdef _ZETA_MINAMI_INET6
 424 yes
 425 #endif],
 426                                 [ipv6type=$i;
 427                                 ipv6lib=inet6;
 428                                 ipv6libdir=/usr/local/v6/lib;
 429                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 430                         ;;
 431                 cygwin)
 432                         AC_EGREP_CPP(yes, [
 433 #include <netinet/in.h>
 434 #ifdef _CYGWIN_IN6_H
 435 yes
 436 #endif],
 437                                 [ipv6type=$i;
 438                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 439                         ;;
 440                 esac
 441                 if test "$ipv6type" != "unknown"; then
 442                         break
 443                 fi
 444         done
 445         AC_MSG_RESULT($ipv6type)
 446
 447         AC_SEARCH_LIBS(getaddrinfo, inet6)
 448 fi
 449
 450 dnl Do you want to disable use of locale functions
 451 AC_ARG_ENABLE([locale],
 452         AS_HELP_STRING([--disable-locale],[disable locale features]))
 453 AH_TEMPLATE([CONFIG_LOCALE],
 454 [Undefine if you do not want locale features.  By default this is defined.])
 455 if test x"$enable_locale" != x"no"; then
 456         AC_DEFINE(CONFIG_LOCALE)
 457 fi
 458
 459 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 460 case $host_os in
 461         *cygwin* ) AC_MSG_RESULT(yes)
 462                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 463                             [Define to 1 if sockets need to be shutdown])
 464                    ;;
 465                * ) AC_MSG_RESULT(no);;
 466 esac
 467
 468 AC_C_BIGENDIAN
 469 AC_HEADER_DIRENT
 470 AC_HEADER_TIME
 471 AC_HEADER_SYS_WAIT
 472 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 473     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 474     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 475     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 476     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 477     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 478     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 479     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 480 AC_HEADER_MAJOR_FIXED
 481
 482 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 483 AC_ARG_ENABLE([openssl],
 484         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 485 AH_TEMPLATE([USE_OPENSSL],
 486 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 487 if test x"$enable_openssl" != x"no"; then
 488     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 489       AC_MSG_RESULT(yes)
 490       AC_SEARCH_LIBS(MD5_Init, crypto,
 491           [AC_DEFINE(USE_OPENSSL)],
 492           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 493 Use --disable-openssl to continue without openssl crypto lib support.)])
 494     else
 495         AC_MSG_RESULT(no)
 496         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 497 Use --disable-openssl to continue without it.)
 498     fi
 499 else
 500     AC_MSG_RESULT(no)
 501 fi
 502
 503 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 504 AC_ARG_ENABLE([xxhash],
 505         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 506 AH_TEMPLATE([SUPPORT_XXHASH],
 507 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 508 if test x"$enable_xxhash" != x"no"; then
 509     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 510         AC_MSG_RESULT(yes)
 511         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 512             [AC_DEFINE(SUPPORT_XXHASH)],
 513             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 514 Use --disable-xxhash to continue without xxhash checksums.)])
 515     else
 516         AC_MSG_RESULT(no)
 517         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 518 Use --disable-xxhash to continue without it.)
 519     fi
 520 else
 521     AC_MSG_RESULT(no)
 522 fi
 523
 524 AC_MSG_CHECKING([whether to enable zstd compression])
 525 AC_ARG_ENABLE([zstd],
 526         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 527 AH_TEMPLATE([SUPPORT_ZSTD],
 528 [Undefine if you do not want zstd compression.  By default this is defined.])
 529 if test x"$enable_zstd" != x"no"; then
 530     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 531         AC_MSG_RESULT(yes)
 532         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 533             [AC_DEFINE(SUPPORT_ZSTD)],
 534             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 535 Use --disable-zstd to continue without zstd compression.)])
 536     else
 537         AC_MSG_RESULT(no)
 538         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 539 Use --disable-zstd to continue without it.)
 540     fi
 541 else
 542     AC_MSG_RESULT(no)
 543 fi
 544
 545 AC_MSG_CHECKING([whether to enable LZ4 compression])
 546 AC_ARG_ENABLE([lz4],
 547         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 548 AH_TEMPLATE([SUPPORT_LZ4],
 549 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 550 if test x"$enable_lz4" != x"no"; then
 551     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 552         AC_MSG_RESULT(yes)
 553         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 554             [AC_DEFINE(SUPPORT_LZ4)],
 555             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 556 Use --disable-lz4 to continue without lz4 compression.)])
 557     else
 558         AC_MSG_RESULT(no)
 559         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 560 Use --disable-lz4 to continue without it.)
 561     fi
 562 else
 563     AC_MSG_RESULT(no)
 564 fi
 565
 566 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 567 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 568 #include <sys/types.h>
 569 #ifdef MAJOR_IN_MKDEV
 570 #include <sys/mkdev.h>
 571 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 572 #  define makedev mkdev
 573 # endif
 574 #elif defined MAJOR_IN_SYSMACROS
 575 #include <sys/sysmacros.h>
 576 #endif
 577
 578 int main(void)
 579 {
 580         dev_t dev = makedev(0, 5, 7);
 581         if (major(dev) != 5 || minor(dev) != 7)
 582                 return 1;
 583         return 0;
 584 }
 585 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 586 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 587    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 588 fi
 589
 590 AC_CHECK_SIZEOF(int)
 591 AC_CHECK_SIZEOF(long)
 592 AC_CHECK_SIZEOF(long long)
 593 AC_CHECK_SIZEOF(short)
 594 AC_CHECK_SIZEOF(int16_t)
 595 AC_CHECK_SIZEOF(uint16_t)
 596 AC_CHECK_SIZEOF(int32_t)
 597 AC_CHECK_SIZEOF(uint32_t)
 598 AC_CHECK_SIZEOF(int64_t)
 599 AC_CHECK_SIZEOF(off_t)
 600 AC_CHECK_SIZEOF(off64_t)
 601 AC_CHECK_SIZEOF(time_t)
 602 AC_CHECK_SIZEOF(char*)
 603
 604 AC_C_INLINE
 605
 606 AC_TYPE_LONG_DOUBLE_WIDER
 607 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 608 if test $ac_cv_c_long_double = yes; then
 609   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 610 fi
 611
 612 AC_TYPE_UID_T
 613 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 614 AC_TYPE_GETGROUPS
 615 AC_CHECK_MEMBERS([struct stat.st_rdev,
 616                   struct stat.st_mtimensec,
 617                   struct stat.st_mtimespec.tv_nsec,
 618                   struct stat.st_mtim.tv_nsec],,,[
 619 #ifdef HAVE_SYS_TYPES_H
 620 #include <sys/types.h>
 621 #endif
 622 #ifdef HAVE_SYS_STAT_H
 623 #include <sys/stat.h>
 624 #endif
 625 #ifdef HAVE_UNISTD_H
 626 #include <unistd.h>
 627 #endif])
 628
 629 TYPE_SOCKLEN_T
 630
 631 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 632     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 633 if test x"$rsync_cv_errno" = x"yes"; then
 634    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 635 fi
 636
 637 # The following test taken from the cvs sources
 638 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 639 # These need checks to be before checks for any other functions that
 640 #    might be in the same libraries.
 641 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 642 # libsocket.so which has a bad implementation of gethostbyname (it
 643 # only looks in /etc/hosts), so we only look for -lsocket if we need
 644 # it.
 645 AC_CHECK_FUNCS(connect)
 646 if test x"$ac_cv_func_connect" = x"no"; then
 647     case "$LIBS" in
 648     *-lnsl*) ;;
 649     *) AC_CHECK_LIB(nsl_s, printf) ;;
 650     esac
 651     case "$LIBS" in
 652     *-lnsl*) ;;
 653     *) AC_CHECK_LIB(nsl, printf) ;;
 654     esac
 655     case "$LIBS" in
 656     *-lsocket*) ;;
 657     *) AC_CHECK_LIB(socket, connect) ;;
 658     esac
 659     case "$LIBS" in
 660     *-linet*) ;;
 661     *) AC_CHECK_LIB(inet, connect) ;;
 662     esac
 663     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 664     dnl has been cached.
 665     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 666        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 667         # ac_cv_func_connect=yes
 668         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 669         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 670     fi
 671 fi
 672
 673 AC_SEARCH_LIBS(inet_ntop, resolv)
 674
 675 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 676 # accept either iconv_open or libiconv_open, since some include files map
 677 # the former to the latter.
 678 AC_SEARCH_LIBS(iconv_open, iconv)
 679 AC_SEARCH_LIBS(libiconv_open, iconv)
 680
 681 AC_MSG_CHECKING([for iconv declaration])
 682 AC_CACHE_VAL(am_cv_proto_iconv, [
 683     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 684 #include <stdlib.h>
 685 #include <iconv.h>
 686 extern
 687 #ifdef __cplusplus
 688 "C"
 689 #endif
 690 #if defined(__STDC__) || defined(__cplusplus)
 691 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 692 #else
 693 size_t iconv();
 694 #endif
 695 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 696       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 697     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 698 AC_MSG_RESULT([$]{ac_t:-
 699          }[$]am_cv_proto_iconv)
 700 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 701                    [Define as const if the declaration of iconv() needs const.])
 702
 703 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 704
 705 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 706
 707 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 708 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 709 #include <sys/socket.h>])
 710
 711 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 712 #   builtin getaddrinfo if one of the defines don't exist
 713 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 714                rsync_cv_HAVE_GETADDR_DEFINES,[
 715                         AC_EGREP_CPP(yes, [
 716                         #include <sys/types.h>
 717                         #include <sys/socket.h>
 718                         #include <netdb.h>
 719                         #ifdef AI_PASSIVE
 720                         yes
 721                         #endif],
 722                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 723                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 724 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 725         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 726         # something else so we must include <netdb.h> to get the
 727         # redefinition.
 728         AC_CHECK_FUNCS(getaddrinfo, ,
 729                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 730                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 731                 #include <sys/socket.h>
 732                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 733                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 734                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 735                         AC_LIBOBJ([getaddrinfo])])])
 736     ],[AC_LIBOBJ([getaddrinfo])])
 737
 738 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 739                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 740                 [],
 741                 [
 742 #include <sys/types.h>
 743 #include <sys/socket.h>
 744 ])
 745
 746 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 747                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 748                 [],
 749                 [
 750 #include <sys/types.h>
 751 #include <sys/socket.h>
 752 #include <netinet/in.h>
 753 ])
 754
 755 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 756                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 757                 [],
 758                 [
 759 #include <sys/types.h>
 760 #include <sys/socket.h>
 761 #include <netinet/in.h>
 762 ])
 763
 764 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 765                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 766                 [],
 767                 [
 768 #include <sys/types.h>
 769 #include <sys/socket.h>
 770 #include <netinet/in.h>
 771 ])
 772
 773 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 774 #if HAVE_SYS_TYPES_H
 775 # include <sys/types.h>
 776 #endif
 777 #if HAVE_SYS_STAT_H
 778 # include <sys/stat.h>
 779 #endif
 780 #if STDC_HEADERS
 781 # include <stdlib.h>
 782 # include <stddef.h>
 783 #else
 784 # if HAVE_STDLIB_H
 785 #  include <stdlib.h>
 786 # endif
 787 #endif
 788 ])
 789
 790 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 791 #
 792 AC_CHECK_FUNCS(strcasecmp)
 793 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 794     AC_CHECK_LIB(resolv, strcasecmp)
 795 fi
 796
 797 AC_CHECK_FUNCS(aclsort)
 798 if test x"$ac_cv_func_aclsort" = x"no"; then
 799     AC_CHECK_LIB(sec, aclsort)
 800 fi
 801
 802 dnl At the moment we don't test for a broken memcmp(), because all we
 803 dnl need to do is test for equality, not comparison, and it seems that
 804 dnl every platform has a memcmp that can do at least that.
 805 dnl AC_FUNC_MEMCMP
 806
 807 AC_FUNC_UTIME_NULL
 808 AC_FUNC_ALLOCA
 809 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 810     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 811     chflags getattrlist \
 812     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 813     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 814     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 815     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 816     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 817     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 818
 819 dnl cygwin iconv.h defines iconv_open as libiconv_open
 820 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 821     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 822 fi
 823
 824 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 825
 826 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 827 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 828 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 829 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 830     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 831 fi
 832
 833 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 834 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 835         #define _GNU_SOURCE 1
 836         #include <linux/falloc.h>
 837         #ifndef FALLOC_FL_PUNCH_HOLE
 838         #error FALLOC_FL_PUNCH_HOLE is missing
 839         #endif
 840     ]])], [
 841         AC_MSG_RESULT([yes])
 842         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 843     ], [
 844         AC_MSG_RESULT([no])
 845     ]
 846 )
 847
 848 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 849 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 850         #define _GNU_SOURCE 1
 851         #include <linux/falloc.h>
 852         #ifndef FALLOC_FL_ZERO_RANGE
 853         #error FALLOC_FL_ZERO_RANGE is missing
 854         #endif
 855     ]])], [
 856         AC_MSG_RESULT([yes])
 857         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 858     ], [
 859         AC_MSG_RESULT([no])
 860     ]
 861 )
 862
 863 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 864 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 865 #include <unistd.h>
 866 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 867 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 868     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 869 fi
 870
 871 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 872     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 873     case $host_os in
 874     *cygwin*)
 875         AC_MSG_RESULT(yes)
 876         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 877                   [Define if posix_fallocate is efficient (Cygwin)])
 878         ;;
 879     *)
 880         AC_MSG_RESULT(no)
 881         ;;
 882     esac
 883 fi
 884
 885 dnl End of preallocation stuff
 886
 887 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 888 if test $ac_cv_func_getpgrp = yes; then
 889     AC_FUNC_GETPGRP
 890 fi
 891
 892 AC_ARG_ENABLE(iconv-open,
 893     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 894     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 895
 896 if test x"$enable_iconv_open" != x"no"; then
 897     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 898 fi
 899
 900 AC_ARG_ENABLE(iconv,
 901     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 902     [], [enable_iconv=$enable_iconv_open])
 903 AH_TEMPLATE([ICONV_OPTION],
 904 [Define if you want the --iconv option.  Specifying a value will set the
 905 default iconv setting (a NULL means no --iconv processing by default).])
 906 if test x"$enable_iconv" != x"no"; then
 907         if test x"$enable_iconv" = x"yes"; then
 908                 AC_DEFINE(ICONV_OPTION, NULL)
 909         else
 910                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 911         fi
 912         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 913 fi
 914
 915 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 916   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 917 #if HAVE_UNISTD_H
 918 # include <unistd.h>
 919 #endif
 920 #include <stdlib.h>
 921 #include <errno.h>
 922 int main(void) {
 923         char const *dangling_symlink = "conftest.dangle";
 924         unlink(dangling_symlink);
 925         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 926         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 927         return 0;
 928     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 929 if test $rsync_cv_chown_modifies_symlink = yes; then
 930   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 931 fi
 932
 933 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 934   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 935 #if HAVE_UNISTD_H
 936 # include <unistd.h>
 937 #endif
 938 #include <stdlib.h>
 939 #include <errno.h>
 940 #define FILENAME "conftest.dangle"
 941 int main(void) {
 942         unlink(FILENAME);
 943         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 944         unlink(FILENAME "2");
 945         if (link(FILENAME, FILENAME "2") < 0) return 1;
 946         return 0;
 947     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 948 if test $rsync_cv_can_hardlink_symlink = yes; then
 949   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 950 fi
 951
 952 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 953   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 954 #if HAVE_UNISTD_H
 955 # include <unistd.h>
 956 #endif
 957 #ifdef HAVE_SYS_STAT_H
 958 #include <sys/stat.h>
 959 #endif
 960 #include <stdlib.h>
 961 #include <errno.h>
 962 #define FILENAME "conftest.fifi"
 963 int main(void) {
 964         unlink(FILENAME);
 965         if (mkfifo(FILENAME, 0777) < 0) abort();
 966         unlink(FILENAME "2");
 967         if (link(FILENAME, FILENAME "2") < 0) return 1;
 968         return 0;
 969     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 970 if test $rsync_cv_can_hardlink_special = yes; then
 971     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 972 fi
 973
 974 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 975 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 976 #include <sys/types.h>
 977 #include <sys/socket.h>
 978
 979 int main(void) {
 980        int fd[2];
 981        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 982 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 983 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 984     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 985 fi
 986
 987 AC_REPLACE_FUNCS([getpass])
 988
 989 if test x"$with_included_popt" != x"yes"; then
 990     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 991 fi
 992 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 993     # If the system has /usr/include/popt/popt.h, we enable the
 994     # included popt because an attempt to "#include <popt/popt.h>"
 995     # would use our included header file anyway (due to -I.), and
 996     # might conflict with the system popt.
 997     with_included_popt=yes
 998 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 999     with_included_popt=yes
1000 fi
1001
1002 AC_MSG_CHECKING([whether to use included libpopt])
1003 if test x"$with_included_popt" = x"yes"; then
1004     AC_MSG_RESULT($srcdir/popt)
1005     BUILD_POPT='$(popt_OBJS)'
1006     CFLAGS="-I$srcdir/popt $CFLAGS"
1007     if test x"$ALLOCA" != x
1008     then
1009         # this can be removed when/if we add an included alloca.c;
1010         #  see autoconf documentation on AC_FUNC_ALLOCA
1011         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1012     fi
1013 else
1014     AC_MSG_RESULT(no)
1015 fi
1016
1017 # We default to using our zlib unless --with-included-zlib=no is given.
1018 if test x"$with_included_zlib" != x"no"; then
1019     with_included_zlib=yes
1020 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1021     with_included_zlib=yes
1022 fi
1023 if test x"$with_included_zlib" != x"yes"; then
1024     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1025 fi
1026
1027 AC_MSG_CHECKING([whether to use included zlib])
1028 if test x"$with_included_zlib" = x"yes"; then
1029     AC_MSG_RESULT($srcdir/zlib)
1030     BUILD_ZLIB='$(zlib_OBJS)'
1031     CFLAGS="-I$srcdir/zlib $CFLAGS"
1032 else
1033     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1034     AC_MSG_RESULT(no)
1035 fi
1036
1037 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1038 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1039 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1040     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1041 fi
1042
1043 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1044 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1045 #include <dirent.h>
1046 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1047 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1048 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1049 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1050     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1051 fi
1052
1053 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1054 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1055 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1056 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1057     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1058 fi
1059
1060 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1061 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1062 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1063 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1064     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1065 fi
1066
1067 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1068 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1069 #include <sys/types.h>
1070 #include <stdarg.h>
1071 #include <stdio.h>
1072 #include <stdlib.h>
1073 #include <string.h>
1074 void foo(const char *format, ...) {
1075        va_list ap;
1076        int len;
1077        static char buf[] = "12345678901234567890";
1078
1079        va_start(ap, format);
1080        len = vsnprintf(0, 0, format, ap);
1081        va_end(ap);
1082        if (len != 5) exit(1);
1083
1084        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1085 }
1086 int main(void) { foo("hello"); return 0; }
1087 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1088 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1089     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1090 fi
1091
1092
1093 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1094 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1095 #include <sys/types.h>
1096 #include <sys/stat.h>
1097 #include <unistd.h>
1098 int main(void) {
1099   struct stat st;
1100   char tpl[20]="/tmp/test.XXXXXX";
1101   int fd = mkstemp(tpl);
1102   if (fd == -1) return 1;
1103   unlink(tpl);
1104   if (fstat(fd, &st) != 0) return 1;
1105   if ((st.st_mode & 0777) != 0600) return 1;
1106   return 0;
1107 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1108 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1109     case $host_os in
1110     hpux*)
1111         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1112         dnl so we noisily skip using it.  See HP change request JAGaf34426
1113         dnl for details. (sbonds)
1114         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1115         ;;
1116     *)
1117         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1118         ;;
1119     esac
1120 fi
1121
1122
1123 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1124 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1125 #include <stdio.h>
1126 #include <sys/stat.h>
1127 #include <errno.h>
1128 #if HAVE_UNISTD_H
1129 # include <unistd.h>
1130 #endif
1131 int main(void) { int rc, ec; char *fn = "fifo-test";
1132 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1133 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1134 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1135 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1136     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1137 fi
1138
1139 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1140 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1141 #include <stdio.h>
1142 #include <sys/stat.h>
1143 #include <errno.h>
1144 #if HAVE_UNISTD_H
1145 # include <unistd.h>
1146 #endif
1147 int main(void) { int rc, ec; char *fn = "sock-test";
1148 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1149 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1150 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1151 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1152     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1153 fi
1154
1155 #
1156 # The following test was mostly taken from the tcl/tk plus patches
1157 #
1158 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1159 rm -rf conftest*
1160 cat > conftest.$ac_ext <<EOF
1161 int main(void) { return 0; }
1162 EOF
1163 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1164 if test -f conftest..o; then
1165     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1166 else
1167     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1168 fi
1169 rm -rf conftest*
1170 ])
1171 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1172     OBJ_SAVE="#"
1173     OBJ_RESTORE="#"
1174     CC_SHOBJ_FLAG='-o $@'
1175 else
1176     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1177     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1178     CC_SHOBJ_FLAG=""
1179 fi
1180
1181 AC_SUBST(OBJ_SAVE)
1182 AC_SUBST(OBJ_RESTORE)
1183 AC_SUBST(CC_SHOBJ_FLAG)
1184 AC_SUBST(BUILD_POPT)
1185 AC_SUBST(BUILD_ZLIB)
1186 AC_SUBST(MAKE_MAN)
1187
1188 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1189 #################################################
1190 # check for ACL support
1191
1192 AC_MSG_CHECKING([whether to support ACLs])
1193 AC_ARG_ENABLE(acl-support,
1194         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1195
1196 if test x"$enable_acl_support" = x"no"; then
1197     AC_MSG_RESULT(no)
1198 else
1199     case "$host_os" in
1200     *sysv5*)
1201         AC_MSG_RESULT(Using UnixWare ACLs)
1202         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1203         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1204         ;;
1205     solaris*)
1206         AC_MSG_RESULT(Using solaris ACLs)
1207         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1208         AC_DEFINE(SUPPORT_ACLS, 1)
1209         ;;
1210     *hpux*)
1211         AC_MSG_RESULT(Using HPUX ACLs)
1212         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1213         AC_DEFINE(SUPPORT_ACLS, 1)
1214         ;;
1215     *irix*)
1216         AC_MSG_RESULT(Using IRIX ACLs)
1217         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1218         AC_DEFINE(SUPPORT_ACLS, 1)
1219         ;;
1220     *aix*)
1221         AC_MSG_RESULT(Using AIX ACLs)
1222         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1223         AC_DEFINE(SUPPORT_ACLS, 1)
1224         ;;
1225     *osf*)
1226         AC_MSG_RESULT(Using Tru64 ACLs)
1227         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1228         AC_DEFINE(SUPPORT_ACLS, 1)
1229         LIBS="$LIBS -lpacl"
1230         ;;
1231     darwin*)
1232         AC_MSG_RESULT(Using OS X ACLs)
1233         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1234         AC_DEFINE(SUPPORT_ACLS, 1)
1235         ;;
1236     *)
1237         AC_MSG_RESULT(running tests:)
1238         AC_CHECK_LIB(acl,acl_get_file)
1239         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1240             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1241 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1242         AC_MSG_CHECKING(ACL test results)
1243         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1244             AC_MSG_RESULT(Using posix ACLs)
1245             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1246             AC_DEFINE(SUPPORT_ACLS, 1)
1247             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1248                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1249 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1250             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1251                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1252             fi
1253         else
1254             if test x"$enable_acl_support" = x"yes"; then
1255                 AC_MSG_ERROR(Failed to find ACL support)
1256             else
1257                 AC_MSG_RESULT(No ACL support found)
1258             fi
1259         fi
1260         ;;
1261     esac
1262 fi
1263
1264 #################################################
1265 # check for extended attribute support
1266 AC_MSG_CHECKING(whether to support extended attributes)
1267 AC_ARG_ENABLE(xattr-support,
1268     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1269     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1270         *yes*) enable_xattr_support=maybe ;;
1271         *) enable_xattr_support=no ;;
1272         esac])
1273 AH_TEMPLATE([SUPPORT_XATTRS],
1274 [Define to 1 to add support for extended attributes])
1275 if test x"$enable_xattr_support" = x"no"; then
1276     AC_MSG_RESULT(no)
1277 else
1278     case "$host_os" in
1279     *linux*|*netbsd*)
1280         AC_MSG_RESULT(Using Linux xattrs)
1281         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1282         AC_DEFINE(SUPPORT_XATTRS, 1)
1283         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1284         AC_CHECK_LIB(attr,getxattr)
1285         ;;
1286     darwin*)
1287         AC_MSG_RESULT(Using OS X xattrs)
1288         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1289         AC_DEFINE(SUPPORT_XATTRS, 1)
1290         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1291         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1292         ;;
1293     freebsd*)
1294         AC_MSG_RESULT(Using FreeBSD extattrs)
1295         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1296         AC_DEFINE(SUPPORT_XATTRS, 1)
1297         ;;
1298     solaris*)
1299         AC_MSG_RESULT(Using Solaris xattrs)
1300         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1301         AC_DEFINE(SUPPORT_XATTRS, 1)
1302         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1303         ;;
1304     *)
1305         if test x"$enable_xattr_support" = x"yes"; then
1306             AC_MSG_ERROR(Failed to find extended attribute support)
1307         else
1308             AC_MSG_RESULT(No extended attribute support found)
1309         fi
1310         ;;
1311     esac
1312 fi
1313
1314 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1315     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1316     OLD_CFLAGS="$CFLAGS"
1317     CFLAGS="$CFLAGS -Wno-unused-parameter"
1318     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1319     AC_MSG_RESULT([$rsync_warn_flag])
1320     if test x"$rsync_warn_flag" = x"no"; then
1321         CFLAGS="$OLD_CFLAGS"
1322     fi
1323 fi
1324
1325 case "$CC" in
1326 ' checker'*|checker*)
1327     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1328     ;;
1329 esac
1330
1331 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1332 AC_OUTPUT
1333
1334 AC_MSG_RESULT()
1335 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1336 AC_MSG_RESULT()