src/resolve/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 basic_dns_sources = files('''
   4         resolved-dns-dnssec.c
   5         resolved-dns-dnssec.h
   6         resolved-dns-packet.c
   7         resolved-dns-packet.h
   8         resolved-dns-rr.c
   9         resolved-dns-rr.h
  10         resolved-dns-answer.c
  11         resolved-dns-answer.h
  12         resolved-dns-question.c
  13         resolved-dns-question.h
  14         dns-type.c
  15 '''.split())
  16
  17 dns_type_h = files('dns-type.h')[0]
  18
  19 systemd_resolved_sources = files('''
  20         resolved.c
  21         resolved-manager.c
  22         resolved-manager.h
  23         resolved-dnssd.c
  24         resolved-dnssd.h
  25         resolved-dnssd-bus.c
  26         resolved-dnssd-bus.h
  27         resolved-conf.c
  28         resolved-conf.h
  29         resolved-resolv-conf.c
  30         resolved-resolv-conf.h
  31         resolved-bus.c
  32         resolved-bus.h
  33         resolved-link.h
  34         resolved-link.c
  35         resolved-link-bus.c
  36         resolved-link-bus.h
  37         resolved-llmnr.h
  38         resolved-llmnr.c
  39         resolved-mdns.h
  40         resolved-mdns.c
  41         resolved-def.h
  42         resolved-dns-query.h
  43         resolved-dns-query.c
  44         resolved-dns-synthesize.h
  45         resolved-dns-synthesize.c
  46         resolved-dns-transaction.h
  47         resolved-dns-transaction.c
  48         resolved-dns-scope.h
  49         resolved-dns-scope.c
  50         resolved-dns-server.h
  51         resolved-dns-server.c
  52         resolved-dns-search-domain.h
  53         resolved-dns-search-domain.c
  54         resolved-dns-cache.h
  55         resolved-dns-cache.c
  56         resolved-dns-zone.h
  57         resolved-dns-zone.c
  58         resolved-dns-stream.h
  59         resolved-dns-stream.c
  60         resolved-dns-trust-anchor.h
  61         resolved-dns-trust-anchor.c
  62         resolved-dns-stub.h
  63         resolved-dns-stub.c
  64         resolved-etc-hosts.h
  65         resolved-etc-hosts.c
  66         resolved-dnstls.h
  67 '''.split())
  68
  69 resolvectl_sources = files('''
  70          resolvconf-compat.c
  71          resolvconf-compat.h
  72          resolvectl.c
  73          resolvectl.h
  74 '''.split())
  75
  76 ############################################################
  77
  78 dns_type_list_txt = custom_target(
  79         'dns_type-list.txt',
  80         input : ['generate-dns_type-list.sed', dns_type_h],
  81         output : 'dns_type-list.txt',
  82         command : [sed, '-n', '-r', '-f', '@INPUT0@', '@INPUT1@'],
  83         capture : true)
  84
  85 generate_dns_type_gperf = find_program('generate-dns_type-gperf.py')
  86
  87 dns_type_headers = [dns_type_h]
  88 foreach item : [['dns_type', dns_type_list_txt, 'dns_type', 'DNS_TYPE_']]
  89
  90         fname = '@0@-from-name.gperf'.format(item[0])
  91         gperf_file = custom_target(
  92                 fname,
  93                 input : item[1],
  94                 output : fname,
  95                 command : [generate_dns_type_gperf, item[2], item[3], '@INPUT@'],
  96                 capture : true)
  97
  98         fname = '@0@-from-name.h'.format(item[0])
  99         target1 = custom_target(
 100                 fname,
 101                 input : gperf_file,
 102                 output : fname,
 103                 command : [gperf,
 104                            '-L', 'ANSI-C', '-t', '--ignore-case',
 105                            '-N', 'lookup_@0@'.format(item[2]),
 106                            '-H', 'hash_@0@_name'.format(item[2]),
 107                            '-p', '-C',
 108                            '@INPUT@'],
 109                 capture : true)
 110
 111         fname = '@0@-to-name.h'.format(item[0])
 112         awkscript = '@0@-to-name.awk'.format(item[0])
 113         target2 = custom_target(
 114                 fname,
 115                 input : [awkscript, item[1]],
 116                 output : fname,
 117                 command : [awk, '-f', '@INPUT0@', '@INPUT1@'],
 118                 capture : true)
 119
 120         dns_type_headers += [target1, target2]
 121 endforeach
 122
 123 resolved_gperf_c = custom_target(
 124         'resolved_gperf.c',
 125         input : 'resolved-gperf.gperf',
 126         output : 'resolved-gperf.c',
 127         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 128
 129 resolved_dnssd_gperf_c = custom_target(
 130         'resolved_dnssd_gperf.c',
 131         input : 'resolved-dnssd-gperf.gperf',
 132         output : 'resolved-dnssd-gperf.c',
 133         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 134
 135 libsystemd_resolve_core = static_library(
 136         'systemd-resolve-core',
 137         basic_dns_sources,
 138         dns_type_headers,
 139         include_directories : includes)
 140
 141 systemd_resolved_sources += [resolved_gperf_c, resolved_dnssd_gperf_c]
 142
 143 systemd_resolved_dependencies = [threads, libgpg_error, libm, libidn]
 144 if conf.get('ENABLE_DNS_OVER_TLS') == 1
 145         if conf.get('DNS_OVER_TLS_USE_GNUTLS') == 1
 146                 systemd_resolved_sources += [files(['resolved-dnstls-gnutls.c', 'resolved-dnstls-gnutls.h'])]
 147                 systemd_resolved_dependencies += [libgnutls]
 148         elif conf.get('DNS_OVER_TLS_USE_OPENSSL') == 1
 149                 systemd_resolved_sources += [files(['resolved-dnstls-openssl.c', 'resolved-dnstls-openssl.h'])]
 150                 systemd_resolved_dependencies += [libopenssl]
 151         else
 152                 error('unknown dependency for supporting DNS-over-TLS')
 153         endif
 154 endif
 155
 156 if conf.get('ENABLE_RESOLVE') == 1
 157         install_data('org.freedesktop.resolve1.conf',
 158                      install_dir : dbuspolicydir)
 159         install_data('org.freedesktop.resolve1.service',
 160                      install_dir : dbussystemservicedir)
 161         install_data('org.freedesktop.resolve1.policy',
 162                      install_dir : polkitpolicydir)
 163
 164         resolved_conf = configure_file(
 165                 input : 'resolved.conf.in',
 166                 output : 'resolved.conf',
 167                 configuration : substs)
 168         install_data(resolved_conf,
 169                      install_dir : pkgsysconfdir)
 170
 171         install_data('resolv.conf',
 172                      install_dir : rootlibexecdir)
 173 endif
 174
 175 tests += [
 176         [['src/resolve/test-resolve-tables.c',
 177           dns_type_headers,
 178           'src/shared/test-tables.h'],
 179          [libsystemd_resolve_core,
 180           libshared],
 181          [libgcrypt,
 182           libgpg_error,
 183           libm],
 184          'ENABLE_RESOLVE'],
 185
 186         [['src/resolve/test-dns-packet.c',
 187           dns_type_headers],
 188          [libsystemd_resolve_core,
 189           libshared],
 190          [libgcrypt,
 191           libgpg_error,
 192           libm],
 193          'ENABLE_RESOLVE'],
 194
 195         [['src/resolve/test-resolved-packet.c',
 196           dns_type_headers],
 197          [libsystemd_resolve_core,
 198           libshared],
 199          [libgcrypt,
 200           libgpg_error,
 201           libm],
 202          'ENABLE_RESOLVE'],
 203
 204         [['src/resolve/test-dnssec.c',
 205           dns_type_headers],
 206          [libsystemd_resolve_core,
 207           libshared],
 208          [libgcrypt,
 209           libgpg_error,
 210           libm],
 211          'ENABLE_RESOLVE'],
 212
 213         [['src/resolve/test-dnssec-complex.c',
 214           'src/resolve/dns-type.c',
 215           dns_type_headers],
 216          [],
 217          [],
 218          'ENABLE_RESOLVE', 'manual'],
 219 ]