configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [233],
  24         [https://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [https://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(ARM, arm*)
  61 SET_ARCH(AARCH64, aarch64*)
  62
  63 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  64 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  65 AS_IF([test x"$intltool_found" != xyes],
  66       [AS_IF([test x"$enable_nls" = xyes],
  67              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  68              [AS_IF([test x"$enable_nls" != xno],
  69                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  70                      enable_nls=no])
  71              ])
  72       ])
  73
  74 AM_NLS
  75 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  76     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  77 IT_PROG_INTLTOOL([0.40.0])
  78 ])
  79
  80 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  81     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  82     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  83     AC_SUBST(INTLTOOL_POLICY_RULE)
  84 ])
  85
  86 GETTEXT_PACKAGE=systemd
  87 AC_SUBST(GETTEXT_PACKAGE)
  88 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  89
  90 AC_PROG_MKDIR_P
  91 AC_PROG_LN_S
  92 AC_PROG_SED
  93 AC_PROG_GREP
  94 AC_PROG_AWK
  95
  96 AC_PATH_PROG([M4], [m4])
  97
  98 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  99 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
 100
 101 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 102
 103 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 104
 105 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 106
 107 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 108
 109 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 110 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 111
 112 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 113
 114 M4_DEFINES=
 115
 116 AC_CHECK_TOOL(OBJCOPY, objcopy)
 117 AC_CHECK_TOOL(STRINGS, strings)
 118 AC_CHECK_TOOL(GPERF, gperf)
 119 if test -z "$GPERF" ; then
 120         AC_MSG_ERROR([*** gperf not found])
 121 fi
 122
 123 # ------------------------------------------------------------------------------
 124 address_sanitizer_cflags=
 125 address_sanitizer_cppflags=
 126 address_sanitizer_ldflags=
 127 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 128 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 129             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 130             AS_IF([test -z "$with_as_cflags"],
 131                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 132             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 133             address_sanitizer_cppflags="-DVALGRIND=1"
 134             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 135       ])
 136
 137 undefined_sanitizer_cflags=
 138 undefined_sanitizer_cppflags=
 139 undefined_sanitizer_ldflags=
 140 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 141 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 142             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 143             AS_IF([test -z "$with_us_cflags"],
 144                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 145             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 146             undefined_sanitizer_cppflags="-DVALGRIND=1"
 147             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 148       ])
 149
 150 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 151 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 152 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 153
 154 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 155         -pipe \
 156         -Wall \
 157         -Wextra \
 158         -Wundef \
 159         -Wlogical-op \
 160         -Wmissing-include-dirs \
 161         -Wold-style-definition \
 162         -Wpointer-arith \
 163         -Winit-self \
 164         -Wdeclaration-after-statement \
 165         -Wfloat-equal \
 166         -Wsuggest-attribute=noreturn \
 167         -Werror=missing-prototypes \
 168         -Werror=implicit-function-declaration \
 169         -Werror=missing-declarations \
 170         -Werror=return-type \
 171         -Werror=incompatible-pointer-types \
 172         -Werror=format=2 \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AC_ARG_ENABLE([lto], [AS_HELP_STRING([--disable-lto], [disable -flto])],
 215                      [], [enable_lto=yes])
 216 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 217         [AS_IF([test "x$enable_lto" = "xyes"],
 218                [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-flto])],
 219                [AC_MSG_RESULT([disabling -flto as requested])])],
 220         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 221
 222 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 223         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 224                -Wp,-D_FORTIFY_SOURCE=2])],
 225         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 226
 227 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 228         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 229                -Wl,--gc-sections])],
 230         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 231
 232 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 233         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 234                -ffunction-sections -fdata-sections])],
 235         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 236
 237 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 238         -Wl,--as-needed \
 239         -Wl,--no-undefined \
 240         -Wl,-z,relro \
 241         -Wl,-z,now \
 242         -pie \
 243         -Wl,-fuse-ld=gold])
 244
 245 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 246 AC_SUBST([OUR_CFLAGS], "-D__SANE_USERSPACE_TYPES__ $with_cflags $sanitizer_cflags")
 247 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 248
 249 AC_CHECK_SIZEOF(pid_t)
 250 AC_CHECK_SIZEOF(uid_t)
 251 AC_CHECK_SIZEOF(gid_t)
 252 AC_CHECK_SIZEOF(time_t)
 253 AC_CHECK_SIZEOF(dev_t)
 254 AC_CHECK_SIZEOF(ino_t)
 255 AC_CHECK_SIZEOF(rlim_t,,[
 256        #include <sys/time.h>
 257        #include <sys/resource.h>
 258 ])
 259
 260 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
 261
 262 AC_COMPILE_IFELSE(
 263         [AC_LANG_PROGRAM([
 264                 #include <string.h>
 265                 const char * in_word_set(const char *, size_t);
 266                 $GPERF_TEST]
 267         )],
 268         [GPERF_LEN_TYPE=size_t],
 269         [AC_COMPILE_IFELSE(
 270                 [AC_LANG_PROGRAM([
 271                         #include <string.h>
 272                         const char * in_word_set(const char *, unsigned);
 273                         $GPERF_TEST]
 274                 )],
 275                 [GPERF_LEN_TYPE=unsigned],
 276                 [AC_MSG_ERROR([** unable to determine gperf len type])]
 277         )]
 278 )
 279
 280 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
 281
 282 # ------------------------------------------------------------------------------
 283 # we use python to build the man page index
 284 have_python=no
 285 AC_ARG_WITH([python],
 286         [AS_HELP_STRING([--without-python], [disable building the man page index and systemd-python (default: test)])])
 287
 288 have_lxml=no
 289 AS_IF([test "x$with_python" != "xno"], [
 290         AM_PATH_PYTHON([3],, [:])
 291         AS_IF([test "x$PYTHON" != "x:"], [
 292                 AC_MSG_CHECKING([for python lxml module])
 293                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 294                 AC_MSG_RESULT([$have_lxml])
 295                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 296                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 297         ])
 298 ])
 299 AS_IF([test "$have_python" != "yes"], [
 300       AS_IF([test "$with_python" = "yes"],
 301             [AC_MSG_ERROR([*** python support requested but python support not found])])
 302       AS_IF([test "$with_python" != "no"],
 303             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 304 ])
 305 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 306
 307 # ------------------------------------------------------------------------------
 308
 309 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 310 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 311 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 312 AC_CHECK_HEADERS([linux/vm_sockets.h], [], [], [#include <sys/socket.h>])
 313
 314 # unconditionally pull-in librt with old glibc versions
 315 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 316
 317 save_LIBS="$LIBS"
 318 LIBS=
 319 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 320 CAP_LIBS="$LIBS"
 321 LIBS="$save_LIBS"
 322 AC_SUBST(CAP_LIBS)
 323
 324 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 325 AC_CHECK_DECLS([
 326         memfd_create,
 327         gettid,
 328         pivot_root,
 329         name_to_handle_at,
 330         setns,
 331         renameat2,
 332         kcmp,
 333         keyctl,
 334         LO_FLAGS_PARTSCAN,
 335         copy_file_range,
 336         explicit_bzero],
 337         [], [], [[
 338 #include <sys/types.h>
 339 #include <unistd.h>
 340 #include <sys/mount.h>
 341 #include <fcntl.h>
 342 #include <sched.h>
 343 #include <string.h>
 344 #include <linux/loop.h>
 345 ]])
 346
 347 AC_CHECK_DECLS([getrandom],
 348                [AC_DEFINE([USE_SYS_RANDOM_H], [], [sys/random.h is usable])],
 349                [AC_CHECK_DECLS([getrandom], [], [], [[
 350 #include <sys/random.h>
 351 ]])], [[
 352 #include <linux/random.h>
 353 ]])
 354
 355 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t, struct ethtool_link_settings],
 356                [], [], [[
 357 #include <uchar.h>
 358 #include <linux/ethtool.h>
 359 ]])
 360
 361 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 362                 IN6_ADDR_GEN_MODE_STABLE_PRIVACY,
 363                 IFLA_VRF_TABLE,
 364                 IFLA_MACVLAN_FLAGS,
 365                 IFLA_IPVLAN_MODE,
 366                 IFLA_VTI_REMOTE,
 367                 IFLA_PHYS_PORT_ID,
 368                 IFLA_BOND_AD_INFO,
 369                 IFLA_VLAN_PROTOCOL,
 370                 IFLA_VXLAN_GPE,
 371                 IFLA_GENEVE_LABEL,
 372                 IFLA_IPTUN_ENCAP_DPORT,
 373                 IFLA_GRE_ENCAP_DPORT,
 374                 IFLA_BRIDGE_VLAN_INFO,
 375                 IFLA_BRPORT_PROXYARP,
 376                 IFLA_BRPORT_LEARNING_SYNC,
 377                 IFLA_BR_VLAN_DEFAULT_PVID,
 378                 NDA_IFINDEX,
 379                 IFA_FLAGS],
 380 [], [], [[
 381 #include <inttypes.h>
 382 #include <netinet/in.h>
 383 #include <netinet/ether.h>
 384 #include <linux/rtnetlink.h>
 385 #include <net/if.h>
 386 #include <linux/ip.h>
 387 #include <linux/if_tunnel.h>
 388 #include <linux/if_link.h>
 389 #include <linux/if_bridge.h>
 390 #include <linux/if_addr.h>
 391 #include <linux/neighbour.h>
 392 ]])
 393
 394 # This makes sure pkg.m4 is available.
 395 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 396
 397 # ------------------------------------------------------------------------------
 398 have_dbus=no
 399 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 400 AS_IF([test "x$enable_dbus" != "xno"], [
 401         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 402                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 403                 [have_dbus=no])
 404         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 405                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 406 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 407
 408 # ------------------------------------------------------------------------------
 409 have_glib=no
 410 AC_ARG_ENABLE(glib, AS_HELP_STRING([--disable-glib], [disable usage of glib,gobject,gio in tests]))
 411 AS_IF([test "x$enable_glib" != "xno"], [
 412         PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 413                 [AC_DEFINE(HAVE_GLIB, 1, [Define if glib,gobject,gio are available]) have_glib=yes],
 414                 [have_glib=no])
 415         AS_IF([test "x$have_glib" = "xno" -a "x$enable_glib" = "xyes"],
 416                 [AC_MSG_ERROR([*** glib support requested but libraries not found])])])
 417
 418 # ------------------------------------------------------------------------------
 419 have_utmp=yes
 420 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 421         AS_CASE("x${enableval}",
 422                 [xyes], [have_utmp=yes],
 423                 [xno],  [have_utmp=no],
 424                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 425 AS_IF([test "x$have_utmp" = "xyes"], [
 426         AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])
 427         have_utmp=yes
 428         M4_DEFINES="$M4_DEFINES -DHAVE_UTMP"],
 429         [have_utmp=no])
 430 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 431
 432 # ------------------------------------------------------------------------------
 433 have_coverage=no
 434 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 435 if test "x$enable_coverage" = "xyes" ; then
 436         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 437         if test "x$lcov_found" = xno ; then
 438                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 439         else
 440                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 441                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 442                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 443                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 444                 else
 445                         have_coverage=yes
 446                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 447                         -fprofile-arcs \
 448                         -ftest-coverage])
 449                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 450                 fi
 451         fi
 452 fi
 453 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 454
 455 # ------------------------------------------------------------------------------
 456 have_kmod=no
 457 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 458 if test "x$enable_kmod" != "xno"; then
 459         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 460         if test "x$have_kmod" = "xyes"; then
 461                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 462                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 463                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 464         fi
 465         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 466                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 467         fi
 468 fi
 469 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 470
 471 # ------------------------------------------------------------------------------
 472 have_xkbcommon=no
 473 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 474 if test "x$enable_xkbcommon" != "xno"; then
 475         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 476                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 477         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 478                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 479         fi
 480 fi
 481 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 482
 483 # ------------------------------------------------------------------------------
 484 have_blkid=no
 485 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 486 if test "x$enable_blkid" != "xno"; then
 487         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 488                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 489         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 490                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 491         fi
 492 fi
 493 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 494
 495 # ------------------------------------------------------------------------------
 496 have_libmount=no
 497 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 498         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 499 if test "x$have_libmount" = xno; then
 500         AC_MSG_ERROR([*** libmount support required but libraries not found])
 501 fi
 502 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 503
 504 # ------------------------------------------------------------------------------
 505 have_seccomp=no
 506 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [disable optional SECCOMP support]))
 507 if test "x$enable_seccomp" != "xno"; then
 508         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 2.3.1],
 509                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 510                 have_seccomp=yes
 511                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 512                [have_seccomp=no])
 513         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 514                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 515         fi
 516 fi
 517 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 518
 519 # ------------------------------------------------------------------------------
 520 have_ima=yes
 521 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima], [disable optional IMA support]),
 522                 [case "${enableval}" in
 523                         yes) have_ima=yes ;;
 524                         no) have_ima=no ;;
 525                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 526                 esac],
 527                 [have_ima=yes])
 528
 529 if test "x${have_ima}" != xno ; then
 530         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 531 fi
 532
 533 # ------------------------------------------------------------------------------
 534 have_selinux=no
 535 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [disable optional SELINUX support]))
 536 if test "x$enable_selinux" != "xno"; then
 537         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 538                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 539                  have_selinux=yes
 540                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 541                 [have_selinux=no])
 542         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 543                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 544         fi
 545 fi
 546 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 547
 548 have_apparmor=no
 549 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [disable optional AppArmor support]))
 550 if test "x$enable_apparmor" != "xno"; then
 551         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 552                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 553                  have_apparmor=yes
 554                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 555                 [have_apparmor=no])
 556         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 557                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 558         fi
 559 fi
 560 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 561
 562 have_adm_group=no
 563 AC_ARG_ENABLE(adm-group, AS_HELP_STRING([--disable-adm-group], [disable adm group]))
 564 AS_IF([test "x$enable_adm_group" != "xno"], [
 565         AC_DEFINE(ENABLE_ADM_GROUP, 1, [Define if the ACL for adm group should be enabled])
 566         have_adm_group=yes
 567         M4_DEFINES="$M4_DEFINES -DENABLE_ADM_GROUP"
 568 ])
 569
 570 have_wheel_group=no
 571 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 572 AS_IF([test "x$enable_wheel_group" != "xno"], [
 573         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 574         have_wheel_group=yes
 575         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 576 ])
 577
 578
 579 AC_ARG_WITH(debug-shell,
 580         AS_HELP_STRING([--with-debug-shell=PATH],
 581                 [path to debug shell binary]),
 582         [SUSHELL="$withval"],
 583         [SUSHELL="/bin/sh"])
 584
 585 AC_SUBST(SUSHELL)
 586
 587 AC_ARG_WITH([debug-tty],
 588         AS_HELP_STRING([--with-debug-tty=PATH],
 589                 [specify the tty device for debug shell]),
 590         [DEBUGTTY="$withval"],
 591         [DEBUGTTY=/dev/tty9])
 592
 593 AC_SUBST(DEBUGTTY)
 594
 595 AC_ARG_WITH([certificate-root],
 596         AS_HELP_STRING([--with-certificate-root=PATH],
 597                 [specify the prefix for TLS certificates [/etc/ssl]]),
 598         [CERTIFICATEROOT="$withval"],
 599         [CERTIFICATEROOT="/etc/ssl"])
 600
 601 AC_SUBST(CERTIFICATEROOT)
 602
 603 AC_ARG_WITH([support-url],
 604         AS_HELP_STRING([--with-support-url=URL],
 605                 [specify the support URL to show in catalog entries included in systemd]),
 606         [SUPPORT_URL="$withval"],
 607         [SUPPORT_URL=https://lists.freedesktop.org/mailman/listinfo/systemd-devel])
 608
 609 AC_SUBST(SUPPORT_URL)
 610
 611 AC_ARG_WITH([nobody-user],
 612         AS_HELP_STRING([--with-nobody-user=NAME],
 613                 [specify the name of the nobody user (the one with UID 65534)]),
 614         [NOBODY_USER_NAME="$withval"],
 615         [NOBODY_USER_NAME=nobody])
 616
 617 AC_SUBST(NOBODY_USER_NAME)
 618 AC_DEFINE_UNQUOTED(NOBODY_USER_NAME, ["$NOBODY_USER_NAME"], [The name of the nobody user (the one with UID 65534)])
 619
 620 AC_ARG_WITH([nobody-group],
 621         AS_HELP_STRING([--with-nobody-group=NAME],
 622                 [specify the name of the nobody group (the one with GID 65534)]),
 623         [NOBODY_GROUP_NAME="$withval"],
 624         [NOBODY_GROUP_NAME=nobody])
 625
 626 AC_SUBST(NOBODY_GROUP_NAME)
 627 AC_DEFINE_UNQUOTED(NOBODY_GROUP_NAME, ["$NOBODY_GROUP_NAME"], [The name of the nobody group (the one with GID 65534)])
 628
 629 AC_ARG_WITH([fallback-hostname],
 630         AS_HELP_STRING([--with-fallback-hostname=NAME],
 631                 [specify the hostname used if none configured]),
 632         [FALLBACK_HOSTNAME="$withval"],
 633         [FALLBACK_HOSTNAME=localhost])
 634
 635 AC_SUBST(FALLBACK_HOSTNAME)
 636 AC_DEFINE_UNQUOTED(FALLBACK_HOSTNAME, ["$FALLBACK_HOSTNAME"], [The hostname used if none configured])
 637
 638 # ------------------------------------------------------------------------------
 639
 640 AC_ARG_WITH(default-hierarchy,
 641         AS_HELP_STRING([--with-default-hierarchy=MODE],
 642                 [default cgroup hierarchy, defaults to "hybrid"]),
 643         [DEFAULT_HIERARCHY="$withval"],
 644         [DEFAULT_HIERARCHY="hybrid"])
 645
 646 AS_CASE("$DEFAULT_HIERARCHY",
 647         [legacy], [mode=CGROUP_UNIFIED_NONE],
 648         [hybrid], [mode=CGROUP_UNIFIED_SYSTEMD],
 649         [unified], [mode=CGROUP_UNIFIED_ALL],
 650         AC_MSG_ERROR(Bad default hierarchy mode ${DEFAULT_HIERARCHY}))
 651 AC_DEFINE_UNQUOTED(DEFAULT_HIERARCHY, [$mode], [Default cgroup hierarchy])
 652 AC_DEFINE_UNQUOTED(DEFAULT_HIERARCHY_NAME, ["$DEFAULT_HIERARCHY"],
 653                                            [Default cgroup hierarchy as string])
 654
 655 # ------------------------------------------------------------------------------
 656 have_xz=no
 657 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [disable optional XZ support]))
 658 AS_IF([test "x$enable_xz" != "xno"], [
 659         PKG_CHECK_MODULES(XZ, [ liblzma ],
 660                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 661                  have_xz=yes],
 662                  have_xz=no)
 663         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 664               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 665 ])
 666 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 667
 668 # ------------------------------------------------------------------------------
 669 have_zlib=no
 670 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [disable optional ZLIB support]))
 671 AS_IF([test "x$enable_zlib" != "xno"], [
 672         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 673                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 674                  have_zlib=yes],
 675                  have_zlib=no)
 676         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 677               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 678 ])
 679 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 680
 681 # ------------------------------------------------------------------------------
 682 have_bzip2=no
 683 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--disable-bzip2], [disable optional BZIP2 support]))
 684 AS_IF([test "x$enable_bzip2" != "xno"], [
 685         AC_CHECK_HEADERS(bzlib.h,
 686                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 687                  have_bzip2=yes],
 688                 [AS_IF([test "x$enable_bzip2" = xyes],
 689                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 690         )
 691 ])
 692 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 693
 694 # ------------------------------------------------------------------------------
 695 have_lz4=no
 696 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [disable optional LZ4 support]))
 697 AS_IF([test "x$enable_lz4" != "xno"], [
 698         PKG_CHECK_MODULES(LZ4, [ liblz4 < 10 ],
 699                [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 700                 have_lz4=yes],
 701                 [PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 702                       [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 703                       have_lz4=yes],
 704                       have_lz4=no)])
 705         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 706               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 707 ])
 708 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 709
 710 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 711
 712 # ------------------------------------------------------------------------------
 713 AC_ARG_ENABLE([pam],
 714         AS_HELP_STRING([--disable-pam], [disable optional PAM support]),
 715                 [case "${enableval}" in
 716                         yes) have_pam=yes ;;
 717                         no) have_pam=no ;;
 718                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 719                 esac],
 720                 [have_pam=auto])
 721
 722 if test "x${have_pam}" != xno ; then
 723         AC_CHECK_HEADERS(
 724                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 725                 [have_pam=yes],
 726                 [if test "x$have_pam" = xyes ; then
 727                         AC_MSG_ERROR([*** PAM headers not found.])
 728                 fi])
 729
 730         AC_CHECK_LIB(
 731                 [pam],
 732                 [pam_syslog],
 733                 [have_pam=yes],
 734                 [if test "x$have_pam" = xyes ; then
 735                         AC_MSG_ERROR([*** libpam not found.])
 736                 fi])
 737
 738         if test "x$have_pam" = xyes ; then
 739                 PAM_LIBS="-lpam -lpam_misc"
 740                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 741                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 742         else
 743                 have_pam=no
 744         fi
 745 else
 746         PAM_LIBS=
 747 fi
 748 AC_SUBST(PAM_LIBS)
 749 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 750
 751 # ------------------------------------------------------------------------------
 752 AC_ARG_ENABLE([acl],
 753         AS_HELP_STRING([--disable-acl], [disable optional ACL support]),
 754                 [case "${enableval}" in
 755                         yes) have_acl=yes ;;
 756                         no) have_acl=no ;;
 757                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 758                 esac],
 759                 [have_acl=auto])
 760
 761 if test "x${have_acl}" != xno ; then
 762         AC_CHECK_HEADERS(
 763                 [sys/acl.h acl/libacl.h],
 764                 [have_acl=yes],
 765                 [if test "x$have_acl" = xyes ; then
 766                         AC_MSG_ERROR([*** ACL headers not found.])
 767                 fi])
 768
 769         AC_CHECK_LIB(
 770                 [acl],
 771                 [acl_get_file],
 772                 [have_acl=yes],
 773                 [if test "x$have_acl" = xyes ; then
 774                         AC_MSG_ERROR([*** libacl not found.])
 775                 fi])
 776
 777         if test "x$have_acl" = xyes ; then
 778                 ACL_LIBS="-lacl"
 779                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 780                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 781         else
 782                 have_acl=no
 783         fi
 784 else
 785         ACL_LIBS=
 786 fi
 787 AC_SUBST(ACL_LIBS)
 788 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 789
 790 # ------------------------------------------------------------------------------
 791 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack], [disable optional SMACK support]),
 792                 [case "${enableval}" in
 793                         yes) have_smack=yes ;;
 794                         no) have_smack=no ;;
 795                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 796                 esac],
 797                 [have_smack=auto])
 798
 799 if test "x${have_smack}" != xno; then
 800         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 801         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 802         have_smack=yes
 803 fi
 804
 805 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 806
 807 have_smack_run_label=no
 808 AC_ARG_WITH(smack-run-label,
 809 AS_HELP_STRING([--with-smack-run-label=STRING],
 810         [run systemd --system itself with a specific SMACK label]),
 811         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 812         [])
 813
 814 if test "x${have_smack_run_label}" = xyes; then
 815         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 816 fi
 817
 818 AC_ARG_WITH(smack-default-process-label,
 819 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 820         [default SMACK label for executed processes]),
 821         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 822         [])
 823
 824 # ------------------------------------------------------------------------------
 825 AC_ARG_ENABLE([gcrypt],
 826         AS_HELP_STRING([--disable-gcrypt], [disable optional GCRYPT support]),
 827                 [case "${enableval}" in
 828                         yes) have_gcrypt=yes ;;
 829                         no) have_gcrypt=no ;;
 830                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 831                 esac],
 832                 [have_gcrypt=auto])
 833
 834 if test "x${have_gcrypt}" != xno ; then
 835         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 836                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 837         )
 838         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 839                         [1.4.5],
 840                         [have_gcrypt=yes],
 841                         dnl  If we have the gcrypt m4 macros, but don't have
 842                         dnl  gcrypt, throw an error if gcrypt is explicitly
 843                         dnl  requested.
 844                         [AM_PATH_LIBGCRYPT_FAIL]
 845                 )],
 846                 dnl  If we don't have the gcrypt m4 macros, but build with
 847                 dnl  gcrypt explicitly requested, throw an error.
 848                 [AM_PATH_LIBGCRYPT_FAIL]
 849         )
 850
 851         have_gpg_error=no
 852         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 853                         [1.12],
 854                         [have_gpg_error=yes],
 855                         [AM_PATH_LIBGCRYPT_FAIL]
 856                 )],
 857                 [AM_PATH_LIBGCRYPT_FAIL]
 858         )
 859
 860         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 861                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 862                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 863                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 864         else
 865                 have_gcrypt=no
 866                 have_gpg_error=no
 867         fi
 868 else
 869         GCRYPT_LIBS=
 870         GCRYPT_CFLAGS=
 871 fi
 872 AC_SUBST(GCRYPT_LIBS)
 873 AC_SUBST(GCRYPT_CFLAGS)
 874 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 875
 876 # ------------------------------------------------------------------------------
 877 AC_ARG_ENABLE([audit],
 878         AS_HELP_STRING([--disable-audit], [disable optional AUDIT support]),
 879                 [case "${enableval}" in
 880                         yes) have_audit=yes ;;
 881                         no) have_audit=no ;;
 882                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 883                 esac],
 884                 [have_audit=auto])
 885
 886 if test "x${have_audit}" != xno ; then
 887         AC_CHECK_HEADERS(
 888                 [libaudit.h],
 889                 [have_audit=yes],
 890                 [if test "x$have_audit" = xyes ; then
 891                         AC_MSG_ERROR([*** AUDIT headers not found.])
 892                 fi])
 893
 894         AC_CHECK_LIB(
 895                 [audit],
 896                 [audit_open],
 897                 [have_audit=yes],
 898                 [if test "x$have_audit" = xyes ; then
 899                         AC_MSG_ERROR([*** libaudit not found.])
 900                 fi])
 901
 902         if test "x$have_audit" = xyes ; then
 903                 AUDIT_LIBS="-laudit"
 904                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 905         else
 906                 have_audit=no
 907         fi
 908 else
 909         AUDIT_LIBS=
 910 fi
 911 AC_SUBST(AUDIT_LIBS)
 912 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 913
 914 # ------------------------------------------------------------------------------
 915 AC_ARG_ENABLE([elfutils],
 916         AS_HELP_STRING([--disable-elfutils], [disable optional ELFUTILS support]),
 917                 [case "${enableval}" in
 918                         yes) have_elfutils=yes ;;
 919                         no) have_elfutils=no ;;
 920                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 921                 esac],
 922                 [have_elfutils=auto])
 923
 924 if test "x${have_elfutils}" != xno ; then
 925         AC_CHECK_HEADERS(
 926                 [elfutils/libdwfl.h],
 927                 [],
 928                 [if test "x$have_elfutils" = xyes ; then
 929                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 930                 fi])
 931
 932         AC_CHECK_LIB(
 933                 [dw],
 934                 [dwfl_core_file_attach],
 935                 [have_elfutils=yes],
 936                 [if test "x$have_elfutils" = xyes ; then
 937                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 938                 fi])
 939
 940         if test "x$have_elfutils" = xyes ; then
 941                 ELFUTILS_LIBS="-lelf -ldw"
 942                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 943         else
 944                 have_elfutils=no
 945         fi
 946 else
 947         ELFUTILS_LIBS=
 948 fi
 949 AC_SUBST(ELFUTILS_LIBS)
 950 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 951
 952 # ------------------------------------------------------------------------------
 953 have_libcryptsetup=no
 954 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 955 if test "x$enable_libcryptsetup" != "xno"; then
 956         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 957                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 958         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 959                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 960         fi
 961 fi
 962 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 963
 964 # ------------------------------------------------------------------------------
 965 have_qrencode=no
 966 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 967 if test "x$enable_qrencode" != "xno"; then
 968         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 969                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 970         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 971                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 972         fi
 973 fi
 974 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 975
 976 # ------------------------------------------------------------------------------
 977 have_gnutls=no
 978 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 979 if test "x$enable_gnutls" != "xno"; then
 980         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 981                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 982         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 983                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 984         fi
 985 fi
 986 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 987
 988 # ------------------------------------------------------------------------------
 989 have_microhttpd=no
 990 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 991 if test "x$enable_microhttpd" != "xno"; then
 992         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 993                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 994                  have_microhttpd=yes
 995                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 996                 [have_microhttpd=no])
 997         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 998                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 999         fi
