src/resolve/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4 #
   5 # systemd is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU Lesser General Public License as published by
   7 # the Free Software Foundation; either version 2.1 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # systemd is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 # Lesser General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU Lesser General Public License
  16 # along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 basic_dns_sources = files('''
  19         resolved-dns-dnssec.c
  20         resolved-dns-dnssec.h
  21         resolved-dns-packet.c
  22         resolved-dns-packet.h
  23         resolved-dns-rr.c
  24         resolved-dns-rr.h
  25         resolved-dns-answer.c
  26         resolved-dns-answer.h
  27         resolved-dns-question.c
  28         resolved-dns-question.h
  29         dns-type.c
  30 '''.split())
  31
  32 dns_type_h = files('dns-type.h')[0]
  33
  34 systemd_resolved_only_sources = files('''
  35         resolved.c
  36         resolved-manager.c
  37         resolved-manager.h
  38         resolved-dnssd.c
  39         resolved-dnssd.h
  40         resolved-dnssd-bus.c
  41         resolved-dnssd-bus.h
  42         resolved-conf.c
  43         resolved-conf.h
  44         resolved-resolv-conf.c
  45         resolved-resolv-conf.h
  46         resolved-bus.c
  47         resolved-bus.h
  48         resolved-link.h
  49         resolved-link.c
  50         resolved-link-bus.c
  51         resolved-link-bus.h
  52         resolved-llmnr.h
  53         resolved-llmnr.c
  54         resolved-mdns.h
  55         resolved-mdns.c
  56         resolved-def.h
  57         resolved-dns-query.h
  58         resolved-dns-query.c
  59         resolved-dns-synthesize.h
  60         resolved-dns-synthesize.c
  61         resolved-dns-transaction.h
  62         resolved-dns-transaction.c
  63         resolved-dns-scope.h
  64         resolved-dns-scope.c
  65         resolved-dns-server.h
  66         resolved-dns-server.c
  67         resolved-dns-search-domain.h
  68         resolved-dns-search-domain.c
  69         resolved-dns-cache.h
  70         resolved-dns-cache.c
  71         resolved-dns-zone.h
  72         resolved-dns-zone.c
  73         resolved-dns-stream.h
  74         resolved-dns-stream.c
  75         resolved-dns-trust-anchor.h
  76         resolved-dns-trust-anchor.c
  77         resolved-dns-stub.h
  78         resolved-dns-stub.c
  79         resolved-etc-hosts.h
  80         resolved-etc-hosts.c
  81 '''.split())
  82
  83 systemd_resolve_only_sources = files('resolve-tool.c')
  84
  85 ############################################################
  86
  87 dns_type_list_txt = custom_target(
  88         'dns_type-list.txt',
  89         input : ['generate-dns_type-list.sed', dns_type_h],
  90         output : 'dns_type-list.txt',
  91         command : [sed, '-n', '-r', '-f', '@INPUT0@', '@INPUT1@'],
  92         capture : true)
  93
  94 generate_dns_type_gperf = find_program('generate-dns_type-gperf.py')
  95
  96 dns_type_headers = [dns_type_h]
  97 foreach item : [['dns_type', dns_type_list_txt, 'dns_type', 'DNS_TYPE_']]
  98
  99         fname = '@0@-from-name.gperf'.format(item[0])
 100         gperf_file = custom_target(
 101                 fname,
 102                 input : item[1],
 103                 output : fname,
 104                 command : [generate_dns_type_gperf, item[2], item[3], '@INPUT@'],
 105                 capture : true)
 106
 107         fname = '@0@-from-name.h'.format(item[0])
 108         target1 = custom_target(
 109                 fname,
 110                 input : gperf_file,
 111                 output : fname,
 112                 command : [gperf,
 113                            '-L', 'ANSI-C', '-t', '--ignore-case',
 114                            '-N', 'lookup_@0@'.format(item[2]),
 115                            '-H', 'hash_@0@_name'.format(item[2]),
 116                            '-p', '-C',
 117                            '@INPUT@'],
 118                 capture : true)
 119
 120         fname = '@0@-to-name.h'.format(item[0])
 121         awkscript = '@0@-to-name.awk'.format(item[0])
 122         target2 = custom_target(
 123                 fname,
 124                 input : [awkscript, item[1]],
 125                 output : fname,
 126                 command : [awk, '-f', '@INPUT0@', '@INPUT1@'],
 127                 capture : true)
 128
 129         dns_type_headers += [target1, target2]
 130 endforeach
 131
 132 resolved_gperf_c = custom_target(
 133         'resolved_gperf.c',
 134         input : 'resolved-gperf.gperf',
 135         output : 'resolved-gperf.c',
 136         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 137
 138 resolved_dnssd_gperf_c = custom_target(
 139         'resolved_dnssd_gperf.c',
 140         input : 'resolved-dnssd-gperf.gperf',
 141         output : 'resolved-dnssd-gperf.c',
 142         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 143
 144 systemd_resolved_sources = (basic_dns_sources +
 145                             [resolved_gperf_c, resolved_dnssd_gperf_c] +
 146                             systemd_resolved_only_sources +
 147                             dns_type_headers)
 148
 149 systemd_resolve_sources = (basic_dns_sources +
 150                            systemd_resolve_only_sources +
 151                            dns_type_headers)
 152
 153 if conf.get('ENABLE_RESOLVE') == 1
 154         install_data('org.freedesktop.resolve1.conf',
 155                      install_dir : dbuspolicydir)
 156         install_data('org.freedesktop.resolve1.service',
 157                      install_dir : dbussystemservicedir)
 158
 159         resolved_conf = configure_file(
 160                 input : 'resolved.conf.in',
 161                 output : 'resolved.conf',
 162                 configuration : substs)
 163         install_data(resolved_conf,
 164                      install_dir : pkgsysconfdir)
 165
 166         install_data('resolv.conf',
 167                      install_dir : rootlibexecdir)
 168
 169         i18n.merge_file(
 170                 'org.freedesktop.resolve1.policy',
 171                 input : 'org.freedesktop.resolve1.policy.in',
 172                 output : 'org.freedesktop.resolve1.policy',
 173                 po_dir : po_dir,
 174                 data_dirs : po_dir,
 175                 install : install_polkit,
 176                 install_dir : polkitpolicydir)
 177 endif
 178
 179 tests += [
 180         [['src/resolve/test-resolve-tables.c',
 181           basic_dns_sources,
 182           dns_type_headers,
 183           'src/shared/test-tables.h'],
 184          [],
 185          [libgcrypt,
 186           libgpg_error,
 187           libm],
 188          'ENABLE_RESOLVE'],
 189
 190         [['src/resolve/test-dns-packet.c',
 191           basic_dns_sources,
 192           dns_type_headers],
 193          [],
 194          [libgcrypt,
 195           libgpg_error,
 196           libm],
 197          'ENABLE_RESOLVE'],
 198
 199         [['src/resolve/test-resolved-packet.c',
 200           basic_dns_sources,
 201           dns_type_headers],
 202          [],
 203          [libgcrypt,
 204           libgpg_error,
 205           libm],
 206          'ENABLE_RESOLVE'],
 207
 208         [['src/resolve/test-dnssec.c',
 209           basic_dns_sources,
 210           dns_type_headers],
 211          [],
 212          [libgcrypt,
 213           libgpg_error,
 214           libm],
 215          'ENABLE_RESOLVE'],
 216
 217         [['src/resolve/test-dnssec-complex.c',
 218           'src/resolve/dns-type.c',
 219           dns_type_headers],
 220          [],
 221          [],
 222          'ENABLE_RESOLVE', 'manual'],
 223 ]