configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.1dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 204 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 205
 206 if test x"$enable_simd" != x"no"; then
 207     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 208     if test x"$build_cpu" = x"x86_64"; then
 209         AC_LANG(C++)
 210         AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 211 #include <immintrin.h>
 212 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 213 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 214 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 215 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 216 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 217 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 218 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 219 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 220 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 221 {
 222     int i;
 223     for (i = 0; i < (len-32); i+=32) {
 224         __m128i in8_1, in8_2;
 225         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 226         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 227     }
 228 }
 229 ]], [[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],[CXX_OK=yes],[CXX_OK=no])
 230         AC_LANG(C)
 231         if test x"$CXX_OK" = x"yes"; then
 232             # AC_MSG_RESULT() is called below.
 233             SIMD="x86_64"
 234         elif test x"$enable_simd" = x"yes"; then
 235             AC_MSG_RESULT(error)
 236             AC_MSG_ERROR(The SIMD compilation test failed.
 237 Omit --enable-simd to continue without it.)
 238         fi
 239     elif test x"$enable_simd" = x"yes"; then
 240         AC_MSG_RESULT(unavailable)
 241         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 242 Omit --enable-simd to continue without it.)
 243     fi
 244 fi
 245
 246 if test x"$SIMD" != x""; then
 247     AC_MSG_RESULT([yes ($SIMD)])
 248     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 249     SIMD='$(SIMD_'"$SIMD)"
 250     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 251     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 252     case "$CXX" in
 253     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 254     esac
 255 else
 256     AC_MSG_RESULT(no)
 257 fi
 258
 259 AC_SUBST(SIMD)
 260
 261 AC_MSG_CHECKING([if assembler accepts noexecstack])
 262 OLD_CFLAGS="$CFLAGS"
 263 CFLAGS="$CFLAGS -Wa,--noexecstack"
 264 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 265 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 266 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 267 CFLAGS="$OLD_CFLAGS"
 268 AC_SUBST(NOEXECSTACK)
 269
 270 ASM=
 271
 272 AC_MSG_CHECKING([whether to enable ASM optimizations])
 273 AC_ARG_ENABLE(asm,
 274     AS_HELP_STRING([--disable-asm],[disable ASM optimizations]))
 275
 276 if test x"$enable_asm" != x"no"; then
 277     if test x"$build_cpu" = x"x86_64"; then
 278         ASM="$build_cpu"
 279     elif test x"$enable_asm" = x"yes"; then
 280         AC_MSG_RESULT(unavailable)
 281         AC_MSG_ERROR(The ASM optimizations are currently x86_64 only.
 282 Omit --enable-asm to continue without it.)
 283     fi
 284 fi
 285
 286 if test x"$ASM" != x""; then
 287     AC_MSG_RESULT([yes ($ASM)])
 288     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 289     ASM='$(ASM_'"$ASM)"
 290 else
 291     AC_MSG_RESULT(no)
 292 fi
 293
 294 AC_SUBST(ASM)
 295
 296 # arrgh. libc in some old debian version screwed up the largefile
 297 # stuff, getting byte range locking wrong
 298 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 299 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 300 #define _FILE_OFFSET_BITS 64
 301 #include <stdio.h>
 302 #include <fcntl.h>
 303 #include <sys/types.h>
 304 #include <sys/wait.h>
 305 #if HAVE_UNISTD_H
 306 #include <unistd.h>
 307 #endif
 308
 309 int main(void)
 310 {
 311         struct flock lock;
 312         int status;
 313         char tpl[32] = "/tmp/locktest.XXXXXX";
 314         int fd = mkstemp(tpl);
 315         if (fd < 0) {
 316                 strcpy(tpl, "conftest.dat");
 317                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 318         }
 319
 320         lock.l_type = F_WRLCK;
 321         lock.l_whence = SEEK_SET;
 322         lock.l_start = 0;
 323         lock.l_len = 1;
 324         lock.l_pid = 0;
 325         fcntl(fd,F_SETLK,&lock);
 326         if (fork() == 0) {
 327                 lock.l_start = 1;
 328                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 329         }
 330         wait(&status);
 331         unlink(tpl);
 332         return WEXITSTATUS(status);
 333 }
 334 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 335 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 336    AC_SYS_LARGEFILE
 337 fi
 338
 339 ipv6type=unknown
 340 ipv6lib=none
 341 ipv6trylibc=yes
 342
 343 AC_ARG_ENABLE(ipv6,
 344         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 345 if test x"$enable_ipv6" != x"no"; then
 346         AC_MSG_CHECKING([ipv6 stack type])
 347         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 348                 case $i in
 349                 inria)
 350                         # http://www.kame.net/
 351                         AC_EGREP_CPP(yes, [
 352 #include <netinet/in.h>
 353 #ifdef IPV6_INRIA_VERSION
 354 yes
 355 #endif],
 356                                 [ipv6type=$i;
 357                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 358                                 ])
 359                         ;;
 360                 kame)
 361                         # http://www.kame.net/
 362                         AC_EGREP_CPP(yes, [
 363 #include <netinet/in.h>
 364 #ifdef __KAME__
 365 yes
 366 #endif],
 367                                 [ipv6type=$i;
 368                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 369                         ;;
 370                 linux-glibc)
 371                         # http://www.v6.linux.or.jp/
 372                         AC_EGREP_CPP(yes, [
 373 #include <features.h>
 374 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 375 yes
 376 #endif],
 377                                 [ipv6type=$i;
 378 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 379                         ;;
 380                 linux-inet6)
 381                         # http://www.v6.linux.or.jp/
 382                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 383                                 ipv6type=$i
 384                                 ipv6lib=inet6
 385                                 ipv6libdir=/usr/inet6/lib
 386                                 ipv6trylibc=yes;
 387                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 388                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 389                         fi
 390                         ;;
 391                 solaris)
 392                         # http://www.sun.com
 393                         AC_EGREP_CPP(yes, [
 394 #include <netinet/ip6.h>
 395 #ifdef __sun
 396 yes
 397 #endif],
 398                                 [ipv6type=$i;
 399                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 400                         ;;
 401                 toshiba)
 402                         AC_EGREP_CPP(yes, [
 403 #include <sys/param.h>
 404 #ifdef _TOSHIBA_INET6
 405 yes
 406 #endif],
 407                                 [ipv6type=$i;
 408                                 ipv6lib=inet6;
 409                                 ipv6libdir=/usr/local/v6/lib;
 410                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 411                         ;;
 412                 v6d)
 413                         AC_EGREP_CPP(yes, [
 414 #include </usr/local/v6/include/sys/v6config.h>
 415 #ifdef __V6D__
 416 yes
 417 #endif],
 418                                 [ipv6type=$i;
 419                                 ipv6lib=v6;
 420                                 ipv6libdir=/usr/local/v6/lib;
 421                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 422                         ;;
 423                 zeta)
 424                         AC_EGREP_CPP(yes, [
 425 #include <sys/param.h>
 426 #ifdef _ZETA_MINAMI_INET6
 427 yes
 428 #endif],
 429                                 [ipv6type=$i;
 430                                 ipv6lib=inet6;
 431                                 ipv6libdir=/usr/local/v6/lib;
 432                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 433                         ;;
 434                 cygwin)
 435                         AC_EGREP_CPP(yes, [
 436 #include <netinet/in.h>
 437 #ifdef _CYGWIN_IN6_H
 438 yes
 439 #endif],
 440                                 [ipv6type=$i;
 441                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 442                         ;;
 443                 esac
 444                 if test "$ipv6type" != "unknown"; then
 445                         break
 446                 fi
 447         done
 448         AC_MSG_RESULT($ipv6type)
 449
 450         AC_SEARCH_LIBS(getaddrinfo, inet6)
 451 fi
 452
 453 dnl Do you want to disable use of locale functions
 454 AC_ARG_ENABLE([locale],
 455         AS_HELP_STRING([--disable-locale],[disable locale features]))
 456 AH_TEMPLATE([CONFIG_LOCALE],
 457 [Undefine if you do not want locale features.  By default this is defined.])
 458 if test x"$enable_locale" != x"no"; then
 459         AC_DEFINE(CONFIG_LOCALE)
 460 fi
 461
 462 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 463 case $host_os in
 464         *cygwin* ) AC_MSG_RESULT(yes)
 465                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 466                             [Define to 1 if sockets need to be shutdown])
 467                    ;;
 468                * ) AC_MSG_RESULT(no);;
 469 esac
 470
 471 AC_C_BIGENDIAN
 472 AC_HEADER_DIRENT
 473 AC_HEADER_TIME
 474 AC_HEADER_SYS_WAIT
 475 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 476     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 477     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 478     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 479     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 480     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 481     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 482     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 483 AC_HEADER_MAJOR_FIXED
 484
 485 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 486 AC_ARG_ENABLE([openssl],
 487         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 488 AH_TEMPLATE([USE_OPENSSL],
 489 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 490 if test x"$enable_openssl" != x"no"; then
 491     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 492       AC_MSG_RESULT(yes)
 493       AC_SEARCH_LIBS(MD5_Init, crypto,
 494           [AC_DEFINE(USE_OPENSSL)],
 495           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 496 Use --disable-openssl to continue without openssl crypto lib support.)])
 497     else
 498         AC_MSG_RESULT(no)
 499         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 500 Use --disable-openssl to continue without it.)
 501     fi
 502 else
 503     AC_MSG_RESULT(no)
 504 fi
 505
 506 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 507 AC_ARG_ENABLE([xxhash],
 508         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 509 AH_TEMPLATE([SUPPORT_XXHASH],
 510 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 511 if test x"$enable_xxhash" != x"no"; then
 512     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 513         AC_MSG_RESULT(yes)
 514         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 515             [AC_DEFINE(SUPPORT_XXHASH)],
 516             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 517 Use --disable-xxhash to continue without xxhash checksums.)])
 518     else
 519         AC_MSG_RESULT(no)
 520         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 521 Use --disable-xxhash to continue without it.)
 522     fi
 523 else
 524     AC_MSG_RESULT(no)
 525 fi
 526
 527 AC_MSG_CHECKING([whether to enable zstd compression])
 528 AC_ARG_ENABLE([zstd],
 529         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 530 AH_TEMPLATE([SUPPORT_ZSTD],
 531 [Undefine if you do not want zstd compression.  By default this is defined.])
 532 if test x"$enable_zstd" != x"no"; then
 533     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 534         AC_MSG_RESULT(yes)
 535         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 536             [AC_DEFINE(SUPPORT_ZSTD)],
 537             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 538 Use --disable-zstd to continue without zstd compression.)])
 539     else
 540         AC_MSG_RESULT(no)
 541         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 542 Use --disable-zstd to continue without it.)
 543     fi
 544 else
 545     AC_MSG_RESULT(no)
 546 fi
 547
 548 AC_MSG_CHECKING([whether to enable LZ4 compression])
 549 AC_ARG_ENABLE([lz4],
 550         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 551 AH_TEMPLATE([SUPPORT_LZ4],
 552 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 553 if test x"$enable_lz4" != x"no"; then
 554     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 555         AC_MSG_RESULT(yes)
 556         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 557             [AC_DEFINE(SUPPORT_LZ4)],
 558             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 559 Use --disable-lz4 to continue without lz4 compression.)])
 560     else
 561         AC_MSG_RESULT(no)
 562         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 563 Use --disable-lz4 to continue without it.)
 564     fi
 565 else
 566     AC_MSG_RESULT(no)
 567 fi
 568
 569 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 570 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 571 #include <sys/types.h>
 572 #ifdef MAJOR_IN_MKDEV
 573 #include <sys/mkdev.h>
 574 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 575 #  define makedev mkdev
 576 # endif
 577 #elif defined MAJOR_IN_SYSMACROS
 578 #include <sys/sysmacros.h>
 579 #endif
 580
 581 int main(void)
 582 {
 583         dev_t dev = makedev(0, 5, 7);
 584         if (major(dev) != 5 || minor(dev) != 7)
 585                 return 1;
 586         return 0;
 587 }
 588 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 589 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 590    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 591 fi
 592
 593 AC_CHECK_SIZEOF(int)
 594 AC_CHECK_SIZEOF(long)
 595 AC_CHECK_SIZEOF(long long)
 596 AC_CHECK_SIZEOF(short)
 597 AC_CHECK_SIZEOF(int16_t)
 598 AC_CHECK_SIZEOF(uint16_t)
 599 AC_CHECK_SIZEOF(int32_t)
 600 AC_CHECK_SIZEOF(uint32_t)
 601 AC_CHECK_SIZEOF(int64_t)
 602 AC_CHECK_SIZEOF(off_t)
 603 AC_CHECK_SIZEOF(off64_t)
 604 AC_CHECK_SIZEOF(time_t)
 605 AC_CHECK_SIZEOF(char*)
 606
 607 AC_C_INLINE
 608
 609 AC_TYPE_LONG_DOUBLE_WIDER
 610 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 611 if test $ac_cv_c_long_double = yes; then
 612   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 613 fi
 614
 615 AC_TYPE_UID_T
 616 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 617 AC_TYPE_GETGROUPS
 618 AC_CHECK_MEMBERS([struct stat.st_rdev,
 619                   struct stat.st_mtimensec,
 620                   struct stat.st_mtimespec.tv_nsec,
 621                   struct stat.st_mtim.tv_nsec],,,[
 622 #ifdef HAVE_SYS_TYPES_H
 623 #include <sys/types.h>
 624 #endif
 625 #ifdef HAVE_SYS_STAT_H
 626 #include <sys/stat.h>
 627 #endif
 628 #ifdef HAVE_UNISTD_H
 629 #include <unistd.h>
 630 #endif])
 631
 632 TYPE_SOCKLEN_T
 633
 634 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 635     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 636 if test x"$rsync_cv_errno" = x"yes"; then
 637    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 638 fi
 639
 640 # The following test taken from the cvs sources
 641 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 642 # These need checks to be before checks for any other functions that
 643 #    might be in the same libraries.
 644 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 645 # libsocket.so which has a bad implementation of gethostbyname (it
 646 # only looks in /etc/hosts), so we only look for -lsocket if we need
 647 # it.
 648 AC_CHECK_FUNCS(connect)
 649 if test x"$ac_cv_func_connect" = x"no"; then
 650     case "$LIBS" in
 651     *-lnsl*) ;;
 652     *) AC_CHECK_LIB(nsl_s, printf) ;;
 653     esac
 654     case "$LIBS" in
 655     *-lnsl*) ;;
 656     *) AC_CHECK_LIB(nsl, printf) ;;
 657     esac
 658     case "$LIBS" in
 659     *-lsocket*) ;;
 660     *) AC_CHECK_LIB(socket, connect) ;;
 661     esac
 662     case "$LIBS" in
 663     *-linet*) ;;
 664     *) AC_CHECK_LIB(inet, connect) ;;
 665     esac
 666     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 667     dnl has been cached.
 668     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 669        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 670         # ac_cv_func_connect=yes
 671         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 672         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 673     fi
 674 fi
 675
 676 AC_SEARCH_LIBS(inet_ntop, resolv)
 677
 678 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 679 # accept either iconv_open or libiconv_open, since some include files map
 680 # the former to the latter.
 681 AC_SEARCH_LIBS(iconv_open, iconv)
 682 AC_SEARCH_LIBS(libiconv_open, iconv)
 683
 684 AC_MSG_CHECKING([for iconv declaration])
 685 AC_CACHE_VAL(am_cv_proto_iconv, [
 686     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 687 #include <stdlib.h>
 688 #include <iconv.h>
 689 extern
 690 #ifdef __cplusplus
 691 "C"
 692 #endif
 693 #if defined(__STDC__) || defined(__cplusplus)
 694 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 695 #else
 696 size_t iconv();
 697 #endif
 698 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 699       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 700     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 701 AC_MSG_RESULT([$]{ac_t:-
 702          }[$]am_cv_proto_iconv)
 703 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 704                    [Define as const if the declaration of iconv() needs const.])
 705
 706 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 707
 708 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 709
 710 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 711 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 712 #include <sys/socket.h>])
 713
 714 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 715 #   builtin getaddrinfo if one of the defines don't exist
 716 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 717                rsync_cv_HAVE_GETADDR_DEFINES,[
 718                         AC_EGREP_CPP(yes, [
 719                         #include <sys/types.h>
 720                         #include <sys/socket.h>
 721                         #include <netdb.h>
 722                         #ifdef AI_PASSIVE
 723                         yes
 724                         #endif],
 725                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 726                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 727 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 728         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 729         # something else so we must include <netdb.h> to get the
 730         # redefinition.
 731         AC_CHECK_FUNCS(getaddrinfo, ,
 732                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 733                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 734                 #include <sys/socket.h>
 735                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 736                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 737                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 738                         AC_LIBOBJ([getaddrinfo])])])
 739     ],[AC_LIBOBJ([getaddrinfo])])
 740
 741 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 742                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 743                 [],
 744                 [
 745 #include <sys/types.h>
 746 #include <sys/socket.h>
 747 ])
 748
 749 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 750                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 751                 [],
 752                 [
 753 #include <sys/types.h>
 754 #include <sys/socket.h>
 755 #include <netinet/in.h>
 756 ])
 757
 758 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 759                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 760                 [],
 761                 [
 762 #include <sys/types.h>
 763 #include <sys/socket.h>
 764 #include <netinet/in.h>
 765 ])
 766
 767 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 768                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 769                 [],
 770                 [
 771 #include <sys/types.h>
 772 #include <sys/socket.h>
 773 #include <netinet/in.h>
 774 ])
 775
 776 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 777 #if HAVE_SYS_TYPES_H
 778 # include <sys/types.h>
 779 #endif
 780 #if HAVE_SYS_STAT_H
 781 # include <sys/stat.h>
 782 #endif
 783 #if STDC_HEADERS
 784 # include <stdlib.h>
 785 # include <stddef.h>
 786 #else
 787 # if HAVE_STDLIB_H
 788 #  include <stdlib.h>
 789 # endif
 790 #endif
 791 ])
 792
 793 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 794 #
 795 AC_CHECK_FUNCS(strcasecmp)
 796 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 797     AC_CHECK_LIB(resolv, strcasecmp)
 798 fi
 799
 800 AC_CHECK_FUNCS(aclsort)
 801 if test x"$ac_cv_func_aclsort" = x"no"; then
 802     AC_CHECK_LIB(sec, aclsort)
 803 fi
 804
 805 dnl At the moment we don't test for a broken memcmp(), because all we
 806 dnl need to do is test for equality, not comparison, and it seems that
 807 dnl every platform has a memcmp that can do at least that.
 808 dnl AC_FUNC_MEMCMP
 809
 810 AC_FUNC_UTIME_NULL
 811 AC_FUNC_ALLOCA
 812 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 813     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 814     chflags getattrlist \
 815     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 816     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 817     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 818     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 819     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 820     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 821
 822 dnl cygwin iconv.h defines iconv_open as libiconv_open
 823 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 824     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 825 fi
 826
 827 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 828
 829 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 830 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 831 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 832 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 833     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 834 fi
 835
 836 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 837 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 838         #define _GNU_SOURCE 1
 839         #include <linux/falloc.h>
 840         #ifndef FALLOC_FL_PUNCH_HOLE
 841         #error FALLOC_FL_PUNCH_HOLE is missing
 842         #endif
 843     ]])], [
 844         AC_MSG_RESULT([yes])
 845         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 846     ], [
 847         AC_MSG_RESULT([no])
 848     ]
 849 )
 850
 851 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 852 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 853         #define _GNU_SOURCE 1
 854         #include <linux/falloc.h>
 855         #ifndef FALLOC_FL_ZERO_RANGE
 856         #error FALLOC_FL_ZERO_RANGE is missing
 857         #endif
 858     ]])], [
 859         AC_MSG_RESULT([yes])
 860         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 861     ], [
 862         AC_MSG_RESULT([no])
 863     ]
 864 )
 865
 866 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 867 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 868 #include <unistd.h>
 869 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 870 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 871     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 872 fi
 873
 874 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 875     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 876     case $host_os in
 877     *cygwin*)
 878         AC_MSG_RESULT(yes)
 879         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 880                   [Define if posix_fallocate is efficient (Cygwin)])
 881         ;;
 882     *)
 883         AC_MSG_RESULT(no)
 884         ;;
 885     esac
 886 fi
 887
 888 dnl End of preallocation stuff
 889
 890 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 891 if test $ac_cv_func_getpgrp = yes; then
 892     AC_FUNC_GETPGRP
 893 fi
 894
 895 AC_ARG_ENABLE(iconv-open,
 896     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 897     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 898
 899 if test x"$enable_iconv_open" != x"no"; then
 900     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 901 fi
 902
 903 AC_ARG_ENABLE(iconv,
 904     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 905     [], [enable_iconv=$enable_iconv_open])
 906 AH_TEMPLATE([ICONV_OPTION],
 907 [Define if you want the --iconv option.  Specifying a value will set the
 908 default iconv setting (a NULL means no --iconv processing by default).])
 909 if test x"$enable_iconv" != x"no"; then
 910         if test x"$enable_iconv" = x"yes"; then
 911                 AC_DEFINE(ICONV_OPTION, NULL)
 912         else
 913                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 914         fi
 915         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 916 fi
 917
 918 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 919   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 920 #if HAVE_UNISTD_H
 921 # include <unistd.h>
 922 #endif
 923 #include <stdlib.h>
 924 #include <errno.h>
 925 int main(void) {
 926         char const *dangling_symlink = "conftest.dangle";
 927         unlink(dangling_symlink);
 928         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 929         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 930         return 0;
 931     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 932 if test $rsync_cv_chown_modifies_symlink = yes; then
 933   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 934 fi
 935
 936 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 937   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 938 #if HAVE_UNISTD_H
 939 # include <unistd.h>
 940 #endif
 941 #include <stdlib.h>
 942 #include <errno.h>
 943 #define FILENAME "conftest.dangle"
 944 int main(void) {
 945         unlink(FILENAME);
 946         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 947         unlink(FILENAME "2");
 948         if (link(FILENAME, FILENAME "2") < 0) return 1;
 949         return 0;
 950     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 951 if test $rsync_cv_can_hardlink_symlink = yes; then
 952   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 953 fi
 954
 955 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 956   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 957 #if HAVE_UNISTD_H
 958 # include <unistd.h>
 959 #endif
 960 #ifdef HAVE_SYS_STAT_H
 961 #include <sys/stat.h>
 962 #endif
 963 #include <stdlib.h>
 964 #include <errno.h>
 965 #define FILENAME "conftest.fifi"
 966 int main(void) {
 967         unlink(FILENAME);
 968         if (mkfifo(FILENAME, 0777) < 0) abort();
 969         unlink(FILENAME "2");
 970         if (link(FILENAME, FILENAME "2") < 0) return 1;
 971         return 0;
 972     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 973 if test $rsync_cv_can_hardlink_special = yes; then
 974     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 975 fi
 976
 977 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 978 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 979 #include <sys/types.h>
 980 #include <sys/socket.h>
 981
 982 int main(void) {
 983        int fd[2];
 984        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 985 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 986 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 987     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 988 fi
 989
 990 AC_REPLACE_FUNCS([getpass])
 991
 992 if test x"$with_included_popt" != x"yes"; then
 993     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 994 fi
 995 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 996     # If the system has /usr/include/popt/popt.h, we enable the
 997     # included popt because an attempt to "#include <popt/popt.h>"
 998     # would use our included header file anyway (due to -I.), and
 999     # might conflict with the system popt.
1000     with_included_popt=yes
1001 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1002     with_included_popt=yes
1003 fi
1004
1005 AC_MSG_CHECKING([whether to use included libpopt])
1006 if test x"$with_included_popt" = x"yes"; then
1007     AC_MSG_RESULT($srcdir/popt)
1008     BUILD_POPT='$(popt_OBJS)'
1009     CFLAGS="-I$srcdir/popt $CFLAGS"
1010     if test x"$ALLOCA" != x
1011     then
1012         # this can be removed when/if we add an included alloca.c;
1013         #  see autoconf documentation on AC_FUNC_ALLOCA
1014         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1015     fi
1016 else
1017     AC_MSG_RESULT(no)
1018 fi
1019
1020 # We default to using our zlib unless --with-included-zlib=no is given.
1021 if test x"$with_included_zlib" != x"no"; then
1022     with_included_zlib=yes
1023 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1024     with_included_zlib=yes
1025 fi
1026 if test x"$with_included_zlib" != x"yes"; then
1027     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1028 fi
1029
1030 AC_MSG_CHECKING([whether to use included zlib])
1031 if test x"$with_included_zlib" = x"yes"; then
1032     AC_MSG_RESULT($srcdir/zlib)
1033     BUILD_ZLIB='$(zlib_OBJS)'
1034     CFLAGS="-I$srcdir/zlib $CFLAGS"
1035 else
1036     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1037     AC_MSG_RESULT(no)
1038 fi
1039
1040 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1041 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1042 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1043     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1044 fi
1045
1046 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1047 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1048 #include <dirent.h>
1049 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1050 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1051 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1052 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1053     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1054 fi
1055
1056 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1057 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1058 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1059 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1060     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1061 fi
1062
1063 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1064 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1065 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1066 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1067     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1068 fi
1069
1070 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1071 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1072 #include <sys/types.h>
1073 #include <stdarg.h>
1074 #include <stdio.h>
1075 #include <stdlib.h>
1076 #include <string.h>
1077 void foo(const char *format, ...) {
1078        va_list ap;
1079        int len;
1080        static char buf[] = "12345678901234567890";
1081
1082        va_start(ap, format);
1083        len = vsnprintf(0, 0, format, ap);
1084        va_end(ap);
1085        if (len != 5) exit(1);
1086
1087        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1088 }
1089 int main(void) { foo("hello"); return 0; }
1090 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1091 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1092     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1093 fi
1094
1095
1096 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1097 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1098 #include <sys/types.h>
1099 #include <sys/stat.h>
1100 #include <unistd.h>
1101 int main(void) {
1102   struct stat st;
1103   char tpl[20]="/tmp/test.XXXXXX";
1104   int fd = mkstemp(tpl);
1105   if (fd == -1) return 1;
1106   unlink(tpl);
1107   if (fstat(fd, &st) != 0) return 1;
1108   if ((st.st_mode & 0777) != 0600) return 1;
1109   return 0;
1110 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1111 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1112     case $host_os in
1113     hpux*)
1114         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1115         dnl so we noisily skip using it.  See HP change request JAGaf34426
1116         dnl for details. (sbonds)
1117         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1118         ;;
1119     *)
1120         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1121         ;;
1122     esac
1123 fi
1124
1125
1126 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1127 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1128 #include <stdio.h>
1129 #include <sys/stat.h>
1130 #include <errno.h>
1131 #if HAVE_UNISTD_H
1132 # include <unistd.h>
1133 #endif
1134 int main(void) { int rc, ec; char *fn = "fifo-test";
1135 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1136 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1137 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1138 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1139     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1140 fi
1141
1142 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1143 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1144 #include <stdio.h>
1145 #include <sys/stat.h>
1146 #include <errno.h>
1147 #if HAVE_UNISTD_H
1148 # include <unistd.h>
1149 #endif
1150 int main(void) { int rc, ec; char *fn = "sock-test";
1151 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1152 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1153 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1154 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1155     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1156 fi
1157
1158 #
1159 # The following test was mostly taken from the tcl/tk plus patches
1160 #
1161 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1162 rm -rf conftest*
1163 cat > conftest.$ac_ext <<EOF
1164 int main(void) { return 0; }
1165 EOF
1166 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1167 if test -f conftest..o; then
1168     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1169 else
1170     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1171 fi
1172 rm -rf conftest*
1173 ])
1174 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1175     OBJ_SAVE="#"
1176     OBJ_RESTORE="#"
1177     CC_SHOBJ_FLAG='-o $@'
1178 else
1179     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1180     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1181     CC_SHOBJ_FLAG=""
1182 fi
1183
1184 AC_SUBST(OBJ_SAVE)
1185 AC_SUBST(OBJ_RESTORE)
1186 AC_SUBST(CC_SHOBJ_FLAG)
1187 AC_SUBST(BUILD_POPT)
1188 AC_SUBST(BUILD_ZLIB)
1189 AC_SUBST(MAKE_MAN)
1190
1191 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1192 #################################################
1193 # check for ACL support
1194
1195 AC_MSG_CHECKING([whether to support ACLs])
1196 AC_ARG_ENABLE(acl-support,
1197         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1198
1199 if test x"$enable_acl_support" = x"no"; then
1200     AC_MSG_RESULT(no)
1201 else
1202     case "$host_os" in
1203     *sysv5*)
1204         AC_MSG_RESULT(Using UnixWare ACLs)
1205         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1206         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1207         ;;
1208     solaris*)
1209         AC_MSG_RESULT(Using solaris ACLs)
1210         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1211         AC_DEFINE(SUPPORT_ACLS, 1)
1212         ;;
1213     *hpux*)
1214         AC_MSG_RESULT(Using HPUX ACLs)
1215         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1216         AC_DEFINE(SUPPORT_ACLS, 1)
1217         ;;
1218     *irix*)
1219         AC_MSG_RESULT(Using IRIX ACLs)
1220         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1221         AC_DEFINE(SUPPORT_ACLS, 1)
1222         ;;
1223     *aix*)
1224         AC_MSG_RESULT(Using AIX ACLs)
1225         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1226         AC_DEFINE(SUPPORT_ACLS, 1)
1227         ;;
1228     *osf*)
1229         AC_MSG_RESULT(Using Tru64 ACLs)
1230         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1231         AC_DEFINE(SUPPORT_ACLS, 1)
1232         LIBS="$LIBS -lpacl"
1233         ;;
1234     darwin*)
1235         AC_MSG_RESULT(Using OS X ACLs)
1236         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1237         AC_DEFINE(SUPPORT_ACLS, 1)
1238         ;;
1239     *)
1240         AC_MSG_RESULT(running tests:)
1241         AC_CHECK_LIB(acl,acl_get_file)
1242         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1243             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1244 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1245         AC_MSG_CHECKING(ACL test results)
1246         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1247             AC_MSG_RESULT(Using posix ACLs)
1248             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1249             AC_DEFINE(SUPPORT_ACLS, 1)
1250             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1251                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1252 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1253             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1254                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1255             fi
1256         else
1257             if test x"$enable_acl_support" = x"yes"; then
1258                 AC_MSG_ERROR(Failed to find ACL support)
1259             else
1260                 AC_MSG_RESULT(No ACL support found)
1261             fi
1262         fi
1263         ;;
1264     esac
1265 fi
1266
1267 #################################################
1268 # check for extended attribute support
1269 AC_MSG_CHECKING(whether to support extended attributes)
1270 AC_ARG_ENABLE(xattr-support,
1271     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1272     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1273         *yes*) enable_xattr_support=maybe ;;
1274         *) enable_xattr_support=no ;;
1275         esac])
1276 AH_TEMPLATE([SUPPORT_XATTRS],
1277 [Define to 1 to add support for extended attributes])
1278 if test x"$enable_xattr_support" = x"no"; then
1279     AC_MSG_RESULT(no)
1280 else
1281     case "$host_os" in
1282     *linux*|*netbsd*)
1283         AC_MSG_RESULT(Using Linux xattrs)
1284         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1285         AC_DEFINE(SUPPORT_XATTRS, 1)
1286         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1287         AC_CHECK_LIB(attr,getxattr)
1288         ;;
1289     darwin*)
1290         AC_MSG_RESULT(Using OS X xattrs)
1291         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1292         AC_DEFINE(SUPPORT_XATTRS, 1)
1293         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1294         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1295         ;;
1296     freebsd*)
1297         AC_MSG_RESULT(Using FreeBSD extattrs)
1298         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1299         AC_DEFINE(SUPPORT_XATTRS, 1)
1300         ;;
1301     solaris*)
1302         AC_MSG_RESULT(Using Solaris xattrs)
1303         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1304         AC_DEFINE(SUPPORT_XATTRS, 1)
1305         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1306         ;;
1307     *)
1308         if test x"$enable_xattr_support" = x"yes"; then
1309             AC_MSG_ERROR(Failed to find extended attribute support)
1310         else
1311             AC_MSG_RESULT(No extended attribute support found)
1312         fi
1313         ;;
1314     esac
1315 fi
1316
1317 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1318     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1319     OLD_CFLAGS="$CFLAGS"
1320     CFLAGS="$CFLAGS -Wno-unused-parameter"
1321     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1322     AC_MSG_RESULT([$rsync_warn_flag])
1323     if test x"$rsync_warn_flag" = x"no"; then
1324         CFLAGS="$OLD_CFLAGS"
1325     fi
1326 fi
1327
1328 case "$CC" in
1329 ' checker'*|checker*)
1330     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1331     ;;
1332 esac
1333
1334 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1335 AC_OUTPUT
1336
1337 AC_MSG_RESULT()
1338 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1339 AC_MSG_RESULT()