1000 fi
1001 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
1002
1003 # ------------------------------------------------------------------------------
1004 have_libcurl=no
1005 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
1006 if test "x$enable_libcurl" != "xno"; then
1007         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
1008                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
1009                  have_libcurl=yes
1010                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
1011                 [have_libcurl=no])
1012         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
1013                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
1014         fi
1015 fi
1016 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
1017
1018 # ------------------------------------------------------------------------------
1019 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
1020
1021 # ------------------------------------------------------------------------------
1022 have_libidn2=no
1023 AC_ARG_ENABLE(libidn2, AS_HELP_STRING([--disable-libidn2], [disable optional LIBIDN2 support]))
1024 if test "x$enable_libidn2" != "xno"; then
1025         PKG_CHECK_MODULES(LIBIDN2, [libidn2 >= 2.0.0],
1026                [AC_DEFINE(HAVE_LIBIDN2, 1, [Define if libidn2 is available])
1027                 have_libidn2=yes
1028                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN2"],
1029                [have_libidn2=no])
1030         if test "x$have_libidn2" = "xno" -a "x$enable_libidn2" = "xyes"; then
1031                 AC_MSG_ERROR([*** libidn2 support requested but libraries not found])
1032         fi
1033 fi
1034 AM_CONDITIONAL(HAVE_LIBIDN2, [test "$have_libidn2" = "yes"])
1035
1036 have_libidn=no
1037 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [disable optional LIBIDN support]))
1038 if test "$have_libidn2" != "yes"; then
1039         if test "x$enable_libidn" != "xno"; then
1040                 PKG_CHECK_MODULES(LIBIDN, [libidn],
1041                        [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
1042                         have_libidn=yes
1043                         M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
1044                        [have_libidn=no])
1045                 if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
1046                         AC_MSG_ERROR([*** libidn support requested but libraries not found])
1047                 fi
1048         fi
1049 fi
1050 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
1051
1052 # ------------------------------------------------------------------------------
1053 have_idn=no
1054 AC_ARG_ENABLE(idn, AS_HELP_STRING([--disable-idn], [disable IDN when printing host names]))
1055 if test "x$enable_idn" != "xno"; then
1056         have_idn=yes
1057         AC_DEFINE(ENABLE_IDN, [1], [IDN is enabled])
1058 fi
1059 AM_CONDITIONAL(ENABLE_IDN, [test "$have_idn" = "yes"])
1060
1061 # ------------------------------------------------------------------------------
1062 have_nss_systemd=no
1063 AC_ARG_ENABLE(nss-systemd, AS_HELP_STRING([--disable-nss-systemd], [disable nss-systemd support]))
1064 if test "x$enable_nss_systemd" != "xno"; then
1065         have_nss_systemd=yes
1066         AC_DEFINE(ENABLE_NSS_SYSTEMD, [1], [nss-systemd is enabled])
1067 fi
1068 AM_CONDITIONAL(ENABLE_NSS_SYSTEMD, [test "$have_nss_systemd" = "yes"])
1069
1070 # ------------------------------------------------------------------------------
1071 have_libiptc=no
1072 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [disable optional LIBIPTC support]))
1073 if test "x$enable_libiptc" != "xno"; then
1074         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
1075                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
1076                 have_libiptc=yes
1077                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
1078                [have_libiptc=no])
1079         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
1080                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
1081         fi
1082 fi
1083 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
1084
1085 # ------------------------------------------------------------------------------
1086 have_binfmt=no
1087 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
1088 if test "x$enable_binfmt" != "xno"; then
1089         have_binfmt=yes
1090 fi
1091 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
1092
1093 # ------------------------------------------------------------------------------
1094 have_vconsole=no
1095 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
1096 if test "x$enable_vconsole" != "xno"; then
1097         have_vconsole=yes
1098 fi
1099 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
1100
1101 # ------------------------------------------------------------------------------
1102 have_quotacheck=no
1103 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
1104 if test "x$enable_quotacheck" != "xno"; then
1105         have_quotacheck=yes
1106 fi
1107 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
1108
1109 # ------------------------------------------------------------------------------
1110 have_tmpfiles=no
1111 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
1112 if test "x$enable_tmpfiles" != "xno"; then
1113         have_tmpfiles=yes
1114 fi
1115 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
1116
1117 # ------------------------------------------------------------------------------
1118 have_environment_d=no
1119 AC_ARG_ENABLE(environment-d, AS_HELP_STRING([--disable-environment-d], [disable environment.d support]))
1120 if test "x$enable_environment_d" != "xno"; then
1121         have_environment_d=yes
1122 fi
1123 AM_CONDITIONAL(ENABLE_ENVIRONMENT_D, [test "$have_environment_d" = "yes"])
1124
1125 # ------------------------------------------------------------------------------
1126 have_sysusers=no
1127 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
1128 if test "x$enable_sysusers" != "xno"; then
1129         have_sysusers=yes
1130 fi
1131 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
1132
1133 AC_ARG_ENABLE(gshadow, AS_HELP_STRING([--disable-gshadow], [disable shadow group support]))
1134 AS_IF([test "x${enable_gshadow}" != "xno"], [
1135         AC_DEFINE(ENABLE_GSHADOW, 1, [shadow group support is enabled])
1136 ])
1137
1138 # ------------------------------------------------------------------------------
1139 have_firstboot=no
1140 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
1141 if test "x$enable_firstboot" != "xno"; then
1142         have_firstboot=yes
1143 fi
1144 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
1145
1146 # ------------------------------------------------------------------------------
1147 have_randomseed=no
1148 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
1149 if test "x$enable_randomseed" != "xno"; then
1150         have_randomseed=yes
1151 fi
1152 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
1153
1154 # ------------------------------------------------------------------------------
1155 have_backlight=no
1156 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
1157 if test "x$enable_backlight" != "xno"; then
1158         have_backlight=yes
1159 fi
1160 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
1161
1162 # ------------------------------------------------------------------------------
1163 have_rfkill=no
1164 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1165 if test "x$enable_rfkill" != "xno"; then
1166         have_rfkill=yes
1167 fi
1168 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1169
1170 # ------------------------------------------------------------------------------
1171 have_logind=no
1172 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1173 if test "x$enable_logind" != "xno"; then
1174         have_logind=yes
1175 fi
1176 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1177 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(ENABLE_LOGIND, [1], [Logind support available]) ])
1178
1179 AC_ARG_WITH([kill-user-processes],
1180         [AS_HELP_STRING([--without-kill-user-processes], [set logind's KillUserProcesses=no by default])])
1181 AS_IF([test "$with_kill_user_processes" != "no"],
1182        [kill_user_processes=true
1183         KILL_USER_PROCESSES=yes],
1184        [kill_user_processes=false
1185         KILL_USER_PROCESSES=no])
1186 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
1187 AC_SUBST(KILL_USER_PROCESSES)
1188
1189 # ------------------------------------------------------------------------------
1190 have_machined=no
1191 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1192 if test "x$enable_machined" != "xno"; then
1193         have_machined=yes
1194         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1195 fi
1196 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1197
1198 # ------------------------------------------------------------------------------
1199 have_importd=no
1200 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1201 if test "x$enable_importd" != "xno"; then
1202         have_importd=yes
1203 fi
1204 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1205 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1206
1207 # ------------------------------------------------------------------------------
1208 have_hostnamed=no
1209 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1210 if test "x$enable_hostnamed" != "xno"; then
1211         have_hostnamed=yes
1212 fi
1213 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1214
1215 # ------------------------------------------------------------------------------
1216 have_timedated=no
1217 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1218 if test "x$enable_timedated" != "xno"; then
1219         have_timedated=yes
1220 fi
1221 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1222
1223 # ------------------------------------------------------------------------------
1224 have_timesyncd=no
1225 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1226 if test "x$enable_timesyncd" != "xno"; then
1227         have_timesyncd=yes
1228         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1229 fi
1230 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1231
1232 AC_ARG_WITH(ntp-servers,
1233         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1234                 [space-separated list of default NTP servers]),
1235         [NTP_SERVERS="$withval"],
1236         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"])
1237
1238 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1239 AC_SUBST(NTP_SERVERS)
1240
1241 AC_ARG_WITH(time-epoch,
1242         AS_HELP_STRING([--with-time-epoch=SECONDS],
1243                 [time epoch for time clients]),
1244         [TIME_EPOCH="$withval"],
1245         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1246
1247 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1248
1249 # ------------------------------------------------------------------------------
1250 AC_ARG_WITH(system-uid-max,
1251         AS_HELP_STRING([--with-system-uid-max=UID]
1252                 [maximum UID for system users]),
1253         [SYSTEM_UID_MAX="$withval"],
1254         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1255
1256 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1257 AC_SUBST(SYSTEM_UID_MAX)
1258
1259 # ------------------------------------------------------------------------------
1260 AC_ARG_WITH(system-gid-max,
1261         AS_HELP_STRING([--with-system-gid-max=GID]
1262                 [maximum GID for system groups]),
1263         [SYSTEM_GID_MAX="$withval"],
1264         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1265
1266 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1267 AC_SUBST(SYSTEM_GID_MAX)
1268
1269 # ------------------------------------------------------------------------------
1270
1271 AC_ARG_WITH(dev-kvm-mode,
1272         AS_HELP_STRING([--with-dev-kvm-mode=MODE],
1273                 [/dev/kvm access mode, defaults to "0660"]),
1274         [DEV_KVM_MODE="$withval"],
1275         [DEV_KVM_MODE="0660"])
1276
1277 AC_SUBST(DEV_KVM_MODE, [$DEV_KVM_MODE], [/dev/kvm access mode])
1278
1279 # ------------------------------------------------------------------------------
1280 have_localed=no
1281 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1282 if test "x$enable_localed" != "xno"; then
1283         have_localed=yes
1284 fi
1285 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1286
1287 # ------------------------------------------------------------------------------
1288 have_coredump=no
1289 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1290 if test "x$enable_coredump" != "xno"; then
1291         have_coredump=yes
1292         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1293 fi
1294 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1295
1296 # ------------------------------------------------------------------------------
1297 have_polkit=no
1298 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1299 if test "x$enable_polkit" != "xno"; then
1300         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1301         have_polkit=yes
1302
1303         # also enable support for *.pkla files on old polkit
1304         PKG_CHECK_MODULES(POLKIT, [ polkit-gobject-1 < 0.106 ],
1305                            [polkit_pkla=yes],
1306                            [polkit_pkla=no])
1307 fi
1308 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1309 AM_CONDITIONAL(ENABLE_POLKIT_PKLA, [test "x$polkit_pkla" = "xyes"])
1310
1311 # ------------------------------------------------------------------------------
1312 have_resolved=no
1313 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1314 AS_IF([test "x$enable_resolved" != "xno"], [
1315         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1316
1317         have_resolved=yes
1318         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1319         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1320 ])
1321 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1322
1323 AC_ARG_WITH(dns-servers,
1324         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1325                 [space-separated list of default DNS servers]),
1326         [DNS_SERVERS="$withval"],
1327         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1328
1329 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1330 AC_SUBST(DNS_SERVERS)
1331
1332 AC_ARG_WITH(default-dnssec,
1333         AS_HELP_STRING([--with-default-dnssec=MODE],
1334                [default DNSSEC mode, defaults to "allow-downgrade"]),
1335         [DEFAULT_DNSSEC_MODE="$withval"],
1336         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1337
1338 if test "x$have_gcrypt" = xno -a "x${DEFAULT_DNSSEC_MODE}" != xno ; then
1339         AC_MSG_WARN(default-dnssec cannot be set to yes or allow-downgrade when gcrypt is disabled. Setting default-dnssec to no.)
1340         DEFAULT_DNSSEC_MODE="no"
1341 fi
1342
1343 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1344         [xno], [mode=DNSSEC_NO],
1345         [xyes], [mode=DNSSEC_YES],
1346         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1347         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1348 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1349 AC_SUBST(DEFAULT_DNSSEC_MODE)
1350
1351 # ------------------------------------------------------------------------------
1352 have_networkd=no
1353 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1354 AS_IF([test "x$enable_networkd" != "xno"], [
1355         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1356         have_networkd=yes
1357         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1358 ])
1359 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1360
1361 # ------------------------------------------------------------------------------
1362 have_efi=no
1363 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable systemd-boot and bootctl (EFI support)]))
1364 if test "x$enable_efi" != "xno"; then
1365         AC_DEFINE(ENABLE_EFI, 1, [Define if systemd-boot and bootctl are to be enabled])
1366         have_efi=yes
1367 fi
1368 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1369
1370 # ------------------------------------------------------------------------------
1371 AC_CHECK_TOOL(EFI_CC, gcc)
1372
1373 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1374
1375 AM_COND_IF(ARCH_IA32, [
1376         EFI_ARCH=ia32
1377         EFI_MACHINE_TYPE_NAME=ia32])
1378
1379 AM_COND_IF(ARCH_X86_64, [
1380         EFI_MACHINE_TYPE_NAME=x64])
1381
1382 AM_COND_IF(ARCH_ARM, [
1383         EFI_MACHINE_TYPE_NAME=arm])
1384
1385 AM_COND_IF(ARCH_AARCH64, [
1386         EFI_MACHINE_TYPE_NAME=aa64])
1387
1388 AC_SUBST([EFI_ARCH])
1389 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1390
1391 have_gnuefi=no
1392 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [enable optional gnuefi support]))
1393 AS_IF([test "x$enable_gnuefi" != "xno"], [
1394         AC_ARG_WITH(efi-includedir,
1395                 AS_HELP_STRING([--with-efi-includedir=PATH], [path to EFI include directory]),
1396                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1397         )
1398         AC_SUBST([EFI_INC_DIR])
1399
1400         AC_CHECK_HEADERS(${EFI_INC_DIR}/efi/${EFI_ARCH}/efibind.h,
1401                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1402                  have_gnuefi=yes],
1403                 [AS_IF([test "x$enable_gnuefi" = xyes],
1404                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1405         ])
1406
1407         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1408
1409         EFI_LIB_DIR="$efiroot"
1410         AC_ARG_WITH(efi-libdir,
1411                 AS_HELP_STRING([--with-efi-libdir=PATH], [path to EFI lib directory]),
1412                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1413         )
1414         AC_SUBST([EFI_LIB_DIR])
1415
1416         have_efi_lds=no
1417         AC_ARG_WITH(efi-ldsdir,
1418                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [path to EFI lds directory]),
1419                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1420                         [have_efi_lds=yes])],
1421                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1422                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1423                                        [have_efi_lds=yes && break])])])
1424         AS_IF([test "x$have_efi_lds" = xyes],
1425               [AC_SUBST([EFI_LDS_DIR])],
1426               [AS_IF([test "x$enable_gnuefi" = xyes],
1427                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1428                      [have_gnuefi=no])])
1429 ])
1430 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1431
1432 # ------------------------------------------------------------------------------
1433 have_tpm=no
1434 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm], [enable optional TPM support]),
1435                 [case "${enableval}" in
1436                         yes) have_tpm=yes ;;
1437                         no) have_tpm=no ;;
1438                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1439                 esac],
1440                 [have_tpm=no])
1441
1442 if test "x${have_tpm}" != xno ; then
1443         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1444 fi
1445
1446 AC_ARG_WITH(tpm-pcrindex,
1447         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1448                 [TPM PCR register number to use]),
1449         [SD_TPM_PCR="$withval"],
1450         [SD_TPM_PCR="8"])
1451
1452 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1453
1454 # ------------------------------------------------------------------------------
1455 AC_ARG_WITH(rc-local-script-path-start,
1456         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1457                 [path to /etc/rc.local]),
1458         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1459         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1460
1461 AC_ARG_WITH(rc-local-script-path-stop,
1462         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1463                 [path to /usr/sbin/halt.local]),
1464         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1465         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1466
1467 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1468 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1469
1470 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1471 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1472
1473 # ------------------------------------------------------------------------------
1474 AC_ARG_WITH(kbd-loadkeys,
1475         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1476                 [path to loadkeys]),
1477         [KBD_LOADKEYS="$withval"],
1478         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1479
1480 AC_ARG_WITH(kbd-setfont,
1481         AS_HELP_STRING([--with-kbd-setfont=PATH],
1482                 [path to setfont]),
1483         [KBD_SETFONT="$withval"],
1484         [KBD_SETFONT="/usr/bin/setfont"])
1485
1486 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1487 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1488
1489 AC_SUBST(KBD_LOADKEYS)
1490 AC_SUBST(KBD_SETFONT)
1491
1492 AC_ARG_WITH(telinit,
1493         AS_HELP_STRING([--with-telinit=PATH],
1494                 [path to telinit]),
1495         [TELINIT="$withval"],
1496         [TELINIT="/lib/sysvinit/telinit"])
1497
1498 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1499
1500 AC_SUBST(TELINIT)
1501
1502 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1503
1504 # ------------------------------------------------------------------------------
1505 have_myhostname=no
1506 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1507 if test "x$enable_myhostname" != "xno"; then
1508         AC_HEADER_STDC
1509         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1510
1511         AC_C_CONST
1512         AC_TYPE_SIZE_T
1513         AC_HEADER_TIME
1514
1515         AC_FUNC_SELECT_ARGTYPES
1516         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1517
1518         have_myhostname=yes
1519         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1520 fi
1521 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1522
1523 # ------------------------------------------------------------------------------
1524 AC_ARG_ENABLE(hwdb, [AS_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1525        enable_hwdb=$enableval, enable_hwdb=yes)
1526 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1527
1528 # ------------------------------------------------------------------------------
1529 have_manpages=no
1530 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1531 AC_PATH_PROG([XSLTPROC], [xsltproc])
1532 AS_IF([test "x$enable_manpages" != xno], [
1533        have_manpages=yes
1534        AS_IF([test -z "$XSLTPROC"],
1535              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1536 ])
1537 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1538
1539 # ------------------------------------------------------------------------------
1540 AC_ARG_ENABLE(hibernate,
1541        [AS_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1542        enable_hibernate=$enableval, enable_hibernate=yes)
1543 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1544
1545 # ------------------------------------------------------------------------------
1546 AC_ARG_ENABLE(ldconfig,
1547        [AS_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1548        enable_ldconfig=$enableval, enable_ldconfig=yes)
1549 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1550
1551 # ------------------------------------------------------------------------------
1552 # Location of the init scripts as mandated by LSB
1553 SYSTEM_SYSVINIT_PATH=/etc/init.d
1554 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1555
1556 AC_ARG_WITH([sysvinit-path],
1557         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1558                 [specify the path to where the SysV init scripts are located])],
1559         [SYSTEM_SYSVINIT_PATH="$withval"],
1560         [])
1561
1562 AC_ARG_WITH([sysvrcnd-path],
1563         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1564                 [specify the path to the base directory for the SysV rcN.d directories])],
1565         [SYSTEM_SYSVRCND_PATH="$withval"],
1566         [])
1567
1568 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1569         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1570         SYSTEM_SYSV_COMPAT="yes"
1571         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1572 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1573         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1574 else
1575         SYSTEM_SYSV_COMPAT="no"
1576 fi
1577
1578 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1579 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1580 AC_SUBST(M4_DEFINES)
1581
1582 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1583
1584 AC_ARG_WITH([tty-gid],
1585         [AS_HELP_STRING([--with-tty-gid=GID],
1586                 [specify the numeric GID of the 'tty' group])],
1587         [TTY_GID="$withval"],
1588         [TTY_GID="5"])
1589
1590 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1591 AC_SUBST(TTY_GID)
1592
1593 AC_ARG_WITH([dbuspolicydir],
1594         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1595         [],
1596         [with_dbuspolicydir=${datadir}/dbus-1/system.d])
1597 AX_NORMALIZE_PATH([with_dbuspolicydir])
1598
1599 AC_ARG_WITH([dbussessionservicedir],
1600         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1601         [],
1602         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1603 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1604
1605 AC_ARG_WITH([dbussystemservicedir],
1606         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1607         [],
1608         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1609 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1610
1611 AC_ARG_WITH([bashcompletiondir],
1612         AS_HELP_STRING([--with-bashcompletiondir=DIR], [bash completions directory]),
1613         [],
1614         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1615                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1616         ] , [
1617                 with_bashcompletiondir=${datadir}/bash-completion/completions
1618         ])])
1619 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1620 AX_NORMALIZE_PATH([with_bashcompletiondir])
1621
1622 AC_ARG_WITH([zshcompletiondir],
1623         AS_HELP_STRING([--with-zshcompletiondir=DIR], [zsh completions directory]),
1624         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1625 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1626 AX_NORMALIZE_PATH([with_zshcompletiondir])
1627
1628 AC_ARG_WITH([rootprefix],
1629         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1630         [], [with_rootprefix=${ac_default_prefix}])
1631 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1632 # defaults those to ".", solve that here for now until we can find a suitable
1633 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1634 # See: https://github.com/systemd/systemd/issues/54
1635 if test "x${with_rootprefix}" = "x"; then
1636         with_rootprefix="/"
1637 fi
1638 AX_NORMALIZE_PATH([with_rootprefix])
1639
1640 AC_ARG_WITH([rootlibdir],
1641         AS_HELP_STRING([--with-rootlibdir=DIR], [root directory for libraries necessary for boot]),
1642         [],
1643         [with_rootlibdir=${libdir}])
1644 AX_NORMALIZE_PATH([with_rootlibdir])
1645
1646 AC_ARG_WITH([pamlibdir],
1647         AS_HELP_STRING([--with-pamlibdir=DIR], [directory for PAM modules]),
1648         [],
1649         [with_pamlibdir=${with_rootlibdir}/security])
1650 AX_NORMALIZE_PATH([with_pamlibdir])
1651
1652 AC_ARG_WITH([pamconfdir],
1653         AS_HELP_STRING([--with-pamconfdir=DIR], [directory for PAM configuration (pass no to disable installing)]),
1654         [],
1655         [with_pamconfdir=${sysconfdir}/pam.d])
1656 AM_CONDITIONAL(ENABLE_PAM_CONFIG, [test "$with_pamconfdir" != "no"])
1657 AX_NORMALIZE_PATH([with_pamconfdir])
1658
1659 AC_ARG_WITH([rpmmacrosdir],
1660         AS_HELP_STRING([--with-rpmmacrosdir=DIR], [directory to store macros for RPM]),
1661         [], [with_rpmmacrosdir=\${prefix}/lib/rpm/macros.d])
1662 AM_CONDITIONAL(ENABLE_RPM_MACROS, [test "$with_rpmmacrosdir" != "no"])
1663 AX_NORMALIZE_PATH([with_rpmmacrosdir])
1664
1665 AC_ARG_ENABLE([split-usr],
1666         AS_HELP_STRING([--enable-split-usr], [assume that /bin, /sbin aren't symlinks into /usr]),
1667         [],
1668         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1669                 enable_split_usr=yes
1670         ], [
1671                 enable_split_usr=no
1672         ])])
1673
1674 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1675         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1676 ])
1677 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1678
1679 # work around intltool-update issues during 'make distcheck'
1680 AS_IF([test "x$0" != "x./configure"], [
1681         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1682 ])
1683
1684 # QEMU and OVMF UEFI firmware
1685 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1686         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1687         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1688                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1689         AC_SUBST([QEMU_BIOS])
1690 ])
1691
1692 AC_ARG_ENABLE(tests,
1693         [AS_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1694         enable_tests=$enableval, enable_tests=yes)
1695 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1696 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1697
1698 AC_ARG_ENABLE(debug,
1699         [AS_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1700         [if test "x$enableval" = "xyes"; then
1701                 enableval="hashmap,mmap-cache"
1702         fi
1703         saved_ifs="$IFS"
1704         IFS="$IFS$PATH_SEPARATOR,"
1705         for name in $enableval; do
1706                 case $name in
1707                 hashmap)
1708                         enable_debug_hashmap=yes
1709                         ;;
1710                 mmap-cache)
1711                         enable_debug_mmap_cache=yes
1712                         ;;
1713                 esac
1714         done
1715         IFS="$saved_ifs"],[])
1716
1717 enable_debug=""
1718 AS_IF([test x$enable_debug_hashmap = xyes], [
1719         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1720         enable_debug="hashmap $enable_debug"
1721 ])
1722 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1723         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1724         enable_debug="mmap-cache $enable_debug"
1725 ])
1726 test -z "$enable_debug" && enable_debug="none"
1727
1728 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1729 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1730 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1731 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1732 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1733 AC_SUBST([pamlibdir], [$with_pamlibdir])
1734 AC_SUBST([pamconfdir], [$with_pamconfdir])
1735 AC_SUBST([rpmmacrosdir], [$with_rpmmacrosdir])
1736 AC_SUBST([rootprefix], [$with_rootprefix])
1737 AC_SUBST([rootlibdir], [$with_rootlibdir])
1738
1739 AC_CONFIG_FILES([
1740         Makefile
1741         po/Makefile.in
1742 ])
1743
1744 AC_OUTPUT
1745 AC_MSG_RESULT([
1746         $PACKAGE_NAME $PACKAGE_VERSION
1747
1748         libcryptsetup:                     ${have_libcryptsetup}
1749         PAM:                               ${have_pam}
1750         AUDIT:                             ${have_audit}
1751         IMA:                               ${have_ima}
1752         AppArmor:                          ${have_apparmor}
1753         SELinux:                           ${have_selinux}
1754         SECCOMP:                           ${have_seccomp}
1755         SMACK:                             ${have_smack}
1756         ZLIB:                              ${have_zlib}
1757         XZ:                                ${have_xz}
1758         LZ4:                               ${have_lz4}
1759         BZIP2:                             ${have_bzip2}
1760         ACL:                               ${have_acl}
1761         GCRYPT:                            ${have_gcrypt}
1762         QRENCODE:                          ${have_qrencode}
1763         MICROHTTPD:                        ${have_microhttpd}
1764         GNUTLS:                            ${have_gnutls}
1765         libcurl:                           ${have_libcurl}
1766         libidn2:                           ${have_libidn2}
1767         libidn:                            ${have_libidn}
1768         IDN:                               ${have_idn}
1769         libiptc:                           ${have_libiptc}
1770         ELFUTILS:                          ${have_elfutils}
1771         binfmt:                            ${have_binfmt}
1772         vconsole:                          ${have_vconsole}
1773         quotacheck:                        ${have_quotacheck}
1774         tmpfiles:                          ${have_tmpfiles}
1775         environment.d:                     ${have_environment_d}
1776         sysusers:                          ${have_sysusers}
1777         firstboot:                         ${have_firstboot}
1778         randomseed:                        ${have_randomseed}
1779         backlight:                         ${have_backlight}
1780         rfkill:                            ${have_rfkill}
1781         logind:                            ${have_logind}
1782         default cgroup hierarchy:          ${DEFAULT_HIERARCHY}
1783         default KillUserProcesses setting: ${KILL_USER_PROCESSES}
1784         machined:                          ${have_machined}
1785         importd:                           ${have_importd}
1786         hostnamed:                         ${have_hostnamed}
1787         timedated:                         ${have_timedated}
1788         timesyncd:                         ${have_timesyncd}
1789         default NTP servers:               ${NTP_SERVERS}
1790         time epoch:                        ${TIME_EPOCH}
1791         localed:                           ${have_localed}
1792         networkd:                          ${have_networkd}
1793         resolved:                          ${have_resolved}
1794         default DNS servers:               ${DNS_SERVERS}
1795         default DNSSEC mode:               ${DEFAULT_DNSSEC_MODE}
1796         coredump:                          ${have_coredump}
1797         polkit:                            ${have_polkit} (legacy pkla support: ${polkit_pkla})
1798         efi:                               ${have_efi}
1799         gnuefi:                            ${have_gnuefi}
1800         efi arch:                          ${EFI_ARCH}
1801         EFI machine type:                  ${EFI_MACHINE_TYPE_NAME}
1802         EFI CC                             ${EFI_CC}
1803         EFI libdir:                        ${EFI_LIB_DIR}
1804         EFI ldsdir:                        ${EFI_LDS_DIR}
1805         EFI includedir:                    ${EFI_INC_DIR}
1806         kmod:                              ${have_kmod}
1807         xkbcommon:                         ${have_xkbcommon}
1808         blkid:                             ${have_blkid}
1809         libmount:                          ${have_libmount}
1810         dbus:                              ${have_dbus}
1811         glib:                              ${have_glib}
1812         nss-myhostname:                    ${have_myhostname}
1813         nss-systemd:                       ${have_nss_systemd}
1814         hwdb:                              ${enable_hwdb}
1815         tpm:                               ${have_tpm}
1816         Python:                            ${have_python}
1817         man pages:                         ${have_manpages}
1818         test coverage:                     ${have_coverage}
1819         Split /usr:                        ${enable_split_usr}
1820         SysV compatibility:                ${SYSTEM_SYSV_COMPAT}
1821         utmp/wtmp support:                 ${have_utmp}
1822         ldconfig support:                  ${enable_ldconfig}
1823         hibernate support:                 ${enable_hibernate}
1824         extra debugging:                   ${enable_debug}
1825         tests:                             ${enable_tests}
1826
1827         prefix:                            ${prefix}
1828         rootprefix:                        ${with_rootprefix}
1829         sysconf dir:                       ${sysconfdir}
1830         datarootdir:                       ${datarootdir}
1831         includedir:                        ${includedir}
1832         lib dir:                           ${libdir}
1833         rootlib dir:                       ${with_rootlibdir}
1834         SysV init scripts:                 ${SYSTEM_SYSVINIT_PATH}
1835         SysV rc?.d directories:            ${SYSTEM_SYSVRCND_PATH}
1836         build Python:                      ${PYTHON}
1837         PAM modules dir:                   ${with_pamlibdir}
1838         PAM configuration dir:             ${with_pamconfdir}
1839         RPM macros dir:                    ${with_rpmmacrosdir}
1840         D-Bus policy dir:                  ${with_dbuspolicydir}
1841         D-Bus session dir:                 ${with_dbussessionservicedir}
1842         D-Bus system dir:                  ${with_dbussystemservicedir}
1843         bash completions dir:              ${with_bashcompletiondir}
1844         zsh completions dir:               ${with_zshcompletiondir}
1845         extra start script:                ${RC_LOCAL_SCRIPT_PATH_START}
1846         extra stop script:                 ${RC_LOCAL_SCRIPT_PATH_STOP}
1847         adm group:                         ${have_adm_group}
1848         wheel group:                       ${have_wheel_group}
1849         debug shell:                       ${SUSHELL} @ ${DEBUGTTY}
1850         TTY GID:                           ${TTY_GID}
1851         maximum system UID:                ${SYSTEM_UID_MAX}
1852         maximum system GID:                ${SYSTEM_GID_MAX}
1853         /dev/kvm access mode:              ${DEV_KVM_MODE}
1854         certificate root:                  ${CERTIFICATEROOT}
1855         support URL:                       ${SUPPORT_URL}
1856         nobody user name:                  ${NOBODY_USER_NAME}
1857         nobody group name:                 ${NOBODY_GROUP_NAME}
1858         fallback hostname:                 ${FALLBACK_HOSTNAME}
1859
1860         CFLAGS:   ${OUR_CFLAGS} ${CFLAGS}
1861         CPPFLAGS: ${OUR_CPPFLAGS} ${CPPFLAGS}
1862         LDFLAGS:  ${OUR_LDFLAGS} ${LDFLAGS}
1863 ])