configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [208],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(STRINGS, strings)
  98 AC_CHECK_TOOL(GPERF, gperf)
  99 if test -z "$GPERF" ; then
 100         AC_MSG_ERROR([*** gperf not found])
 101 fi
 102
 103 # ------------------------------------------------------------------------------
 104 address_sanitizer_cflags=
 105 address_sanitizer_cppflags=
 106 address_sanitizer_ldflags=
 107 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 108 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 109             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 110             AS_IF([test -z "$with_as_cflags"],
 111                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 112             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 113             address_sanitizer_cppflags="-DVALGRIND=1"
 114             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 115       ])
 116
 117 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 118         -pipe \
 119         -Wall \
 120         -Wextra \
 121         -Wno-inline \
 122         -Wundef \
 123         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 124         -Wlogical-op \
 125         -Wsign-compare \
 126         -Wmissing-include-dirs \
 127         -Wold-style-definition \
 128         -Wpointer-arith \
 129         -Winit-self \
 130         -Wdeclaration-after-statement \
 131         -Wfloat-equal \
 132         -Wmissing-prototypes \
 133         -Wstrict-prototypes \
 134         -Wredundant-decls \
 135         -Wmissing-declarations \
 136         -Wmissing-noreturn \
 137         -Wshadow \
 138         -Wendif-labels \
 139         -Wcast-align \
 140         -Wstrict-aliasing=2 \
 141         -Wwrite-strings \
 142         -Wno-long-long \
 143         -Wno-overlength-strings \
 144         -Wno-unused-parameter \
 145         -Wno-missing-field-initializers \
 146         -Wno-unused-result \
 147         -Werror=overflow \
 148         -ffast-math \
 149         -fno-common \
 150         -fdiagnostics-show-option \
 151         -fdiagnostics-color \
 152         -fno-strict-aliasing \
 153         -fvisibility=hidden \
 154         -ffunction-sections \
 155         -fdata-sections \
 156         -fstack-protector \
 157         --param=ssp-buffer-size=4])
 158 AC_SUBST([OUR_CFLAGS], "$with_cflags $address_sanitizer_cflags")
 159
 160 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 161         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 162                -Wp,-D_FORTIFY_SOURCE=2])],
 163         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 164 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $address_sanitizer_cppflags")
 165
 166 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 167         -Wl,--as-needed \
 168         -Wl,--no-undefined \
 169         -Wl,--gc-sections \
 170         -Wl,-z,relro \
 171         -Wl,-z,now])
 172 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $address_sanitizer_ldflags")
 173
 174 # ------------------------------------------------------------------------------
 175 # we use python to build the man page index, and for systemd-python
 176 have_python=no
 177 AC_ARG_WITH([python],
 178         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 179
 180 AS_IF([test "x$with_python" != "xno"], [
 181         AM_PATH_PYTHON(,, [:])
 182         AS_IF([test "$PYTHON" != :], [have_python=yes])
 183 ])
 184 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 185 AS_IF([test "x$PYTHON_BINARY" = "x"],
 186       [AS_IF([test "x$have_python" = "xyes"],
 187              [PYTHON_BINARY="$(which "$PYTHON")"],
 188              [PYTHON_BINARY=/usr/bin/python])])
 189 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 190
 191 AS_IF([test "x$have_python" != "xyes" -a "x$enable_python_devel" = "xyes"],
 192       [AC_MSG_ERROR([*** python-devel support requires --with-python])])
 193
 194 have_python_devel=no
 195 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 196 AS_IF([test "x$have_python" = "xyes" -a "x$enable_python_devel" != "xno"], [
 197       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 198             [have_python_devel=yes],
 199             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 200                   [have_python_devel=yes],
 201                   [have_python_devel=no])])
 202       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 203             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 204       AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 205 ])
 206 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 207
 208 # ------------------------------------------------------------------------------
 209
 210 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 211 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 212 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 213
 214 # unconditionally pull-in librt with old glibc versions
 215 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 216
 217 save_LIBS="$LIBS"
 218 LIBS=
 219 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 220 CAP_LIBS="$LIBS"
 221 AC_SUBST(CAP_LIBS)
 222
 223 LIBS=
 224 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 225 RT_LIBS="$LIBS"
 226 AC_SUBST(RT_LIBS)
 227 LIBS="$save_LIBS"
 228
 229 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 230 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 231 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 232 #include <unistd.h>
 233 #include <sys/mount.h>
 234 #include <fcntl.h>]])
 235
 236 # This makes sure pkg.m4 is available.
 237 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 238
 239 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 240
 241
 242 # ------------------------------------------------------------------------------
 243 have_coverage=no
 244 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 245 if test "x$enable_coverage" = "xyes" ; then
 246         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 247         if test "x$lcov_found" = xno ; then
 248                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 249         else
 250                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 251                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 252                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 253                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 254                 else
 255                         have_coverage=yes
 256                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 257                         -fprofile-arcs \
 258                         -ftest-coverage])
 259                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 260                 fi
 261         fi
 262 fi
 263 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 264
 265 # ------------------------------------------------------------------------------
 266 have_kmod=no
 267 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 268 if test "x$enable_kmod" != "xno"; then
 269         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 270         if test "x$have_kmod" = "xyes"; then
 271                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 272                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 273                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 274         fi
 275         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 276                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 277         fi
 278 fi
 279 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 280
 281 # ------------------------------------------------------------------------------
 282 have_blkid=no
 283 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 284 if test "x$enable_blkid" != "xno"; then
 285         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 286                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 287         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 288                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 289         fi
 290 fi
 291 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 292
 293 # ------------------------------------------------------------------------------
 294 have_ima=yes
 295 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 296                 [case "${enableval}" in
 297                         yes) have_ima=yes ;;
 298                         no) have_ima=no ;;
 299                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 300                 esac],
 301                 [have_ima=yes])
 302
 303 if test "x${have_ima}" != xno ; then
 304         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 305 fi
 306
 307 # ------------------------------------------------------------------------------
 308 have_chkconfig=yes
 309 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 310                 [case "${enableval}" in
 311                         yes) have_chkconfig=yes ;;
 312                         no) have_chkconfig=no ;;
 313                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 314                 esac],
 315                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 316                 if test -z "$CHKCONFIG"; then
 317                         have_chkconfig=no
 318                 else
 319                         have_chkconfig=yes
 320                 fi])
 321
 322 if test "x${have_chkconfig}" != xno ; then
 323         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 324 fi
 325
 326 # ------------------------------------------------------------------------------
 327 have_selinux=no
 328 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 329 if test "x$enable_selinux" != "xno"; then
 330         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 331                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 332         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 333                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 334         fi
 335 fi
 336 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 337
 338 AC_ARG_WITH(debug-shell,
 339         AS_HELP_STRING([--with-debug-shell=PATH],
 340                 [Path to debug shell binary]),
 341         [SUSHELL="$withval"],[
 342         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 343
 344 AC_SUBST(SUSHELL)
 345
 346 AC_ARG_WITH([debug-tty],
 347         AS_HELP_STRING([--with-debug-tty=PATH],
 348                 [Specify the tty device for debug shell]),
 349         [DEBUGTTY="$withval"],
 350         [DEBUGTTY=/dev/tty9])
 351
 352 AC_SUBST(DEBUGTTY)
 353
 354 # ------------------------------------------------------------------------------
 355 have_xz=no
 356 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 357 if test "x$enable_xz" != "xno"; then
 358         PKG_CHECK_MODULES(XZ, [ liblzma ],
 359                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 360         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 361                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 362         fi
 363 fi
 364 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 365
 366 # ------------------------------------------------------------------------------
 367 AC_ARG_ENABLE([tcpwrap],
 368         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 369                 [case "${enableval}" in
 370                         yes) have_tcpwrap=yes ;;
 371                         no) have_tcpwrap=no ;;
 372                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 373                 esac],
 374                 [have_tcpwrap=auto])
 375
 376 if test "x${have_tcpwrap}" != xno ; then
 377         ACX_LIBWRAP
 378         if test "x${LIBWRAP_LIBS}" = x ; then
 379                 if test "x$have_tcpwrap" = xyes ; then
 380                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 381                 fi
 382                 have_tcpwrap=no
 383         else
 384                 have_tcpwrap=yes
 385         fi
 386 else
 387         LIBWRAP_LIBS=
 388 fi
 389 AC_SUBST(LIBWRAP_LIBS)
 390
 391 # ------------------------------------------------------------------------------
 392 AC_ARG_ENABLE([pam],
 393         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 394                 [case "${enableval}" in
 395                         yes) have_pam=yes ;;
 396                         no) have_pam=no ;;
 397                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 398                 esac],
 399                 [have_pam=auto])
 400
 401 if test "x${have_pam}" != xno ; then
 402         AC_CHECK_HEADERS(
 403                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 404                 [have_pam=yes],
 405                 [if test "x$have_pam" = xyes ; then
 406                         AC_MSG_ERROR([*** PAM headers not found.])
 407                 fi])
 408
 409         AC_CHECK_LIB(
 410                 [pam],
 411                 [pam_syslog],
 412                 [have_pam=yes],
 413                 [if test "x$have_pam" = xyes ; then
 414                         AC_MSG_ERROR([*** libpam not found.])
 415                 fi])
 416
 417         if test "x$have_pam" = xyes ; then
 418                 PAM_LIBS="-lpam -lpam_misc"
 419                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 420         else
 421                 have_pam=no
 422         fi
 423 else
 424         PAM_LIBS=
 425 fi
 426 AC_SUBST(PAM_LIBS)
 427 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 428
 429 # ------------------------------------------------------------------------------
 430 AC_ARG_ENABLE([acl],
 431         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 432                 [case "${enableval}" in
 433                         yes) have_acl=yes ;;
 434                         no) have_acl=no ;;
 435                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 436                 esac],
 437                 [have_acl=auto])
 438
 439 if test "x${have_acl}" != xno ; then
 440         AC_CHECK_HEADERS(
 441                 [sys/acl.h acl/libacl.h],
 442                 [have_acl=yes],
 443                 [if test "x$have_acl" = xyes ; then
 444                         AC_MSG_ERROR([*** ACL headers not found.])
 445                 fi])
 446
 447         AC_CHECK_LIB(
 448                 [acl],
 449                 [acl_get_file],
 450                 [have_acl=yes],
 451                 [if test "x$have_acl" = xyes ; then
 452                         AC_MSG_ERROR([*** libacl not found.])
 453                 fi])
 454
 455         if test "x$have_acl" = xyes ; then
 456                 ACL_LIBS="-lacl"
 457                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 458         else
 459                 have_acl=no
 460         fi
 461 else
 462         ACL_LIBS=
 463 fi
 464 AC_SUBST(ACL_LIBS)
 465 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 466
 467 # ------------------------------------------------------------------------------
 468 AC_ARG_ENABLE([xattr],
 469         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 470                 [case "${enableval}" in
 471                         yes) have_xattr=yes ;;
 472                         no) have_xattr=no ;;
 473                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 474                 esac],
 475                 [have_xattr=auto])
 476
 477 if test "x${have_xattr}" != xno ; then
 478         AC_CHECK_HEADERS(
 479                 [attr/xattr.h],
 480                 [have_xattr=yes],
 481                 [if test "x$have_xattr" = xyes ; then
 482                         AC_MSG_ERROR([*** XATTR headers not found.])
 483                 fi])
 484
 485         AC_CHECK_LIB(
 486                 [attr],
 487                 [fsetxattr],
 488                 [have_xattr=yes],
 489                 [if test "x$have_xattr" = xyes ; then
 490                         AC_MSG_ERROR([*** libattr not found.])
 491                 fi])
 492
 493         if test "x$have_xattr" = xyes ; then
 494                 XATTR_LIBS="-lattr"
 495                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 496         else
 497                 have_xattr=no
 498         fi
 499 else
 500         XATTR_LIBS=
 501 fi
 502 AC_SUBST(XATTR_LIBS)
 503 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 504
 505 # ------------------------------------------------------------------------------
 506 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 507                 [case "${enableval}" in
 508                         yes) have_smack=yes ;;
 509                         no) have_smack=no ;;
 510                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 511                 esac],
 512                 [have_smack=auto])
 513
 514 if test "x${have_xattr}" = xno; then
 515         if test "x${have_smack}" = xyes; then
 516                 AC_MSG_ERROR(SMACK requires xattr support)
 517         else
 518                 have_smack=no
 519         fi
 520 else
 521         if test "x${have_smack}" = xauto; then
 522                 have_smack=yes
 523         fi
 524 fi
 525
 526 AC_ARG_WITH(smack-run-label,
 527 AS_HELP_STRING([--with-smack-run-label=STRING],
 528         [run systemd --system with a specific SMACK label]),
 529         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 530         [])
 531
 532 if test "x${have_smack}" = xyes ; then
 533         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 534 fi
 535
 536 # ------------------------------------------------------------------------------
 537 AC_ARG_ENABLE([gcrypt],
 538         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 539                 [case "${enableval}" in
 540                         yes) have_gcrypt=yes ;;
 541                         no) have_gcrypt=no ;;
 542                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 543                 esac],
 544                 [have_gcrypt=auto])
 545
 546 if test "x${have_gcrypt}" != xno ; then
 547         AM_PATH_LIBGCRYPT(
 548                 [1.4.5],
 549                 [have_gcrypt=yes],
 550                 [if test "x$have_gcrypt" = xyes ; then
 551                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 552                 fi])
 553
 554         if test "x$have_gcrypt" = xyes ; then
 555                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 556                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 557                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 558         else
 559                 have_gcrypt=no
 560         fi
 561 else
 562         GCRYPT_LIBS=
 563         GCRYPT_CFLAGS=
 564 fi
 565 AC_SUBST(GCRYPT_LIBS)
 566 AC_SUBST(GCRYPT_CFLAGS)
 567 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 568
 569 # ------------------------------------------------------------------------------
 570 AC_ARG_ENABLE([audit],
 571         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 572                 [case "${enableval}" in
 573                         yes) have_audit=yes ;;
 574                         no) have_audit=no ;;
 575                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 576                 esac],
 577                 [have_audit=auto])
 578
 579 if test "x${have_audit}" != xno ; then
 580         AC_CHECK_HEADERS(
 581                 [libaudit.h],
 582                 [have_audit=yes],
 583                 [if test "x$have_audit" = xyes ; then
 584                         AC_MSG_ERROR([*** AUDIT headers not found.])
 585                 fi])
 586
 587         AC_CHECK_LIB(
 588                 [audit],
 589                 [audit_open],
 590                 [have_audit=yes],
 591                 [if test "x$have_audit" = xyes ; then
 592                         AC_MSG_ERROR([*** libaudit not found.])
 593                 fi])
 594
 595         if test "x$have_audit" = xyes ; then
 596                 AUDIT_LIBS="-laudit"
 597                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 598         else
 599                 have_audit=no
 600         fi
 601 else
 602         AUDIT_LIBS=
 603 fi
 604 AC_SUBST(AUDIT_LIBS)
 605
 606 # ------------------------------------------------------------------------------
 607 have_libcryptsetup=no
 608 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 609 if test "x$enable_libcryptsetup" != "xno"; then
 610         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 611                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 612         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 613                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 614         fi
 615 fi
 616 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 617
 618 # ------------------------------------------------------------------------------
 619 have_qrencode=no
 620 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 621 if test "x$enable_qrencode" != "xno"; then
 622         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 623                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 624         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 625                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 626         fi
 627 fi
 628 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 629
 630 # ------------------------------------------------------------------------------
 631 have_microhttpd=no
 632 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 633 if test "x$enable_microhttpd" != "xno"; then
 634         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 635                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 636         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 637                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 638         fi
 639 fi
 640 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 641
 642 # ------------------------------------------------------------------------------
 643 have_binfmt=no
 644 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 645 if test "x$enable_binfmt" != "xno"; then
 646         have_binfmt=yes
 647 fi
 648 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 649
 650 # ------------------------------------------------------------------------------
 651 have_vconsole=no
 652 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 653 if test "x$enable_vconsole" != "xno"; then
 654         have_vconsole=yes
 655 fi
 656 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 657
 658 # ------------------------------------------------------------------------------
 659 have_readahead=no
 660 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 661 if test "x$enable_readahead" != "xno"; then
 662         have_readahead=yes
 663 fi
 664 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 665
 666 # ------------------------------------------------------------------------------
 667 have_bootchart=no
 668 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 669 if test "x$enable_bootchart" != "xno"; then
 670         have_bootchart=yes
 671 fi
 672 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 673
 674 # ------------------------------------------------------------------------------
 675 have_quotacheck=no
 676 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 677 if test "x$enable_quotacheck" != "xno"; then
 678         have_quotacheck=yes
 679 fi
 680 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 681
 682 # ------------------------------------------------------------------------------
 683 have_tmpfiles=no
 684 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 685 if test "x$enable_tmpfiles" != "xno"; then
 686         have_tmpfiles=yes
 687 fi
 688 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 689
 690 # ------------------------------------------------------------------------------
 691 have_randomseed=no
 692 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 693 if test "x$enable_randomseed" != "xno"; then
 694         have_randomseed=yes
 695 fi
 696 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 697
 698 # ------------------------------------------------------------------------------
 699 have_backlight=no
 700 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 701 if test "x$enable_backlight" != "xno"; then
 702         have_backlight=yes
 703 fi
 704 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 705
 706 # ------------------------------------------------------------------------------
 707 have_rfkill=no
 708 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
 709 if test "x$enable_rfkill" != "xno"; then
 710         have_rfkill=yes
 711 fi
 712 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
 713
 714 # ------------------------------------------------------------------------------
 715 have_logind=no
 716 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 717 if test "x$enable_logind" != "xno"; then
 718         have_logind=yes
 719 fi
 720 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 721 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 722
 723 # ------------------------------------------------------------------------------
 724 have_machined=no
 725 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 726 if test "x$enable_machined" != "xno"; then
 727         have_machined=yes
 728 fi
 729 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 730 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 731
 732 # ------------------------------------------------------------------------------
 733 have_hostnamed=no
 734 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 735 if test "x$enable_hostnamed" != "xno"; then
 736         have_hostnamed=yes
 737 fi
 738 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 739
 740 # ------------------------------------------------------------------------------
 741 have_timedated=no
 742 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 743 if test "x$enable_timedated" != "xno"; then
 744         have_timedated=yes
 745 fi
 746 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 747
 748 # ------------------------------------------------------------------------------
 749 have_localed=no
 750 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 751 if test "x$enable_localed" != "xno"; then
 752         have_localed=yes
 753 fi
 754 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 755
 756 # ------------------------------------------------------------------------------
 757 have_coredump=no
 758 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 759 if test "x$enable_coredump" != "xno"; then
 760         have_coredump=yes
 761 fi
 762 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 763
 764 # ------------------------------------------------------------------------------
 765 have_polkit=no
 766 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 767 if test "x$enable_polkit" != "xno"; then
 768         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 769         have_polkit=yes
 770 fi
 771 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 772
 773 # ------------------------------------------------------------------------------
 774 have_efi=no
 775 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 776 if test "x$enable_efi" != "xno"; then
 777         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 778         have_efi=yes
 779 fi
 780 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 781
 782 # ------------------------------------------------------------------------------
 783 AC_ARG_WITH(rc-local-script-path-start,
 784         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 785                 [Path to /etc/rc.local]),
 786         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 787         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 788
 789 AC_ARG_WITH(rc-local-script-path-stop,
 790         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 791                 [Path to /usr/sbin/halt.local]),
 792         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 793         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 794
 795 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 796 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 797
 798 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 799 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 800
 801 # ------------------------------------------------------------------------------
 802 AC_ARG_WITH(kbd-loadkeys,
 803         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 804                 [Path to loadkeys]),
 805         [KBD_LOADKEYS="$withval"],
 806         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 807
 808 AC_ARG_WITH(kbd-setfont,
 809         AS_HELP_STRING([--with-kbd-setfont=PATH],
 810                 [Path to setfont]),
 811         [KBD_SETFONT="$withval"],
 812         [KBD_SETFONT="/usr/bin/setfont"])
 813
 814 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 815 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 816
 817 AC_SUBST(KBD_LOADKEYS)
 818 AC_SUBST(KBD_SETFONT)
 819
 820 AC_ARG_WITH(telinit,
 821         AS_HELP_STRING([--with-telinit=PATH],
 822                 [Path to telinit]),
 823         [TELINIT="$withval"],
 824         [TELINIT="/lib/sysvinit/telinit"])
 825
 826 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 827
 828 AC_SUBST(TELINIT)
 829
 830 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 831
 832 # ------------------------------------------------------------------------------
 833 have_myhostname=no
 834 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 835 if test "x$enable_myhostname" != "xno"; then
 836         AC_HEADER_STDC
 837         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
 838
 839         AC_C_CONST
 840         AC_TYPE_SIZE_T
 841         AC_HEADER_TIME
 842
 843         AC_FUNC_MALLOC
 844         AC_FUNC_SELECT_ARGTYPES
 845         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 846
 847         have_myhostname=yes
 848 fi
 849 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 850
 851 # ------------------------------------------------------------------------------
 852 AC_ARG_WITH(firmware-path,
 853        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 854           [Firmware search path (default="")]),
 855        [], [with_firmware_path=""])
 856 OLD_IFS=$IFS
 857 IFS=:
 858 for i in $with_firmware_path; do
 859        if test "x${FIRMWARE_PATH}" = "x"; then
 860               FIRMWARE_PATH="\\\"${i}/\\\""
 861        else
 862               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 863        fi
 864 done
 865 IFS=$OLD_IFS
 866 AC_SUBST(FIRMWARE_PATH)
 867 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 868 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 869
 870 # ------------------------------------------------------------------------------
 871 AC_ARG_ENABLE([gudev],
 872        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 873        [], [enable_gudev=yes])
 874 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 875 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 876 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 877
 878 # ------------------------------------------------------------------------------
 879 have_manpages=no
 880 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 881 AS_IF([test "x$enable_manpages" != xno], [
 882         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 883                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 884         ])
 885         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 886 ])
 887 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 888
 889 # ------------------------------------------------------------------------------
 890
 891 # Location of the init scripts as mandated by LSB
 892 SYSTEM_SYSVINIT_PATH=/etc/init.d
 893 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 894 M4_DEFINES=
 895
 896 AC_ARG_WITH([sysvinit-path],
 897         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 898                 [Specify the path to where the SysV init scripts are located])],
 899         [SYSTEM_SYSVINIT_PATH="$withval"],
 900         [])
 901
 902 AC_ARG_WITH([sysvrcnd-path],
 903         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 904                 [Specify the path to the base directory for the SysV rcN.d directories])],
 905         [SYSTEM_SYSVRCND_PATH="$withval"],
 906         [])
 907
 908 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 909         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 910         SYSTEM_SYSV_COMPAT="yes"
 911         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 912 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 913         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 914 else
 915         SYSTEM_SYSV_COMPAT="no"
 916 fi
 917
 918 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 919 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 920 AC_SUBST(M4_DEFINES)
 921
 922 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 923
 924 AC_ARG_WITH([tty-gid],
 925         [AS_HELP_STRING([--with-tty-gid=GID],
 926                 [Specify the numeric GID of the 'tty' group])],
 927         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 928         [])
 929
 930 AC_ARG_WITH([dbuspolicydir],
 931         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 932         [],
 933         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 934
 935 AC_ARG_WITH([dbussessionservicedir],
 936         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 937         [],
 938         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 939
 940 AC_ARG_WITH([dbussystemservicedir],
 941         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 942         [],
 943         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 944
 945 AC_ARG_WITH([dbusinterfacedir],
 946         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 947         [],
 948         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 949
 950 AC_ARG_WITH([bashcompletiondir],
 951         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 952         [],
 953         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 954                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 955         ] , [
 956                 with_bashcompletiondir=${datadir}/bash-completion/completions
 957         ])])
 958
 959 AC_ARG_WITH([zshcompletiondir],
 960         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 961         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 962
 963 AC_ARG_WITH([rootprefix],
 964         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 965         [], [with_rootprefix=${ac_default_prefix}])
 966
 967 AC_ARG_WITH([rootlibdir],
 968         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 969         [],
 970         [with_rootlibdir=${libdir}])
 971
 972 AC_ARG_WITH([pamlibdir],
 973         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 974         [],
 975         [with_pamlibdir=${with_rootlibdir}/security])
 976
 977 AC_ARG_WITH([pamconfdir],
 978         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 979         [],
 980         [with_pamconfdir=${sysconfdir}/pam.d])
 981
 982 AC_ARG_ENABLE([split-usr],
 983         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 984         [],
 985         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 986                 enable_split_usr=yes
 987         ], [
 988                 enable_split_usr=no
 989         ])])
 990
 991 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 992         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 993 ])
 994
 995 # Work around intltoolize and gtk-doc problems in VPATH builds
 996 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 997                                        [Define to do gtk-doc tests])
 998 AS_IF([test "x$0" != "x./configure"], [
 999         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1000 ])
