configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [228],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 109
 110 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 111 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 112
 113 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 114
 115 M4_DEFINES=
 116
 117 AC_CHECK_TOOL(OBJCOPY, objcopy)
 118 AC_CHECK_TOOL(STRINGS, strings)
 119 AC_CHECK_TOOL(GPERF, gperf)
 120 if test -z "$GPERF" ; then
 121         AC_MSG_ERROR([*** gperf not found])
 122 fi
 123
 124 # ------------------------------------------------------------------------------
 125 address_sanitizer_cflags=
 126 address_sanitizer_cppflags=
 127 address_sanitizer_ldflags=
 128 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 129 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 131             AS_IF([test -z "$with_as_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 133             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             address_sanitizer_cppflags="-DVALGRIND=1"
 135             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 136       ])
 137
 138 undefined_sanitizer_cflags=
 139 undefined_sanitizer_cppflags=
 140 undefined_sanitizer_ldflags=
 141 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 142 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 143             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 144             AS_IF([test -z "$with_us_cflags"],
 145                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 146             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 147             undefined_sanitizer_cppflags="-DVALGRIND=1"
 148             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 149       ])
 150
 151 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 152 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 153 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 154
 155 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 156         -pipe \
 157         -Wall \
 158         -Wextra \
 159         -Wundef \
 160         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 161         -Wlogical-op \
 162         -Wmissing-include-dirs \
 163         -Wold-style-definition \
 164         -Wpointer-arith \
 165         -Winit-self \
 166         -Wdeclaration-after-statement \
 167         -Wfloat-equal \
 168         -Wsuggest-attribute=noreturn \
 169         -Werror=missing-prototypes \
 170         -Werror=implicit-function-declaration \
 171         -Werror=missing-declarations \
 172         -Werror=return-type \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 216                -flto])],
 217         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 218 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 222                -Wp,-D_FORTIFY_SOURCE=2])],
 223         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 224 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 225
 226 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 227         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 228                -Wl,--gc-sections])],
 229         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 230 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 231
 232 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 233         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 234                -ffunction-sections -fdata-sections])],
 235         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 236 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 237
 238 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 239         -Wl,--as-needed \
 240         -Wl,--no-undefined \
 241         -Wl,-z,relro \
 242         -Wl,-z,now \
 243         -pie \
 244         -Wl,-fuse-ld=gold])
 245 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 246
 247 AC_CHECK_SIZEOF(pid_t)
 248 AC_CHECK_SIZEOF(uid_t)
 249 AC_CHECK_SIZEOF(gid_t)
 250 AC_CHECK_SIZEOF(time_t)
 251 AC_CHECK_SIZEOF(dev_t)
 252 AC_CHECK_SIZEOF(rlim_t,,[
 253        #include <sys/time.h>
 254        #include <sys/resource.h>
 255 ])
 256
 257 # ------------------------------------------------------------------------------
 258 # we use python to build the man page index
 259 have_python=no
 260 AC_ARG_WITH([python],
 261         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 262
 263 have_lxml=no
 264 AS_IF([test "x$with_python" != "xno"], [
 265         AM_PATH_PYTHON(,, [:])
 266         AS_IF([test "x$PYTHON" != "x:"], [
 267                 AC_MSG_CHECKING([for python lxml module])
 268                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 269                 AC_MSG_RESULT([$have_lxml])
 270                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 271                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 272         ])
 273 ])
 274 AS_IF([test "$have_python" != "yes"], [
 275       AS_IF([test "$with_python" = "yes"],
 276             [AC_MSG_ERROR([*** python support requested but python support not found])])
 277       AS_IF([test "$with_python" != "no"],
 278             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 279 ])
 280 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 281
 282 # ------------------------------------------------------------------------------
 283
 284 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 285 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 286 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 287
 288 # unconditionally pull-in librt with old glibc versions
 289 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 290
 291 save_LIBS="$LIBS"
 292 LIBS=
 293 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 294 CAP_LIBS="$LIBS"
 295 LIBS="$save_LIBS"
 296 AC_SUBST(CAP_LIBS)
 297
 298 AC_CHECK_FUNCS([memfd_create])
 299 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 300 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2,
 301                 kcmp, keyctl, key_serial_t, char16_t, char32_t, LO_FLAGS_PARTSCAN],
 302                [], [], [[
 303 #include <sys/types.h>
 304 #include <unistd.h>
 305 #include <sys/mount.h>
 306 #include <fcntl.h>
 307 #include <sched.h>
 308 #include <linux/loop.h>
 309 #include <linux/random.h>
 310 ]])
 311
 312 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 313                 IFLA_MACVLAN_FLAGS,
 314                 IFLA_IPVLAN_MODE,
 315                 IFLA_VTI_REMOTE,
 316                 IFLA_PHYS_PORT_ID,
 317                 IFLA_BOND_AD_INFO,
 318                 IFLA_VLAN_PROTOCOL,
 319                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 320                 IFLA_IPTUN_ENCAP_DPORT,
 321                 IFLA_GRE_ENCAP_DPORT,
 322                 IFLA_BRIDGE_VLAN_INFO,
 323                 IFLA_BRPORT_LEARNING_SYNC,
 324                 IFLA_BR_PRIORITY,
 325                 NDA_IFINDEX,
 326                 IFA_FLAGS],
 327 [], [], [[
 328 #include <inttypes.h>
 329 #include <netinet/in.h>
 330 #include <netinet/ether.h>
 331 #include <linux/rtnetlink.h>
 332 #include <net/if.h>
 333 #include <linux/ip.h>
 334 #include <linux/if_tunnel.h>
 335 #include <linux/if_link.h>
 336 #include <linux/if_bridge.h>
 337 #include <linux/if_addr.h>
 338 #include <linux/neighbour.h>
 339 ]])
 340
 341 # This makes sure pkg.m4 is available.
 342 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 343
 344 # ------------------------------------------------------------------------------
 345 have_dbus=no
 346 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 347 AS_IF([test "x$enable_dbus" != "xno"], [
 348         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 349                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 350                 [have_dbus=no])
 351         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 352                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 353 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 354
 355 # ------------------------------------------------------------------------------
 356 have_utmp=yes
 357 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 358         AS_CASE("x${enableval}",
 359                 [xyes], [have_utmp=yes],
 360                 [xno],  [have_utmp=no],
 361                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 362 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 363 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 364
 365 # ------------------------------------------------------------------------------
 366 have_compat_libs=no
 367 AC_ARG_ENABLE([compat_libs], AS_HELP_STRING([--enable-compat-libs],[Enable creation of compatibility libraries]),
 368                 [case "${enableval}" in
 369                         yes) have_compat_libs=yes ;;
 370                         no) have_compat_libs=no ;;
 371                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libs) ;;
 372                 esac],
 373                 [have_compat_libs=no])
 374 AM_CONDITIONAL([ENABLE_COMPAT_LIBS], [test "$have_compat_libs" = "yes"])
 375
 376 # ------------------------------------------------------------------------------
 377 have_coverage=no
 378 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 379 if test "x$enable_coverage" = "xyes" ; then
 380         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 381         if test "x$lcov_found" = xno ; then
 382                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 383         else
 384                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 385                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 386                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 387                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 388                 else
 389                         have_coverage=yes
 390                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 391                         -fprofile-arcs \
 392                         -ftest-coverage])
 393                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 394                 fi
 395         fi
 396 fi
 397 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 398
 399 # ------------------------------------------------------------------------------
 400 have_kmod=no
 401 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 402 if test "x$enable_kmod" != "xno"; then
 403         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 404         if test "x$have_kmod" = "xyes"; then
 405                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 406                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 407                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 408         fi
 409         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 410                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 411         fi
 412 fi
 413 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 414
 415 # ------------------------------------------------------------------------------
 416 have_xkbcommon=no
 417 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 418 if test "x$enable_xkbcommon" != "xno"; then
 419         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 420                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 421         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 422                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 423         fi
 424 fi
 425 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 426
 427 # ------------------------------------------------------------------------------
 428 have_blkid=no
 429 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 430 if test "x$enable_blkid" != "xno"; then
 431         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 432                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 433         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 434                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 435         fi
 436 fi
 437 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 438
 439 # ------------------------------------------------------------------------------
 440 have_libmount=no
 441 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 442         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 443 if test "x$have_libmount" = xno; then
 444         AC_MSG_ERROR([*** libmount support required but libraries not found])
 445 fi
 446 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 447
 448 # ------------------------------------------------------------------------------
 449 have_seccomp=no
 450 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 451 if test "x$enable_seccomp" != "xno"; then
 452         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 453                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 454                 have_seccomp=yes
 455                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 456                [have_seccomp=no])
 457         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 458                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 459         fi
 460 fi
 461 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 462
 463 # ------------------------------------------------------------------------------
 464 have_ima=yes
 465 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 466                 [case "${enableval}" in
 467                         yes) have_ima=yes ;;
 468                         no) have_ima=no ;;
 469                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 470                 esac],
 471                 [have_ima=yes])
 472
 473 if test "x${have_ima}" != xno ; then
 474         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 475 fi
 476
 477 # ------------------------------------------------------------------------------
 478 have_selinux=no
 479 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 480 if test "x$enable_selinux" != "xno"; then
 481         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 482                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 483                  have_selinux=yes
 484                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 485                 [have_selinux=no])
 486         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 487                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 488         fi
 489 fi
 490 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 491
 492 have_apparmor=no
 493 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 494 if test "x$enable_apparmor" != "xno"; then
 495         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 496                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 497                  have_apparmor=yes
 498                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 499                 [have_apparmor=no])
 500         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 501                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 502         fi
 503 fi
 504 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 505
 506
 507 AC_ARG_WITH(debug-shell,
 508         AS_HELP_STRING([--with-debug-shell=PATH],
 509                 [Path to debug shell binary]),
 510         [SUSHELL="$withval"],[
 511         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 512
 513 AC_SUBST(SUSHELL)
 514
 515 AC_ARG_WITH([debug-tty],
 516         AS_HELP_STRING([--with-debug-tty=PATH],
 517                 [Specify the tty device for debug shell]),
 518         [DEBUGTTY="$withval"],
 519         [DEBUGTTY=/dev/tty9])
 520
 521 AC_SUBST(DEBUGTTY)
 522
 523 AC_ARG_WITH([certificate-root],
 524         AS_HELP_STRING([--with-certificate-root=PATH],
 525                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 526         [CERTIFICATEROOT="$withval"],
 527         [CERTIFICATEROOT="/etc/ssl"])
 528
 529 AC_SUBST(CERTIFICATEROOT)
 530
 531 # ------------------------------------------------------------------------------
 532 have_xz=no
 533 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 534 AS_IF([test "x$enable_xz" != "xno"], [
 535         PKG_CHECK_MODULES(XZ, [ liblzma ],
 536                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 537                  have_xz=yes],
 538                  have_xz=no)
 539         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 540               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 541 ])
 542 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 543
 544 # ------------------------------------------------------------------------------
 545 have_zlib=no
 546 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 547 AS_IF([test "x$enable_zlib" != "xno"], [
 548         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 549                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 550                  have_zlib=yes],
 551                  have_zlib=no)
 552         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 553               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 554 ])
 555 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 556
 557 # ------------------------------------------------------------------------------
 558 have_bzip2=no
 559 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Disable optional BZIP2 support]))
 560 AS_IF([test "x$enable_bzip2" != "xno"], [
 561         AC_CHECK_HEADERS(bzlib.h,
 562                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 563                  have_bzip2=yes],
 564                 [AS_IF([test "x$enable_bzip2" = xyes],
 565                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 566         )
 567 ])
 568 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 569
 570 # ------------------------------------------------------------------------------
 571 have_lz4=no
 572 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [Disable optional LZ4 support]))
 573 AS_IF([test "x$enable_lz4" != "xno"], [
 574         PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 575                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available])
 576                 have_lz4=yes],
 577                 have_lz4=no)
 578         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 579               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 580 ])
 581 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 582
 583 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 584
 585 # ------------------------------------------------------------------------------
 586 AC_ARG_ENABLE([pam],
 587         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 588                 [case "${enableval}" in
 589                         yes) have_pam=yes ;;
 590                         no) have_pam=no ;;
 591                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 592                 esac],
 593                 [have_pam=auto])
 594
 595 if test "x${have_pam}" != xno ; then
 596         AC_CHECK_HEADERS(
 597                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 598                 [have_pam=yes],
 599                 [if test "x$have_pam" = xyes ; then
 600                         AC_MSG_ERROR([*** PAM headers not found.])
 601                 fi])
 602
 603         AC_CHECK_LIB(
 604                 [pam],
 605                 [pam_syslog],
 606                 [have_pam=yes],
 607                 [if test "x$have_pam" = xyes ; then
 608                         AC_MSG_ERROR([*** libpam not found.])
 609                 fi])
 610
 611         if test "x$have_pam" = xyes ; then
 612                 PAM_LIBS="-lpam -lpam_misc"
 613                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 614                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 615         else
 616                 have_pam=no
 617         fi
 618 else
 619         PAM_LIBS=
 620 fi
 621 AC_SUBST(PAM_LIBS)
 622 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 623
 624 # ------------------------------------------------------------------------------
 625 AC_ARG_ENABLE([acl],
 626         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 627                 [case "${enableval}" in
 628                         yes) have_acl=yes ;;
 629                         no) have_acl=no ;;
 630                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 631                 esac],
 632                 [have_acl=auto])
 633
 634 if test "x${have_acl}" != xno ; then
 635         AC_CHECK_HEADERS(
 636                 [sys/acl.h acl/libacl.h],
 637                 [have_acl=yes],
 638                 [if test "x$have_acl" = xyes ; then
 639                         AC_MSG_ERROR([*** ACL headers not found.])
 640                 fi])
 641
 642         AC_CHECK_LIB(
 643                 [acl],
 644                 [acl_get_file],
 645                 [have_acl=yes],
 646                 [if test "x$have_acl" = xyes ; then
 647                         AC_MSG_ERROR([*** libacl not found.])
 648                 fi])
 649
 650         if test "x$have_acl" = xyes ; then
 651                 ACL_LIBS="-lacl"
 652                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 653                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 654         else
 655                 have_acl=no
 656         fi
 657 else
 658         ACL_LIBS=
 659 fi
 660 AC_SUBST(ACL_LIBS)
 661 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 662
 663 # ------------------------------------------------------------------------------
 664 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 665                 [case "${enableval}" in
 666                         yes) have_smack=yes ;;
 667                         no) have_smack=no ;;
 668                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 669                 esac],
 670                 [have_smack=auto])
 671
 672 if test "x${have_smack}" != xno; then
 673         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 674         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 675         have_smack=yes
 676 fi
 677
 678 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 679
 680 have_smack_run_label=no
 681 AC_ARG_WITH(smack-run-label,
 682 AS_HELP_STRING([--with-smack-run-label=STRING],
 683         [run systemd --system itself with a specific SMACK label]),
 684         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 685         [])
 686
 687 if test "x${have_smack_run_label}" = xyes; then
 688         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 689 fi
 690
 691 AC_ARG_WITH(smack-default-process-label,
 692 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 693         [default SMACK label for executed processes]),
 694         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 695         [])
 696
 697 # ------------------------------------------------------------------------------
 698 AC_ARG_ENABLE([gcrypt],
 699         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 700                 [case "${enableval}" in
 701                         yes) have_gcrypt=yes ;;
 702                         no) have_gcrypt=no ;;
 703                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 704                 esac],
 705                 [have_gcrypt=auto])
 706
 707 if test "x${have_gcrypt}" != xno ; then
 708         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 709                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 710         )
 711         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 712                         [1.4.5],
 713                         [have_gcrypt=yes],
 714                         dnl  If we have the gcrypt m4 macros, but don't have
 715                         dnl  gcrypt, throw an error if gcrypt is explicitly
 716                         dnl  requested.
 717                         [AM_PATH_LIBGCRYPT_FAIL]
 718                 )],
 719                 dnl  If we don't have the gcrypt m4 macros, but build with
 720                 dnl  gcrypt explicitly requested, throw an error.
 721                 [AM_PATH_LIBGCRYPT_FAIL]
 722         )
 723
 724         have_gpg_error=no
 725         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 726                         [1.12],
 727                         [have_gpg_error=yes],
 728                         [AM_PATH_LIBGCRYPT_FAIL]
 729                 )],
 730                 [AM_PATH_LIBGCRYPT_FAIL]
 731         )
 732
 733         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 734                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 735                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 736                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 737         else
 738                 have_gcrypt=no
 739                 have_gpg_error=no
 740         fi
 741 else
 742         GCRYPT_LIBS=
 743         GCRYPT_CFLAGS=
 744 fi
 745 AC_SUBST(GCRYPT_LIBS)
 746 AC_SUBST(GCRYPT_CFLAGS)
 747 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 748
 749 # ------------------------------------------------------------------------------
 750 AC_ARG_ENABLE([audit],
 751         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 752                 [case "${enableval}" in
 753                         yes) have_audit=yes ;;
 754                         no) have_audit=no ;;
 755                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 756                 esac],
 757                 [have_audit=auto])
 758
 759 if test "x${have_audit}" != xno ; then
 760         AC_CHECK_HEADERS(
 761                 [libaudit.h],
 762                 [have_audit=yes],
 763                 [if test "x$have_audit" = xyes ; then
 764                         AC_MSG_ERROR([*** AUDIT headers not found.])
 765                 fi])
 766
 767         AC_CHECK_LIB(
 768                 [audit],
 769                 [audit_open],
 770                 [have_audit=yes],
 771                 [if test "x$have_audit" = xyes ; then
 772                         AC_MSG_ERROR([*** libaudit not found.])
 773                 fi])
 774
 775         if test "x$have_audit" = xyes ; then
 776                 AUDIT_LIBS="-laudit"
 777                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 778         else
 779                 have_audit=no
 780         fi
 781 else
 782         AUDIT_LIBS=
 783 fi
 784 AC_SUBST(AUDIT_LIBS)
 785 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 786
 787 # ------------------------------------------------------------------------------
 788 AC_ARG_ENABLE([elfutils],
 789         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 790                 [case "${enableval}" in
 791                         yes) have_elfutils=yes ;;
 792                         no) have_elfutils=no ;;
 793                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 794                 esac],
 795                 [have_elfutils=auto])
 796
 797 if test "x${have_elfutils}" != xno ; then
 798         AC_CHECK_HEADERS(
 799                 [elfutils/libdwfl.h],
 800                 [],
 801                 [if test "x$have_elfutils" = xyes ; then
 802                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 803                 fi])
 804
 805         AC_CHECK_LIB(
 806                 [dw],
 807                 [dwfl_core_file_attach],
 808                 [have_elfutils=yes],
 809                 [if test "x$have_elfutils" = xyes ; then
 810                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 811                 fi])
 812
 813         if test "x$have_elfutils" = xyes ; then
 814                 ELFUTILS_LIBS="-lelf -ldw"
 815                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 816         else
 817                 have_elfutils=no
 818         fi
 819 else
 820         ELFUTILS_LIBS=
 821 fi
 822 AC_SUBST(ELFUTILS_LIBS)
 823 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 824
 825 # ------------------------------------------------------------------------------
 826 have_libcryptsetup=no
 827 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 828 if test "x$enable_libcryptsetup" != "xno"; then
 829         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 830                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 831         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 832                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 833         fi
 834 fi
 835 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 836
 837 # ------------------------------------------------------------------------------
 838 have_qrencode=no
 839 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 840 if test "x$enable_qrencode" != "xno"; then
 841         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 842                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 843         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 844                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 845         fi
 846 fi
 847 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 848
 849 # ------------------------------------------------------------------------------
 850 have_gnutls=no
 851 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 852 if test "x$enable_gnutls" != "xno"; then
 853         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 854                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 855         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 856                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 857         fi
 858 fi
 859 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 860
 861 # ------------------------------------------------------------------------------
 862 have_microhttpd=no
 863 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 864 if test "x$enable_microhttpd" != "xno"; then
 865         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 866                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 867                  have_microhttpd=yes
 868                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 869                 [have_microhttpd=no])
 870         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 871                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 872         fi
 873 fi
 874 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 875
 876 # ------------------------------------------------------------------------------
 877 have_libcurl=no
 878 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 879 if test "x$enable_libcurl" != "xno"; then
 880         PKG_CHECK_MODULES(LIBCURL, [libcurl],
 881                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 882                  have_libcurl=yes
 883                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 884                 [have_libcurl=no])
 885         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 886                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 887         fi
 888 fi
 889 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 890
 891 # ------------------------------------------------------------------------------
 892 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 893
 894 # ------------------------------------------------------------------------------
 895 have_libidn=no
 896 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 897 if test "x$enable_libidn" != "xno"; then
 898         PKG_CHECK_MODULES(LIBIDN, [libidn],
 899                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 900                 have_libidn=yes
 901                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 902                [have_libidn=no])
 903         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 904                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 905         fi
 906 fi
 907 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 908
 909 # ------------------------------------------------------------------------------
 910 have_libiptc=no
 911 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 912 if test "x$enable_libiptc" != "xno"; then
 913         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 914                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 915                 have_libiptc=yes
 916                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 917                [have_libiptc=no])
 918         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 919                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 920         fi
 921 fi
 922 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 923
 924 # ------------------------------------------------------------------------------
 925 have_binfmt=no
 926 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 927 if test "x$enable_binfmt" != "xno"; then
 928         have_binfmt=yes
 929 fi
 930 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 931
 932 # ------------------------------------------------------------------------------
 933 have_vconsole=no
 934 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 935 if test "x$enable_vconsole" != "xno"; then
 936         have_vconsole=yes
 937 fi
 938 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 939
 940 # ------------------------------------------------------------------------------
 941 have_bootchart=no
 942 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 943 if test "x$enable_bootchart" != "xno"; then
 944         have_bootchart=yes
 945 fi
 946 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 947
 948 # ------------------------------------------------------------------------------
 949 have_quotacheck=no
 950 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 951 if test "x$enable_quotacheck" != "xno"; then
 952         have_quotacheck=yes
 953 fi
 954 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 955
 956 # ------------------------------------------------------------------------------
 957 have_tmpfiles=no
 958 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 959 if test "x$enable_tmpfiles" != "xno"; then
 960         have_tmpfiles=yes
 961 fi
 962 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 963
 964 # ------------------------------------------------------------------------------
 965 have_sysusers=no
 966 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 967 if test "x$enable_sysusers" != "xno"; then
 968         have_sysusers=yes
 969 fi
 970 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 971
 972 # ------------------------------------------------------------------------------
 973 have_firstboot=no
 974 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 975 if test "x$enable_firstboot" != "xno"; then
 976         have_firstboot=yes
 977 fi
 978 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 979
 980 # ------------------------------------------------------------------------------
 981 have_randomseed=no
 982 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 983 if test "x$enable_randomseed" != "xno"; then
 984         have_randomseed=yes
 985 fi
 986 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 987
 988 # ------------------------------------------------------------------------------
 989 have_backlight=no
 990 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 991 if test "x$enable_backlight" != "xno"; then
 992         have_backlight=yes
 993 fi
 994 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 995
 996 # ------------------------------------------------------------------------------
 997 have_rfkill=no
 998 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
 999 if test "x$enable_rfkill" != "xno"; then
