configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [222],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41 LT_PREREQ(2.2)
  42 LT_INIT([disable-static])
  43
  44 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  45 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  46
  47 SET_ARCH(X86_64, x86_64*)
  48 SET_ARCH(IA32, i*86*)
  49 SET_ARCH(MIPS, mips*)
  50 SET_ARCH(AARCH64, aarch64*)
  51
  52 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  53 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  54 AS_IF([test x"$intltool_found" != xyes],
  55       [AS_IF([test x"$enable_nls" = xyes],
  56              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  57              [AS_IF([test x"$enable_nls" != xno],
  58                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  59                      enable_nls=no])
  60              ])
  61       ])
  62
  63 AM_NLS
  64 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  65     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  66 IT_PROG_INTLTOOL([0.40.0])
  67 ])
  68
  69 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  70     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  71     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  72     AC_SUBST(INTLTOOL_POLICY_RULE)
  73 ])
  74
  75 GETTEXT_PACKAGE=systemd
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  78
  79 AC_PROG_MKDIR_P
  80 AC_PROG_LN_S
  81 AC_PROG_SED
  82 AC_PROG_GREP
  83 AC_PROG_AWK
  84
  85 AC_PROG_CC_C99
  86
  87 AC_PATH_PROG([M4], [m4])
  88 AC_PATH_PROG([XSLTPROC], [xsltproc])
  89
  90 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  91 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  92
  93 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
  94
  95 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
  96
  97 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
  98
  99 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 100
 101 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 102
 103 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 104 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 105
 106 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 107
 108 M4_DEFINES=
 109
 110 AC_CHECK_TOOL(OBJCOPY, objcopy)
 111 AC_CHECK_TOOL(STRINGS, strings)
 112 AC_CHECK_TOOL(GPERF, gperf)
 113 if test -z "$GPERF" ; then
 114         AC_MSG_ERROR([*** gperf not found])
 115 fi
 116
 117 # ------------------------------------------------------------------------------
 118 address_sanitizer_cflags=
 119 address_sanitizer_cppflags=
 120 address_sanitizer_ldflags=
 121 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 122 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 123             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 124             AS_IF([test -z "$with_as_cflags"],
 125                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 126             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 127             address_sanitizer_cppflags="-DVALGRIND=1"
 128             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 129       ])
 130
 131 undefined_sanitizer_cflags=
 132 undefined_sanitizer_cppflags=
 133 undefined_sanitizer_ldflags=
 134 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 135 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 136             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 137             AS_IF([test -z "$with_us_cflags"],
 138                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 139             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 140             undefined_sanitizer_cppflags="-DVALGRIND=1"
 141             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 142       ])
 143
 144 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 145 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 146 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 147
 148 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 149         -pipe \
 150         -Wall \
 151         -Wextra \
 152         -Wundef \
 153         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 154         -Wlogical-op \
 155         -Wmissing-include-dirs \
 156         -Wold-style-definition \
 157         -Wpointer-arith \
 158         -Winit-self \
 159         -Wdeclaration-after-statement \
 160         -Wfloat-equal \
 161         -Wsuggest-attribute=noreturn \
 162         -Werror=missing-prototypes \
 163         -Werror=implicit-function-declaration \
 164         -Werror=missing-declarations \
 165         -Werror=return-type \
 166         -Werror=shadow \
 167         -Wstrict-prototypes \
 168         -Wredundant-decls \
 169         -Wmissing-noreturn \
 170         -Wshadow \
 171         -Wendif-labels \
 172         -Wstrict-aliasing=2 \
 173         -Wwrite-strings \
 174         -Wno-unused-parameter \
 175         -Wno-missing-field-initializers \
 176         -Wno-unused-result \
 177         -Wno-format-signedness \
 178         -Werror=overflow \
 179         -Wdate-time \
 180         -Wnested-externs \
 181         -ffast-math \
 182         -fno-common \
 183         -fdiagnostics-show-option \
 184         -fno-strict-aliasing \
 185         -fvisibility=hidden \
 186         -fstack-protector \
 187         -fstack-protector-strong \
 188         -fPIE \
 189         --param=ssp-buffer-size=4])
 190
 191 AS_CASE([$CC], [*clang*],
 192         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 193                -Wno-typedef-redefinition \
 194                -Wno-gnu-variable-sized-type-not-at-end \
 195         ])])
 196
 197 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 198         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 199                -flto -ffat-lto-objects])],
 200         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 201 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 202
 203 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 204         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 205                -Wp,-D_FORTIFY_SOURCE=2])],
 206         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 207 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 208
 209 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 210         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 211                -Wl,--gc-sections])],
 212         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 213 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 214
 215 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 216         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 217                -ffunction-sections -fdata-sections])],
 218         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 219 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 220
 221 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 222         -Wl,--as-needed \
 223         -Wl,--no-undefined \
 224         -Wl,-z,relro \
 225         -Wl,-z,now \
 226         -pie \
 227         -Wl,-fuse-ld=gold])
 228 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 229
 230 AC_CHECK_SIZEOF(pid_t)
 231 AC_CHECK_SIZEOF(uid_t)
 232 AC_CHECK_SIZEOF(gid_t)
 233 AC_CHECK_SIZEOF(time_t)
 234 AC_CHECK_SIZEOF(dev_t)
 235 AC_CHECK_SIZEOF(rlim_t,,[
 236        #include <sys/time.h>
 237        #include <sys/resource.h>
 238 ])
 239
 240 # ------------------------------------------------------------------------------
 241 # we use python to build the man page index
 242 have_python=no
 243 AC_ARG_WITH([python],
 244         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 245
 246 have_lxml=no
 247 AS_IF([test "x$with_python" != "xno"], [
 248         AM_PATH_PYTHON(,, [:])
 249         AS_IF([test "x$PYTHON" != "x:"], [
 250                 AC_MSG_CHECKING([for python lxml module])
 251                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 252                 AC_MSG_RESULT([$have_lxml])
 253                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 254                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 255         ])
 256 ])
 257 AS_IF([test "$have_python" != "yes"], [
 258       AS_IF([test "$with_python" = "yes"],
 259             [AC_MSG_ERROR([*** python support requested but python support not found])])
 260       AS_IF([test "$with_python" != "no"],
 261             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 262 ])
 263 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 264
 265 # ------------------------------------------------------------------------------
 266
 267 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 268 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 269 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 270 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 271
 272 # unconditionally pull-in librt with old glibc versions
 273 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 274
 275 save_LIBS="$LIBS"
 276 LIBS=
 277 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 278 CAP_LIBS="$LIBS"
 279 AC_SUBST(CAP_LIBS)
 280
 281 AC_CHECK_FUNCS([memfd_create])
 282 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 283 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 284                [], [], [[
 285 #include <sys/types.h>
 286 #include <unistd.h>
 287 #include <sys/mount.h>
 288 #include <fcntl.h>
 289 #include <sched.h>
 290 #include <linux/loop.h>
 291 #include <linux/random.h>
 292 ]])
 293
 294 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 295                 IFLA_MACVLAN_FLAGS,
 296                 IFLA_IPVLAN_MODE,
 297                 IFLA_VTI_REMOTE,
 298                 IFLA_PHYS_PORT_ID,
 299                 IFLA_BOND_AD_INFO,
 300                 IFLA_VLAN_PROTOCOL,
 301                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 302                 IFLA_IPTUN_ENCAP_DPORT,
 303                 IFLA_GRE_ENCAP_DPORT,
 304                 IFLA_BRIDGE_VLAN_INFO,
 305                 IFLA_BRPORT_UNICAST_FLOOD,
 306                 NDA_IFINDEX,
 307                 IFA_FLAGS],
 308 [], [], [[
 309 #include <inttypes.h>
 310 #include <netinet/in.h>
 311 #include <netinet/ether.h>
 312 #include <linux/rtnetlink.h>
 313 #include <net/if.h>
 314 #include <linux/ip.h>
 315 #include <linux/if_tunnel.h>
 316 #include <linux/if_link.h>
 317 #include <linux/if_bridge.h>
 318 #include <linux/if_addr.h>
 319 #include <linux/neighbour.h>
 320 ]])
 321
 322 # This makes sure pkg.m4 is available.
 323 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 324
 325 # ------------------------------------------------------------------------------
 326 have_dbus=no
 327 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 328 AS_IF([test "x$enable_dbus" != "xno"], [
 329         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 330                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 331                 [have_dbus=no])
 332         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 333                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 334 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 335
 336 # ------------------------------------------------------------------------------
 337 have_utmp=yes
 338 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 339         AS_CASE("x${enableval}",
 340                 [xyes], [have_utmp=yes],
 341                 [xno],  [have_utmp=no],
 342                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 343 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 344 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 345
 346 # ------------------------------------------------------------------------------
 347 have_compat_libs=no
 348 AC_ARG_ENABLE([compat_libs], AS_HELP_STRING([--enable-compat-libs],[Enable creation of compatibility libraries]),
 349                 [case "${enableval}" in
 350                         yes) have_compat_libs=yes ;;
 351                         no) have_compat_libs=no ;;
 352                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libs) ;;
 353                 esac],
 354                 [have_compat_libs=no])
 355 AM_CONDITIONAL([ENABLE_COMPAT_LIBS], [test "$have_compat_libs" = "yes"])
 356
 357 # ------------------------------------------------------------------------------
 358 have_coverage=no
 359 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 360 if test "x$enable_coverage" = "xyes" ; then
 361         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 362         if test "x$lcov_found" = xno ; then
 363                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 364         else
 365                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 366                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 367                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 368                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 369                 else
 370                         have_coverage=yes
 371                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 372                         -fprofile-arcs \
 373                         -ftest-coverage])
 374                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 375                 fi
 376         fi
 377 fi
 378 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 379
 380 # ------------------------------------------------------------------------------
 381 have_kmod=no
 382 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 383 if test "x$enable_kmod" != "xno"; then
 384         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 385         if test "x$have_kmod" = "xyes"; then
 386                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 387                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 388                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 389         fi
 390         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 391                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 392         fi
 393 fi
 394 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 395
 396 # ------------------------------------------------------------------------------
 397 have_xkbcommon=no
 398 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 399 if test "x$enable_xkbcommon" != "xno"; then
 400         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 401                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 402         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 403                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 404         fi
 405 fi
 406 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 407
 408 # ------------------------------------------------------------------------------
 409 have_blkid=no
 410 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 411 if test "x$enable_blkid" != "xno"; then
 412         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 413                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 414         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 415                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 416         fi
 417 fi
 418 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 419
 420 # ------------------------------------------------------------------------------
 421 have_libmount=no
 422 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.20 ],
 423         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 424 if test "x$have_libmount" = xno; then
 425         AC_MSG_ERROR([*** libmount support required but libraries not found])
 426 fi
 427 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 428
 429 # ------------------------------------------------------------------------------
 430 have_seccomp=no
 431 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 432 if test "x$enable_seccomp" != "xno"; then
 433         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 434                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 435                 have_seccomp=yes
 436                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 437                [have_seccomp=no])
 438         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 439                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 440         fi
 441 fi
 442 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 443
 444 # ------------------------------------------------------------------------------
 445 have_ima=yes
 446 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 447                 [case "${enableval}" in
 448                         yes) have_ima=yes ;;
 449                         no) have_ima=no ;;
 450                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 451                 esac],
 452                 [have_ima=yes])
 453
 454 if test "x${have_ima}" != xno ; then
 455         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 456 fi
 457
 458 # ------------------------------------------------------------------------------
 459 have_selinux=no
 460 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 461 if test "x$enable_selinux" != "xno"; then
 462         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 463                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 464                  have_selinux=yes
 465                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 466                 [have_selinux=no])
 467         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 468                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 469         fi
 470 fi
 471 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 472
 473 have_apparmor=no
 474 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 475 if test "x$enable_apparmor" != "xno"; then
 476         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 477                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 478                  have_apparmor=yes
 479                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 480                 [have_apparmor=no])
 481         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 482                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 483         fi
 484 fi
 485 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 486
 487
 488 AC_ARG_WITH(debug-shell,
 489         AS_HELP_STRING([--with-debug-shell=PATH],
 490                 [Path to debug shell binary]),
 491         [SUSHELL="$withval"],[
 492         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 493
 494 AC_SUBST(SUSHELL)
 495
 496 AC_ARG_WITH([debug-tty],
 497         AS_HELP_STRING([--with-debug-tty=PATH],
 498                 [Specify the tty device for debug shell]),
 499         [DEBUGTTY="$withval"],
 500         [DEBUGTTY=/dev/tty9])
 501
 502 AC_SUBST(DEBUGTTY)
 503
 504 AC_ARG_WITH([certificate-root],
 505         AS_HELP_STRING([--with-certificate-root=PATH],
 506                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 507         [CERTIFICATEROOT="$withval"],
 508         [CERTIFICATEROOT="/etc/ssl"])
 509
 510 AC_SUBST(CERTIFICATEROOT)
 511
 512 # ------------------------------------------------------------------------------
 513 have_xz=no
 514 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 515 if test "x$enable_xz" != "xno"; then
 516         PKG_CHECK_MODULES(XZ, [ liblzma ],
 517                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 518         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 519                 AC_MSG_ERROR([*** XZ support requested but libraries not found])
 520         fi
 521 fi
 522 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 523
 524 # ------------------------------------------------------------------------------
 525 have_zlib=no
 526 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 527 if test "x$enable_zlib" != "xno"; then
 528         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 529                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available]) have_zlib=yes], have_zlib=no)
 530         if test "x$have_zlib" = xno -a "x$enable_zlib" = xyes; then
 531                 AC_MSG_ERROR([*** ZLIB support requested but libraries not found])
 532         fi
 533 fi
 534 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 535
 536 # ------------------------------------------------------------------------------
 537 have_bzip2=no
 538 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Disable optional BZIP2 support]))
 539 AS_IF([test "x$enable_bzip2" != "xno"], [
 540         AC_CHECK_HEADERS(bzlib.h,
 541                 [AC_DEFINE(HAVE_BZIP2, 1, [Define in BZIP2 is available])
 542                  have_bzip2=yes],
 543                 [AS_IF([test "x$have_bzip2" = xyes], [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])
 544         ])
 545 ])
 546 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 547
 548 # ------------------------------------------------------------------------------
 549 have_lz4=no
 550 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--enable-lz4], [Enable optional LZ4 support]))
 551 AS_IF([test "x$enable_lz4" = "xyes"], [
 552         AC_CHECK_HEADERS(lz4.h,
 553                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available]) have_lz4=yes],
 554                [AC_MSG_ERROR([*** LZ4 support requested but headers not found])])
 555 ])
 556 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 557
 558 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 559
 560 # ------------------------------------------------------------------------------
 561 AC_ARG_ENABLE([pam],
 562         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 563                 [case "${enableval}" in
 564                         yes) have_pam=yes ;;
 565                         no) have_pam=no ;;
 566                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 567                 esac],
 568                 [have_pam=auto])
 569
 570 if test "x${have_pam}" != xno ; then
 571         AC_CHECK_HEADERS(
 572                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 573                 [have_pam=yes],
 574                 [if test "x$have_pam" = xyes ; then
 575                         AC_MSG_ERROR([*** PAM headers not found.])
 576                 fi])
 577
 578         AC_CHECK_LIB(
 579                 [pam],
 580                 [pam_syslog],
 581                 [have_pam=yes],
 582                 [if test "x$have_pam" = xyes ; then
 583                         AC_MSG_ERROR([*** libpam not found.])
 584                 fi])
 585
 586         if test "x$have_pam" = xyes ; then
 587                 PAM_LIBS="-lpam -lpam_misc"
 588                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 589                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 590         else
 591                 have_pam=no
 592         fi
 593 else
 594         PAM_LIBS=
 595 fi
 596 AC_SUBST(PAM_LIBS)
 597 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 598
 599 # ------------------------------------------------------------------------------
 600 AC_ARG_ENABLE([acl],
 601         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 602                 [case "${enableval}" in
 603                         yes) have_acl=yes ;;
 604                         no) have_acl=no ;;
 605                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 606                 esac],
 607                 [have_acl=auto])
 608
 609 if test "x${have_acl}" != xno ; then
 610         AC_CHECK_HEADERS(
 611                 [sys/acl.h acl/libacl.h],
 612                 [have_acl=yes],
 613                 [if test "x$have_acl" = xyes ; then
 614                         AC_MSG_ERROR([*** ACL headers not found.])
 615                 fi])
 616
 617         AC_CHECK_LIB(
 618                 [acl],
 619                 [acl_get_file],
 620                 [have_acl=yes],
 621                 [if test "x$have_acl" = xyes ; then
 622                         AC_MSG_ERROR([*** libacl not found.])
 623                 fi])
 624
 625         if test "x$have_acl" = xyes ; then
 626                 ACL_LIBS="-lacl"
 627                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 628                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 629         else
 630                 have_acl=no
 631         fi
 632 else
 633         ACL_LIBS=
 634 fi
 635 AC_SUBST(ACL_LIBS)
 636 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 637
 638 # ------------------------------------------------------------------------------
 639 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 640                 [case "${enableval}" in
 641                         yes) have_smack=yes ;;
 642                         no) have_smack=no ;;
 643                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 644                 esac],
 645                 [have_smack=auto])
 646
 647 if test "x${have_smack}" = xauto; then
 648         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 649         have_smack=yes
 650 fi
 651
 652 AC_ARG_WITH(smack-run-label,
 653 AS_HELP_STRING([--with-smack-run-label=STRING],
 654         [run systemd --system itself with a specific SMACK label]),
 655         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label])],
 656         [])
 657
 658 AC_ARG_WITH(smack-default-process-label,
 659 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 660         [default SMACK label for executed processes]),
 661         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 662         [])
 663
 664 if test "x${have_smack}" = xyes ; then
 665         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 666 fi
 667
 668 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 669
 670 # ------------------------------------------------------------------------------
 671 AC_ARG_ENABLE([gcrypt],
 672         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 673                 [case "${enableval}" in
 674                         yes) have_gcrypt=yes ;;
 675                         no) have_gcrypt=no ;;
 676                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 677                 esac],
 678                 [have_gcrypt=auto])
 679
 680 if test "x${have_gcrypt}" != xno ; then
 681         AM_PATH_LIBGCRYPT(
 682                 [1.4.5],
 683                 [have_gcrypt=yes],
 684                 [if test "x$have_gcrypt" = xyes ; then
 685                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 686                 fi])
 687
 688         if test "x$have_gcrypt" = xyes ; then
 689                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 690                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 691                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 692         else
 693                 have_gcrypt=no
 694         fi
 695 else
 696         GCRYPT_LIBS=
 697         GCRYPT_CFLAGS=
 698 fi
 699 AC_SUBST(GCRYPT_LIBS)
 700 AC_SUBST(GCRYPT_CFLAGS)
 701 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 702
 703 # ------------------------------------------------------------------------------
 704 AC_ARG_ENABLE([audit],
 705         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 706                 [case "${enableval}" in
 707                         yes) have_audit=yes ;;
 708                         no) have_audit=no ;;
 709                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 710                 esac],
 711                 [have_audit=auto])
 712
 713 if test "x${have_audit}" != xno ; then
 714         AC_CHECK_HEADERS(
 715                 [libaudit.h],
 716                 [have_audit=yes],
 717                 [if test "x$have_audit" = xyes ; then
 718                         AC_MSG_ERROR([*** AUDIT headers not found.])
 719                 fi])
 720
 721         AC_CHECK_LIB(
 722                 [audit],
 723                 [audit_open],
 724                 [have_audit=yes],
 725                 [if test "x$have_audit" = xyes ; then
 726                         AC_MSG_ERROR([*** libaudit not found.])
 727                 fi])
 728
 729         if test "x$have_audit" = xyes ; then
 730                 AUDIT_LIBS="-laudit"
 731                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 732         else
 733                 have_audit=no
 734         fi
 735 else
 736         AUDIT_LIBS=
 737 fi
 738 AC_SUBST(AUDIT_LIBS)
 739 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 740
 741 # ------------------------------------------------------------------------------
 742 AC_ARG_ENABLE([elfutils],
 743         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 744                 [case "${enableval}" in
 745                         yes) have_elfutils=yes ;;
 746                         no) have_elfutils=no ;;
 747                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 748                 esac],
 749                 [have_elfutils=auto])
 750
 751 if test "x${have_elfutils}" != xno ; then
 752         AC_CHECK_HEADERS(
 753                 [elfutils/libdwfl.h],
 754                 [],
 755                 [if test "x$have_elfutils" = xyes ; then
 756                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 757                 fi])
 758
 759         AC_CHECK_LIB(
 760                 [dw],
 761                 [dwfl_begin],
 762                 [],
 763                 [if test "x$have_elfutils" = xyes ; then
 764                         AC_MSG_ERROR([*** ELFUTILS libs not found.])
 765                 fi])
 766
 767         AC_CHECK_LIB(
 768                 [dw],
 769                 [dwfl_core_file_attach],
 770                 [have_elfutils=yes],
 771                 [if test "x$have_elfutils" = xyes ; then
 772                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 773                 fi])
 774
 775         if test "x$have_elfutils" = xyes ; then
 776                 ELFUTILS_LIBS="-lelf -ldw"
 777                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 778         else
 779                 have_elfutils=no
 780         fi
 781 else
 782         ELFUTILS_LIBS=
 783 fi
 784 AC_SUBST(ELFUTILS_LIBS)
 785 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 786
 787 # ------------------------------------------------------------------------------
 788 have_libcryptsetup=no
 789 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 790 if test "x$enable_libcryptsetup" != "xno"; then
 791         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 792                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 793         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 794                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 795         fi
 796 fi
 797 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 798
 799 # ------------------------------------------------------------------------------
 800 have_qrencode=no
 801 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 802 if test "x$enable_qrencode" != "xno"; then
 803         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 804                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 805         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 806                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 807         fi
 808 fi
 809 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 810
 811 # ------------------------------------------------------------------------------
 812 have_microhttpd=no
 813 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 814 if test "x$enable_microhttpd" != "xno"; then
 815         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 816                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 817         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 818                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 819         fi
 820 fi
 821 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 822
 823 # ------------------------------------------------------------------------------
 824 have_gnutls=no
 825 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 826 if test "x$enable_gnutls" != "xno"; then
 827         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 828                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 829         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 830                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 831         fi
 832 fi
 833 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 834
 835 # ------------------------------------------------------------------------------
 836 have_libcurl=no
 837 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 838 if test "x$enable_libcurl" != "xno"; then
 839         PKG_CHECK_MODULES(LIBCURL, [libcurl],
 840                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available]) have_libcurl=yes], have_libcurl=no)
 841         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 842                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 843         fi
 844 fi
 845 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 846
 847 # ------------------------------------------------------------------------------
 848 have_libidn=no
 849 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 850 if test "x$enable_libidn" != "xno"; then
 851         PKG_CHECK_MODULES(LIBIDN, [libidn],
 852                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 853                 have_libidn=yes
 854                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 855                [have_libidn=no])
 856         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 857                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 858         fi
 859 fi
 860 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 861
 862 # ------------------------------------------------------------------------------
 863 have_libiptc=no
 864 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 865 if test "x$enable_libiptc" != "xno"; then
 866         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 867                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 868                 have_libiptc=yes
 869                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 870                [have_libiptc=no])
 871         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 872                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 873         fi
 874 fi
 875 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 876
 877 # ------------------------------------------------------------------------------
 878 have_binfmt=no
 879 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 880 if test "x$enable_binfmt" != "xno"; then
 881         have_binfmt=yes
 882 fi
 883 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 884
 885 # ------------------------------------------------------------------------------
 886 have_vconsole=no
 887 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 888 if test "x$enable_vconsole" != "xno"; then
 889         have_vconsole=yes
 890 fi
 891 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 892
 893 # ------------------------------------------------------------------------------
 894 have_bootchart=no
 895 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 896 if test "x$enable_bootchart" != "xno"; then
 897         have_bootchart=yes
 898 fi
 899 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 900
 901 # ------------------------------------------------------------------------------
 902 have_quotacheck=no
 903 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 904 if test "x$enable_quotacheck" != "xno"; then
 905         have_quotacheck=yes
 906 fi
 907 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 908
 909 # ------------------------------------------------------------------------------
 910 have_tmpfiles=no
 911 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 912 if test "x$enable_tmpfiles" != "xno"; then
 913         have_tmpfiles=yes
 914 fi
 915 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 916
 917 # ------------------------------------------------------------------------------
 918 have_sysusers=no
 919 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 920 if test "x$enable_sysusers" != "xno"; then
 921         have_sysusers=yes
 922 fi
 923 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 924
 925 # ------------------------------------------------------------------------------
 926 have_firstboot=no
 927 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 928 if test "x$enable_firstboot" != "xno"; then
 929         have_firstboot=yes
 930 fi
 931 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 932
 933 # ------------------------------------------------------------------------------
 934 have_randomseed=no
 935 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 936 if test "x$enable_randomseed" != "xno"; then
 937         have_randomseed=yes
 938 fi
 939 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 940
 941 # ------------------------------------------------------------------------------
 942 have_backlight=no
 943 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 944 if test "x$enable_backlight" != "xno"; then
 945         have_backlight=yes
 946 fi
 947 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 948
 949 # ------------------------------------------------------------------------------
 950 have_rfkill=no
 951 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
 952 if test "x$enable_rfkill" != "xno"; then
 953         have_rfkill=yes
 954 fi
 955 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
 956
 957 # ------------------------------------------------------------------------------
 958 have_logind=no
 959 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 960 if test "x$enable_logind" != "xno"; then
 961         have_logind=yes
 962 fi
 963 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 964 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 965
 966 # ------------------------------------------------------------------------------
 967 have_machined=no
 968 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 969 if test "x$enable_machined" != "xno"; then
 970         have_machined=yes
 971 fi
 972 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 973 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 974
 975 # ------------------------------------------------------------------------------
 976 have_importd=no
 977 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
 978 if test "x$enable_importd" != "xno"; then
 979         have_importd=yes
 980 fi
 981 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
 982 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
 983
 984 # ------------------------------------------------------------------------------
 985 have_hostnamed=no
 986 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 987 if test "x$enable_hostnamed" != "xno"; then
 988         have_hostnamed=yes
 989 fi
 990 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 991
 992 # ------------------------------------------------------------------------------
 993 have_timedated=no
 994 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 995 if test "x$enable_timedated" != "xno"; then
 996         have_timedated=yes
 997 fi
 998 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 999
