src/login/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 systemd_logind_sources = files('''
   4         logind.c
   5         logind.h
   6 '''.split())
   7
   8 logind_gperf_c = custom_target(
   9         'logind_gperf.c',
  10         input : 'logind-gperf.gperf',
  11         output : 'logind-gperf.c',
  12         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  13
  14 liblogind_core_sources = files('''
  15         logind-core.c
  16         logind-device.c
  17         logind-device.h
  18         logind-button.c
  19         logind-button.h
  20         logind-action.c
  21         logind-action.h
  22         logind-seat.c
  23         logind-seat.h
  24         logind-session.c
  25         logind-session.h
  26         logind-session-device.c
  27         logind-session-device.h
  28         logind-user.c
  29         logind-user.h
  30         logind-inhibit.c
  31         logind-inhibit.h
  32         logind-dbus.c
  33         logind-session-dbus.c
  34         logind-seat-dbus.c
  35         logind-user-dbus.c
  36         logind-utmp.c
  37         logind-acl.h
  38 '''.split())
  39
  40 liblogind_core_sources += [logind_gperf_c]
  41
  42 logind_acl_c = files('logind-acl.c')
  43 if conf.get('HAVE_ACL') == 1
  44         liblogind_core_sources += logind_acl_c
  45 endif
  46
  47 liblogind_core = static_library(
  48         'logind-core',
  49         liblogind_core_sources,
  50         include_directories : includes,
  51         dependencies : [libacl])
  52
  53 loginctl_sources = files('''
  54         loginctl.c
  55         sysfs-show.h
  56         sysfs-show.c
  57 '''.split())
  58
  59 user_runtime_dir_sources = files('''
  60         user-runtime-dir.c
  61 '''.split())
  62
  63 if conf.get('ENABLE_LOGIND') == 1
  64         logind_conf = configure_file(
  65                 input : 'logind.conf.in',
  66                 output : 'logind.conf',
  67                 configuration : substs)
  68         install_data(logind_conf,
  69                      install_dir : pkgsysconfdir)
  70
  71         pam_systemd_sym = 'src/login/pam_systemd.sym'
  72         pam_systemd_c = files('pam_systemd.c')
  73
  74         install_data('org.freedesktop.login1.conf',
  75                      install_dir : dbuspolicydir)
  76         install_data('org.freedesktop.login1.service',
  77                      install_dir : dbussystemservicedir)
  78         install_data('org.freedesktop.login1.policy',
  79                      install_dir : polkitpolicydir)
  80
  81         install_data('70-power-switch.rules', install_dir : udevrulesdir)
  82
  83         seat_rules = configure_file(
  84                 input : '71-seat.rules.in',
  85                 output : '71-seat.rules',
  86                 configuration : substs)
  87         install_data(seat_rules,
  88                      install_dir : udevrulesdir)
  89
  90         custom_target(
  91                 '70-uaccess.rules',
  92                 input : '70-uaccess.rules.m4',
  93                 output: '70-uaccess.rules',
  94                 command : [meson_apply_m4, config_h, '@INPUT@'],
  95                 capture : true,
  96                 install : conf.get('HAVE_ACL') == 1,
  97                 install_dir : udevrulesdir)
  98
  99         custom_target(
 100                 '73-seat-late.rules',
 101                 input : '73-seat-late.rules.m4',
 102                 output: '73-seat-late.rules',
 103                 command : [meson_apply_m4, config_h, '@INPUT@'],
 104                 capture : true,
 105                 install : true,
 106                 install_dir : udevrulesdir)
 107
 108         custom_target(
 109                 'systemd-user',
 110                 input : 'systemd-user.m4',
 111                 output: 'systemd-user',
 112                 command : [meson_apply_m4, config_h, '@INPUT@'],
 113                 capture : true,
 114                 install : pamconfdir != 'no',
 115                 install_dir : pamconfdir)
 116 endif