configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [206],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(OBJCOPY, objcopy)
  98 AC_CHECK_TOOL(STRINGS, strings)
  99 AC_CHECK_TOOL(GPERF, gperf)
 100 if test -z "$GPERF" ; then
 101         AC_MSG_ERROR([*** gperf not found])
 102 fi
 103
 104 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 105         -pipe \
 106         -Wall \
 107         -Wextra \
 108         -Wno-inline \
 109         -Wundef \
 110         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 111         -Wlogical-op \
 112         -Wsign-compare \
 113         -Wmissing-include-dirs \
 114         -Wold-style-definition \
 115         -Wpointer-arith \
 116         -Winit-self \
 117         -Wdeclaration-after-statement \
 118         -Wfloat-equal \
 119         -Wmissing-prototypes \
 120         -Wstrict-prototypes \
 121         -Wredundant-decls \
 122         -Wmissing-declarations \
 123         -Wmissing-noreturn \
 124         -Wshadow \
 125         -Wendif-labels \
 126         -Wcast-align \
 127         -Wstrict-aliasing=2 \
 128         -Wwrite-strings \
 129         -Wno-long-long \
 130         -Wno-overlength-strings \
 131         -Wno-unused-parameter \
 132         -Wno-missing-field-initializers \
 133         -Wno-unused-result \
 134         -Werror=overflow \
 135         -ffast-math \
 136         -fno-common \
 137         -fdiagnostics-show-option \
 138         -fdiagnostics-color \
 139         -fno-strict-aliasing \
 140         -fvisibility=hidden \
 141         -ffunction-sections \
 142         -fdata-sections \
 143         -fstack-protector \
 144         --param=ssp-buffer-size=4])
 145 AC_SUBST([OUR_CFLAGS], $with_cflags)
 146
 147 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 148         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 149                -Wp,-D_FORTIFY_SOURCE=2])],
 150         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 151 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 152
 153 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 154         -Wl,--as-needed \
 155         -Wl,--no-undefined \
 156         -Wl,--gc-sections \
 157         -Wl,-z,relro \
 158         -Wl,-z,now])
 159 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 160
 161 # ------------------------------------------------------------------------------
 162 # we use python to build the man page index, and for systemd-python
 163 have_python=no
 164 AC_ARG_WITH([python],
 165         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 166
 167 AS_IF([test "x$with_python" != "xno"], [
 168         AM_PATH_PYTHON(,, [:])
 169         AS_IF([test "$PYTHON" != :], [have_python=yes])
 170 ])
 171 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 172 AS_IF([test "x$PYTHON_BINARY" = "x"],
 173       [AS_IF([test "x$have_python" = "xyes"],
 174              [PYTHON_BINARY="$(which "$PYTHON")"],
 175              [PYTHON_BINARY=/usr/bin/python])])
 176 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 177
 178 have_python_devel=no
 179 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 180 AS_IF([test "x$enable_python_devel" != "xno"], [
 181       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 182             [have_python_devel=yes],
 183             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 184                   [have_python_devel=yes],
 185                   [have_python_devel=no])])
 186       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 187             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 188 ])
 189 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 190
 191 # ------------------------------------------------------------------------------
 192
 193 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 194
 195 save_LIBS="$LIBS"
 196 LIBS=
 197 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 198 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 199 CAP_LIBS="$LIBS"
 200 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 201 RT_LIBS="$LIBS"
 202 AC_SUBST(RT_LIBS)
 203 LIBS="$save_LIBS"
 204 AC_SUBST(CAP_LIBS)
 205
 206 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 207 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 208 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 209 #include <unistd.h>
 210 #include <sys/mount.h>
 211 #include <fcntl.h>]])
 212
 213 # This makes sure pkg.m4 is available.
 214 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 215
 216 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 217
 218 # ------------------------------------------------------------------------------
 219 have_coverage=no
 220 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 221 if test "x$enable_coverage" = "xyes" ; then
 222         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 223         if test "x$lcov_found" = xno ; then
 224                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 225         else
 226                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 227                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 228                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 229                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 230                 else
 231                         have_coverage=yes
 232                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 233                         -fprofile-arcs \
 234                         -ftest-coverage])
 235                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 236                 fi
 237         fi
 238 fi
 239 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 240
 241 # ------------------------------------------------------------------------------
 242 have_kmod=no
 243 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 244 if test "x$enable_kmod" != "xno"; then
 245         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 246         if test "x$have_kmod" = "xyes"; then
 247                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 248                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 249                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 250         fi
 251         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 252                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 253         fi
 254 fi
 255 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 256
 257 # ------------------------------------------------------------------------------
 258 have_blkid=no
 259 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 260 if test "x$enable_blkid" != "xno"; then
 261         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 262                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 263         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 264                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 265         fi
 266 fi
 267 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 268
 269 # ------------------------------------------------------------------------------
 270 have_ima=yes
 271 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 272                 [case "${enableval}" in
 273                         yes) have_ima=yes ;;
 274                         no) have_ima=no ;;
 275                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 276                 esac],
 277                 [have_ima=yes])
 278
 279 if test "x${have_ima}" != xno ; then
 280         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 281 fi
 282
 283 # ------------------------------------------------------------------------------
 284 have_chkconfig=yes
 285 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 286                 [case "${enableval}" in
 287                         yes) have_chkconfig=yes ;;
 288                         no) have_chkconfig=no ;;
 289                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 290                 esac],
 291                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 292                 if test -z "$CHKCONFIG"; then
 293                         have_chkconfig=no
 294                 else
 295                         have_chkconfig=yes
 296                 fi])
 297
 298 if test "x${have_chkconfig}" != xno ; then
 299         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 300 fi
 301
 302 # ------------------------------------------------------------------------------
 303 have_selinux=no
 304 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 305 if test "x$enable_selinux" != "xno"; then
 306         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 307                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 308         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 309                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 310         fi
 311 fi
 312 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 313
 314 AC_ARG_WITH(debug-shell,
 315         AS_HELP_STRING([--with-debug-shell=PATH],
 316                 [Path to debug shell binary]),
 317         [SUSHELL="$withval"],[
 318         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 319
 320 AC_SUBST(SUSHELL)
 321
 322 AC_ARG_WITH([debug-tty],
 323         AS_HELP_STRING([--with-debug-tty=PATH],
 324                 [Specify the tty device for debug shell]),
 325         [DEBUGTTY="$withval"],
 326         [DEBUGTTY=/dev/tty9])
 327
 328 AC_SUBST(DEBUGTTY)
 329
 330 # ------------------------------------------------------------------------------
 331 have_xz=no
 332 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 333 if test "x$enable_xz" != "xno"; then
 334         PKG_CHECK_MODULES(XZ, [ liblzma ],
 335                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 336         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 337                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 338         fi
 339 fi
 340 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 341
 342 # ------------------------------------------------------------------------------
 343 AC_ARG_ENABLE([tcpwrap],
 344         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 345                 [case "${enableval}" in
 346                         yes) have_tcpwrap=yes ;;
 347                         no) have_tcpwrap=no ;;
 348                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 349                 esac],
 350                 [have_tcpwrap=auto])
 351
 352 if test "x${have_tcpwrap}" != xno ; then
 353         ACX_LIBWRAP
 354         if test "x${LIBWRAP_LIBS}" = x ; then
 355                 if test "x$have_tcpwrap" = xyes ; then
 356                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 357                 fi
 358                 have_tcpwrap=no
 359         else
 360                 have_tcpwrap=yes
 361         fi
 362 else
 363         LIBWRAP_LIBS=
 364 fi
 365 AC_SUBST(LIBWRAP_LIBS)
 366
 367 # ------------------------------------------------------------------------------
 368 AC_ARG_ENABLE([pam],
 369         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 370                 [case "${enableval}" in
 371                         yes) have_pam=yes ;;
 372                         no) have_pam=no ;;
 373                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 374                 esac],
 375                 [have_pam=auto])
 376
 377 if test "x${have_pam}" != xno ; then
 378         AC_CHECK_HEADERS(
 379                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 380                 [have_pam=yes],
 381                 [if test "x$have_pam" = xyes ; then
 382                         AC_MSG_ERROR([*** PAM headers not found.])
 383                 fi])
 384
 385         AC_CHECK_LIB(
 386                 [pam],
 387                 [pam_syslog],
 388                 [have_pam=yes],
 389                 [if test "x$have_pam" = xyes ; then
 390                         AC_MSG_ERROR([*** libpam not found.])
 391                 fi])
 392
 393         if test "x$have_pam" = xyes ; then
 394                 PAM_LIBS="-lpam -lpam_misc"
 395                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 396         else
 397                 have_pam=no
 398         fi
 399 else
 400         PAM_LIBS=
 401 fi
 402 AC_SUBST(PAM_LIBS)
 403 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 404
 405 # ------------------------------------------------------------------------------
 406 AC_ARG_ENABLE([acl],
 407         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 408                 [case "${enableval}" in
 409                         yes) have_acl=yes ;;
 410                         no) have_acl=no ;;
 411                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 412                 esac],
 413                 [have_acl=auto])
 414
 415 if test "x${have_acl}" != xno ; then
 416         AC_CHECK_HEADERS(
 417                 [sys/acl.h acl/libacl.h],
 418                 [have_acl=yes],
 419                 [if test "x$have_acl" = xyes ; then
 420                         AC_MSG_ERROR([*** ACL headers not found.])
 421                 fi])
 422
 423         AC_CHECK_LIB(
 424                 [acl],
 425                 [acl_get_file],
 426                 [have_acl=yes],
 427                 [if test "x$have_acl" = xyes ; then
 428                         AC_MSG_ERROR([*** libacl not found.])
 429                 fi])
 430
 431         if test "x$have_acl" = xyes ; then
 432                 ACL_LIBS="-lacl"
 433                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 434         else
 435                 have_acl=no
 436         fi
 437 else
 438         ACL_LIBS=
 439 fi
 440 AC_SUBST(ACL_LIBS)
 441 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 442
 443 # ------------------------------------------------------------------------------
 444 AC_ARG_ENABLE([xattr],
 445         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 446                 [case "${enableval}" in
 447                         yes) have_xattr=yes ;;
 448                         no) have_xattr=no ;;
 449                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 450                 esac],
 451                 [have_xattr=auto])
 452
 453 if test "x${have_xattr}" != xno ; then
 454         AC_CHECK_HEADERS(
 455                 [attr/xattr.h],
 456                 [have_xattr=yes],
 457                 [if test "x$have_xattr" = xyes ; then
 458                         AC_MSG_ERROR([*** XATTR headers not found.])
 459                 fi])
 460
 461         AC_CHECK_LIB(
 462                 [attr],
 463                 [fsetxattr],
 464                 [have_xattr=yes],
 465                 [if test "x$have_xattr" = xyes ; then
 466                         AC_MSG_ERROR([*** libattr not found.])
 467                 fi])
 468
 469         if test "x$have_xattr" = xyes ; then
 470                 XATTR_LIBS="-lattr"
 471                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 472         else
 473                 have_xattr=no
 474         fi
 475 else
 476         XATTR_LIBS=
 477 fi
 478 AC_SUBST(XATTR_LIBS)
 479 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 480
 481 # ------------------------------------------------------------------------------
 482 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 483                 [case "${enableval}" in
 484                         yes) have_smack=yes ;;
 485                         no) have_smack=no ;;
 486                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 487                 esac],
 488                 [have_smack=auto])
 489
 490 if test "x${have_xattr}" = xno; then
 491         if test "x${have_smack}" = xyes; then
 492                 AC_MSG_ERROR(SMACK requires xattr support)
 493         else
 494                 have_smack=no
 495         fi
 496 else
 497         if test "x${have_smack}" = xauto; then
 498                 have_smack=yes
 499         fi
 500 fi
 501
 502 if test "x${have_smack}" = xyes ; then
 503         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 504 fi
 505
 506 # ------------------------------------------------------------------------------
 507 AC_ARG_ENABLE([gcrypt],
 508         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 509                 [case "${enableval}" in
 510                         yes) have_gcrypt=yes ;;
 511                         no) have_gcrypt=no ;;
 512                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 513                 esac],
 514                 [have_gcrypt=auto])
 515
 516 if test "x${have_gcrypt}" != xno ; then
 517         AM_PATH_LIBGCRYPT(
 518                 [1.4.5],
 519                 [have_gcrypt=yes],
 520                 [if test "x$have_gcrypt" = xyes ; then
 521                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 522                 fi])
 523
 524         if test "x$have_gcrypt" = xyes ; then
 525                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 526                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 527                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 528         else
 529                 have_gcrypt=no
 530         fi
 531 else
 532         GCRYPT_LIBS=
 533         GCRYPT_CFLAGS=
 534 fi
 535 AC_SUBST(GCRYPT_LIBS)
 536 AC_SUBST(GCRYPT_CFLAGS)
 537 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 538
 539 # ------------------------------------------------------------------------------
 540 AC_ARG_ENABLE([audit],
 541         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 542                 [case "${enableval}" in
 543                         yes) have_audit=yes ;;
 544                         no) have_audit=no ;;
 545                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 546                 esac],
 547                 [have_audit=auto])
 548
 549 if test "x${have_audit}" != xno ; then
 550         AC_CHECK_HEADERS(
 551                 [libaudit.h],
 552                 [have_audit=yes],
 553                 [if test "x$have_audit" = xyes ; then
 554                         AC_MSG_ERROR([*** AUDIT headers not found.])
 555                 fi])
 556
 557         AC_CHECK_LIB(
 558                 [audit],
 559                 [audit_open],
 560                 [have_audit=yes],
 561                 [if test "x$have_audit" = xyes ; then
 562                         AC_MSG_ERROR([*** libaudit not found.])
 563                 fi])
 564
 565         if test "x$have_audit" = xyes ; then
 566                 AUDIT_LIBS="-laudit"
 567                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 568         else
 569                 have_audit=no
 570         fi
 571 else
 572         AUDIT_LIBS=
 573 fi
 574 AC_SUBST(AUDIT_LIBS)
 575
 576 # ------------------------------------------------------------------------------
 577 have_libcryptsetup=no
 578 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 579 if test "x$enable_libcryptsetup" != "xno"; then
 580         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 581                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 582         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 583                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 584         fi
 585 fi
 586 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 587
 588 # ------------------------------------------------------------------------------
 589 have_qrencode=no
 590 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 591 if test "x$enable_qrencode" != "xno"; then
 592         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 593                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 594         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 595                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 596         fi
 597 fi
 598 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 599
 600 # ------------------------------------------------------------------------------
 601 have_microhttpd=no
 602 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 603 if test "x$enable_microhttpd" != "xno"; then
 604         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 605                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 606         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 607                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 608         fi
 609 fi
 610 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 611
 612 # ------------------------------------------------------------------------------
 613 have_binfmt=no
 614 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 615 if test "x$enable_binfmt" != "xno"; then
 616         have_binfmt=yes
 617 fi
 618 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 619
 620 # ------------------------------------------------------------------------------
 621 have_vconsole=no
 622 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 623 if test "x$enable_vconsole" != "xno"; then
 624         have_vconsole=yes
 625 fi
 626 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 627
 628 # ------------------------------------------------------------------------------
 629 have_readahead=no
 630 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 631 if test "x$enable_readahead" != "xno"; then
 632         have_readahead=yes
 633 fi
 634 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 635
 636 # ------------------------------------------------------------------------------
 637 have_bootchart=no
 638 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 639 if test "x$enable_bootchart" != "xno"; then
 640         have_bootchart=yes
 641 fi
 642 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 643
 644 # ------------------------------------------------------------------------------
 645 have_quotacheck=no
 646 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 647 if test "x$enable_quotacheck" != "xno"; then
 648         have_quotacheck=yes
 649 fi
 650 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 651
 652 # ------------------------------------------------------------------------------
 653 have_tmpfiles=no
 654 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 655 if test "x$enable_tmpfiles" != "xno"; then
 656         have_tmpfiles=yes
 657 fi
 658 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 659
 660 # ------------------------------------------------------------------------------
 661 have_randomseed=no
 662 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 663 if test "x$enable_randomseed" != "xno"; then
 664         have_randomseed=yes
 665 fi
 666 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 667
 668 # ------------------------------------------------------------------------------
 669 have_logind=no
 670 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 671 if test "x$enable_logind" != "xno"; then
 672         have_logind=yes
 673 fi
 674 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 675 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 676
 677 # ------------------------------------------------------------------------------
 678 have_machined=no
 679 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 680 if test "x$enable_machined" != "xno"; then
 681         have_machined=yes
 682 fi
 683 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 684 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 685
 686 # ------------------------------------------------------------------------------
 687 have_hostnamed=no
 688 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 689 if test "x$enable_hostnamed" != "xno"; then
 690         have_hostnamed=yes
 691 fi
 692 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 693
 694 # ------------------------------------------------------------------------------
 695 have_timedated=no
 696 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 697 if test "x$enable_timedated" != "xno"; then
 698         have_timedated=yes
 699 fi
 700 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 701
 702 # ------------------------------------------------------------------------------
 703 have_localed=no
 704 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 705 if test "x$enable_localed" != "xno"; then
 706         have_localed=yes
 707 fi
 708 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 709
 710 # ------------------------------------------------------------------------------
 711 have_coredump=no
 712 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 713 if test "x$enable_coredump" != "xno"; then
 714         have_coredump=yes
 715 fi
 716 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 717
 718 # ------------------------------------------------------------------------------
 719 have_polkit=no
 720 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 721 if test "x$enable_polkit" != "xno"; then
 722         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 723         have_polkit=yes
 724 fi
 725 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 726
 727 # ------------------------------------------------------------------------------
 728 have_efi=no
 729 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 730 if test "x$enable_efi" != "xno"; then
 731         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 732         have_efi=yes
 733 fi
 734 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 735
 736 # ------------------------------------------------------------------------------
 737 AC_ARG_WITH(rc-local-script-path-start,
 738         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 739                 [Path to /etc/rc.local]),
 740         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 741         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 742
 743 AC_ARG_WITH(rc-local-script-path-stop,
 744         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 745                 [Path to /usr/sbin/halt.local]),
 746         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 747         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 748
 749 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 750 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 751
 752 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 753 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 754
 755 # ------------------------------------------------------------------------------
 756 AC_ARG_WITH(kbd-loadkeys,
 757         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 758                 [Path to loadkeys]),
 759         [KBD_LOADKEYS="$withval"],
 760         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 761
 762 AC_ARG_WITH(kbd-setfont,
 763         AS_HELP_STRING([--with-kbd-setfont=PATH],
 764                 [Path to setfont]),
 765         [KBD_SETFONT="$withval"],
 766         [KBD_SETFONT="/usr/bin/setfont"])
 767
 768 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 769 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 770
 771 AC_SUBST(KBD_LOADKEYS)
 772 AC_SUBST(KBD_SETFONT)
 773
 774 AC_ARG_WITH(telinit,
 775         AS_HELP_STRING([--with-telinit=PATH],
 776                 [Path to telinit]),
 777         [TELINIT="$withval"],
 778         [TELINIT="/lib/upstart/telinit"])
 779
 780 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 781
 782 AC_SUBST(TELINIT)
 783
 784 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 785
 786 # ------------------------------------------------------------------------------
 787 have_myhostname=no
 788 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 789 if test "x$enable_myhostname" != "xno"; then
 790         AC_HEADER_STDC
 791         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 792
 793         AC_C_CONST
 794         AC_TYPE_SIZE_T
 795         AC_HEADER_TIME
 796
 797         AC_FUNC_MALLOC
 798         AC_FUNC_SELECT_ARGTYPES
 799         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 800
 801         have_myhostname=yes
 802 fi
 803 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 804
 805 # ------------------------------------------------------------------------------
 806 AC_ARG_WITH(firmware-path,
 807        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 808           [Firmware search path (default="")]),
 809        [], [with_firmware_path=""])
 810 OLD_IFS=$IFS
 811 IFS=:
 812 for i in $with_firmware_path; do
 813        if test "x${FIRMWARE_PATH}" = "x"; then
 814               FIRMWARE_PATH="\\\"${i}/\\\""
 815        else
 816               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 817        fi
 818 done
 819 IFS=$OLD_IFS
 820 AC_SUBST(FIRMWARE_PATH)
 821 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 822 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 823
 824 # ------------------------------------------------------------------------------
 825 AC_ARG_ENABLE([gudev],
 826        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 827        [], [enable_gudev=yes])
 828 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 829 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 830 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 831
 832 # ------------------------------------------------------------------------------
 833 have_manpages=no
 834 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 835 AS_IF([test "x$enable_manpages" != xno], [
 836         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 837                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 838         ])
 839         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 840 ])
 841 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 842
 843 # ------------------------------------------------------------------------------
 844
 845 # Location of the init scripts as mandated by LSB
 846 SYSTEM_SYSVINIT_PATH=/etc/init.d
 847 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 848 M4_DEFINES=
 849
 850 AC_ARG_WITH([sysvinit-path],
 851         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 852                 [Specify the path to where the SysV init scripts are located])],
 853         [SYSTEM_SYSVINIT_PATH="$withval"],
 854         [])
 855
 856 AC_ARG_WITH([sysvrcnd-path],
 857         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 858                 [Specify the path to the base directory for the SysV rcN.d directories])],
 859         [SYSTEM_SYSVRCND_PATH="$withval"],
 860         [])
 861
 862 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 863         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 864         SYSTEM_SYSV_COMPAT="yes"
 865         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 866 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 867         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 868 else
 869         SYSTEM_SYSV_COMPAT="no"
 870 fi
 871
 872 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 873 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 874 AC_SUBST(M4_DEFINES)
 875
 876 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 877
 878 AC_ARG_WITH([tty-gid],
 879         [AS_HELP_STRING([--with-tty-gid=GID],
 880                 [Specify the numeric GID of the 'tty' group])],
 881         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 882         [])
 883
 884 AC_ARG_WITH([dbuspolicydir],
 885         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 886         [],
 887         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 888
 889 AC_ARG_WITH([dbussessionservicedir],
 890         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 891         [],
 892         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 893
 894 AC_ARG_WITH([dbussystemservicedir],
 895         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 896         [],
 897         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 898
 899 AC_ARG_WITH([dbusinterfacedir],
 900         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 901         [],
 902         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 903
 904 AC_ARG_WITH([bashcompletiondir],
 905         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 906         [],
 907         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 908                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 909         ] , [
 910                 with_bashcompletiondir=${datadir}/bash-completion/completions
 911         ])])
 912
 913 AC_ARG_WITH([rootprefix],
 914         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 915         [], [with_rootprefix=${ac_default_prefix}])
 916
 917 AC_ARG_WITH([rootlibdir],
 918         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 919         [],
 920         [with_rootlibdir=${libdir}])
 921
 922 AC_ARG_WITH([pamlibdir],
 923         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 924         [],
 925         [with_pamlibdir=${with_rootlibdir}/security])
 926
 927 AC_ARG_ENABLE([split-usr],
 928         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 929         [],
 930         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 931                 enable_split_usr=yes
 932         ], [
 933                 enable_split_usr=no
 934         ])])
 935
 936 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 937         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 938 ])
 939
 940 # Work around intltoolize and gtk-doc problems in VPATH builds
 941 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 942                                        [Define to do gtk-doc tests])
 943 AS_IF([test "x$0" != "x./configure"], [
 944         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 945 ])
 946
 947 AC_ARG_ENABLE(tests,
 948        [AC_HELP_STRING([--disable-tests], [disable tests])],
 949        enable_tests=$enableval, enable_tests=yes)
 950 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 951
 952 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 953 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 954 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 955 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 956 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 957 AC_SUBST([pamlibdir], [$with_pamlibdir])
 958 AC_SUBST([rootprefix], [$with_rootprefix])
 959 AC_SUBST([rootlibdir], [$with_rootlibdir])
 960
 961 AC_CONFIG_FILES([
 962         Makefile po/Makefile.in
 963         docs/libudev/Makefile
 964         docs/libudev/version.xml
 965         docs/gudev/Makefile
 966         docs/gudev/version.xml
 967 ])
 968
 969 AC_OUTPUT
 970 AC_MSG_RESULT([
 971         $PACKAGE_NAME $VERSION
 972
 973         libcryptsetup:           ${have_libcryptsetup}
 974         tcpwrap:                 ${have_tcpwrap}
 975         PAM:                     ${have_pam}
 976         AUDIT:                   ${have_audit}
 977         IMA:                     ${have_ima}
 978         SELinux:                 ${have_selinux}
 979         SMACK:                   ${have_smack}
 980         XZ:                      ${have_xz}
 981         ACL:                     ${have_acl}
 982         XATTR:                   ${have_xattr}
 983         GCRYPT:                  ${have_gcrypt}
 984         QRENCODE:                ${have_qrencode}
 985         MICROHTTPD:              ${have_microhttpd}
 986         CHKCONFIG:               ${have_chkconfig}
 987         binfmt:                  ${have_binfmt}
 988         vconsole:                ${have_vconsole}
 989         readahead:               ${have_readahead}
 990         bootchart:               ${have_bootchart}
 991         quotacheck:              ${have_quotacheck}
 992         tmpfiles:                ${have_tmpfiles}
 993         randomseed:              ${have_randomseed}
 994         logind:                  ${have_logind}
 995         machined:                ${have_machined}
 996         hostnamed:               ${have_hostnamed}
 997         timedated:               ${have_timedated}
 998         localed:                 ${have_localed}
 999         coredump:                ${have_coredump}
1000         polkit:                  ${have_polkit}
1001         efi:                     ${have_efi}
1002         kmod:                    ${have_kmod}
1003         blkid:                   ${have_blkid}
1004         nss-myhostname:          ${have_myhostname}
1005         gudev:                   ${enable_gudev}
1006         gintrospection:          ${enable_introspection}
1007         Python:                  ${have_python}
1008         Python Headers:          ${have_python_devel}
1009         man pages:               ${have_manpages}
1010         gtk-doc:                 ${enable_gtk_doc}
1011         test coverage:           ${have_coverage}
1012         Split /usr:              ${enable_split_usr}
1013         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1014
1015         prefix:                  ${prefix}
1016         rootprefix:              ${with_rootprefix}
1017         sysconf dir:             ${sysconfdir}
1018         datarootdir:             ${datarootdir}
1019         includedir:              ${includedir}
1020         include_prefix:          ${INCLUDE_PREFIX}
1021         lib dir:                 ${libdir}
1022         rootlib dir:             ${with_rootlibdir}
1023         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1024         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1025         Build Python:            ${PYTHON}
1026         Installation Python:     ${PYTHON_BINARY}
1027         firmware path:           ${FIRMWARE_PATH}
1028         PAM modules dir:         ${with_pamlibdir}
1029         D-Bus policy dir:        ${with_dbuspolicydir}
1030         D-Bus session dir:       ${with_dbussessionservicedir}
1031         D-Bus system dir:        ${with_dbussystemservicedir}
1032         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1033         Bash completions dir:    ${with_bashcompletiondir}
1034         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1035         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1036         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1037
1038         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1039         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1040         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1041         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1042         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1043 ])