1000 # ------------------------------------------------------------------------------
1001 have_timesyncd=no
1002 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1003 if test "x$enable_timesyncd" != "xno"; then
1004         have_timesyncd=yes
1005         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1006 fi
1007 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1008
1009 AC_ARG_WITH(ntp-servers,
1010         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1011                 [Space-separated list of default NTP servers]),
1012         [NTP_SERVERS="$withval"],
1013         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1014         AC_MSG_WARN([*** Using Google NTP servers. Please do not ship OSes or devices with these default settings. See DISTRO_PORTING for details!])])
1015
1016 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1017 AC_SUBST(NTP_SERVERS)
1018
1019 AC_ARG_WITH(time-epoch,
1020         AS_HELP_STRING([--with-time-epoch=SECONDS],
1021                 [Time epoch for time clients]),
1022         [TIME_EPOCH="$withval"],
1023         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1024
1025 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1026
1027 # ------------------------------------------------------------------------------
1028 AC_ARG_WITH(system-uid-max,
1029         AS_HELP_STRING([--with-system-uid-max=UID]
1030                 [Maximum UID for system users]),
1031         [SYSTEM_UID_MAX="$withval"],
1032         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1033
1034 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1035 AC_SUBST(SYSTEM_UID_MAX)
1036
1037 # ------------------------------------------------------------------------------
1038 AC_ARG_WITH(system-gid-max,
1039         AS_HELP_STRING([--with-system-gid-max=GID]
1040                 [Maximum GID for system groups]),
1041         [SYSTEM_GID_MAX="$withval"],
1042         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1043
1044 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1045 AC_SUBST(SYSTEM_GID_MAX)
1046
1047 # ------------------------------------------------------------------------------
1048 have_localed=no
1049 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1050 if test "x$enable_localed" != "xno"; then
1051         have_localed=yes
1052 fi
1053 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1054
1055 # ------------------------------------------------------------------------------
1056 have_coredump=no
1057 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1058 if test "x$enable_coredump" != "xno"; then
1059         have_coredump=yes
1060 fi
1061 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1062
1063 # ------------------------------------------------------------------------------
1064 have_polkit=no
1065 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1066 if test "x$enable_polkit" != "xno"; then
1067         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1068         have_polkit=yes
1069 fi
1070 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1071
1072 # ------------------------------------------------------------------------------
1073 have_resolved=no
1074 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1075 if test "x$enable_resolved" != "xno"; then
1076         have_resolved=yes
1077         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1078 fi
1079 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1080
1081 AC_ARG_WITH(dns-servers,
1082         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1083                 [Space-separated list of default DNS servers]),
1084         [DNS_SERVERS="$withval"],
1085         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1086
1087 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1088 AC_SUBST(DNS_SERVERS)
1089
1090 # ------------------------------------------------------------------------------
1091 have_networkd=no
1092 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1093 AS_IF([test "x$enable_networkd" != "xno"], [
1094         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1095         have_networkd=yes
1096         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1097 ])
1098 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1099
1100 # ------------------------------------------------------------------------------
1101 have_efi=no
1102 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1103 if test "x$enable_efi" != "xno"; then
1104         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1105         have_efi=yes
1106 fi
1107 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1108
1109 # ------------------------------------------------------------------------------
1110 AC_CHECK_TOOL(EFI_CC, gcc)
1111
1112 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1113
1114 AM_COND_IF(ARCH_IA32, [
1115         EFI_ARCH=ia32
1116         EFI_MACHINE_TYPE_NAME=ia32])
1117
1118 AM_COND_IF(ARCH_X86_64, [
1119         EFI_MACHINE_TYPE_NAME=x64])
1120
1121 AM_COND_IF(ARCH_AARCH64, [
1122         EFI_MACHINE_TYPE_NAME=aa64])
1123
1124 AC_SUBST([EFI_ARCH])
1125 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1126
1127 have_gnuefi=no
1128 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Disable optional gnuefi support]))
1129 AS_IF([test "x$enable_gnuefi" != "xno"], [
1130         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1131                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1132                  have_gnuefi=yes],
1133                 [AS_IF([test "x$enable_gnuefi" = xyes],
1134                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1135         ])
1136
1137         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1138
1139         EFI_LIB_DIR="$efiroot"
1140         AC_ARG_WITH(efi-libdir,
1141                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1142                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1143         )
1144         AC_SUBST([EFI_LIB_DIR])
1145
1146         have_efi_lds=no
1147         AC_ARG_WITH(efi-ldsdir,
1148                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1149                 [EFI_LDS_DIR="$withval" && AC_CHECK_FILE([${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds],
1150                         [have_efi_lds=yes])],
1151                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1152                         [AC_CHECK_FILE([${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds],
1153                                        [have_efi_lds=yes && break])])])
1154         AS_IF([test "x$have_efi_lds" = xyes],
1155               [AC_SUBST([EFI_LDS_DIR])],
1156               [AS_IF([test "x$enable_gnuefi" = xyes],
1157                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1158                      [have_gnuefi=no])])
1159
1160         AC_ARG_WITH(efi-includedir,
1161                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1162                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1163         )
1164         AC_SUBST([EFI_INC_DIR])
1165 ])
1166 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1167
1168 # ------------------------------------------------------------------------------
1169 AC_ARG_WITH(unifont,
1170         AS_HELP_STRING([--with-unifont=PATH],
1171                 [Path to unifont.hex]),
1172         [UNIFONT="$withval"],
1173         [UNIFONT="/usr/share/unifont/unifont.hex"])
1174 AC_SUBST(UNIFONT)
1175
1176 have_terminal=no
1177 have_unifont=no
1178 AC_ARG_ENABLE(terminal, AS_HELP_STRING([--enable-terminal], [enable terminal support]))
1179 if test "x$enable_terminal" = "xyes"; then
1180         PKG_CHECK_MODULES([TERMINAL], [ libevdev >= 1.2 xkbcommon >= 0.5 libdrm >= 2.4], [have_terminal=yes])
1181         AC_CHECK_FILE($UNIFONT, [have_unifont=yes])
1182         AS_IF([test "x$have_terminal" != xyes -o "x$have_unifont" != "xyes" -a "x$enable_terminal" = xyes],
1183               [AC_MSG_ERROR([*** terminal support requested but required dependencies not available])],
1184               [test "x$have_terminal" = xyes -a "x$have_unifont" = "xyes"],
1185               [AC_DEFINE(ENABLE_TERMINAL, 1, [Define if terminal support is to be enabled])])
1186 fi
1187 AM_CONDITIONAL(ENABLE_TERMINAL, [test "x$have_terminal" = "xyes" -a "x$have_unifont" = "xyes"])
1188
1189 # ------------------------------------------------------------------------------
1190 have_kdbus=no
1191 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
1192 if test "x$enable_kdbus" != "xno"; then
1193         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
1194         have_kdbus=yes
1195         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
1196 fi
1197 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
1198
1199 # ------------------------------------------------------------------------------
1200 AC_ARG_WITH(rc-local-script-path-start,
1201         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1202                 [Path to /etc/rc.local]),
1203         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1204         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1205
1206 AC_ARG_WITH(rc-local-script-path-stop,
1207         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1208                 [Path to /usr/sbin/halt.local]),
1209         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1210         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1211
1212 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1213 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1214
1215 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1216 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1217
1218 # ------------------------------------------------------------------------------
1219 AC_ARG_WITH(kbd-loadkeys,
1220         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1221                 [Path to loadkeys]),
1222         [KBD_LOADKEYS="$withval"],
1223         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1224
1225 AC_ARG_WITH(kbd-setfont,
1226         AS_HELP_STRING([--with-kbd-setfont=PATH],
1227                 [Path to setfont]),
1228         [KBD_SETFONT="$withval"],
1229         [KBD_SETFONT="/usr/bin/setfont"])
1230
1231 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1232 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1233
1234 AC_SUBST(KBD_LOADKEYS)
1235 AC_SUBST(KBD_SETFONT)
1236
1237 AC_ARG_WITH(telinit,
1238         AS_HELP_STRING([--with-telinit=PATH],
1239                 [Path to telinit]),
1240         [TELINIT="$withval"],
1241         [TELINIT="/lib/sysvinit/telinit"])
1242
1243 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1244
1245 AC_SUBST(TELINIT)
1246
1247 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1248
1249 # ------------------------------------------------------------------------------
1250 have_myhostname=no
1251 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1252 if test "x$enable_myhostname" != "xno"; then
1253         AC_HEADER_STDC
1254         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1255
1256         AC_C_CONST
1257         AC_TYPE_SIZE_T
1258         AC_HEADER_TIME
1259
1260         AC_FUNC_MALLOC
1261         AC_FUNC_SELECT_ARGTYPES
1262         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1263
1264         have_myhostname=yes
1265 fi
1266 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1267
1268 # ------------------------------------------------------------------------------
1269 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1270        enable_hwdb=$enableval, enable_hwdb=yes)
1271 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1272
1273 # ------------------------------------------------------------------------------
1274 have_manpages=no
1275 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1276 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
1277 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1278
1279 # ------------------------------------------------------------------------------
1280 AC_ARG_ENABLE(hibernate,
1281        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1282        enable_hibernate=$enableval, enable_hibernate=yes)
1283 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1284
1285 # ------------------------------------------------------------------------------
1286 AC_ARG_ENABLE(ldconfig,
1287        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1288        enable_ldconfig=$enableval, enable_ldconfig=yes)
1289 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1290
1291 # ------------------------------------------------------------------------------
1292 # Location of the init scripts as mandated by LSB
1293 SYSTEM_SYSVINIT_PATH=/etc/init.d
1294 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1295
1296 AC_ARG_WITH([sysvinit-path],
1297         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1298                 [Specify the path to where the SysV init scripts are located])],
1299         [SYSTEM_SYSVINIT_PATH="$withval"],
1300         [])
1301
1302 AC_ARG_WITH([sysvrcnd-path],
1303         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1304                 [Specify the path to the base directory for the SysV rcN.d directories])],
1305         [SYSTEM_SYSVRCND_PATH="$withval"],
1306         [])
1307
1308 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1309         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1310         SYSTEM_SYSV_COMPAT="yes"
1311         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1312 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1313         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1314 else
1315         SYSTEM_SYSV_COMPAT="no"
1316 fi
1317
1318 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1319 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1320 AC_SUBST(M4_DEFINES)
1321
1322 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1323
1324 AC_ARG_WITH([tty-gid],
1325         [AS_HELP_STRING([--with-tty-gid=GID],
1326                 [Specify the numeric GID of the 'tty' group])],
1327         [TTY_GID="$withval"],
1328         [TTY_GID="5"])
1329
1330 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1331 AC_SUBST(TTY_GID)
1332
1333 AC_ARG_WITH([dbuspolicydir],
1334         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1335         [],
1336         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1337 AX_NORMALIZE_PATH([with_dbuspolicydir])
1338
1339 AC_ARG_WITH([dbussessionservicedir],
1340         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1341         [],
1342         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1343 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1344
1345 AC_ARG_WITH([dbussystemservicedir],
1346         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1347         [],
1348         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1349 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1350
1351 AC_ARG_WITH([bashcompletiondir],
1352         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1353         [],
1354         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1355                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1356         ] , [
1357                 with_bashcompletiondir=${datadir}/bash-completion/completions
1358         ])])
1359 AX_NORMALIZE_PATH([with_bashcompletiondir])
1360
1361 AC_ARG_WITH([zshcompletiondir],
1362         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1363         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1364 AX_NORMALIZE_PATH([with_zshcompletiondir])
1365
1366 AC_ARG_WITH([rootprefix],
1367         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1368         [], [with_rootprefix=${ac_default_prefix}])
1369 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1370 # defaults those to ".", solve that here for now until we can find a suitable
1371 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1372 # See: https://github.com/systemd/systemd/issues/54
1373 if test "x${with_rootprefix}" = "x"; then
1374         with_rootprefix="/"
1375 fi
1376 AX_NORMALIZE_PATH([with_rootprefix])
1377
1378 AC_ARG_WITH([rootlibdir],
1379         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1380         [],
1381         [with_rootlibdir=${libdir}])
1382 AX_NORMALIZE_PATH([with_rootlibdir])
1383
1384 AC_ARG_WITH([pamlibdir],
1385         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1386         [],
1387         [with_pamlibdir=${with_rootlibdir}/security])
1388 AX_NORMALIZE_PATH([with_pamlibdir])
1389
1390 AC_ARG_WITH([pamconfdir],
1391         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1392         [],
1393         [with_pamconfdir=${sysconfdir}/pam.d])
1394 AX_NORMALIZE_PATH([with_pamconfdir])
1395
1396 AC_ARG_ENABLE([split-usr],
1397         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1398         [],
1399         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1400                 enable_split_usr=yes
1401         ], [
1402                 enable_split_usr=no
1403         ])])
1404
1405 AC_ARG_WITH([dkr-index-url],
1406         [AS_HELP_STRING([--dkr-index-url=URL], [Specify the default index URL to use for image downloads])],
1407         [DEFAULT_DKR_INDEX_URL="\"$withval\""],
1408         [DEFAULT_DKR_INDEX_URL="NULL"])
1409
1410 AC_DEFINE_UNQUOTED(DEFAULT_DKR_INDEX_URL, [$DEFAULT_DKR_INDEX_URL], [Default index URL to use for image downloads])
1411 AC_SUBST(DEFAULT_DKR_INDEX_URL)
1412
1413 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1414         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1415 ])
1416 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1417
1418 # work around intltool-update issues during 'make distcheck'
1419 AS_IF([test "x$0" != "x./configure"], [
1420         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1421 ])
1422
1423 # QEMU and OVMF UEFI firmware
1424 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1425         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1426         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1427                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1428         AC_SUBST([QEMU_BIOS])
1429 ])
1430
1431 AC_ARG_ENABLE(tests,
1432         [AC_HELP_STRING([--disable-tests], [disable tests])],
1433         enable_tests=$enableval, enable_tests=yes)
1434 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1435
1436 AC_ARG_ENABLE(debug,
1437         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1438         [if test "x$enableval" = "xyes"; then
1439                 enableval="hashmap,mmap-cache"
1440         fi
1441         saved_ifs="$IFS"
1442         IFS="$IFS$PATH_SEPARATOR,"
1443         for name in $enableval; do
1444                 case $name in
1445                 hashmap)
1446                         enable_debug_hashmap=yes
1447                         ;;
1448                 mmap-cache)
1449                         enable_debug_mmap_cache=yes
1450                         ;;
1451                 esac
1452         done
1453         IFS="$saved_ifs"],[])
1454
1455 enable_debug=""
1456 AS_IF([test x$enable_debug_hashmap = xyes], [
1457         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1458         enable_debug="hashmap $enable_debug"
1459 ])
1460 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1461         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1462         enable_debug="mmap-cache $enable_debug"
1463 ])
1464 test -z "$enable_debug" && enable_debug="none"
1465
1466 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1467 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1468 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1469 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1470 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1471 AC_SUBST([pamlibdir], [$with_pamlibdir])
1472 AC_SUBST([pamconfdir], [$with_pamconfdir])
1473 AC_SUBST([rootprefix], [$with_rootprefix])
1474 AC_SUBST([rootlibdir], [$with_rootlibdir])
1475
1476 AC_CONFIG_FILES([
1477         Makefile
1478         po/Makefile.in
1479 ])
1480
1481 AC_OUTPUT
1482 AC_MSG_RESULT([
1483         $PACKAGE_NAME $VERSION
1484
1485         libcryptsetup:           ${have_libcryptsetup}
1486         PAM:                     ${have_pam}
1487         AUDIT:                   ${have_audit}
1488         IMA:                     ${have_ima}
1489         AppArmor:                ${have_apparmor}
1490         SELinux:                 ${have_selinux}
1491         SECCOMP:                 ${have_seccomp}
1492         SMACK:                   ${have_smack}
1493         ZLIB:                    ${have_zlib}
1494         XZ:                      ${have_xz}
1495         LZ4:                     ${have_lz4}
1496         BZIP2:                   ${have_bzip2}
1497         ACL:                     ${have_acl}
1498         GCRYPT:                  ${have_gcrypt}
1499         QRENCODE:                ${have_qrencode}
1500         MICROHTTPD:              ${have_microhttpd}
1501         GNUTLS:                  ${have_gnutls}
1502         libcurl:                 ${have_libcurl}
1503         libidn:                  ${have_libidn}
1504         libiptc:                 ${have_libiptc}
1505         ELFUTILS:                ${have_elfutils}
1506         binfmt:                  ${have_binfmt}
1507         vconsole:                ${have_vconsole}
1508         bootchart:               ${have_bootchart}
1509         quotacheck:              ${have_quotacheck}
1510         tmpfiles:                ${have_tmpfiles}
1511         sysusers:                ${have_sysusers}
1512         firstboot:               ${have_firstboot}
1513         randomseed:              ${have_randomseed}
1514         backlight:               ${have_backlight}
1515         rfkill:                  ${have_rfkill}
1516         logind:                  ${have_logind}
1517         machined:                ${have_machined}
1518         importd:                 ${have_importd}
1519         hostnamed:               ${have_hostnamed}
1520         timedated:               ${have_timedated}
1521         timesyncd:               ${have_timesyncd}
1522         default NTP servers:     ${NTP_SERVERS}
1523         time epoch:              ${TIME_EPOCH}
1524         localed:                 ${have_localed}
1525         networkd:                ${have_networkd}
1526         resolved:                ${have_resolved}
1527         default DNS servers:     ${DNS_SERVERS}
1528         coredump:                ${have_coredump}
1529         polkit:                  ${have_polkit}
1530         efi:                     ${have_efi}
1531         gnuefi:                  ${have_gnuefi}
1532         efi arch:                ${EFI_ARCH}
1533         EFI machine type:        ${EFI_MACHINE_TYPE_NAME}
1534         EFI CC                   ${EFI_CC}
1535         EFI libdir:              ${EFI_LIB_DIR}
1536         EFI ldsdir:              ${EFI_LDS_DIR}
1537         EFI includedir:          ${EFI_INC_DIR}
1538         kmod:                    ${have_kmod}
1539         xkbcommon:               ${have_xkbcommon}
1540         blkid:                   ${have_blkid}
1541         libmount:                ${have_libmount}
1542         dbus:                    ${have_dbus}
1543         nss-myhostname:          ${have_myhostname}
1544         hwdb:                    ${enable_hwdb}
1545         terminal:                ${have_terminal}
1546         kdbus:                   ${have_kdbus}
1547         Python:                  ${have_python}
1548         man pages:               ${have_manpages}
1549         test coverage:           ${have_coverage}
1550         Split /usr:              ${enable_split_usr}
1551         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1552         compatibility libraries: ${have_compat_libs}
1553         utmp/wtmp support:       ${have_utmp}
1554         ldconfig support:        ${enable_ldconfig}
1555         hibernate support:       ${enable_hibernate}
1556         extra debugging:         ${enable_debug}
1557
1558         prefix:                  ${prefix}
1559         rootprefix:              ${with_rootprefix}
1560         sysconf dir:             ${sysconfdir}
1561         datarootdir:             ${datarootdir}
1562         includedir:              ${includedir}
1563         lib dir:                 ${libdir}
1564         rootlib dir:             ${with_rootlibdir}
1565         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1566         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1567         Build Python:            ${PYTHON}
1568         sphinx binary:           ${SPHINX_BUILD}
1569         PAM modules dir:         ${with_pamlibdir}
1570         PAM configuration dir:   ${with_pamconfdir}
1571         D-Bus policy dir:        ${with_dbuspolicydir}
1572         D-Bus session dir:       ${with_dbussessionservicedir}
1573         D-Bus system dir:        ${with_dbussystemservicedir}
1574         Bash completions dir:    ${with_bashcompletiondir}
1575         Zsh completions dir:     ${with_zshcompletiondir}
1576         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1577         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1578         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1579         TTY GID:                 ${TTY_GID}
1580         Maximum System UID:      ${SYSTEM_UID_MAX}
1581         Maximum System GID:      ${SYSTEM_GID_MAX}
1582         Certificate root:        ${CERTIFICATEROOT}
1583         Default dkr Index        ${DEFAULT_DKR_INDEX_URL}
1584
1585         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1586         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1587         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1588 ])