1000         have_rfkill=yes
1001 fi
1002 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1003
1004 # ------------------------------------------------------------------------------
1005 have_logind=no
1006 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1007 if test "x$enable_logind" != "xno"; then
1008         have_logind=yes
1009 fi
1010 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1011 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1012
1013 # ------------------------------------------------------------------------------
1014 have_machined=no
1015 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1016 if test "x$enable_machined" != "xno"; then
1017         have_machined=yes
1018 fi
1019 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1020 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
1021
1022 # ------------------------------------------------------------------------------
1023 have_importd=no
1024 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1025 if test "x$enable_importd" != "xno"; then
1026         have_importd=yes
1027 fi
1028 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1029 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1030
1031 # ------------------------------------------------------------------------------
1032 have_hostnamed=no
1033 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1034 if test "x$enable_hostnamed" != "xno"; then
1035         have_hostnamed=yes
1036 fi
1037 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1038
1039 # ------------------------------------------------------------------------------
1040 have_timedated=no
1041 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1042 if test "x$enable_timedated" != "xno"; then
1043         have_timedated=yes
1044 fi
1045 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1046
1047 # ------------------------------------------------------------------------------
1048 have_timesyncd=no
1049 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1050 if test "x$enable_timesyncd" != "xno"; then
1051         have_timesyncd=yes
1052         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1053 fi
1054 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1055
1056 AC_ARG_WITH(ntp-servers,
1057         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1058                 [Space-separated list of default NTP servers]),
1059         [NTP_SERVERS="$withval"],
1060         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1061         AC_MSG_WARN([*** Using Google NTP servers.
1062                         Do not ship OSes or devices with these default settings.
1063                         See DISTRO_PORTING for details!])])
1064
1065 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1066 AC_SUBST(NTP_SERVERS)
1067
1068 AC_ARG_WITH(time-epoch,
1069         AS_HELP_STRING([--with-time-epoch=SECONDS],
1070                 [Time epoch for time clients]),
1071         [TIME_EPOCH="$withval"],
1072         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1073
1074 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1075
1076 # ------------------------------------------------------------------------------
1077 AC_ARG_WITH(system-uid-max,
1078         AS_HELP_STRING([--with-system-uid-max=UID]
1079                 [Maximum UID for system users]),
1080         [SYSTEM_UID_MAX="$withval"],
1081         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1082
1083 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1084 AC_SUBST(SYSTEM_UID_MAX)
1085
1086 # ------------------------------------------------------------------------------
1087 AC_ARG_WITH(system-gid-max,
1088         AS_HELP_STRING([--with-system-gid-max=GID]
1089                 [Maximum GID for system groups]),
1090         [SYSTEM_GID_MAX="$withval"],
1091         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1092
1093 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1094 AC_SUBST(SYSTEM_GID_MAX)
1095
1096 # ------------------------------------------------------------------------------
1097 have_localed=no
1098 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1099 if test "x$enable_localed" != "xno"; then
1100         have_localed=yes
1101 fi
1102 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1103
1104 # ------------------------------------------------------------------------------
1105 have_coredump=no
1106 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1107 if test "x$enable_coredump" != "xno"; then
1108         have_coredump=yes
1109 fi
1110 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1111
1112 # ------------------------------------------------------------------------------
1113 have_polkit=no
1114 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1115 if test "x$enable_polkit" != "xno"; then
1116         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1117         have_polkit=yes
1118 fi
1119 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1120
1121 # ------------------------------------------------------------------------------
1122 have_resolved=no
1123 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1124 AS_IF([test "x$enable_resolved" != "xno"], [
1125         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1126
1127         have_resolved=yes
1128         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1129 ])
1130 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1131
1132 AC_ARG_WITH(dns-servers,
1133         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1134                 [Space-separated list of default DNS servers]),
1135         [DNS_SERVERS="$withval"],
1136         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1137
1138 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1139 AC_SUBST(DNS_SERVERS)
1140
1141 # ------------------------------------------------------------------------------
1142 have_networkd=no
1143 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1144 AS_IF([test "x$enable_networkd" != "xno"], [
1145         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1146         have_networkd=yes
1147         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1148 ])
1149 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1150
1151 # ------------------------------------------------------------------------------
1152 have_efi=no
1153 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1154 if test "x$enable_efi" != "xno"; then
1155         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1156         have_efi=yes
1157 fi
1158 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1159
1160 # ------------------------------------------------------------------------------
1161 AC_CHECK_TOOL(EFI_CC, gcc)
1162
1163 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1164
1165 AM_COND_IF(ARCH_IA32, [
1166         EFI_ARCH=ia32
1167         EFI_MACHINE_TYPE_NAME=ia32])
1168
1169 AM_COND_IF(ARCH_X86_64, [
1170         EFI_MACHINE_TYPE_NAME=x64])
1171
1172 AM_COND_IF(ARCH_AARCH64, [
1173         EFI_MACHINE_TYPE_NAME=aa64])
1174
1175 AC_SUBST([EFI_ARCH])
1176 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1177
1178 have_gnuefi=no
1179 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Disable optional gnuefi support]))
1180 AS_IF([test "x$enable_gnuefi" != "xno"], [
1181         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1182                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1183                  have_gnuefi=yes],
1184                 [AS_IF([test "x$enable_gnuefi" = xyes],
1185                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1186         ])
1187
1188         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1189
1190         EFI_LIB_DIR="$efiroot"
1191         AC_ARG_WITH(efi-libdir,
1192                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1193                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1194         )
1195         AC_SUBST([EFI_LIB_DIR])
1196
1197         have_efi_lds=no
1198         AC_ARG_WITH(efi-ldsdir,
1199                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1200                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1201                         [have_efi_lds=yes])],
1202                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1203                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1204                                        [have_efi_lds=yes && break])])])
1205         AS_IF([test "x$have_efi_lds" = xyes],
1206               [AC_SUBST([EFI_LDS_DIR])],
1207               [AS_IF([test "x$enable_gnuefi" = xyes],
1208                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1209                      [have_gnuefi=no])])
1210
1211         AC_ARG_WITH(efi-includedir,
1212                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1213                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1214         )
1215         AC_SUBST([EFI_INC_DIR])
1216 ])
1217 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1218
1219 # ------------------------------------------------------------------------------
1220 have_kdbus=no
1221 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
1222 if test "x$enable_kdbus" != "xno"; then
1223         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
1224         have_kdbus=yes
1225         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
1226 fi
1227 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
1228
1229 # ------------------------------------------------------------------------------
1230 AC_ARG_WITH(rc-local-script-path-start,
1231         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1232                 [Path to /etc/rc.local]),
1233         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1234         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1235
1236 AC_ARG_WITH(rc-local-script-path-stop,
1237         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1238                 [Path to /usr/sbin/halt.local]),
1239         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1240         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1241
1242 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1243 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1244
1245 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1246 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1247
1248 # ------------------------------------------------------------------------------
1249 AC_ARG_WITH(kbd-loadkeys,
1250         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1251                 [Path to loadkeys]),
1252         [KBD_LOADKEYS="$withval"],
1253         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1254
1255 AC_ARG_WITH(kbd-setfont,
1256         AS_HELP_STRING([--with-kbd-setfont=PATH],
1257                 [Path to setfont]),
1258         [KBD_SETFONT="$withval"],
1259         [KBD_SETFONT="/usr/bin/setfont"])
1260
1261 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1262 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1263
1264 AC_SUBST(KBD_LOADKEYS)
1265 AC_SUBST(KBD_SETFONT)
1266
1267 AC_ARG_WITH(telinit,
1268         AS_HELP_STRING([--with-telinit=PATH],
1269                 [Path to telinit]),
1270         [TELINIT="$withval"],
1271         [TELINIT="/lib/sysvinit/telinit"])
1272
1273 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1274
1275 AC_SUBST(TELINIT)
1276
1277 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1278
1279 # ------------------------------------------------------------------------------
1280 have_myhostname=no
1281 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1282 if test "x$enable_myhostname" != "xno"; then
1283         AC_HEADER_STDC
1284         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1285
1286         AC_C_CONST
1287         AC_TYPE_SIZE_T
1288         AC_HEADER_TIME
1289
1290         AC_FUNC_SELECT_ARGTYPES
1291         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1292
1293         have_myhostname=yes
1294 fi
1295 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1296
1297 # ------------------------------------------------------------------------------
1298 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1299        enable_hwdb=$enableval, enable_hwdb=yes)
1300 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1301
1302 # ------------------------------------------------------------------------------
1303 have_manpages=no
1304 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1305 AC_PATH_PROG([XSLTPROC], [xsltproc])
1306 AS_IF([test "x$enable_manpages" != xno], [
1307        have_manpages=yes
1308        AS_IF([test -z "$XSLTPROC"],
1309              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1310 ])
1311 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1312
1313 # ------------------------------------------------------------------------------
1314 AC_ARG_ENABLE(hibernate,
1315        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1316        enable_hibernate=$enableval, enable_hibernate=yes)
1317 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1318
1319 # ------------------------------------------------------------------------------
1320 AC_ARG_ENABLE(ldconfig,
1321        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1322        enable_ldconfig=$enableval, enable_ldconfig=yes)
1323 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1324
1325 # ------------------------------------------------------------------------------
1326 # Location of the init scripts as mandated by LSB
1327 SYSTEM_SYSVINIT_PATH=/etc/init.d
1328 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1329
1330 AC_ARG_WITH([sysvinit-path],
1331         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1332                 [Specify the path to where the SysV init scripts are located])],
1333         [SYSTEM_SYSVINIT_PATH="$withval"],
1334         [])
1335
1336 AC_ARG_WITH([sysvrcnd-path],
1337         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1338                 [Specify the path to the base directory for the SysV rcN.d directories])],
1339         [SYSTEM_SYSVRCND_PATH="$withval"],
1340         [])
1341
1342 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1343         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1344         SYSTEM_SYSV_COMPAT="yes"
1345         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1346 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1347         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1348 else
1349         SYSTEM_SYSV_COMPAT="no"
1350 fi
1351
1352 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1353 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1354 AC_SUBST(M4_DEFINES)
1355
1356 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1357
1358 AC_ARG_WITH([tty-gid],
1359         [AS_HELP_STRING([--with-tty-gid=GID],
1360                 [Specify the numeric GID of the 'tty' group])],
1361         [TTY_GID="$withval"],
1362         [TTY_GID="5"])
1363
1364 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1365 AC_SUBST(TTY_GID)
1366
1367 AC_ARG_WITH([dbuspolicydir],
1368         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1369         [],
1370         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1371 AX_NORMALIZE_PATH([with_dbuspolicydir])
1372
1373 AC_ARG_WITH([dbussessionservicedir],
1374         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1375         [],
1376         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1377 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1378
1379 AC_ARG_WITH([dbussystemservicedir],
1380         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1381         [],
1382         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1383 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1384
1385 AC_ARG_WITH([bashcompletiondir],
1386         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1387         [],
1388         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1389                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1390         ] , [
1391                 with_bashcompletiondir=${datadir}/bash-completion/completions
1392         ])])
1393 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1394 AX_NORMALIZE_PATH([with_bashcompletiondir])
1395
1396 AC_ARG_WITH([zshcompletiondir],
1397         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1398         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1399 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1400 AX_NORMALIZE_PATH([with_zshcompletiondir])
1401
1402 AC_ARG_WITH([rootprefix],
1403         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1404         [], [with_rootprefix=${ac_default_prefix}])
1405 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1406 # defaults those to ".", solve that here for now until we can find a suitable
1407 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1408 # See: https://github.com/systemd/systemd/issues/54
1409 if test "x${with_rootprefix}" = "x"; then
1410         with_rootprefix="/"
1411 fi
1412 AX_NORMALIZE_PATH([with_rootprefix])
1413
1414 AC_ARG_WITH([rootlibdir],
1415         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1416         [],
1417         [with_rootlibdir=${libdir}])
1418 AX_NORMALIZE_PATH([with_rootlibdir])
1419
1420 AC_ARG_WITH([pamlibdir],
1421         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1422         [],
1423         [with_pamlibdir=${with_rootlibdir}/security])
1424 AX_NORMALIZE_PATH([with_pamlibdir])
1425
1426 AC_ARG_WITH([pamconfdir],
1427         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1428         [],
1429         [with_pamconfdir=${sysconfdir}/pam.d])
1430 AX_NORMALIZE_PATH([with_pamconfdir])
1431
1432 AC_ARG_ENABLE([split-usr],
1433         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1434         [],
1435         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1436                 enable_split_usr=yes
1437         ], [
1438                 enable_split_usr=no
1439         ])])
1440
1441 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1442         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1443 ])
1444 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1445
1446 # work around intltool-update issues during 'make distcheck'
1447 AS_IF([test "x$0" != "x./configure"], [
1448         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1449 ])
1450
1451 # QEMU and OVMF UEFI firmware
1452 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1453         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1454         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1455                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1456         AC_SUBST([QEMU_BIOS])
1457 ])
1458
1459 AC_ARG_ENABLE(tests,
1460         [AC_HELP_STRING([--disable-tests], [disable tests])],
1461         enable_tests=$enableval, enable_tests=yes)
1462 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1463
1464 AC_ARG_ENABLE(debug,
1465         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1466         [if test "x$enableval" = "xyes"; then
1467                 enableval="hashmap,mmap-cache"
1468         fi
1469         saved_ifs="$IFS"
1470         IFS="$IFS$PATH_SEPARATOR,"
1471         for name in $enableval; do
1472                 case $name in
1473                 hashmap)
1474                         enable_debug_hashmap=yes
1475                         ;;
1476                 mmap-cache)
1477                         enable_debug_mmap_cache=yes
1478                         ;;
1479                 esac
1480         done
1481         IFS="$saved_ifs"],[])
1482
1483 enable_debug=""
1484 AS_IF([test x$enable_debug_hashmap = xyes], [
1485         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1486         enable_debug="hashmap $enable_debug"
1487 ])
1488 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1489         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1490         enable_debug="mmap-cache $enable_debug"
1491 ])
1492 test -z "$enable_debug" && enable_debug="none"
1493
1494 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1495 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1496 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1497 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1498 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1499 AC_SUBST([pamlibdir], [$with_pamlibdir])
1500 AC_SUBST([pamconfdir], [$with_pamconfdir])
1501 AC_SUBST([rootprefix], [$with_rootprefix])
1502 AC_SUBST([rootlibdir], [$with_rootlibdir])
1503
1504 AC_CONFIG_FILES([
1505         Makefile
1506         po/Makefile.in
1507 ])
1508
1509 AC_OUTPUT
1510 AC_MSG_RESULT([
1511         $PACKAGE_NAME $VERSION
1512
1513         libcryptsetup:           ${have_libcryptsetup}
1514         PAM:                     ${have_pam}
1515         AUDIT:                   ${have_audit}
1516         IMA:                     ${have_ima}
1517         AppArmor:                ${have_apparmor}
1518         SELinux:                 ${have_selinux}
1519         SECCOMP:                 ${have_seccomp}
1520         SMACK:                   ${have_smack}
1521         ZLIB:                    ${have_zlib}
1522         XZ:                      ${have_xz}
1523         LZ4:                     ${have_lz4}
1524         BZIP2:                   ${have_bzip2}
1525         ACL:                     ${have_acl}
1526         GCRYPT:                  ${have_gcrypt}
1527         QRENCODE:                ${have_qrencode}
1528         MICROHTTPD:              ${have_microhttpd}
1529         GNUTLS:                  ${have_gnutls}
1530         libcurl:                 ${have_libcurl}
1531         libidn:                  ${have_libidn}
1532         libiptc:                 ${have_libiptc}
1533         ELFUTILS:                ${have_elfutils}
1534         binfmt:                  ${have_binfmt}
1535         vconsole:                ${have_vconsole}
1536         bootchart:               ${have_bootchart}
1537         quotacheck:              ${have_quotacheck}
1538         tmpfiles:                ${have_tmpfiles}
1539         sysusers:                ${have_sysusers}
1540         firstboot:               ${have_firstboot}
1541         randomseed:              ${have_randomseed}
1542         backlight:               ${have_backlight}
1543         rfkill:                  ${have_rfkill}
1544         logind:                  ${have_logind}
1545         machined:                ${have_machined}
1546         importd:                 ${have_importd}
1547         hostnamed:               ${have_hostnamed}
1548         timedated:               ${have_timedated}
1549         timesyncd:               ${have_timesyncd}
1550         default NTP servers:     ${NTP_SERVERS}
1551         time epoch:              ${TIME_EPOCH}
1552         localed:                 ${have_localed}
1553         networkd:                ${have_networkd}
1554         resolved:                ${have_resolved}
1555         default DNS servers:     ${DNS_SERVERS}
1556         coredump:                ${have_coredump}
1557         polkit:                  ${have_polkit}
1558         efi:                     ${have_efi}
1559         gnuefi:                  ${have_gnuefi}
1560         efi arch:                ${EFI_ARCH}
1561         EFI machine type:        ${EFI_MACHINE_TYPE_NAME}
1562         EFI CC                   ${EFI_CC}
1563         EFI libdir:              ${EFI_LIB_DIR}
1564         EFI ldsdir:              ${EFI_LDS_DIR}
1565         EFI includedir:          ${EFI_INC_DIR}
1566         kmod:                    ${have_kmod}
1567         xkbcommon:               ${have_xkbcommon}
1568         blkid:                   ${have_blkid}
1569         libmount:                ${have_libmount}
1570         dbus:                    ${have_dbus}
1571         nss-myhostname:          ${have_myhostname}
1572         hwdb:                    ${enable_hwdb}
1573         kdbus:                   ${have_kdbus}
1574         Python:                  ${have_python}
1575         man pages:               ${have_manpages}
1576         test coverage:           ${have_coverage}
1577         Split /usr:              ${enable_split_usr}
1578         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1579         compatibility libraries: ${have_compat_libs}
1580         utmp/wtmp support:       ${have_utmp}
1581         ldconfig support:        ${enable_ldconfig}
1582         hibernate support:       ${enable_hibernate}
1583         extra debugging:         ${enable_debug}
1584
1585         prefix:                  ${prefix}
1586         rootprefix:              ${with_rootprefix}
1587         sysconf dir:             ${sysconfdir}
1588         datarootdir:             ${datarootdir}
1589         includedir:              ${includedir}
1590         lib dir:                 ${libdir}
1591         rootlib dir:             ${with_rootlibdir}
1592         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1593         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1594         Build Python:            ${PYTHON}
1595         PAM modules dir:         ${with_pamlibdir}
1596         PAM configuration dir:   ${with_pamconfdir}
1597         D-Bus policy dir:        ${with_dbuspolicydir}
1598         D-Bus session dir:       ${with_dbussessionservicedir}
1599         D-Bus system dir:        ${with_dbussystemservicedir}
1600         Bash completions dir:    ${with_bashcompletiondir}
1601         Zsh completions dir:     ${with_zshcompletiondir}
1602         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1603         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1604         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1605         TTY GID:                 ${TTY_GID}
1606         Maximum System UID:      ${SYSTEM_UID_MAX}
1607         Maximum System GID:      ${SYSTEM_GID_MAX}
1608         Certificate root:        ${CERTIFICATEROOT}
1609
1610         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1611         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1612         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1613 ])