shell-completion/zsh/_systemd-resolve

   1 #compdef systemd-resolve
   2 # SPDX-License-Identifier: LGPL-2.1+
   3
   4 #
   5 # This file is part of systemd.
   6 #
   7 # systemd is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU Lesser General Public License as published by
   9 # the Free Software Foundation; either version 2.1 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # systemd is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Lesser General Public License
  18 # along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 (( $+functions[_systemd-resolve_protocols] )) ||
  21 _systemd-resolve_protocols() {
  22     local -a _protocol
  23     _protocol=( $(_call_program protocol ${service} --legend=no --protocol help; echo help) )
  24     _values 'protocol' "$_protocol[@]"
  25 }
  26
  27 (( $+functions[_systemd-resolve_types] )) ||
  28 _systemd-resolve_types() {
  29     local -a _type
  30     _type=( $(_call_program type ${service} --legend=no --type help; echo help) )
  31     _values 'type' "$_type[@]"
  32 }
  33
  34 (( $+functions[_systemd-resolve_classes] )) ||
  35 _systemd-resolve_classes() {
  36     local -a _class
  37     _class=( $(_call_program class ${service} --legend=no --class help; echo help) )
  38     _values 'class' "$_class[@]"
  39 }
  40
  41 (( $+functions[_systemd-resolve_none] )) ||
  42 _systemd-resolve_none() {
  43     _alternative : \
  44         'domain:DNS address:' \
  45         'address:email address:'
  46 }
  47
  48 _arguments \
  49     {-h,--help}'[Print a short help text and exit]' \
  50     '--version[Print a short version string and exit]' \
  51     '--legend=no[Do not show headers and footers]' \
  52     '-4[Resolve IPv4 addresses]' \
  53     '-6[Resolve IPv6 addresses]' \
  54     {-i+,--interface=}'[Look on interface]:interface:_net_interfaces' \
  55     {-p+,--protocol=}'[Look via protocol]:protocol:_systemd-resolve_protocols' \
  56     {-t+,--type=}'[Query RR with DNS type]:type:_systemd-resolve_types' \
  57     {-c+,--class=}'[Query RR with DNS class]:class:_systemd-resolve_classes' \
  58     '--service[Resolve services]' \
  59     '--service-address=no[Do not resolve address for services]' \
  60     '--service-txt=no[Do not resolve TXT records for services]' \
  61     '--openpgp[Query OpenPGP public key]' \
  62     '--tlsa[Query TLS public key]' \
  63     '--cname=no[Do not follow CNAME redirects]' \
  64     '--search=no[Do not use search domains]' \
  65     '--statistics[Show resolver statistics]' \
  66     '--reset-statistics[Reset resolver statistics]' \
  67     '*::default: _systemd-resolve_none'