configure.ac

   1
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [186],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65
  66 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  67 m4_ifdef([GTK_DOC_CHECK], [
  68 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  69 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  70
  71 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  72 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  73 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  74
  75 AC_CHECK_TOOL(OBJCOPY, objcopy)
  76 AC_CHECK_TOOL(STRINGS, strings)
  77 AC_CHECK_TOOL(GPERF, gperf)
  78 if test -z "$GPERF" ; then
  79         AC_MSG_ERROR([*** gperf not found])
  80 fi
  81
  82 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  83         -pipe \
  84         -Wall \
  85         -W \
  86         -Wextra \
  87         -Wno-inline \
  88         -Wvla \
  89         -Wundef \
  90         -Wformat=2 \
  91         -Wlogical-op \
  92         -Wsign-compare \
  93         -Wformat-security \
  94         -Wmissing-include-dirs \
  95         -Wformat-nonliteral \
  96         -Wold-style-definition \
  97         -Wpointer-arith \
  98         -Winit-self \
  99         -Wdeclaration-after-statement \
 100         -Wfloat-equal \
 101         -Wmissing-prototypes \
 102         -Wstrict-prototypes \
 103         -Wredundant-decls \
 104         -Wmissing-declarations \
 105         -Wmissing-noreturn \
 106         -Wshadow \
 107         -Wendif-labels \
 108         -Wcast-align \
 109         -Wstrict-aliasing=2 \
 110         -Wwrite-strings \
 111         -Wno-long-long \
 112         -Wno-overlength-strings \
 113         -Wno-unused-parameter \
 114         -Wno-missing-field-initializers \
 115         -Wno-unused-result \
 116         -Werror=overflow \
 117         -Wp,-D_FORTIFY_SOURCE=2 \
 118         -ffast-math \
 119         -fno-common \
 120         -fdiagnostics-show-option \
 121         -fno-strict-aliasing \
 122         -fvisibility=hidden \
 123         -ffunction-sections \
 124         -fdata-sections])
 125 AC_SUBST([WARNINGFLAGS], $with_cflags)
 126
 127 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 128         -Wl,--as-needed \
 129         -Wl,--gc-sections])
 130 AC_SUBST([GCLDFLAGS], $with_ldflags)
 131
 132 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 133 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 134
 135 save_LIBS="$LIBS"
 136 LIBS=
 137 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 138 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 139 CAP_LIBS="$LIBS"
 140 LIBS="$save_LIBS"
 141 AC_SUBST(CAP_LIBS)
 142
 143 # This makes sure pkg.m4 is available.
 144 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 145
 146 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 147 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 148 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 149
 150 # ------------------------------------------------------------------------------
 151 have_ima=yes
 152 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 153                 [case "${enableval}" in
 154                         yes) have_ima=yes ;;
 155                         no) have_ima=no ;;
 156                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 157                 esac],
 158                 [have_ima=yes])
 159
 160 if test "x${have_ima}" != xno ; then
 161         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 162 fi
 163
 164 # ------------------------------------------------------------------------------
 165 have_selinux=no
 166 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 167 if test "x$enable_selinux" != "xno"; then
 168         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 169                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 170         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 171                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 172         fi
 173 fi
 174 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 175 if test "x${have_selinux}" != xno ; then
 176         sushell=/sbin/sushell
 177 else
 178         sushell=/bin/bash
 179 fi
 180 AC_SUBST(sushell)
 181
 182 # ------------------------------------------------------------------------------
 183 have_xz=no
 184 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 185 if test "x$enable_xz" != "xno"; then
 186         PKG_CHECK_MODULES(XZ, [ liblzma ],
 187                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 188         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 189                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 190         fi
 191 fi
 192 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 193
 194 # ------------------------------------------------------------------------------
 195 AC_ARG_ENABLE([tcpwrap],
 196         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 197                 [case "${enableval}" in
 198                         yes) have_tcpwrap=yes ;;
 199                         no) have_tcpwrap=no ;;
 200                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 201                 esac],
 202                 [have_tcpwrap=auto])
 203
 204 if test "x${have_tcpwrap}" != xno ; then
 205         ACX_LIBWRAP
 206         if test "x${LIBWRAP_LIBS}" = x ; then
 207                 if test "x$have_tcpwrap" = xyes ; then
 208                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 209                 fi
 210                 have_tcpwrap=no
 211         else
 212                 have_tcpwrap=yes
 213         fi
 214 else
 215         LIBWRAP_LIBS=
 216 fi
 217 AC_SUBST(LIBWRAP_LIBS)
 218
 219 # ------------------------------------------------------------------------------
 220 AC_ARG_ENABLE([pam],
 221         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 222                 [case "${enableval}" in
 223                         yes) have_pam=yes ;;
 224                         no) have_pam=no ;;
 225                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 226                 esac],
 227                 [have_pam=auto])
 228
 229 if test "x${have_pam}" != xno ; then
 230         AC_CHECK_HEADERS(
 231                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 232                 [have_pam=yes],
 233                 [if test "x$have_pam" = xyes ; then
 234                         AC_MSG_ERROR([*** PAM headers not found.])
 235                 fi])
 236
 237         AC_CHECK_LIB(
 238                 [pam],
 239                 [pam_syslog],
 240                 [have_pam=yes],
 241                 [if test "x$have_pam" = xyes ; then
 242                         AC_MSG_ERROR([*** libpam not found.])
 243                 fi])
 244
 245         if test "x$have_pam" = xyes ; then
 246                 PAM_LIBS="-lpam -lpam_misc"
 247                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 248         else
 249                 have_pam=no
 250         fi
 251 else
 252         PAM_LIBS=
 253 fi
 254 AC_SUBST(PAM_LIBS)
 255 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 256
 257 # ------------------------------------------------------------------------------
 258 AC_ARG_ENABLE([acl],
 259         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 260                 [case "${enableval}" in
 261                         yes) have_acl=yes ;;
 262                         no) have_acl=no ;;
 263                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 264                 esac],
 265                 [have_acl=auto])
 266
 267 if test "x${have_acl}" != xno ; then
 268         AC_CHECK_HEADERS(
 269                 [sys/acl.h acl/libacl.h],
 270                 [have_acl=yes],
 271                 [if test "x$have_acl" = xyes ; then
 272                         AC_MSG_ERROR([*** ACL headers not found.])
 273                 fi])
 274
 275         AC_CHECK_LIB(
 276                 [acl],
 277                 [acl_get_file],
 278                 [have_acl=yes],
 279                 [if test "x$have_acl" = xyes ; then
 280                         AC_MSG_ERROR([*** libacl not found.])
 281                 fi])
 282
 283         if test "x$have_acl" = xyes ; then
 284                 ACL_LIBS="-lacl"
 285                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 286         else
 287                 have_acl=no
 288         fi
 289 else
 290         ACL_LIBS=
 291 fi
 292 AC_SUBST(ACL_LIBS)
 293 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 294
 295 # ------------------------------------------------------------------------------
 296 AC_ARG_ENABLE([audit],
 297         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 298                 [case "${enableval}" in
 299                         yes) have_audit=yes ;;
 300                         no) have_audit=no ;;
 301                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 302                 esac],
 303                 [have_audit=auto])
 304
 305 if test "x${have_audit}" != xno ; then
 306         AC_CHECK_HEADERS(
 307                 [libaudit.h],
 308                 [have_audit=yes],
 309                 [if test "x$have_audit" = xyes ; then
 310                         AC_MSG_ERROR([*** AUDIT headers not found.])
 311                 fi])
 312
 313         AC_CHECK_LIB(
 314                 [audit],
 315                 [audit_open],
 316                 [have_audit=yes],
 317                 [if test "x$have_audit" = xyes ; then
 318                         AC_MSG_ERROR([*** libaudit not found.])
 319                 fi])
 320
 321         if test "x$have_audit" = xyes ; then
 322                 AUDIT_LIBS="-laudit"
 323                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 324         else
 325                 have_audit=no
 326         fi
 327 else
 328         AUDIT_LIBS=
 329 fi
 330 AC_SUBST(AUDIT_LIBS)
 331
 332 # ------------------------------------------------------------------------------
 333 have_libcryptsetup=no
 334 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 335 if test "x$enable_libcryptsetup" != "xno"; then
 336         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 337                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 338         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 339                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 340         fi
 341 fi
 342 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 343
 344 # ------------------------------------------------------------------------------
 345 have_binfmt=no
 346 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 347 if test "x$enable_binfmt" != "xno"; then
 348         have_binfmt=yes
 349 fi
 350 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 351
 352 # ------------------------------------------------------------------------------
 353 have_vconsole=no
 354 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 355 if test "x$enable_vconsole" != "xno"; then
 356         have_vconsole=yes
 357 fi
 358 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 359
 360 # ------------------------------------------------------------------------------
 361 have_readahead=no
 362 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 363 if test "x$enable_readahead" != "xno"; then
 364         have_readahead=yes
 365 fi
 366 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 367
 368 # ------------------------------------------------------------------------------
 369 have_quotacheck=no
 370 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 371 if test "x$enable_quotacheck" != "xno"; then
 372         have_quotacheck=yes
 373 fi
 374 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 375
 376 # ------------------------------------------------------------------------------
 377 have_randomseed=no
 378 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 379 if test "x$enable_randomseed" != "xno"; then
 380         have_randomseed=yes
 381 fi
 382 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 383
 384 # ------------------------------------------------------------------------------
 385 have_logind=no
 386 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 387 if test "x$enable_logind" != "xno"; then
 388         have_logind=yes
 389 fi
 390 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 391 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 392
 393 # ------------------------------------------------------------------------------
 394 have_hostnamed=no
 395 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 396 if test "x$enable_hostnamed" != "xno"; then
 397         have_hostnamed=yes
 398 fi
 399 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 400
 401 # ------------------------------------------------------------------------------
 402 have_timedated=no
 403 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 404 if test "x$enable_timedated" != "xno"; then
 405         have_timedated=yes
 406 fi
 407 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 408
 409 # ------------------------------------------------------------------------------
 410 have_localed=no
 411 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 412 if test "x$enable_localed" != "xno"; then
 413         have_localed=yes
 414 fi
 415 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 416
 417 # ------------------------------------------------------------------------------
 418 have_coredump=no
 419 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 420 if test "x$enable_coredump" != "xno"; then
 421         have_coredump=yes
 422 fi
 423 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 424
 425 # ------------------------------------------------------------------------------
 426 AC_ARG_WITH(usb-ids-path,
 427         [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 428         [USB_DATABASE=${withval}],
 429         [if test -n "$usbids" ; then
 430                 USB_DATABASE="$usbids"
 431         else
 432                 PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 433                 AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 434         fi])
 435 AC_MSG_CHECKING([for USB database location])
 436 AC_MSG_RESULT([$USB_DATABASE])
 437 AC_SUBST(USB_DATABASE)
 438
 439 AC_ARG_WITH(pci-ids-path,
 440         [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 441         [PCI_DATABASE=${withval}],
 442         [if test -n "$pciids" ; then
 443                 PCI_DATABASE="$pciids"
 444         else
 445                 PKG_CHECK_MODULES(LIBPCI, libpci >= 3)
 446                 AC_SUBST([PCI_DATABASE], [$($PKG_CONFIG --variable=idsdir libpci)/pci.ids])
 447         fi])
 448 AC_MSG_CHECKING([for PCI database location])
 449 AC_MSG_RESULT([$PCI_DATABASE])
 450 AC_SUBST(PCI_DATABASE)
 451
 452 # ------------------------------------------------------------------------------
 453 AC_ARG_WITH(firmware-path,
 454        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 455           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 456        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 457 OLD_IFS=$IFS
 458 IFS=:
 459 for i in $with_firmware_path; do
 460        if test "x${FIRMWARE_PATH}" = "x"; then
 461               FIRMWARE_PATH="\\\"${i}/\\\""
 462        else
 463               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 464        fi
 465 done
 466 IFS=$OLD_IFS
 467 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 468
 469 # ------------------------------------------------------------------------------
 470 AC_ARG_ENABLE([gudev],
 471        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 472        [], [enable_gudev=yes])
 473 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 474 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 475
 476 # ------------------------------------------------------------------------------
 477 AC_ARG_ENABLE([keymap],
 478        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 479        [], [enable_keymap=yes])
 480 AS_IF([test "x$enable_keymap" = "xyes"], [
 481        AC_PATH_PROG([GPERF], [gperf])
 482        if test -z "$GPERF"; then
 483               AC_MSG_ERROR([gperf is needed])
 484        fi
 485
 486        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 487        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 488 ])
 489 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 490
 491 # ------------------------------------------------------------------------------
 492 have_manpages=no
 493 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 494 if test "x$enable_manpages" != "xno"; then
 495         have_manpages=yes
 496 fi
 497 AM_CONDITIONAL(ENABLE_MANPAGES, [test "$have_manpages" = "yes"])
 498
 499 # ------------------------------------------------------------------------------
 500 AC_PATH_PROG([XSLTPROC], [xsltproc])
 501 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 502
 503 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 504 if test "z$with_distro" = "z"; then
 505         if test "$cross_compiling" = yes; then
 506                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 507         else
 508                 with_distro=$($GREP '^ID=' /etc/os-release | $SED 's/ID=//');
 509         fi
 510         if test "z$with_distro" = "z"; then
 511                 with_distro=other
 512         fi
 513 fi
 514 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 515 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 516
 517 # Location of the init scripts as mandated by LSB
 518 SYSTEM_SYSVINIT_PATH=/etc/init.d
 519 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 520
 521 M4_DEFINES=
 522
 523 case $with_distro in
 524         fedora)
 525                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 526                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 527                 M4_DEFINES=-DTARGET_FEDORA=1
 528                 ;;
 529         opensuse|suse)
 530                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 531                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 532                 M4_DEFINES=-DTARGET_SUSE=1
 533                 ;;
 534         debian)
 535                 SYSTEM_SYSVRCND_PATH=/etc
 536                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 537                 M4_DEFINES=-DTARGET_DEBIAN=1
 538                 ;;
 539         ubuntu)
 540                 SYSTEM_SYSVRCND_PATH=/etc
 541                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 542                 M4_DEFINES=-DTARGET_UBUNTU=1
 543                 ;;
 544         arch)
 545                 SYSTEM_SYSVINIT_PATH=
 546                 SYSTEM_SYSVRCND_PATH=
 547                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 548                 M4_DEFINES=-DTARGET_ARCH=1
 549                 ;;
 550         gentoo)
 551                 SYSTEM_SYSVINIT_PATH=
 552                 SYSTEM_SYSVRCND_PATH=
 553                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 554                 M4_DEFINES=-DTARGET_GENTOO=1
 555                 ;;
 556         slackware)
 557                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 558                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 559                 M4_DEFINES=-DTARGET_SLACKWARE=1
 560                 ;;
 561         frugalware)
 562                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 563                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 564                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 565                 ;;
 566         altlinux)
 567                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 568                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 569                 M4_DEFINES=-DTARGET_ALTLINUX=1
 570                 ;;
 571         mandriva)
 572                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 573                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 574                 M4_DEFINES=-DTARGET_MANDRIVA=1
 575                 ;;
 576         angstrom)
 577                 SYSTEM_SYSVRCND_PATH=/etc
 578                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 579                 M4_DEFINES=-DTARGET_ANGSTROM=1
 580                 ;;
 581         mageia)
 582                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 583                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 584                 M4_DEFINES=-DTARGET_MAGEIA=1
 585                 ;;
 586         other)
 587                 ;;
 588         *)
 589                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 590                 ;;
 591 esac
 592
 593 AC_ARG_WITH([sysvinit-path],
 594         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 595                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 596         [SYSTEM_SYSVINIT_PATH="$withval"],
 597         [])
 598
 599 AC_ARG_WITH([sysvrcd-path],
 600         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 601                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 602         [SYSTEM_SYSVRCND_PATH="$withval"],
 603         [])
 604
 605 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 606 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 607 AC_SUBST(M4_DEFINES)
 608
 609 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 610         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 611         SYSTEM_SYSV_COMPAT="yes"
 612         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 613 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 614         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 615 else
 616         SYSTEM_SYSV_COMPAT="no"
 617 fi
 618
 619 AC_ARG_WITH([tty-gid],
 620         [AS_HELP_STRING([--with-tty-gid=GID],
 621                 [Specify the numeric GID of the 'tty' group])],
 622         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 623         [])
 624
 625 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 626 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 627 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 628 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 629 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 630 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 631 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 632 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 633 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 634 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 635 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 636 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 637 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 638
 639 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 640
 641 AC_ARG_WITH([dbuspolicydir],
 642         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 643         [],
 644         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 645
 646 AC_ARG_WITH([dbussessionservicedir],
 647         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 648         [],
 649         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 650
 651 AC_ARG_WITH([dbussystemservicedir],
 652         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 653         [],
 654         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 655
 656 AC_ARG_WITH([dbusinterfacedir],
 657         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 658         [],
 659         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 660
 661 AC_ARG_WITH([rootprefix],
 662         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 663         [], [with_rootprefix=${ac_default_prefix}])
 664
 665 AC_ARG_WITH([rootlibdir],
 666         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 667         [],
 668         [with_rootlibdir=${libdir}])
 669
 670 AC_ARG_WITH([pamlibdir],
 671         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 672         [],
 673         [with_pamlibdir=${with_rootlibdir}/security])
 674
 675 AC_ARG_ENABLE([split-usr],
 676         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 677         [],
 678         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 679                 enable_split_usr=yes
 680         ], [
 681                 enable_split_usr=no
 682         ])])
 683
 684 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 685         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 686 ])
 687
 688 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 689 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 690 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 691 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 692 AC_SUBST([pamlibdir], [$with_pamlibdir])
 693 AC_SUBST([rootprefix], [$with_rootprefix])
 694 AC_SUBST([rootlibdir], [$with_rootlibdir])
 695
 696 AC_CONFIG_FILES([
 697         Makefile po/Makefile.in
 698         docs/libudev/Makefile
 699         docs/libudev/version.xml
 700         docs/gudev/Makefile
 701         docs/gudev/version.xml
 702 ])
 703
 704 AC_OUTPUT
 705 AC_MSG_RESULT([
 706         $PACKAGE_NAME $VERSION
 707
 708         Distribution:            ${with_distro}
 709         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 710         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 711         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 712         libcryptsetup:           ${have_libcryptsetup}
 713         tcpwrap:                 ${have_tcpwrap}
 714         PAM:                     ${have_pam}
 715         AUDIT:                   ${have_audit}
 716         IMA:                     ${have_ima}
 717         SELinux:                 ${have_selinux}
 718         XZ:                      ${have_xz}
 719         ACL:                     ${have_acl}
 720         binfmt:                  ${have_binfmt}
 721         vconsole:                ${have_vconsole}
 722         readahead:               ${have_readahead}
 723         quotacheck:              ${have_quotacheck}
 724         randomseed:              ${have_randomseed}
 725         logind:                  ${have_logind}
 726         hostnamed:               ${have_hostnamed}
 727         timedated:               ${have_timedated}
 728         localed:                 ${have_localed}
 729         coredump:                ${have_coredump}
 730         firmware path:           ${FIRMWARE_PATH}
 731         usb.ids:                 ${USB_DATABASE}
 732         pci.ids:                 ${PCI_DATABASE}
 733         gudev:                   ${enable_gudev}
 734         gintrospection:          ${enable_introspection}
 735         keymap:                  ${enable_keymap}
 736
 737         prefix:                  ${prefix}
 738         rootprefix:              ${with_rootprefix}
 739         sysconf dir:             ${sysconfdir}
 740         datarootdir:             ${datarootdir}
 741         includedir:              ${includedir}
 742         include_prefix:          ${INCLUDE_PREFIX}
 743         lib dir:                 ${libdir}
 744         rootlib dir:             ${with_rootlibdir}
 745         PAM modules dir:         ${with_pamlibdir}
 746         D-Bus policy dir:        ${with_dbuspolicydir}
 747         D-Bus session dir:       ${with_dbussessionservicedir}
 748         D-Bus system dir:        ${with_dbussystemservicedir}
 749         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 750         Split /usr:              ${enable_split_usr}
 751         man pages:               ${have_manpages}
 752
 753         CFLAGS:                  ${CFLAGS}
 754         CPPLAGS:                 ${CPPFLAGS}
 755         LDFLAGS:                 ${LDFLAGS}
 756 ])