src/machine/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 libmachine_core_sources = files(
   4         'image-dbus.c',
   5         'machine-dbus.c',
   6         'machine.c',
   7         'machined-core.c',
   8         'machined-dbus.c',
   9         'machined-varlink.c',
  10         'operation.c',
  11 )
  12
  13 libmachine_core = static_library(
  14         'machine-core',
  15         libmachine_core_sources,
  16         include_directories : includes,
  17         dependencies : [threads,
  18                         userspace],
  19         build_by_default : false)
  20
  21 executables += [
  22         libexec_template + {
  23                 'name' : 'systemd-machined',
  24                 'dbus' : true,
  25                 'conditions' : ['ENABLE_MACHINED'],
  26                 'sources' : files('machined.c'),
  27                 'link_with' : [
  28                         libmachine_core,
  29                         libshared,
  30                 ],
  31         },
  32         executable_template + {
  33                 'name' : 'machinectl',
  34                 'public' : true,
  35                 'conditions' : ['ENABLE_MACHINED'],
  36                 'sources' : files('machinectl.c'),
  37                 'dependencies' : [
  38                         liblz4_cflags,
  39                         libxz_cflags,
  40                         libzstd_cflags,
  41                         threads,
  42                 ],
  43         },
  44         test_template + {
  45                 'sources' : files('test-machine-tables.c'),
  46                 'link_with': [
  47                         libmachine_core,
  48                         libshared
  49                 ],
  50                 'dependencies': threads,
  51         },
  52 ]
  53
  54 if conf.get('ENABLE_MACHINED') == 1
  55         install_data('org.freedesktop.machine1.conf',
  56                      install_dir : dbuspolicydir)
  57         install_data('org.freedesktop.machine1.service',
  58                      install_dir : dbussystemservicedir)
  59         install_data('org.freedesktop.machine1.policy',
  60                      install_dir : polkitpolicydir)
  61 endif