shell-completion/zsh/_systemd-nspawn

   1 #compdef systemd-nspawn
   2 # SPDX-License-Identifier: LGPL-2.1+
   3
   4 _nspawn-caps(){
   5     local -a _caps
   6     _caps=( CAP_CHOWN CAP_DAC_OVERRIDE CAP_DAC_READ_SEARCH
   7             CAP_FOWNER CAP_FSETID CAP_IPC_OWNER CAP_KILL CAP_LEASE CAP_LINUX_IMMUTABLE
   8             CAP_NET_BIND_SERVICE CAP_NET_BROADCAST CAP_NET_RAW CAP_SETGID CAP_SETFCAP CAP_SETPCAP
   9             CAP_SETUID CAP_SYS_ADMIN CAP_SYS_CHROOT CAP_SYS_NICE CAP_SYS_PTRACE CAP_SYS_TTY_CONFIG
  10             CAP_SYS_RESOURCE CAP_SYS_BOOT )
  11     _values -s , 'capabilities' "$_caps[@]"
  12 }
  13
  14 _arguments \
  15     {-h,--help}'[Show this help.]' \
  16     '--version[Print a short version string and exit.]' \
  17     {--quiet,-q}'[Turns off any status output by the tool itself.]' \
  18     {--directory=,-D+}'[Directory to use as file system root for the namespace container. If omitted the current directory will be used.]:directories:_directories' \
  19     '--template=[Initialize root directory from template directory, if missing.]:template:_directories' \
  20     {--ephemeral,-x}'[Run container with snapshot of root directory, and remove it after exit.]' \
  21     {--image=,-i+}'[Disk image to mount the root directory for the container from.]:disk image: _files' \
  22     {--boot,-b}'[Automatically search for an init binary and invoke it instead of a shell or a user supplied program.]' \
  23     {--user=,-u+}'[Run the command under specified user, create home directory and cd into it.]:user:_users' \
  24     {--machine=,-M+}'[Sets the machine name for this container.]: : _message "container name"' \
  25     '--uuid=[Set the specified uuid for the container.]: : _message "container UUID"' \
  26     {--slice=,-S+}'[Make the container part of the specified slice, instead of the default machine.slice.]: : _message slice' \
  27     '--private-network[Disconnect networking of the container from the host.]' \
  28     '--network-interface=[Assign the specified network interface to the container.]: : _net_interfaces' \
  29     '--network-macvlan=[Create a "macvlan" interface of the specified Ethernet network interface and add it to the container.]: : _net_interfaces' \
  30     '--network-ipvlan=[Create a ipvlan network interface based on an existing network interface to the container.]: : _net_interfaces' \
  31     {--network-veth,-n}'[Create a virtual Ethernet link (veth) between host and container.]' \
  32     '--network-bridge=[Adds the host side of the Ethernet link created with --network-veth to the specified bridge.]: : _net_interfaces' \
  33     {--port=,-p+}'[Expose a container IP port on the host.]: : _message port' \
  34     {--selinux-context=,-Z+}'[Sets the SELinux security context to be used to label processes in the container.]: : _message "SELinux context"' \
  35     {--selinux-apifs-context=,-L+}'[Sets the SELinux security context to be used to label files in the virtual API file systems in the container.]: : _message "SELinux context"' \
  36     '--capability=[List one or more additional capabilities to grant the container.]:capabilities:_nspawn-caps' \
  37     '--drop-capability=[Specify one or more additional capabilities to drop for the containerm]:capabilities:_nspawn-caps' \
  38     "--link-journal=[Control whether the container's journal shall be made visible to the host system.]:options:(no host guest auto)" \
  39     '-j[Equivalent to --link-journal=guest.]' \
  40     '--read-only[Mount the root file system read only for the container.]' \
  41     '--bind=[Bind mount a file or directory from the host into the container.]: : _files' \
  42     '--bind-ro=[Bind mount a file or directory from the host into the container (read-only).]: : _files' \
  43     '--tmpfs=[Mount an empty tmpfs to the specified directory.]: : _files' \
  44     '--setenv=[Specifies an environment variable assignment to pass to the init process in the container, in the format "NAME=VALUE".]: : _message "environment variables"' \
  45     '--share-system[Allows the container to share certain system facilities with the host.]' \
  46     '--register=[Controls whether the container is registered with systemd-machined(8).]:systemd-machined registration:( yes no )' \
  47     '--keep-unit[Instead of creating a transient scope unit to run the container in, simply register the service or scope unit systemd-nspawn has been invoked in with systemd-machined(8).]' \
  48     '--personality=[Control the architecture ("personality") reported by uname(2) in the container.]:architecture:(x86 x86-64)' \
  49     '--volatile=[Run the system in volatile mode.]:volatile:(no yes state)' \
  50     "--notify-ready=[Control when the ready notification is sent]:options:(yes no)" \
  51     '*:: : _normal'