configure.ac

   1
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [192],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/sbin/quotacheck])
  69
  70 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  71 m4_ifdef([GTK_DOC_CHECK], [
  72 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  73 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  74
  75 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  76         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  77 ])
  78
  79 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  80 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  81 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  82
  83 AC_PATH_TOOL(OBJCOPY, objcopy)
  84 AC_PATH_TOOL(STRINGS, strings)
  85 AC_PATH_TOOL(GPERF, gperf)
  86 if test -z "$GPERF" ; then
  87         AC_MSG_ERROR([*** gperf not found])
  88 fi
  89
  90 # we use python to build the man page index, and for systemd-python
  91 have_python=no
  92 have_python_devel=no
  93 AM_PATH_PYTHON(,, [:])
  94 if test "$PYTHON" != : ; then
  95         have_python=yes
  96         AC_PATH_PROG([PYTHON_CONFIG], python-config)
  97
  98         if test -n "$PYTHON_CONFIG" ; then
  99                 have_python_devel=yes
 100                 PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
 101                 PYTHON_LIBS="`$PYTHON_CONFIG --libs`"
 102                 AC_SUBST(PYTHON_CFLAGS)
 103                 AC_SUBST(PYTHON_LIBS)
 104         fi
 105 fi
 106 AM_CONDITIONAL([HAVE_PYTHON], [test "$have_python" = "yes"])
 107 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 108
 109 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 110         -pipe \
 111         -Wall \
 112         -Wextra \
 113         -Wno-inline \
 114         -Wundef \
 115         -Wformat=2 \
 116         -Wlogical-op \
 117         -Wsign-compare \
 118         -Wformat-security \
 119         -Wmissing-include-dirs \
 120         -Wformat-nonliteral \
 121         -Wold-style-definition \
 122         -Wpointer-arith \
 123         -Winit-self \
 124         -Wdeclaration-after-statement \
 125         -Wfloat-equal \
 126         -Wmissing-prototypes \
 127         -Wstrict-prototypes \
 128         -Wredundant-decls \
 129         -Wmissing-declarations \
 130         -Wmissing-noreturn \
 131         -Wshadow \
 132         -Wendif-labels \
 133         -Wcast-align \
 134         -Wstrict-aliasing=2 \
 135         -Wwrite-strings \
 136         -Wno-long-long \
 137         -Wno-overlength-strings \
 138         -Wno-unused-parameter \
 139         -Wno-missing-field-initializers \
 140         -Wno-unused-result \
 141         -Werror=overflow \
 142         -ffast-math \
 143         -fno-common \
 144         -fdiagnostics-show-option \
 145         -fno-strict-aliasing \
 146         -fvisibility=hidden \
 147         -ffunction-sections \
 148         -fdata-sections \
 149         -fstack-protector \
 150         --param=ssp-buffer-size=4])
 151 AC_SUBST([OUR_CFLAGS], $with_cflags)
 152
 153 CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 154         -Wp,-D_FORTIFY_SOURCE=2])
 155 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 156
 157 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 158         -Wl,--as-needed \
 159         -Wl,--gc-sections \
 160         -Wl,-z,relro \
 161         -Wl,-z,now])
 162 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 163
 164 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 165 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 166
 167 save_LIBS="$LIBS"
 168 LIBS=
 169 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 170 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 171 CAP_LIBS="$LIBS"
 172 LIBS="$save_LIBS"
 173 AC_SUBST(CAP_LIBS)
 174
 175 AC_CHECK_FUNCS([fanotify_init fanotify_mark name_to_handle_at])
 176 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 177 AC_CHECK_DECLS([gettid, pivot_root], [], [], [[#include <sys/types.h>
 178 #include <unistd.h>
 179 #include <sys/mount.h>]])
 180
 181 # This makes sure pkg.m4 is available.
 182 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 183
 184 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 185 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 186 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 187
 188 # ------------------------------------------------------------------------------
 189 have_ima=yes
 190 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 191                 [case "${enableval}" in
 192                         yes) have_ima=yes ;;
 193                         no) have_ima=no ;;
 194                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 195                 esac],
 196                 [have_ima=yes])
 197
 198 if test "x${have_ima}" != xno ; then
 199         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 200 fi
 201
 202 # ------------------------------------------------------------------------------
 203 have_selinux=no
 204 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 205 if test "x$enable_selinux" != "xno"; then
 206         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 207                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 208         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 209                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 210         fi
 211 fi
 212 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 213 if test "x${have_selinux}" != xno ; then
 214         sushell=/sbin/sushell
 215 else
 216         sushell=/bin/bash
 217 fi
 218 AC_SUBST(sushell)
 219
 220 # ------------------------------------------------------------------------------
 221 have_xz=no
 222 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 223 if test "x$enable_xz" != "xno"; then
 224         PKG_CHECK_MODULES(XZ, [ liblzma ],
 225                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 226         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 227                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 228         fi
 229 fi
 230 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 231
 232 # ------------------------------------------------------------------------------
 233 AC_ARG_ENABLE([tcpwrap],
 234         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 235                 [case "${enableval}" in
 236                         yes) have_tcpwrap=yes ;;
 237                         no) have_tcpwrap=no ;;
 238                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 239                 esac],
 240                 [have_tcpwrap=auto])
 241
 242 if test "x${have_tcpwrap}" != xno ; then
 243         ACX_LIBWRAP
 244         if test "x${LIBWRAP_LIBS}" = x ; then
 245                 if test "x$have_tcpwrap" = xyes ; then
 246                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 247                 fi
 248                 have_tcpwrap=no
 249         else
 250                 have_tcpwrap=yes
 251         fi
 252 else
 253         LIBWRAP_LIBS=
 254 fi
 255 AC_SUBST(LIBWRAP_LIBS)
 256
 257 # ------------------------------------------------------------------------------
 258 AC_ARG_ENABLE([pam],
 259         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 260                 [case "${enableval}" in
 261                         yes) have_pam=yes ;;
 262                         no) have_pam=no ;;
 263                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 264                 esac],
 265                 [have_pam=auto])
 266
 267 if test "x${have_pam}" != xno ; then
 268         AC_CHECK_HEADERS(
 269                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 270                 [have_pam=yes],
 271                 [if test "x$have_pam" = xyes ; then
 272                         AC_MSG_ERROR([*** PAM headers not found.])
 273                 fi])
 274
 275         AC_CHECK_LIB(
 276                 [pam],
 277                 [pam_syslog],
 278                 [have_pam=yes],
 279                 [if test "x$have_pam" = xyes ; then
 280                         AC_MSG_ERROR([*** libpam not found.])
 281                 fi])
 282
 283         if test "x$have_pam" = xyes ; then
 284                 PAM_LIBS="-lpam -lpam_misc"
 285                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 286         else
 287                 have_pam=no
 288         fi
 289 else
 290         PAM_LIBS=
 291 fi
 292 AC_SUBST(PAM_LIBS)
 293 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 294
 295 # ------------------------------------------------------------------------------
 296 AC_ARG_ENABLE([acl],
 297         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 298                 [case "${enableval}" in
 299                         yes) have_acl=yes ;;
 300                         no) have_acl=no ;;
 301                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 302                 esac],
 303                 [have_acl=auto])
 304
 305 if test "x${have_acl}" != xno ; then
 306         AC_CHECK_HEADERS(
 307                 [sys/acl.h acl/libacl.h],
 308                 [have_acl=yes],
 309                 [if test "x$have_acl" = xyes ; then
 310                         AC_MSG_ERROR([*** ACL headers not found.])
 311                 fi])
 312
 313         AC_CHECK_LIB(
 314                 [acl],
 315                 [acl_get_file],
 316                 [have_acl=yes],
 317                 [if test "x$have_acl" = xyes ; then
 318                         AC_MSG_ERROR([*** libacl not found.])
 319                 fi])
 320
 321         if test "x$have_acl" = xyes ; then
 322                 ACL_LIBS="-lacl"
 323                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 324         else
 325                 have_acl=no
 326         fi
 327 else
 328         ACL_LIBS=
 329 fi
 330 AC_SUBST(ACL_LIBS)
 331 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 332
 333 # ------------------------------------------------------------------------------
 334 AC_ARG_ENABLE([gcrypt],
 335         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 336                 [case "${enableval}" in
 337                         yes) have_gcrypt=yes ;;
 338                         no) have_gcrypt=no ;;
 339                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 340                 esac],
 341                 [have_gcrypt=auto])
 342
 343 if test "x${have_gcrypt}" != xno ; then
 344         AM_PATH_LIBGCRYPT(
 345                 [1.4.5],
 346                 [have_gcrypt=yes],
 347                 [if test "x$have_gcrypt" = xyes ; then
 348                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 349                 fi])
 350
 351         if test "x$have_gcrypt" = xyes ; then
 352                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 353                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 354                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 355         else
 356                 have_gcrypt=no
 357         fi
 358 else
 359         GCRYPT_LIBS=
 360         GCRYPT_CFLAGS=
 361 fi
 362 AC_SUBST(GCRYPT_LIBS)
 363 AC_SUBST(GCRYPT_CFLAGS)
 364 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 365
 366 # ------------------------------------------------------------------------------
 367 AC_ARG_ENABLE([audit],
 368         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 369                 [case "${enableval}" in
 370                         yes) have_audit=yes ;;
 371                         no) have_audit=no ;;
 372                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 373                 esac],
 374                 [have_audit=auto])
 375
 376 if test "x${have_audit}" != xno ; then
 377         AC_CHECK_HEADERS(
 378                 [libaudit.h],
 379                 [have_audit=yes],
 380                 [if test "x$have_audit" = xyes ; then
 381                         AC_MSG_ERROR([*** AUDIT headers not found.])
 382                 fi])
 383
 384         AC_CHECK_LIB(
 385                 [audit],
 386                 [audit_open],
 387                 [have_audit=yes],
 388                 [if test "x$have_audit" = xyes ; then
 389                         AC_MSG_ERROR([*** libaudit not found.])
 390                 fi])
 391
 392         if test "x$have_audit" = xyes ; then
 393                 AUDIT_LIBS="-laudit"
 394                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 395         else
 396                 have_audit=no
 397         fi
 398 else
 399         AUDIT_LIBS=
 400 fi
 401 AC_SUBST(AUDIT_LIBS)
 402
 403 # ------------------------------------------------------------------------------
 404 have_libcryptsetup=no
 405 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 406 if test "x$enable_libcryptsetup" != "xno"; then
 407         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 408                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 409         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 410                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 411         fi
 412 fi
 413 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 414
 415 # ------------------------------------------------------------------------------
 416 have_qrencode=no
 417 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 418 if test "x$enable_qrencode" != "xno"; then
 419         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 420                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 421         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 422                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 423         fi
 424 fi
 425 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 426
 427 # ------------------------------------------------------------------------------
 428 have_microhttpd=no
 429 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 430 if test "x$enable_microhttpd" != "xno"; then
 431         PKG_CHECK_MODULES(MICROHTTPD, [ libmicrohttpd ],
 432                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 433         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 434                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 435         fi
 436 fi
 437 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 438
 439 # ------------------------------------------------------------------------------
 440 have_binfmt=no
 441 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 442 if test "x$enable_binfmt" != "xno"; then
 443         have_binfmt=yes
 444 fi
 445 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 446
 447 # ------------------------------------------------------------------------------
 448 have_vconsole=no
 449 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 450 if test "x$enable_vconsole" != "xno"; then
 451         have_vconsole=yes
 452 fi
 453 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 454
 455 # ------------------------------------------------------------------------------
 456 have_readahead=no
 457 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 458 if test "x$enable_readahead" != "xno"; then
 459         have_readahead=yes
 460 fi
 461 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 462
 463 # ------------------------------------------------------------------------------
 464 have_quotacheck=no
 465 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 466 if test "x$enable_quotacheck" != "xno"; then
 467         have_quotacheck=yes
 468 fi
 469 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 470
 471 # ------------------------------------------------------------------------------
 472 have_randomseed=no
 473 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 474 if test "x$enable_randomseed" != "xno"; then
 475         have_randomseed=yes
 476 fi
 477 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 478
 479 # ------------------------------------------------------------------------------
 480 have_logind=no
 481 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 482 if test "x$enable_logind" != "xno"; then
 483         have_logind=yes
 484 fi
 485 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 486 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 487
 488 # ------------------------------------------------------------------------------
 489 have_hostnamed=no
 490 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 491 if test "x$enable_hostnamed" != "xno"; then
 492         have_hostnamed=yes
 493 fi
 494 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 495
 496 # ------------------------------------------------------------------------------
 497 have_timedated=no
 498 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 499 if test "x$enable_timedated" != "xno"; then
 500         have_timedated=yes
 501 fi
 502 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 503
 504 # ------------------------------------------------------------------------------
 505 have_localed=no
 506 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 507 if test "x$enable_localed" != "xno"; then
 508         have_localed=yes
 509 fi
 510 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 511
 512 # ------------------------------------------------------------------------------
 513 have_coredump=no
 514 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 515 if test "x$enable_coredump" != "xno"; then
 516         have_coredump=yes
 517 fi
 518 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 519
 520 # ------------------------------------------------------------------------------
 521 AC_ARG_WITH(usb-ids-path,
 522         [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 523         [USB_DATABASE=${withval}],
 524         [if test -n "$usbids" ; then
 525                 USB_DATABASE="$usbids"
 526         else
 527                 PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 528                 AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 529         fi])
 530 AC_MSG_CHECKING([for USB database location])
 531 AC_MSG_RESULT([$USB_DATABASE])
 532 AC_SUBST(USB_DATABASE)
 533
 534 AC_ARG_WITH(pci-ids-path,
 535         [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 536         [PCI_DATABASE=${withval}],
 537         [if test -n "$pciids" ; then
 538                 PCI_DATABASE="$pciids"
 539         else
 540                 PKG_CHECK_MODULES(LIBPCI, libpci >= 3)
 541                 AC_SUBST([PCI_DATABASE], [$($PKG_CONFIG --variable=idsdir libpci)/pci.ids])
 542         fi])
 543 AC_MSG_CHECKING([for PCI database location])
 544 AC_MSG_RESULT([$PCI_DATABASE])
 545 AC_SUBST(PCI_DATABASE)
 546
 547 # ------------------------------------------------------------------------------
 548 AC_ARG_WITH(firmware-path,
 549        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 550           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 551        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 552 OLD_IFS=$IFS
 553 IFS=:
 554 for i in $with_firmware_path; do
 555        if test "x${FIRMWARE_PATH}" = "x"; then
 556               FIRMWARE_PATH="\\\"${i}/\\\""
 557        else
 558               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 559        fi
 560 done
 561 IFS=$OLD_IFS
 562 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 563
 564 # ------------------------------------------------------------------------------
 565 AC_ARG_ENABLE([gudev],
 566        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 567        [], [enable_gudev=yes])
 568 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 569 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 570
 571 # ------------------------------------------------------------------------------
 572 AC_ARG_ENABLE([keymap],
 573        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 574        [], [enable_keymap=yes])
 575 AS_IF([test "x$enable_keymap" = "xyes"], [
 576        AC_PATH_PROG([GPERF], [gperf])
 577        if test -z "$GPERF"; then
 578               AC_MSG_ERROR([gperf is needed])
 579        fi
 580
 581        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 582        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 583 ])
 584 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 585
 586 # ------------------------------------------------------------------------------
 587 have_manpages=no
 588 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 589 AS_IF([test "x$enable_manpages" != xno], [
 590         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 591                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 592         ])
 593         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 594 ])
 595 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 596
 597 # ------------------------------------------------------------------------------
 598
 599 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 600 if test "z$with_distro" = "z"; then
 601         if test "$cross_compiling" = yes; then
 602                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 603         else
 604                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 605         fi
 606         if test "z$with_distro" = "z"; then
 607                 with_distro=other
 608         fi
 609 fi
 610 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 611 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 612
 613 # Location of the init scripts as mandated by LSB
 614 SYSTEM_SYSVINIT_PATH=/etc/init.d
 615 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 616
 617 M4_DEFINES=
 618
 619 case $with_distro in
 620         fedora)
 621                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 622                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 623                 M4_DEFINES=-DTARGET_FEDORA=1
 624                 ;;
 625         opensuse|suse)
 626                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 627                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 628                 M4_DEFINES=-DTARGET_SUSE=1
 629                 ;;
 630         debian)
 631                 SYSTEM_SYSVRCND_PATH=/etc
 632                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 633                 M4_DEFINES=-DTARGET_DEBIAN=1
 634                 ;;
 635         ubuntu)
 636                 SYSTEM_SYSVRCND_PATH=/etc
 637                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 638                 M4_DEFINES=-DTARGET_UBUNTU=1
 639                 ;;
 640         arch)
 641                 SYSTEM_SYSVINIT_PATH=
 642                 SYSTEM_SYSVRCND_PATH=
 643                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 644                 M4_DEFINES=-DTARGET_ARCH=1
 645                 ;;
 646         gentoo)
 647                 SYSTEM_SYSVINIT_PATH=
 648                 SYSTEM_SYSVRCND_PATH=
 649                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 650                 M4_DEFINES=-DTARGET_GENTOO=1
 651                 ;;
 652         slackware)
 653                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 654                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 655                 M4_DEFINES=-DTARGET_SLACKWARE=1
 656                 ;;
 657         frugalware)
 658                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 659                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 660                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 661                 ;;
 662         altlinux)
 663                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 664                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 665                 M4_DEFINES=-DTARGET_ALTLINUX=1
 666                 ;;
 667         mandriva)
 668                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 669                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 670                 M4_DEFINES=-DTARGET_MANDRIVA=1
 671                 ;;
 672         angstrom)
 673                 SYSTEM_SYSVRCND_PATH=/etc
 674                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 675                 M4_DEFINES=-DTARGET_ANGSTROM=1
 676                 ;;
 677         mageia)
 678                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 679                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 680                 M4_DEFINES=-DTARGET_MAGEIA=1
 681                 ;;
 682         other)
 683                 ;;
 684         *)
 685                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 686                 ;;
 687 esac
 688
 689 AC_ARG_WITH([sysvinit-path],
 690         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 691                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 692         [SYSTEM_SYSVINIT_PATH="$withval"],
 693         [])
 694
 695 AC_ARG_WITH([sysvrcd-path],
 696         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 697                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 698         [SYSTEM_SYSVRCND_PATH="$withval"],
 699         [])
 700
 701 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 702 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 703 AC_SUBST(M4_DEFINES)
 704
 705 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 706         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 707         SYSTEM_SYSV_COMPAT="yes"
 708         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 709 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 710         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 711 else
 712         SYSTEM_SYSV_COMPAT="no"
 713 fi
 714
 715 AC_ARG_WITH([tty-gid],
 716         [AS_HELP_STRING([--with-tty-gid=GID],
 717                 [Specify the numeric GID of the 'tty' group])],
 718         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 719         [])
 720
 721 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 722 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 723 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 724 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 725 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 726 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 727 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 728 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 729 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 730 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 731 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 732 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 733 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 734
 735 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 736
 737 AC_ARG_WITH([dbuspolicydir],
 738         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 739         [],
 740         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 741
 742 AC_ARG_WITH([dbussessionservicedir],
 743         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 744         [],
 745         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 746
 747 AC_ARG_WITH([dbussystemservicedir],
 748         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 749         [],
 750         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 751
 752 AC_ARG_WITH([dbusinterfacedir],
 753         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 754         [],
 755         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 756
 757 AC_ARG_WITH([rootprefix],
 758         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 759         [], [with_rootprefix=${ac_default_prefix}])
 760
 761 AC_ARG_WITH([rootlibdir],
 762         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 763         [],
 764         [with_rootlibdir=${libdir}])
 765
 766 AC_ARG_WITH([pamlibdir],
 767         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 768         [],
 769         [with_pamlibdir=${with_rootlibdir}/security])
 770
 771 AC_ARG_ENABLE([split-usr],
 772         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 773         [],
 774         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 775                 enable_split_usr=yes
 776         ], [
 777                 enable_split_usr=no
 778         ])])
 779
 780 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 781         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 782 ])
 783
 784 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 785 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 786 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 787 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 788 AC_SUBST([pamlibdir], [$with_pamlibdir])
 789 AC_SUBST([rootprefix], [$with_rootprefix])
 790 AC_SUBST([rootlibdir], [$with_rootlibdir])
 791
 792 AC_CONFIG_FILES([
 793         Makefile po/Makefile.in
 794         docs/libudev/Makefile
 795         docs/libudev/version.xml
 796         docs/gudev/Makefile
 797         docs/gudev/version.xml
 798 ])
 799
 800 AC_OUTPUT
 801 AC_MSG_RESULT([
 802         $PACKAGE_NAME $VERSION
 803
 804         Distribution:            ${with_distro}
 805         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 806         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 807         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 808         libcryptsetup:           ${have_libcryptsetup}
 809         tcpwrap:                 ${have_tcpwrap}
 810         PAM:                     ${have_pam}
 811         AUDIT:                   ${have_audit}
 812         IMA:                     ${have_ima}
 813         SELinux:                 ${have_selinux}
 814         XZ:                      ${have_xz}
 815         ACL:                     ${have_acl}
 816         GCRYPT:                  ${have_gcrypt}
 817         QRENCODE:                ${have_qrencode}
 818         MICROHTTPD:              ${have_microhttpd}
 819         binfmt:                  ${have_binfmt}
 820         vconsole:                ${have_vconsole}
 821         readahead:               ${have_readahead}
 822         quotacheck:              ${have_quotacheck}
 823         randomseed:              ${have_randomseed}
 824         logind:                  ${have_logind}
 825         hostnamed:               ${have_hostnamed}
 826         timedated:               ${have_timedated}
 827         localed:                 ${have_localed}
 828         coredump:                ${have_coredump}
 829         firmware path:           ${FIRMWARE_PATH}
 830         usb.ids:                 ${USB_DATABASE}
 831         pci.ids:                 ${PCI_DATABASE}
 832         gudev:                   ${enable_gudev}
 833         gintrospection:          ${enable_introspection}
 834         keymap:                  ${enable_keymap}
 835         Python:                  ${have_python}
 836         Python Headers:          ${have_python_devel}
 837
 838         prefix:                  ${prefix}
 839         rootprefix:              ${with_rootprefix}
 840         sysconf dir:             ${sysconfdir}
 841         datarootdir:             ${datarootdir}
 842         includedir:              ${includedir}
 843         include_prefix:          ${INCLUDE_PREFIX}
 844         lib dir:                 ${libdir}
 845         rootlib dir:             ${with_rootlibdir}
 846         PAM modules dir:         ${with_pamlibdir}
 847         D-Bus policy dir:        ${with_dbuspolicydir}
 848         D-Bus session dir:       ${with_dbussessionservicedir}
 849         D-Bus system dir:        ${with_dbussystemservicedir}
 850         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 851         Split /usr:              ${enable_split_usr}
 852         man pages:               ${have_manpages}
 853         gtk-doc:                 ${enable_gtk_doc}
 854
 855         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 856         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 857         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 858 ])