man/meson.build

   1 # This is lame, I know, but meson has no other include mechanism
   2 subdir('rules')
   3
   4 want_man = get_option('man')
   5 want_html = get_option('html')
   6 xsltproc = find_program('xsltproc',
   7                         required : want_man == 'true' or want_html == 'true')
   8 want_man = want_man != 'false' and xsltproc.found()
   9 want_html = want_html != 'false' and xsltproc.found()
  10
  11 xsltproc_flags = [
  12         '--nonet',
  13         '--xinclude',
  14         '--stringparam', 'man.output.quietly', '1',
  15         '--stringparam', 'funcsynopsis.style', 'ansi',
  16         '--stringparam', 'man.authors.section.enabled', '0',
  17         '--stringparam', 'man.copyright.section.enabled', '0',
  18         '--stringparam', 'systemd.version', '@0@'.format(meson.project_version()),
  19         '--path',
  20         '@0@:@1@'.format(meson.current_build_dir(), meson.current_source_dir())]
  21
  22 custom_man_xsl = files('custom-man.xsl')
  23 custom_html_xsl = files('custom-html.xsl')
  24 xslt_cmd = [xsltproc, '-o', '@OUTPUT0@'] + xsltproc_flags
  25
  26 custom_entities_ent = configure_file(
  27         input : 'custom-entities.ent.in',
  28         output : 'custom-entities.ent',
  29         configuration : conf)
  30
  31 man_pages = []
  32 html_pages = []
  33 source_xml_files = []
  34 foreach tuple : manpages
  35         stem = tuple[0]
  36         section = tuple[1]
  37         aliases = tuple[2]
  38         condition = tuple[3]
  39
  40         xml = stem + '.xml'
  41         html = stem + '.html'
  42         man = stem + '.' + section
  43
  44         manaliases = []
  45         htmlaliases = []
  46         foreach alias : aliases
  47                 manaliases += [alias + '.' + section]
  48                 htmlaliases += [alias + '.html']
  49         endforeach
  50
  51         mandirn = join_paths(get_option('mandir'), 'man' + section)
  52
  53         if condition == '' or conf.get(condition, 0) == 1
  54                 p1 = custom_target(
  55                         man,
  56                         input : xml,
  57                         output : [man] + manaliases,
  58                         command : xslt_cmd + [custom_man_xsl, '@INPUT@'],
  59                         depend_files : custom_entities_ent,
  60                         install : want_man,
  61                         install_dir : mandirn)
  62                 man_pages += [p1]
  63
  64                 p2 = custom_target(
  65                         html,
  66                         input : xml,
  67                         output : html,
  68                         command : xslt_cmd + [custom_html_xsl, '@INPUT@'],
  69                         depend_files : custom_entities_ent,
  70                         install : want_html,
  71                         install_dir : join_paths(docdir, 'html'))
  72                 html_pages += [p2]
  73
  74                 foreach htmlalias : htmlaliases
  75                         p3 = custom_target(
  76                                 htmlalias,
  77                                 input : p2,
  78                                 output : htmlalias,
  79                                 command : ['ln', '-fs', html, '@OUTPUT@'])
  80                         if want_html
  81                                 dst = join_paths(docdir, 'html', htmlalias)
  82                                 cmd = 'ln -fs @0@ $DESTDIR@1@'.format(html, dst)
  83                                 meson.add_install_script('sh', '-c', cmd)
  84                         endif
  85                         html_pages += [p3]
  86                 endforeach
  87
  88                 source_xml_files += files(tuple[0] + '.xml')
  89         else
  90                 message('Skipping @0@.@1@ because @2@ is false'.format(stem, section, condition))
  91         endif
  92 endforeach
  93
  94 ############################################################
  95
  96 have_lxml = run_command(xml_helper_py).returncode() == 0
  97 if not have_lxml
  98         message('python-lxml not available, not making man page indices')
  99 endif
 100
 101 systemd_directives_xml = custom_target(
 102         'systemd.directives.xml',
 103         input : source_xml_files,
 104         output : 'systemd.directives.xml',
 105         command : [make_directive_index_py, '@OUTPUT@'] + source_xml_files)
 106
 107 nonindex_xml_files = source_xml_files + [systemd_directives_xml]
 108 systemd_index_xml = custom_target(
 109         'systemd.index.xml',
 110         input : nonindex_xml_files,
 111         output : 'systemd.index.xml',
 112         command : [make_man_index_py, '@OUTPUT@'] + nonindex_xml_files)
 113
 114 foreach tuple : [['systemd.directives', '7', systemd_directives_xml],
 115                  ['systemd.index',      '7', systemd_index_xml]]
 116         stem = tuple[0]
 117         section = tuple[1]
 118         xml = tuple[2]
 119
 120         html = stem + '.html'
 121         man = stem + '.' + section
 122
 123         mandirn = join_paths(get_option('mandir'), 'man' + section)
 124
 125         p1 = custom_target(
 126                 man,
 127                 input : xml,
 128                 output : man,
 129                 command : xslt_cmd + [custom_man_xsl, '@INPUT@'],
 130                 install : want_man and have_lxml,
 131                 install_dir : mandirn)
 132         man_pages += [p1]
 133
 134         p2 = custom_target(
 135                 html,
 136                 input : xml,
 137                 output : html,
 138                 command : xslt_cmd + [custom_html_xsl, '@INPUT@'],
 139                 install : want_html and have_lxml,
 140                 install_dir : join_paths(docdir, 'html'))
 141         html_pages += [p2]
 142 endforeach
 143
 144 # cannot use run_target until https://github.com/mesonbuild/meson/issues/1644 is resolved
 145 man = custom_target(
 146         'man',
 147         output : 'man',
 148         depends : man_pages,
 149         command : ['echo'])
 150
 151 html = run_target(
 152         'html',
 153         depends : html_pages,
 154         output : 'html',
 155         command : ['echo'])
 156
 157 run_target(
 158         'doc-sync',
 159         depends : man_pages + html_pages,
 160         command : ['rsync', '-rlv',
 161                    '--delete-excluded',
 162                    '--include=man',
 163                    '--include=*.html',
 164                    '--exclude=*',
 165                    '--omit-dir-times',
 166                    meson.current_build_dir(),
 167                    get_option('www-target')])
 168
 169 ############################################################
 170
 171 if git.found()
 172         run_target(
 173                 'update-man-rules',
 174                 # slightly strange syntax because of
 175                 # https://github.com/mesonbuild/meson/issues/1643
 176                 # and https://github.com/mesonbuild/meson/issues/1512
 177                 command : ['sh', '-c',
 178                            'cd @0@ && '.format(meson.build_root()) +
 179                            'python3 @0@/tools/make-man-rules.py --meson `git ls-files ":/man/*.xml"` >t && '.format(meson.source_root()) +
 180                            'mv t @0@/rules/meson.build'.format(meson.current_source_dir())],
 181                 depend_files : custom_entities_ent)
 182 endif