configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [195],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  71
  72 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  73
  74 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  75 m4_ifdef([GTK_DOC_CHECK], [
  76 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  77 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  78
  79 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  80         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  81 ])
  82
  83 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  84 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  85 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  86
  87 AC_PATH_TOOL(OBJCOPY, objcopy)
  88 AC_PATH_TOOL(STRINGS, strings)
  89 AC_PATH_TOOL(GPERF, gperf)
  90 if test -z "$GPERF" ; then
  91         AC_MSG_ERROR([*** gperf not found])
  92 fi
  93
  94 # we use python to build the man page index, and for systemd-python
  95 have_python=no
  96 have_python_devel=no
  97
  98 AC_ARG_WITH([python],
  99         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 100
 101 AS_IF([test "x$with_python" != "xno"], [
 102         AM_PATH_PYTHON(,, [:])
 103         AS_IF([test "$PYTHON" != :], [have_python=yes])
 104 ])
 105 AM_CONDITIONAL([HAVE_PYTHON], [test "$have_python" = "yes"])
 106
 107 AS_IF([test "x$with_python" != "xno"], [
 108         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 109         AS_IF([test -n "$PYTHON_CONFIG"], [
 110               have_python_devel=yes
 111               PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
 112               PYTHON_LIBS="`$PYTHON_CONFIG --ldflags`"
 113               AC_SUBST(PYTHON_CFLAGS)
 114               AC_SUBST(PYTHON_LIBS)
 115         ])
 116 ])
 117 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 118
 119 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 120         -pipe \
 121         -Wall \
 122         -Wextra \
 123         -Wno-inline \
 124         -Wundef \
 125         -Wformat=2 \
 126         -Wlogical-op \
 127         -Wsign-compare \
 128         -Wformat-security \
 129         -Wmissing-include-dirs \
 130         -Wformat-nonliteral \
 131         -Wold-style-definition \
 132         -Wpointer-arith \
 133         -Winit-self \
 134         -Wdeclaration-after-statement \
 135         -Wfloat-equal \
 136         -Wmissing-prototypes \
 137         -Wstrict-prototypes \
 138         -Wredundant-decls \
 139         -Wmissing-declarations \
 140         -Wmissing-noreturn \
 141         -Wshadow \
 142         -Wendif-labels \
 143         -Wcast-align \
 144         -Wstrict-aliasing=2 \
 145         -Wwrite-strings \
 146         -Wno-long-long \
 147         -Wno-overlength-strings \
 148         -Wno-unused-parameter \
 149         -Wno-missing-field-initializers \
 150         -Wno-unused-result \
 151         -Werror=overflow \
 152         -ffast-math \
 153         -fno-common \
 154         -fdiagnostics-show-option \
 155         -fno-strict-aliasing \
 156         -fvisibility=hidden \
 157         -ffunction-sections \
 158         -fdata-sections \
 159         -fstack-protector \
 160         --param=ssp-buffer-size=4])
 161 AC_SUBST([OUR_CFLAGS], $with_cflags)
 162
 163 CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 164         -Wp,-D_FORTIFY_SOURCE=2])
 165 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 166
 167 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 168         -Wl,--as-needed \
 169         -Wl,--gc-sections \
 170         -Wl,-z,relro \
 171         -Wl,-z,now])
 172 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 173
 174 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 175 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 176
 177 save_LIBS="$LIBS"
 178 LIBS=
 179 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 180 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 181 CAP_LIBS="$LIBS"
 182 LIBS="$save_LIBS"
 183 AC_SUBST(CAP_LIBS)
 184
 185 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 186 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 187 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 188 #include <unistd.h>
 189 #include <sys/mount.h>
 190 #include <fcntl.h>]])
 191
 192 # This makes sure pkg.m4 is available.
 193 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 194
 195 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 196 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 197
 198 # ------------------------------------------------------------------------------
 199 have_blkid=no
 200 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 201 if test "x$enable_blkid" != "xno"; then
 202         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 203                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 204         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 205                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 206         fi
 207 fi
 208 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 209
 210 # ------------------------------------------------------------------------------
 211 have_ima=yes
 212 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 213                 [case "${enableval}" in
 214                         yes) have_ima=yes ;;
 215                         no) have_ima=no ;;
 216                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 217                 esac],
 218                 [have_ima=yes])
 219
 220 if test "x${have_ima}" != xno ; then
 221         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 222 fi
 223
 224 # ------------------------------------------------------------------------------
 225 have_selinux=no
 226 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 227 if test "x$enable_selinux" != "xno"; then
 228         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 229                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 230         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 231                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 232         fi
 233 fi
 234 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 235 if test "x${have_selinux}" != xno ; then
 236         sushell=/sbin/sushell
 237 else
 238         sushell=/bin/bash
 239 fi
 240 AC_SUBST(sushell)
 241
 242 # ------------------------------------------------------------------------------
 243 have_xz=no
 244 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 245 if test "x$enable_xz" != "xno"; then
 246         PKG_CHECK_MODULES(XZ, [ liblzma ],
 247                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 248         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 249                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 250         fi
 251 fi
 252 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 253
 254 # ------------------------------------------------------------------------------
 255 AC_ARG_ENABLE([tcpwrap],
 256         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 257                 [case "${enableval}" in
 258                         yes) have_tcpwrap=yes ;;
 259                         no) have_tcpwrap=no ;;
 260                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 261                 esac],
 262                 [have_tcpwrap=auto])
 263
 264 if test "x${have_tcpwrap}" != xno ; then
 265         ACX_LIBWRAP
 266         if test "x${LIBWRAP_LIBS}" = x ; then
 267                 if test "x$have_tcpwrap" = xyes ; then
 268                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 269                 fi
 270                 have_tcpwrap=no
 271         else
 272                 have_tcpwrap=yes
 273         fi
 274 else
 275         LIBWRAP_LIBS=
 276 fi
 277 AC_SUBST(LIBWRAP_LIBS)
 278
 279 # ------------------------------------------------------------------------------
 280 AC_ARG_ENABLE([pam],
 281         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 282                 [case "${enableval}" in
 283                         yes) have_pam=yes ;;
 284                         no) have_pam=no ;;
 285                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 286                 esac],
 287                 [have_pam=auto])
 288
 289 if test "x${have_pam}" != xno ; then
 290         AC_CHECK_HEADERS(
 291                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 292                 [have_pam=yes],
 293                 [if test "x$have_pam" = xyes ; then
 294                         AC_MSG_ERROR([*** PAM headers not found.])
 295                 fi])
 296
 297         AC_CHECK_LIB(
 298                 [pam],
 299                 [pam_syslog],
 300                 [have_pam=yes],
 301                 [if test "x$have_pam" = xyes ; then
 302                         AC_MSG_ERROR([*** libpam not found.])
 303                 fi])
 304
 305         if test "x$have_pam" = xyes ; then
 306                 PAM_LIBS="-lpam -lpam_misc"
 307                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 308         else
 309                 have_pam=no
 310         fi
 311 else
 312         PAM_LIBS=
 313 fi
 314 AC_SUBST(PAM_LIBS)
 315 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 316
 317 # ------------------------------------------------------------------------------
 318 AC_ARG_ENABLE([acl],
 319         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 320                 [case "${enableval}" in
 321                         yes) have_acl=yes ;;
 322                         no) have_acl=no ;;
 323                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 324                 esac],
 325                 [have_acl=auto])
 326
 327 if test "x${have_acl}" != xno ; then
 328         AC_CHECK_HEADERS(
 329                 [sys/acl.h acl/libacl.h],
 330                 [have_acl=yes],
 331                 [if test "x$have_acl" = xyes ; then
 332                         AC_MSG_ERROR([*** ACL headers not found.])
 333                 fi])
 334
 335         AC_CHECK_LIB(
 336                 [acl],
 337                 [acl_get_file],
 338                 [have_acl=yes],
 339                 [if test "x$have_acl" = xyes ; then
 340                         AC_MSG_ERROR([*** libacl not found.])
 341                 fi])
 342
 343         if test "x$have_acl" = xyes ; then
 344                 ACL_LIBS="-lacl"
 345                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 346         else
 347                 have_acl=no
 348         fi
 349 else
 350         ACL_LIBS=
 351 fi
 352 AC_SUBST(ACL_LIBS)
 353 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 354
 355 # ------------------------------------------------------------------------------
 356 AC_ARG_ENABLE([xattr],
 357         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 358                 [case "${enableval}" in
 359                         yes) have_xattr=yes ;;
 360                         no) have_xattr=no ;;
 361                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 362                 esac],
 363                 [have_xattr=auto])
 364
 365 if test "x${have_xattr}" != xno ; then
 366         AC_CHECK_HEADERS(
 367                 [attr/xattr.h],
 368                 [have_xattr=yes],
 369                 [if test "x$have_xattr" = xyes ; then
 370                         AC_MSG_ERROR([*** XATTR headers not found.])
 371                 fi])
 372
 373         AC_CHECK_LIB(
 374                 [attr],
 375                 [fsetxattr],
 376                 [have_xattr=yes],
 377                 [if test "x$have_xattr" = xyes ; then
 378                         AC_MSG_ERROR([*** libattr not found.])
 379                 fi])
 380
 381         if test "x$have_xattr" = xyes ; then
 382                 XATTR_LIBS="-lattr"
 383                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 384         else
 385                 have_xattr=no
 386         fi
 387 else
 388         XATTR_LIBS=
 389 fi
 390 AC_SUBST(XATTR_LIBS)
 391 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 392
 393 # ------------------------------------------------------------------------------
 394 AC_ARG_ENABLE([gcrypt],
 395         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 396                 [case "${enableval}" in
 397                         yes) have_gcrypt=yes ;;
 398                         no) have_gcrypt=no ;;
 399                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 400                 esac],
 401                 [have_gcrypt=auto])
 402
 403 if test "x${have_gcrypt}" != xno ; then
 404         AM_PATH_LIBGCRYPT(
 405                 [1.4.5],
 406                 [have_gcrypt=yes],
 407                 [if test "x$have_gcrypt" = xyes ; then
 408                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 409                 fi])
 410
 411         if test "x$have_gcrypt" = xyes ; then
 412                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 413                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 414                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 415         else
 416                 have_gcrypt=no
 417         fi
 418 else
 419         GCRYPT_LIBS=
 420         GCRYPT_CFLAGS=
 421 fi
 422 AC_SUBST(GCRYPT_LIBS)
 423 AC_SUBST(GCRYPT_CFLAGS)
 424 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 425
 426 # ------------------------------------------------------------------------------
 427 AC_ARG_ENABLE([audit],
 428         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 429                 [case "${enableval}" in
 430                         yes) have_audit=yes ;;
 431                         no) have_audit=no ;;
 432                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 433                 esac],
 434                 [have_audit=auto])
 435
 436 if test "x${have_audit}" != xno ; then
 437         AC_CHECK_HEADERS(
 438                 [libaudit.h],
 439                 [have_audit=yes],
 440                 [if test "x$have_audit" = xyes ; then
 441                         AC_MSG_ERROR([*** AUDIT headers not found.])
 442                 fi])
 443
 444         AC_CHECK_LIB(
 445                 [audit],
 446                 [audit_open],
 447                 [have_audit=yes],
 448                 [if test "x$have_audit" = xyes ; then
 449                         AC_MSG_ERROR([*** libaudit not found.])
 450                 fi])
 451
 452         if test "x$have_audit" = xyes ; then
 453                 AUDIT_LIBS="-laudit"
 454                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 455         else
 456                 have_audit=no
 457         fi
 458 else
 459         AUDIT_LIBS=
 460 fi
 461 AC_SUBST(AUDIT_LIBS)
 462
 463 # ------------------------------------------------------------------------------
 464 have_libcryptsetup=no
 465 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 466 if test "x$enable_libcryptsetup" != "xno"; then
 467         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 468                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 469         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 470                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 471         fi
 472 fi
 473 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 474
 475 # ------------------------------------------------------------------------------
 476 have_qrencode=no
 477 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 478 if test "x$enable_qrencode" != "xno"; then
 479         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 480                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 481         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 482                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 483         fi
 484 fi
 485 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 486
 487 # ------------------------------------------------------------------------------
 488 have_microhttpd=no
 489 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 490 if test "x$enable_microhttpd" != "xno"; then
 491         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 492                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 493         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 494                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 495         fi
 496 fi
 497 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 498
 499 # ------------------------------------------------------------------------------
 500 have_binfmt=no
 501 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 502 if test "x$enable_binfmt" != "xno"; then
 503         have_binfmt=yes
 504 fi
 505 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 506
 507 # ------------------------------------------------------------------------------
 508 have_vconsole=no
 509 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 510 if test "x$enable_vconsole" != "xno"; then
 511         have_vconsole=yes
 512 fi
 513 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 514
 515 # ------------------------------------------------------------------------------
 516 have_readahead=no
 517 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 518 if test "x$enable_readahead" != "xno"; then
 519         have_readahead=yes
 520 fi
 521 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 522
 523 # ------------------------------------------------------------------------------
 524 have_quotacheck=no
 525 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 526 if test "x$enable_quotacheck" != "xno"; then
 527         have_quotacheck=yes
 528 fi
 529 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 530
 531 # ------------------------------------------------------------------------------
 532 have_randomseed=no
 533 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 534 if test "x$enable_randomseed" != "xno"; then
 535         have_randomseed=yes
 536 fi
 537 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 538
 539 # ------------------------------------------------------------------------------
 540 have_logind=no
 541 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 542 if test "x$enable_logind" != "xno"; then
 543         have_logind=yes
 544 fi
 545 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 546 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 547
 548 # ------------------------------------------------------------------------------
 549 have_hostnamed=no
 550 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 551 if test "x$enable_hostnamed" != "xno"; then
 552         have_hostnamed=yes
 553 fi
 554 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 555
 556 # ------------------------------------------------------------------------------
 557 have_timedated=no
 558 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 559 if test "x$enable_timedated" != "xno"; then
 560         have_timedated=yes
 561 fi
 562 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 563
 564 # ------------------------------------------------------------------------------
 565 have_localed=no
 566 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 567 if test "x$enable_localed" != "xno"; then
 568         have_localed=yes
 569 fi
 570 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 571
 572 # ------------------------------------------------------------------------------
 573 have_coredump=no
 574 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 575 if test "x$enable_coredump" != "xno"; then
 576         have_coredump=yes
 577 fi
 578 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 579
 580 # ------------------------------------------------------------------------------
 581 AC_ARG_WITH(firmware-path,
 582        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 583           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 584        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 585 OLD_IFS=$IFS
 586 IFS=:
 587 for i in $with_firmware_path; do
 588        if test "x${FIRMWARE_PATH}" = "x"; then
 589               FIRMWARE_PATH="\\\"${i}/\\\""
 590        else
 591               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 592        fi
 593 done
 594 IFS=$OLD_IFS
 595 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 596
 597 # ------------------------------------------------------------------------------
 598 AC_ARG_ENABLE([gudev],
 599        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 600        [], [enable_gudev=yes])
 601 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 602 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 603
 604 # ------------------------------------------------------------------------------
 605 AC_ARG_ENABLE([keymap],
 606        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 607        [], [enable_keymap=yes])
 608 AS_IF([test "x$enable_keymap" = "xyes"], [
 609        AC_PATH_PROG([GPERF], [gperf])
 610        if test -z "$GPERF"; then
 611               AC_MSG_ERROR([gperf is needed])
 612        fi
 613
 614        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 615        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 616 ])
 617 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 618
 619 # ------------------------------------------------------------------------------
 620 have_manpages=no
 621 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 622 AS_IF([test "x$enable_manpages" != xno], [
 623         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 624                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 625         ])
 626         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 627 ])
 628 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 629
 630 # ------------------------------------------------------------------------------
 631
 632 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 633 if test "z$with_distro" = "z"; then
 634         if test "$cross_compiling" = yes; then
 635                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 636         else
 637                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 638         fi
 639         if test "z$with_distro" = "z"; then
 640                 with_distro=other
 641         fi
 642 fi
 643 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 644 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 645
 646 # Location of the init scripts as mandated by LSB
 647 SYSTEM_SYSVINIT_PATH=/etc/init.d
 648 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 649
 650 M4_DEFINES=
 651
 652 case $with_distro in
 653         fedora)
 654                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 655                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 656                 M4_DEFINES=-DTARGET_FEDORA=1
 657                 ;;
 658         opensuse|suse)
 659                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 660                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 661                 M4_DEFINES=-DTARGET_SUSE=1
 662                 ;;
 663         debian)
 664                 SYSTEM_SYSVRCND_PATH=/etc
 665                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 666                 M4_DEFINES=-DTARGET_DEBIAN=1
 667                 ;;
 668         ubuntu)
 669                 SYSTEM_SYSVRCND_PATH=/etc
 670                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 671                 M4_DEFINES=-DTARGET_UBUNTU=1
 672                 ;;
 673         arch)
 674                 SYSTEM_SYSVINIT_PATH=
 675                 SYSTEM_SYSVRCND_PATH=
 676                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 677                 M4_DEFINES=-DTARGET_ARCH=1
 678                 ;;
 679         gentoo)
 680                 SYSTEM_SYSVINIT_PATH=
 681                 SYSTEM_SYSVRCND_PATH=
 682                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 683                 M4_DEFINES=-DTARGET_GENTOO=1
 684                 ;;
 685         slackware)
 686                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 687                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 688                 M4_DEFINES=-DTARGET_SLACKWARE=1
 689                 ;;
 690         frugalware)
 691                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 692                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 693                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 694                 ;;
 695         altlinux)
 696                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 697                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 698                 M4_DEFINES=-DTARGET_ALTLINUX=1
 699                 ;;
 700         mandriva)
 701                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 702                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 703                 M4_DEFINES=-DTARGET_MANDRIVA=1
 704                 ;;
 705         angstrom)
 706                 SYSTEM_SYSVRCND_PATH=/etc
 707                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 708                 M4_DEFINES=-DTARGET_ANGSTROM=1
 709                 ;;
 710         mageia)
 711                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 712                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 713                 M4_DEFINES=-DTARGET_MAGEIA=1
 714                 ;;
 715         other)
 716                 ;;
 717         *)
 718                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 719                 ;;
 720 esac
 721
 722 AC_ARG_WITH([sysvinit-path],
 723         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 724                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 725         [SYSTEM_SYSVINIT_PATH="$withval"],
 726         [])
 727
 728 AC_ARG_WITH([sysvrcd-path],
 729         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 730                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 731         [SYSTEM_SYSVRCND_PATH="$withval"],
 732         [])
 733
 734 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 735 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 736 AC_SUBST(M4_DEFINES)
 737
 738 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 739         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 740         SYSTEM_SYSV_COMPAT="yes"
 741         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 742 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 743         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 744 else
 745         SYSTEM_SYSV_COMPAT="no"
 746 fi
 747
 748 AC_ARG_WITH([tty-gid],
 749         [AS_HELP_STRING([--with-tty-gid=GID],
 750                 [Specify the numeric GID of the 'tty' group])],
 751         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 752         [])
 753
 754 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 755 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 756 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 757 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 758 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 759 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 760 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 761 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 762 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 763 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 764 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 765 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 766 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 767
 768 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 769
 770 AC_ARG_WITH([dbuspolicydir],
 771         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 772         [],
 773         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 774
 775 AC_ARG_WITH([dbussessionservicedir],
 776         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 777         [],
 778         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 779
 780 AC_ARG_WITH([dbussystemservicedir],
 781         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 782         [],
 783         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 784
 785 AC_ARG_WITH([dbusinterfacedir],
 786         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 787         [],
 788         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 789
 790 AC_ARG_WITH([rootprefix],
 791         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 792         [], [with_rootprefix=${ac_default_prefix}])
 793
 794 AC_ARG_WITH([rootlibdir],
 795         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 796         [],
 797         [with_rootlibdir=${libdir}])
 798
 799 AC_ARG_WITH([pamlibdir],
 800         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 801         [],
 802         [with_pamlibdir=${with_rootlibdir}/security])
 803
 804 AC_ARG_ENABLE([split-usr],
 805         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 806         [],
 807         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 808                 enable_split_usr=yes
 809         ], [
 810                 enable_split_usr=no
 811         ])])
 812
 813 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 814         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 815 ])
 816
 817 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 818 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 819 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 820 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 821 AC_SUBST([pamlibdir], [$with_pamlibdir])
 822 AC_SUBST([rootprefix], [$with_rootprefix])
 823 AC_SUBST([rootlibdir], [$with_rootlibdir])
 824
 825 AC_CONFIG_FILES([
 826         Makefile po/Makefile.in
 827         docs/libudev/Makefile
 828         docs/libudev/version.xml
 829         docs/gudev/Makefile
 830         docs/gudev/version.xml
 831 ])
 832
 833 AC_OUTPUT
 834 AC_MSG_RESULT([
 835         $PACKAGE_NAME $VERSION
 836
 837         Distribution:            ${with_distro}
 838         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 839         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 840         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 841         libcryptsetup:           ${have_libcryptsetup}
 842         tcpwrap:                 ${have_tcpwrap}
 843         PAM:                     ${have_pam}
 844         AUDIT:                   ${have_audit}
 845         IMA:                     ${have_ima}
 846         SELinux:                 ${have_selinux}
 847         XZ:                      ${have_xz}
 848         ACL:                     ${have_acl}
 849         XATTR:                   ${have_xattr}
 850         GCRYPT:                  ${have_gcrypt}
 851         QRENCODE:                ${have_qrencode}
 852         MICROHTTPD:              ${have_microhttpd}
 853         binfmt:                  ${have_binfmt}
 854         vconsole:                ${have_vconsole}
 855         readahead:               ${have_readahead}
 856         quotacheck:              ${have_quotacheck}
 857         randomseed:              ${have_randomseed}
 858         logind:                  ${have_logind}
 859         hostnamed:               ${have_hostnamed}
 860         timedated:               ${have_timedated}
 861         localed:                 ${have_localed}
 862         coredump:                ${have_coredump}
 863         blkid:                   ${have_blkid}
 864         firmware path:           ${FIRMWARE_PATH}
 865         gudev:                   ${enable_gudev}
 866         gintrospection:          ${enable_introspection}
 867         keymap:                  ${enable_keymap}
 868         Python:                  ${have_python}
 869         Python Headers:          ${have_python_devel}
 870
 871         prefix:                  ${prefix}
 872         rootprefix:              ${with_rootprefix}
 873         sysconf dir:             ${sysconfdir}
 874         datarootdir:             ${datarootdir}
 875         includedir:              ${includedir}
 876         include_prefix:          ${INCLUDE_PREFIX}
 877         lib dir:                 ${libdir}
 878         rootlib dir:             ${with_rootlibdir}
 879         PAM modules dir:         ${with_pamlibdir}
 880         D-Bus policy dir:        ${with_dbuspolicydir}
 881         D-Bus session dir:       ${with_dbussessionservicedir}
 882         D-Bus system dir:        ${with_dbussystemservicedir}
 883         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 884         Split /usr:              ${enable_split_usr}
 885         man pages:               ${have_manpages}
 886         gtk-doc:                 ${enable_gtk_doc}
 887
 888         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 889         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 890         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 891         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
 892         PYTHON_LIBS:             ${PYTHON_LIBS}
 893 ])