1001
1002 AC_ARG_ENABLE(tests,
1003        [AC_HELP_STRING([--disable-tests], [disable tests])],
1004        enable_tests=$enableval, enable_tests=yes)
1005 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1006
1007 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1008 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1009 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1010 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
1011 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1012 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1013 AC_SUBST([pamlibdir], [$with_pamlibdir])
1014 AC_SUBST([pamconfdir], [$with_pamconfdir])
1015 AC_SUBST([rootprefix], [$with_rootprefix])
1016 AC_SUBST([rootlibdir], [$with_rootlibdir])
1017
1018 AC_CONFIG_FILES([
1019         Makefile po/Makefile.in
1020         docs/libudev/Makefile
1021         docs/libudev/version.xml
1022         docs/gudev/Makefile
1023         docs/gudev/version.xml
1024 ])
1025
1026 AC_OUTPUT
1027 AC_MSG_RESULT([
1028         $PACKAGE_NAME $VERSION
1029
1030         libcryptsetup:           ${have_libcryptsetup}
1031         tcpwrap:                 ${have_tcpwrap}
1032         PAM:                     ${have_pam}
1033         AUDIT:                   ${have_audit}
1034         IMA:                     ${have_ima}
1035         SELinux:                 ${have_selinux}
1036         SMACK:                   ${have_smack}
1037         XZ:                      ${have_xz}
1038         ACL:                     ${have_acl}
1039         XATTR:                   ${have_xattr}
1040         GCRYPT:                  ${have_gcrypt}
1041         QRENCODE:                ${have_qrencode}
1042         MICROHTTPD:              ${have_microhttpd}
1043         CHKCONFIG:               ${have_chkconfig}
1044         binfmt:                  ${have_binfmt}
1045         vconsole:                ${have_vconsole}
1046         readahead:               ${have_readahead}
1047         bootchart:               ${have_bootchart}
1048         quotacheck:              ${have_quotacheck}
1049         tmpfiles:                ${have_tmpfiles}
1050         randomseed:              ${have_randomseed}
1051         backlight:               ${have_backlight}
1052         rfkill:                  ${have_rfkill}
1053         logind:                  ${have_logind}
1054         machined:                ${have_machined}
1055         hostnamed:               ${have_hostnamed}
1056         timedated:               ${have_timedated}
1057         localed:                 ${have_localed}
1058         coredump:                ${have_coredump}
1059         polkit:                  ${have_polkit}
1060         efi:                     ${have_efi}
1061         kmod:                    ${have_kmod}
1062         blkid:                   ${have_blkid}
1063         nss-myhostname:          ${have_myhostname}
1064         gudev:                   ${enable_gudev}
1065         gintrospection:          ${enable_introspection}
1066         Python:                  ${have_python}
1067         Python Headers:          ${have_python_devel}
1068         man pages:               ${have_manpages}
1069         gtk-doc:                 ${enable_gtk_doc}
1070         test coverage:           ${have_coverage}
1071         Split /usr:              ${enable_split_usr}
1072         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1073
1074         prefix:                  ${prefix}
1075         rootprefix:              ${with_rootprefix}
1076         sysconf dir:             ${sysconfdir}
1077         datarootdir:             ${datarootdir}
1078         includedir:              ${includedir}
1079         include_prefix:          ${INCLUDE_PREFIX}
1080         lib dir:                 ${libdir}
1081         rootlib dir:             ${with_rootlibdir}
1082         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1083         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1084         Build Python:            ${PYTHON}
1085         Installation Python:     ${PYTHON_BINARY}
1086         sphinx binary:           ${SPHINX_BUILD}
1087         firmware path:           ${FIRMWARE_PATH}
1088         PAM modules dir:         ${with_pamlibdir}
1089         PAM configuration dir:   ${with_pamconfdir}
1090         D-Bus policy dir:        ${with_dbuspolicydir}
1091         D-Bus session dir:       ${with_dbussessionservicedir}
1092         D-Bus system dir:        ${with_dbussystemservicedir}
1093         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1094         Bash completions dir:    ${with_bashcompletiondir}
1095         Zsh completions dir:     ${with_zshcompletiondir}
1096         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1097         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1098         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1099
1100         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1101         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1102         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1103         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1104         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1105 ])