shell-completion/zsh/_systemctl.in

   1 #compdef systemctl
   2
   3 (( $+functions[_systemctl_command] )) || _systemctl_command()
   4 {
   5   local -a _systemctl_cmds
   6   _systemctl_cmds=(
   7     "list-sockets:List sockets"
   8     "list-timers:List timers"
   9     "list-units:List units"
  10     "start:Start (activate) one or more units"
  11     "stop:Stop (deactivate) one or more units"
  12     "reload:Reload one or more units"
  13     "restart:Start or restart one or more units"
  14     "condrestart:Restart one or more units if active"
  15     "try-restart:Restart one or more units if active"
  16     "reload-or-restart:Reload one or more units if possible, otherwise start or restart"
  17     "force-reload:Reload one or more units if possible, otherwise restart if active"
  18     "hibernate:Hibernate the system"
  19     "hybrid-sleep:Hibernate and suspend the system"
  20     "try-reload-or-restart:Reload one or more units if possible, otherwise restart if active"
  21     "isolate:Start one unit and stop all others"
  22     "kill:Send signal to processes of a unit"
  23     "is-active:Check whether units are active"
  24     "is-failed:Check whether units are failed"
  25     "status:Show runtime status of one or more units"
  26     "show:Show properties of one or more units/jobs or the manager"
  27     "cat:Show the source unit files and drop-ins"
  28     "reset-failed:Reset failed state for all, one, or more units"
  29     "list-unit-files:List installed unit files"
  30     "enable:Enable one or more unit files"
  31     "disable:Disable one or more unit files"
  32     "add-wants:Add Wants= dependencies to a unit"
  33     "add-requires:Add Requires= dependencies to a unit"
  34     "reenable:Reenable one or more unit files"
  35     "preset:Enable/disable one or more unit files based on preset configuration"
  36     "set-default:Set the default target"
  37     "get-default:Query the default target"
  38     "edit:Edit one or more unit files"
  39     "is-system-running:Query overall status of the system"
  40     "help:Show documentation for specified units"
  41     "list-dependencies:Show unit dependency tree"
  42     "mask:Mask one or more units"
  43     "unmask:Unmask one or more units"
  44     "link:Link one or more units files into the search path"
  45     "is-enabled:Check whether unit files are enabled"
  46     "list-jobs:List jobs"
  47     "cancel:Cancel all, one, or more jobs"
  48     "show-environment:Dump environment"
  49     "set-environment:Set one or more environment variables"
  50     "unset-environment:Unset one or more environment variables"
  51     "daemon-reload:Reload systemd manager configuration"
  52     "daemon-reexec:Reexecute systemd manager"
  53     "default:Enter system default mode"
  54     "rescue:Enter system rescue mode"
  55     "emergency:Enter system emergency mode"
  56     "halt:Shut down and halt the system"
  57     "suspend:Suspend the system"
  58     "poweroff:Shut down and power-off the system"
  59     "reboot:Shut down and reboot the system"
  60     "kexec:Shut down and reboot the system with kexec"
  61     "exit:Ask for user instance termination"
  62     "switch-root:Change root directory"
  63     "revert:Revert unit files to their vendor versions"
  64   )
  65
  66   if (( CURRENT == 1 )); then
  67     _describe -t commands 'systemctl command' _systemctl_cmds || compadd "$@"
  68   else
  69     local curcontext="$curcontext" expl
  70
  71     cmd="${${_systemctl_cmds[(r)$words[1]:*]%%:*}}"
  72     # Deal with any aliases
  73     case $cmd in
  74       condrestart) cmd="try-restart";;
  75       force-reload) cmd="try-reload-or-restart";;
  76     esac
  77
  78     if (( $#cmd )); then
  79       curcontext="${curcontext%:*:*}:systemctl-${cmd}:"
  80
  81       local update_policy
  82       zstyle -s ":completion:${curcontext}:" cache-policy update_policy
  83       if [[ -z "$update_policy" ]]; then
  84         zstyle ":completion:${curcontext}:" cache-policy _systemctl_caching_policy
  85       fi
  86
  87       _call_function ret _systemctl_$cmd || _message 'no more arguments'
  88     else
  89       _message "unknown systemctl command: $words[1]"
  90     fi
  91     return ret
  92   fi
  93 }
  94
  95 __systemctl()
  96 {
  97   systemctl $_sys_service_mgr --full --no-legend --no-pager "$@" 2>/dev/null
  98 }
  99
 100
 101 # Fills the unit list
 102 _systemctl_all_units()
 103 {
 104   if ( [[ ${+_sys_all_units} -eq 0 ]] || _cache_invalid SYS_ALL_UNITS$_sys_service_mgr ) ||
 105     ! _retrieve_cache SYS_ALL_UNITS$_sys_service_mgr;
 106   then
 107     _sys_all_units=( ${${(f)"$(__systemctl list-units --all)"}%% *} )
 108     _store_cache SYS_ALL_UNITS$_sys_service_mgr _sys_all_units
 109   fi
 110 }
 111
 112 # Fills the unit list including all file units
 113 _systemctl_really_all_units()
 114 {
 115   local -a all_unit_files;
 116   local -a really_all_units;
 117   if ( [[ ${+_sys_really_all_units} -eq 0 ]] || _cache_invalid SYS_REALLY_ALL_UNITS$_sys_service_mgr ) ||
 118     ! _retrieve_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr;
 119   then
 120     all_unit_files=( ${${(f)"$(__systemctl list-unit-files)"}%% *} )
 121     _systemctl_all_units
 122     really_all_units=($_sys_all_units $all_unit_files)
 123     _sys_really_all_units=(${(u)really_all_units})
 124     _store_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr _sys_really_all_units
 125   fi
 126 }
 127
 128 _filter_units_by_property() {
 129   local property=$1 value=$2; shift 2
 130   local -a units; units=("${(q-)@}")
 131   local -A props
 132   props=(${(f)"$(_call_program units "$service $_sys_service_mgr show --no-pager --property=\"Id,$property\" -- ${units} 2>/dev/null")"})
 133   echo -E - "${(@g:o:)${(k@)props[(Re)$property=$value]}#Id=}"
 134 }
 135
 136 _systemctl_get_template_names() { echo -E - ${^${(M)${(f)"$(__systemctl list-unit-files)"}##*@.[^[:space:]]##}%%@.*}\@ }
 137
 138
 139 _systemctl_active_units()  {_sys_active_units=(  ${${(f)"$(__systemctl list-units)"}%% *} )}
 140
 141 _systemctl_startable_units(){
 142     _sys_startable_units=( $( _filter_units_by_property ActiveState inactive $(
 143                           _filter_units_by_property CanStart yes $(
 144                           __systemctl $mode list-unit-files --state enabled,disabled,static | \
 145                                { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
 146                           __systemctl $mode list-units --state inactive,failed | \
 147                                { while read -r a b; do echo -E - " $a"; done; } )) ) )
 148 }
 149
 150 _systemctl_restartable_units(){
 151     _sys_restartable_units=( $(_filter_units_by_property CanStart yes $(
 152                           __systemctl $mode list-unit-files --state enabled,disabled,static | \
 153                                { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
 154                           __systemctl $mode list-units | \
 155                                { while read -r a b; do echo -E - " $a"; done; } )) )
 156 }
 157
 158 _systemctl_failed_units()  {_sys_failed_units=( ${${(f)"$(__systemctl list-units --state=failed)"}%% *} ) }
 159 _systemctl_unit_state() { typeset -gA _sys_unit_state; _sys_unit_state=( $(__systemctl list-unit-files) ) }
 160
 161 local fun
 162 # Completion functions for ALL_UNITS
 163 for fun in is-active is-failed is-enabled status show cat mask preset help list-dependencies edit revert add-wants add-requires ; do
 164   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 165   {
 166     _systemctl_really_all_units
 167     _wanted systemd-units expl unit \
 168       compadd "$@" -a - _sys_really_all_units
 169   }
 170 done
 171
 172 # Completion functions for ENABLED_UNITS
 173 (( $+functions[_systemctl_disable] )) || _systemctl_disable()
 174 {
 175     local _sys_unit_state; _systemctl_unit_state
 176     _wanted systemd-units expl 'enabled unit' \
 177       compadd "$@" - ${(k)_sys_unit_state[(R)enabled]}
 178 }
 179
 180 (( $+functions[_systemctl_reenable] )) || _systemctl_reenable()
 181 {
 182     local _sys_unit_state; _systemctl_unit_state
 183     _wanted systemd-units expl 'enabled/disabled unit' \
 184       compadd "$@" - ${(k)_sys_unit_state[(R)(enabled|disabled)]} $(_systemctl_get_template_names)
 185 }
 186
 187 # Completion functions for DISABLED_UNITS
 188 (( $+functions[_systemctl_enable] )) || _systemctl_enable()
 189 {
 190   local _sys_unit_state; _systemctl_unit_state
 191   _wanted systemd-units expl 'disabled unit' \
 192     compadd "$@" - ${(k)_sys_unit_state[(R)disabled]} $(_systemctl_get_template_names)
 193 }
 194
 195 # Completion functions for FAILED_UNITS
 196 (( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
 197 {
 198   local _sys_failed_units; _systemctl_failed_units
 199   _wanted systemd-units expl 'failed unit' \
 200     compadd "$@" -a - _sys_failed_units || _message "no failed unit found"
 201 }
 202
 203 # Completion functions for STARTABLE_UNITS
 204 (( $+functions[_systemctl_start] )) || _systemctl_start()
 205 {
 206    local _sys_startable_units; _systemctl_startable_units
 207    _wanted systemd-units expl 'startable unit' \
 208      compadd "$@" - ${_sys_startable_units[*]} $(_systemctl_get_template_names)
 209 }
 210
 211 # Completion functions for STOPPABLE_UNITS
 212 for fun in stop kill try-restart condrestart ; do
 213   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 214   {
 215     local _sys_active_units; _systemctl_active_units
 216     _wanted systemd-units expl 'stoppable unit' \
 217       compadd "$@" - $( _filter_units_by_property CanStop yes \
 218         ${_sys_active_units[*]} )
 219   }
 220 done
 221
 222 # Completion functions for ISOLATABLE_UNITS
 223 (( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
 224 {
 225   _systemctl_all_units
 226   _wanted systemd-units expl 'isolatable unit' \
 227     compadd "$@" - $( _filter_units_by_property AllowIsolate yes \
 228       ${_sys_all_units[*]} )
 229 }
 230
 231 # Completion functions for RELOADABLE_UNITS
 232 for fun in reload try-reload-or-restart force-reload ; do
 233   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 234   {
 235     local _sys_active_units; _systemctl_active_units
 236     _wanted systemd-units expl 'reloadable unit' \
 237       compadd "$@" - $( _filter_units_by_property CanReload yes \
 238         ${_sys_active_units[*]} )
 239   }
 240 done
 241
 242 # Completion functions for RESTARTABLE_UNITS
 243 for fun in restart reload-or-restart ; do
 244   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 245   {
 246     local _sys_restartable_units; _systemctl_restartable_units
 247     _wanted systemd-units expl 'restartable unit' \
 248       compadd "$@" - ${_sys_restartable_units[*]} $(_systemctl_get_template_names)
 249   }
 250 done
 251
 252 # Completion functions for MASKED_UNITS
 253 (( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
 254 {
 255   local _sys_unit_state; _systemctl_unit_state
 256   _wanted systemd-units expl 'masked unit' \
 257     compadd "$@" - ${(k)_sys_unit_state[(R)masked]} || _message "no masked units found"
 258 }
 259
 260 # Completion functions for JOBS
 261 (( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
 262 {
 263   _wanted systemd-jobs expl job \
 264     compadd "$@" - ${${(f)"$(__systemctl list-jobs)"}%% *} ||
 265       _message "no jobs found"
 266 }
 267
 268 # Completion functions for TARGETS
 269 (( $+functions[_systemctl_set-default] )) || _systemctl_set-default()
 270 {
 271   _wanted systemd-targets expl target \
 272     compadd "$@" - ${${(f)"$(__systemctl list-unit-files --type target --all)"}%% *} ||
 273       _message "no targets found"
 274 }
 275
 276 # Completion functions for ENVS
 277 for fun in set-environment unset-environment ; do
 278   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 279   {
 280     local fun=$0 ; fun=${fun##_systemctl_}
 281     local suf
 282     if [[ "${fun}" = "set-environment" ]]; then
 283       suf='-S='
 284     fi
 285     _wanted systemd-environment expl 'environment variable' \
 286       compadd "$@" ${suf} - ${${(f)"$(systemctl show-environment)"}%%=*}
 287   }
 288 done
 289
 290 (( $+functions[_systemctl_link] )) || _systemctl_link() {
 291    _sd_unit_files
 292 }
 293
 294 (( $+functions[_systemctl_switch-root] )) || _systemctl_switch-root() {
 295    _files
 296 }
 297
 298 # no systemctl completion for:
 299 #    [STANDALONE]='daemon-reexec daemon-reload default
 300 #                  emergency exit halt kexec list-jobs list-units
 301 #                  list-unit-files poweroff reboot rescue show-environment'
 302
 303 _systemctl_caching_policy()
 304 {
 305   local _sysunits
 306   local -a oldcache
 307
 308   # rebuild if cache is more than a day old
 309   oldcache=( "$1"(mh+1) )
 310   (( $#oldcache )) && return 0
 311
 312   _sysunits=(${${(f)"$(__systemctl --all)"}%% *})
 313
 314   if (( $#_sysunits )); then
 315     for unit in $_sysunits; do
 316       [[ "$unit" -nt "$1" ]] && return 0
 317     done
 318   fi
 319
 320   return 1
 321 }
 322
 323 _unit_states() {
 324     local -a _states
 325     _states=("${(fo)$(__systemctl --state=help)}")
 326     _values -s , "${_states[@]}"
 327 }
 328
 329 _unit_types() {
 330     local -a _types
 331     _types=("${(fo)$(__systemctl -t help)}")
 332     _values -s , "${_types[@]}"
 333 }
 334
 335 _unit_properties() {
 336   if ( [[ ${+_sys_all_properties} -eq 0 ]] || _cache_invalid SYS_ALL_PROPERTIES$_sys_service_mgr ) ||
 337     ! _retrieve_cache SYS_ALL_PROPERTIES$_sys_service_mgr;
 338   then
 339     _sys_all_properties=( ${${(M)${(f)"$(__systemctl show --all;
 340     @rootlibexecdir@/systemd --dump-configuration-items)"}##[[:alnum:]]##=*}%%=*}
 341     )
 342     _store_cache SYS_ALL_PROPERTIES$_sys_service_mgr _sys_all_properties
 343   fi
 344   _values -s , "${_sys_all_properties[@]}"
 345 }
 346
 347 _job_modes() {
 348     local -a _modes
 349     _modes=(fail replace replace-irreversibly isolate ignore-dependencies ignore-requirements flush)
 350     _values -s , "${_modes[@]}"
 351 }
 352
 353 # Build arguments for "systemctl" to be used in completion.
 354 local -a _modes; _modes=("--user" "--system")
 355 # Use the last mode (they are exclusive and the last one is used).
 356 local _sys_service_mgr=${${words:*_modes}[(R)(${(j.|.)_modes})]}
 357 _arguments -s \
 358     {-h,--help}'[Show help]' \
 359     '--version[Show package version]' \
 360     {-t+,--type=}'[List only units of a particular type]:unit type:_unit_types' \
 361     '--state=[Display units in the specified state]:unit state:_unit_states' \
 362     '--job-mode=[Specify how to deal with other jobs]:mode:_job_modes' \
 363     {-p+,--property=}'[Show only properties by specific name]:unit property:_unit_properties' \
 364     {-a,--all}'[Show all units/properties, including dead/empty ones]' \
 365     '--reverse[Show reverse dependencies]' \
 366     '--after[Show units ordered after]' \
 367     '--before[Show units ordered before]' \
 368     {-l,--full}"[Don't ellipsize unit names on output]" \
 369     '--show-types[When showing sockets, show socket type]' \
 370     {-i,--ignore-inhibitors}'[When executing a job, ignore jobs dependencies]' \
 371     {-q,--quiet}'[Suppress output]' \
 372     '--no-block[Do not wait until operation finished]' \
 373     '--no-legend[Do not print a legend, i.e. the column headers and the footer with hints]' \
 374     '--no-pager[Do not pipe output into a pager]' \
 375     '--system[Connect to system manager]' \
 376     '--user[Connect to user service manager]' \
 377     "--no-wall[Don't send wall message before halt/power-off/reboot]" \
 378     '--global[Enable/disable unit files globally]' \
 379     "--no-reload[When enabling/disabling unit files, don't reload daemon configuration]" \
 380     '--no-ask-password[Do not ask for system passwords]' \
 381     '--kill-who=[Who to send signal to]:killwho:(main control all)' \
 382     {-s+,--signal=}'[Which signal to send]:signal:_signals' \
 383     {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
 384     '--root=[Enable unit files in the specified root directory]:directory:_directories' \
 385     '--runtime[Enable unit files only temporarily until next reboot]' \
 386     {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
 387     {-P,--privileged}'[Acquire privileges before execution]' \
 388     {-n+,--lines=}'[Journal entries to show]:number of entries' \
 389     {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
 390     '--firmware-setup[Tell the firmware to show the setup menu on next boot]' \
 391     '--plain[When used with list-dependencies, print output as a list]' \
 392     '--failed[Show failed units]' \
 393     '*::systemctl command:_systemctl_command'