configure.ac

   1
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [187],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65
  66 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  67 m4_ifdef([GTK_DOC_CHECK], [
  68 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  69 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  70
  71 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  72 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  73 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  74
  75 AC_CHECK_TOOL(OBJCOPY, objcopy)
  76 AC_CHECK_TOOL(STRINGS, strings)
  77 AC_CHECK_TOOL(GPERF, gperf)
  78 if test -z "$GPERF" ; then
  79         AC_MSG_ERROR([*** gperf not found])
  80 fi
  81
  82 # we use python only to build the man page index
  83 AM_PATH_PYTHON(,, [:])
  84 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  85
  86 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  87         -pipe \
  88         -Wall \
  89         -W \
  90         -Wextra \
  91         -Wno-inline \
  92         -Wvla \
  93         -Wundef \
  94         -Wformat=2 \
  95         -Wlogical-op \
  96         -Wsign-compare \
  97         -Wformat-security \
  98         -Wmissing-include-dirs \
  99         -Wformat-nonliteral \
 100         -Wold-style-definition \
 101         -Wpointer-arith \
 102         -Winit-self \
 103         -Wdeclaration-after-statement \
 104         -Wfloat-equal \
 105         -Wmissing-prototypes \
 106         -Wstrict-prototypes \
 107         -Wredundant-decls \
 108         -Wmissing-declarations \
 109         -Wmissing-noreturn \
 110         -Wshadow \
 111         -Wendif-labels \
 112         -Wcast-align \
 113         -Wstrict-aliasing=2 \
 114         -Wwrite-strings \
 115         -Wno-long-long \
 116         -Wno-overlength-strings \
 117         -Wno-unused-parameter \
 118         -Wno-missing-field-initializers \
 119         -Wno-unused-result \
 120         -Werror=overflow \
 121         -Wp,-D_FORTIFY_SOURCE=2 \
 122         -ffast-math \
 123         -fno-common \
 124         -fdiagnostics-show-option \
 125         -fno-strict-aliasing \
 126         -fvisibility=hidden \
 127         -ffunction-sections \
 128         -fdata-sections])
 129 AC_SUBST([WARNINGFLAGS], $with_cflags)
 130
 131 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 132         -Wl,--as-needed \
 133         -Wl,--gc-sections])
 134 AC_SUBST([GCLDFLAGS], $with_ldflags)
 135
 136 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 137 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 138
 139 save_LIBS="$LIBS"
 140 LIBS=
 141 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 142 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 143 CAP_LIBS="$LIBS"
 144 LIBS="$save_LIBS"
 145 AC_SUBST(CAP_LIBS)
 146
 147 # This makes sure pkg.m4 is available.
 148 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 149
 150 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 151 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 152 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 153
 154 # ------------------------------------------------------------------------------
 155 have_ima=yes
 156 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 157                 [case "${enableval}" in
 158                         yes) have_ima=yes ;;
 159                         no) have_ima=no ;;
 160                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 161                 esac],
 162                 [have_ima=yes])
 163
 164 if test "x${have_ima}" != xno ; then
 165         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 166 fi
 167
 168 # ------------------------------------------------------------------------------
 169 have_selinux=no
 170 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 171 if test "x$enable_selinux" != "xno"; then
 172         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 173                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 174         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 175                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 176         fi
 177 fi
 178 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 179 if test "x${have_selinux}" != xno ; then
 180         sushell=/sbin/sushell
 181 else
 182         sushell=/bin/bash
 183 fi
 184 AC_SUBST(sushell)
 185
 186 # ------------------------------------------------------------------------------
 187 have_xz=no
 188 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 189 if test "x$enable_xz" != "xno"; then
 190         PKG_CHECK_MODULES(XZ, [ liblzma ],
 191                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 192         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 193                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 194         fi
 195 fi
 196 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 197
 198 # ------------------------------------------------------------------------------
 199 AC_ARG_ENABLE([tcpwrap],
 200         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 201                 [case "${enableval}" in
 202                         yes) have_tcpwrap=yes ;;
 203                         no) have_tcpwrap=no ;;
 204                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 205                 esac],
 206                 [have_tcpwrap=auto])
 207
 208 if test "x${have_tcpwrap}" != xno ; then
 209         ACX_LIBWRAP
 210         if test "x${LIBWRAP_LIBS}" = x ; then
 211                 if test "x$have_tcpwrap" = xyes ; then
 212                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 213                 fi
 214                 have_tcpwrap=no
 215         else
 216                 have_tcpwrap=yes
 217         fi
 218 else
 219         LIBWRAP_LIBS=
 220 fi
 221 AC_SUBST(LIBWRAP_LIBS)
 222
 223 # ------------------------------------------------------------------------------
 224 AC_ARG_ENABLE([pam],
 225         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 226                 [case "${enableval}" in
 227                         yes) have_pam=yes ;;
 228                         no) have_pam=no ;;
 229                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 230                 esac],
 231                 [have_pam=auto])
 232
 233 if test "x${have_pam}" != xno ; then
 234         AC_CHECK_HEADERS(
 235                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 236                 [have_pam=yes],
 237                 [if test "x$have_pam" = xyes ; then
 238                         AC_MSG_ERROR([*** PAM headers not found.])
 239                 fi])
 240
 241         AC_CHECK_LIB(
 242                 [pam],
 243                 [pam_syslog],
 244                 [have_pam=yes],
 245                 [if test "x$have_pam" = xyes ; then
 246                         AC_MSG_ERROR([*** libpam not found.])
 247                 fi])
 248
 249         if test "x$have_pam" = xyes ; then
 250                 PAM_LIBS="-lpam -lpam_misc"
 251                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 252         else
 253                 have_pam=no
 254         fi
 255 else
 256         PAM_LIBS=
 257 fi
 258 AC_SUBST(PAM_LIBS)
 259 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 260
 261 # ------------------------------------------------------------------------------
 262 AC_ARG_ENABLE([acl],
 263         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 264                 [case "${enableval}" in
 265                         yes) have_acl=yes ;;
 266                         no) have_acl=no ;;
 267                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 268                 esac],
 269                 [have_acl=auto])
 270
 271 if test "x${have_acl}" != xno ; then
 272         AC_CHECK_HEADERS(
 273                 [sys/acl.h acl/libacl.h],
 274                 [have_acl=yes],
 275                 [if test "x$have_acl" = xyes ; then
 276                         AC_MSG_ERROR([*** ACL headers not found.])
 277                 fi])
 278
 279         AC_CHECK_LIB(
 280                 [acl],
 281                 [acl_get_file],
 282                 [have_acl=yes],
 283                 [if test "x$have_acl" = xyes ; then
 284                         AC_MSG_ERROR([*** libacl not found.])
 285                 fi])
 286
 287         if test "x$have_acl" = xyes ; then
 288                 ACL_LIBS="-lacl"
 289                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 290         else
 291                 have_acl=no
 292         fi
 293 else
 294         ACL_LIBS=
 295 fi
 296 AC_SUBST(ACL_LIBS)
 297 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 298
 299 # ------------------------------------------------------------------------------
 300 AC_ARG_ENABLE([audit],
 301         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 302                 [case "${enableval}" in
 303                         yes) have_audit=yes ;;
 304                         no) have_audit=no ;;
 305                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 306                 esac],
 307                 [have_audit=auto])
 308
 309 if test "x${have_audit}" != xno ; then
 310         AC_CHECK_HEADERS(
 311                 [libaudit.h],
 312                 [have_audit=yes],
 313                 [if test "x$have_audit" = xyes ; then
 314                         AC_MSG_ERROR([*** AUDIT headers not found.])
 315                 fi])
 316
 317         AC_CHECK_LIB(
 318                 [audit],
 319                 [audit_open],
 320                 [have_audit=yes],
 321                 [if test "x$have_audit" = xyes ; then
 322                         AC_MSG_ERROR([*** libaudit not found.])
 323                 fi])
 324
 325         if test "x$have_audit" = xyes ; then
 326                 AUDIT_LIBS="-laudit"
 327                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 328         else
 329                 have_audit=no
 330         fi
 331 else
 332         AUDIT_LIBS=
 333 fi
 334 AC_SUBST(AUDIT_LIBS)
 335
 336 # ------------------------------------------------------------------------------
 337 have_libcryptsetup=no
 338 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 339 if test "x$enable_libcryptsetup" != "xno"; then
 340         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 341                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 342         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 343                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 344         fi
 345 fi
 346 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 347
 348 # ------------------------------------------------------------------------------
 349 have_binfmt=no
 350 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 351 if test "x$enable_binfmt" != "xno"; then
 352         have_binfmt=yes
 353 fi
 354 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 355
 356 # ------------------------------------------------------------------------------
 357 have_vconsole=no
 358 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 359 if test "x$enable_vconsole" != "xno"; then
 360         have_vconsole=yes
 361 fi
 362 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 363
 364 # ------------------------------------------------------------------------------
 365 have_readahead=no
 366 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 367 if test "x$enable_readahead" != "xno"; then
 368         have_readahead=yes
 369 fi
 370 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 371
 372 # ------------------------------------------------------------------------------
 373 have_quotacheck=no
 374 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 375 if test "x$enable_quotacheck" != "xno"; then
 376         have_quotacheck=yes
 377 fi
 378 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 379
 380 # ------------------------------------------------------------------------------
 381 have_randomseed=no
 382 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 383 if test "x$enable_randomseed" != "xno"; then
 384         have_randomseed=yes
 385 fi
 386 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 387
 388 # ------------------------------------------------------------------------------
 389 have_logind=no
 390 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 391 if test "x$enable_logind" != "xno"; then
 392         have_logind=yes
 393 fi
 394 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 395 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 396
 397 # ------------------------------------------------------------------------------
 398 have_hostnamed=no
 399 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 400 if test "x$enable_hostnamed" != "xno"; then
 401         have_hostnamed=yes
 402 fi
 403 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 404
 405 # ------------------------------------------------------------------------------
 406 have_timedated=no
 407 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 408 if test "x$enable_timedated" != "xno"; then
 409         have_timedated=yes
 410 fi
 411 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 412
 413 # ------------------------------------------------------------------------------
 414 have_localed=no
 415 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 416 if test "x$enable_localed" != "xno"; then
 417         have_localed=yes
 418 fi
 419 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 420
 421 # ------------------------------------------------------------------------------
 422 have_coredump=no
 423 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 424 if test "x$enable_coredump" != "xno"; then
 425         have_coredump=yes
 426 fi
 427 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 428
 429 # ------------------------------------------------------------------------------
 430 AC_ARG_WITH(usb-ids-path,
 431         [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 432         [USB_DATABASE=${withval}],
 433         [if test -n "$usbids" ; then
 434                 USB_DATABASE="$usbids"
 435         else
 436                 PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 437                 AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 438         fi])
 439 AC_MSG_CHECKING([for USB database location])
 440 AC_MSG_RESULT([$USB_DATABASE])
 441 AC_SUBST(USB_DATABASE)
 442
 443 AC_ARG_WITH(pci-ids-path,
 444         [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 445         [PCI_DATABASE=${withval}],
 446         [if test -n "$pciids" ; then
 447                 PCI_DATABASE="$pciids"
 448         else
 449                 PKG_CHECK_MODULES(LIBPCI, libpci >= 3)
 450                 AC_SUBST([PCI_DATABASE], [$($PKG_CONFIG --variable=idsdir libpci)/pci.ids])
 451         fi])
 452 AC_MSG_CHECKING([for PCI database location])
 453 AC_MSG_RESULT([$PCI_DATABASE])
 454 AC_SUBST(PCI_DATABASE)
 455
 456 # ------------------------------------------------------------------------------
 457 AC_ARG_WITH(firmware-path,
 458        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 459           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 460        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 461 OLD_IFS=$IFS
 462 IFS=:
 463 for i in $with_firmware_path; do
 464        if test "x${FIRMWARE_PATH}" = "x"; then
 465               FIRMWARE_PATH="\\\"${i}/\\\""
 466        else
 467               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 468        fi
 469 done
 470 IFS=$OLD_IFS
 471 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 472
 473 # ------------------------------------------------------------------------------
 474 AC_ARG_ENABLE([gudev],
 475        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 476        [], [enable_gudev=yes])
 477 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 478 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 479
 480 # ------------------------------------------------------------------------------
 481 AC_ARG_ENABLE([keymap],
 482        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 483        [], [enable_keymap=yes])
 484 AS_IF([test "x$enable_keymap" = "xyes"], [
 485        AC_PATH_PROG([GPERF], [gperf])
 486        if test -z "$GPERF"; then
 487               AC_MSG_ERROR([gperf is needed])
 488        fi
 489
 490        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 491        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 492 ])
 493 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 494
 495 # ------------------------------------------------------------------------------
 496 have_manpages=no
 497 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 498 if test "x$enable_manpages" != "xno"; then
 499         have_manpages=yes
 500 fi
 501 AM_CONDITIONAL(ENABLE_MANPAGES, [test "$have_manpages" = "yes"])
 502
 503 # ------------------------------------------------------------------------------
 504 AC_PATH_PROG([XSLTPROC], [xsltproc])
 505 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 506
 507 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 508 if test "z$with_distro" = "z"; then
 509         if test "$cross_compiling" = yes; then
 510                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 511         else
 512                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 513         fi
 514         if test "z$with_distro" = "z"; then
 515                 with_distro=other
 516         fi
 517 fi
 518 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 519 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 520
 521 # Location of the init scripts as mandated by LSB
 522 SYSTEM_SYSVINIT_PATH=/etc/init.d
 523 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 524
 525 M4_DEFINES=
 526
 527 case $with_distro in
 528         fedora)
 529                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 530                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 531                 M4_DEFINES=-DTARGET_FEDORA=1
 532                 ;;
 533         opensuse|suse)
 534                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 535                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 536                 M4_DEFINES=-DTARGET_SUSE=1
 537                 ;;
 538         debian)
 539                 SYSTEM_SYSVRCND_PATH=/etc
 540                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 541                 M4_DEFINES=-DTARGET_DEBIAN=1
 542                 ;;
 543         ubuntu)
 544                 SYSTEM_SYSVRCND_PATH=/etc
 545                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 546                 M4_DEFINES=-DTARGET_UBUNTU=1
 547                 ;;
 548         arch)
 549                 SYSTEM_SYSVINIT_PATH=
 550                 SYSTEM_SYSVRCND_PATH=
 551                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 552                 M4_DEFINES=-DTARGET_ARCH=1
 553                 ;;
 554         gentoo)
 555                 SYSTEM_SYSVINIT_PATH=
 556                 SYSTEM_SYSVRCND_PATH=
 557                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 558                 M4_DEFINES=-DTARGET_GENTOO=1
 559                 ;;
 560         slackware)
 561                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 562                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 563                 M4_DEFINES=-DTARGET_SLACKWARE=1
 564                 ;;
 565         frugalware)
 566                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 567                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 568                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 569                 ;;
 570         altlinux)
 571                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 572                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 573                 M4_DEFINES=-DTARGET_ALTLINUX=1
 574                 ;;
 575         mandriva)
 576                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 577                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 578                 M4_DEFINES=-DTARGET_MANDRIVA=1
 579                 ;;
 580         angstrom)
 581                 SYSTEM_SYSVRCND_PATH=/etc
 582                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 583                 M4_DEFINES=-DTARGET_ANGSTROM=1
 584                 ;;
 585         mageia)
 586                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 587                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 588                 M4_DEFINES=-DTARGET_MAGEIA=1
 589                 ;;
 590         other)
 591                 ;;
 592         *)
 593                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 594                 ;;
 595 esac
 596
 597 AC_ARG_WITH([sysvinit-path],
 598         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 599                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 600         [SYSTEM_SYSVINIT_PATH="$withval"],
 601         [])
 602
 603 AC_ARG_WITH([sysvrcd-path],
 604         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 605                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 606         [SYSTEM_SYSVRCND_PATH="$withval"],
 607         [])
 608
 609 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 610 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 611 AC_SUBST(M4_DEFINES)
 612
 613 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 614         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 615         SYSTEM_SYSV_COMPAT="yes"
 616         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 617 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 618         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 619 else
 620         SYSTEM_SYSV_COMPAT="no"
 621 fi
 622
 623 AC_ARG_WITH([tty-gid],
 624         [AS_HELP_STRING([--with-tty-gid=GID],
 625                 [Specify the numeric GID of the 'tty' group])],
 626         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 627         [])
 628
 629 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 630 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 631 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 632 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 633 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 634 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 635 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 636 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 637 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 638 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 639 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 640 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 641 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 642
 643 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 644
 645 AC_ARG_WITH([dbuspolicydir],
 646         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 647         [],
 648         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 649
 650 AC_ARG_WITH([dbussessionservicedir],
 651         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 652         [],
 653         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 654
 655 AC_ARG_WITH([dbussystemservicedir],
 656         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 657         [],
 658         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 659
 660 AC_ARG_WITH([dbusinterfacedir],
 661         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 662         [],
 663         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 664
 665 AC_ARG_WITH([rootprefix],
 666         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 667         [], [with_rootprefix=${ac_default_prefix}])
 668
 669 AC_ARG_WITH([rootlibdir],
 670         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 671         [],
 672         [with_rootlibdir=${libdir}])
 673
 674 AC_ARG_WITH([pamlibdir],
 675         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 676         [],
 677         [with_pamlibdir=${with_rootlibdir}/security])
 678
 679 AC_ARG_ENABLE([split-usr],
 680         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 681         [],
 682         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 683                 enable_split_usr=yes
 684         ], [
 685                 enable_split_usr=no
 686         ])])
 687
 688 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 689         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 690 ])
 691
 692 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 693 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 694 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 695 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 696 AC_SUBST([pamlibdir], [$with_pamlibdir])
 697 AC_SUBST([rootprefix], [$with_rootprefix])
 698 AC_SUBST([rootlibdir], [$with_rootlibdir])
 699
 700 AC_CONFIG_FILES([
 701         Makefile po/Makefile.in
 702         docs/libudev/Makefile
 703         docs/libudev/version.xml
 704         docs/gudev/Makefile
 705         docs/gudev/version.xml
 706 ])
 707
 708 AC_OUTPUT
 709 AC_MSG_RESULT([
 710         $PACKAGE_NAME $VERSION
 711
 712         Distribution:            ${with_distro}
 713         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 714         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 715         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 716         libcryptsetup:           ${have_libcryptsetup}
 717         tcpwrap:                 ${have_tcpwrap}
 718         PAM:                     ${have_pam}
 719         AUDIT:                   ${have_audit}
 720         IMA:                     ${have_ima}
 721         SELinux:                 ${have_selinux}
 722         XZ:                      ${have_xz}
 723         ACL:                     ${have_acl}
 724         binfmt:                  ${have_binfmt}
 725         vconsole:                ${have_vconsole}
 726         readahead:               ${have_readahead}
 727         quotacheck:              ${have_quotacheck}
 728         randomseed:              ${have_randomseed}
 729         logind:                  ${have_logind}
 730         hostnamed:               ${have_hostnamed}
 731         timedated:               ${have_timedated}
 732         localed:                 ${have_localed}
 733         coredump:                ${have_coredump}
 734         firmware path:           ${FIRMWARE_PATH}
 735         usb.ids:                 ${USB_DATABASE}
 736         pci.ids:                 ${PCI_DATABASE}
 737         gudev:                   ${enable_gudev}
 738         gintrospection:          ${enable_introspection}
 739         keymap:                  ${enable_keymap}
 740
 741         prefix:                  ${prefix}
 742         rootprefix:              ${with_rootprefix}
 743         sysconf dir:             ${sysconfdir}
 744         datarootdir:             ${datarootdir}
 745         includedir:              ${includedir}
 746         include_prefix:          ${INCLUDE_PREFIX}
 747         lib dir:                 ${libdir}
 748         rootlib dir:             ${with_rootlibdir}
 749         PAM modules dir:         ${with_pamlibdir}
 750         D-Bus policy dir:        ${with_dbuspolicydir}
 751         D-Bus session dir:       ${with_dbussessionservicedir}
 752         D-Bus system dir:        ${with_dbussystemservicedir}
 753         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 754         Split /usr:              ${enable_split_usr}
 755         man pages:               ${have_manpages}
 756
 757         CFLAGS:                  ${CFLAGS}
 758         CPPLAGS:                 ${CPPFLAGS}
 759         LDFLAGS:                 ${LDFLAGS}
 760 ])