src/resolve/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4
   5 basic_dns_sources = files('''
   6         resolved-dns-dnssec.c
   7         resolved-dns-dnssec.h
   8         resolved-dns-packet.c
   9         resolved-dns-packet.h
  10         resolved-dns-rr.c
  11         resolved-dns-rr.h
  12         resolved-dns-answer.c
  13         resolved-dns-answer.h
  14         resolved-dns-question.c
  15         resolved-dns-question.h
  16         dns-type.c
  17 '''.split())
  18
  19 dns_type_h = files('dns-type.h')[0]
  20
  21 systemd_resolved_sources = files('''
  22         resolved.c
  23         resolved-manager.c
  24         resolved-manager.h
  25         resolved-dnssd.c
  26         resolved-dnssd.h
  27         resolved-dnssd-bus.c
  28         resolved-dnssd-bus.h
  29         resolved-conf.c
  30         resolved-conf.h
  31         resolved-resolv-conf.c
  32         resolved-resolv-conf.h
  33         resolved-bus.c
  34         resolved-bus.h
  35         resolved-link.h
  36         resolved-link.c
  37         resolved-link-bus.c
  38         resolved-link-bus.h
  39         resolved-llmnr.h
  40         resolved-llmnr.c
  41         resolved-mdns.h
  42         resolved-mdns.c
  43         resolved-def.h
  44         resolved-dns-query.h
  45         resolved-dns-query.c
  46         resolved-dns-synthesize.h
  47         resolved-dns-synthesize.c
  48         resolved-dns-transaction.h
  49         resolved-dns-transaction.c
  50         resolved-dns-scope.h
  51         resolved-dns-scope.c
  52         resolved-dns-server.h
  53         resolved-dns-server.c
  54         resolved-dns-search-domain.h
  55         resolved-dns-search-domain.c
  56         resolved-dns-cache.h
  57         resolved-dns-cache.c
  58         resolved-dns-zone.h
  59         resolved-dns-zone.c
  60         resolved-dns-stream.h
  61         resolved-dns-stream.c
  62         resolved-dns-trust-anchor.h
  63         resolved-dns-trust-anchor.c
  64         resolved-dns-stub.h
  65         resolved-dns-stub.c
  66         resolved-etc-hosts.h
  67         resolved-etc-hosts.c
  68 '''.split())
  69
  70 resolvectl_sources = files('''
  71          resolvconf-compat.c
  72          resolvconf-compat.h
  73          resolvectl.c
  74          resolvectl.h
  75 '''.split())
  76
  77 ############################################################
  78
  79 dns_type_list_txt = custom_target(
  80         'dns_type-list.txt',
  81         input : ['generate-dns_type-list.sed', dns_type_h],
  82         output : 'dns_type-list.txt',
  83         command : [sed, '-n', '-r', '-f', '@INPUT0@', '@INPUT1@'],
  84         capture : true)
  85
  86 generate_dns_type_gperf = find_program('generate-dns_type-gperf.py')
  87
  88 dns_type_headers = [dns_type_h]
  89 foreach item : [['dns_type', dns_type_list_txt, 'dns_type', 'DNS_TYPE_']]
  90
  91         fname = '@0@-from-name.gperf'.format(item[0])
  92         gperf_file = custom_target(
  93                 fname,
  94                 input : item[1],
  95                 output : fname,
  96                 command : [generate_dns_type_gperf, item[2], item[3], '@INPUT@'],
  97                 capture : true)
  98
  99         fname = '@0@-from-name.h'.format(item[0])
 100         target1 = custom_target(
 101                 fname,
 102                 input : gperf_file,
 103                 output : fname,
 104                 command : [gperf,
 105                            '-L', 'ANSI-C', '-t', '--ignore-case',
 106                            '-N', 'lookup_@0@'.format(item[2]),
 107                            '-H', 'hash_@0@_name'.format(item[2]),
 108                            '-p', '-C',
 109                            '@INPUT@'],
 110                 capture : true)
 111
 112         fname = '@0@-to-name.h'.format(item[0])
 113         awkscript = '@0@-to-name.awk'.format(item[0])
 114         target2 = custom_target(
 115                 fname,
 116                 input : [awkscript, item[1]],
 117                 output : fname,
 118                 command : [awk, '-f', '@INPUT0@', '@INPUT1@'],
 119                 capture : true)
 120
 121         dns_type_headers += [target1, target2]
 122 endforeach
 123
 124 resolved_gperf_c = custom_target(
 125         'resolved_gperf.c',
 126         input : 'resolved-gperf.gperf',
 127         output : 'resolved-gperf.c',
 128         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 129
 130 resolved_dnssd_gperf_c = custom_target(
 131         'resolved_dnssd_gperf.c',
 132         input : 'resolved-dnssd-gperf.gperf',
 133         output : 'resolved-dnssd-gperf.c',
 134         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 135
 136 libsystemd_resolve_core = static_library(
 137         'systemd-resolve-core',
 138         basic_dns_sources,
 139         dns_type_headers,
 140         include_directories : includes)
 141
 142 systemd_resolved_sources += [resolved_gperf_c, resolved_dnssd_gperf_c]
 143
 144 if conf.get('ENABLE_RESOLVE') == 1
 145         install_data('org.freedesktop.resolve1.conf',
 146                      install_dir : dbuspolicydir)
 147         install_data('org.freedesktop.resolve1.service',
 148                      install_dir : dbussystemservicedir)
 149         install_data('org.freedesktop.resolve1.policy',
 150                      install_dir : polkitpolicydir)
 151
 152         resolved_conf = configure_file(
 153                 input : 'resolved.conf.in',
 154                 output : 'resolved.conf',
 155                 configuration : substs)
 156         install_data(resolved_conf,
 157                      install_dir : pkgsysconfdir)
 158
 159         install_data('resolv.conf',
 160                      install_dir : rootlibexecdir)
 161 endif
 162
 163 tests += [
 164         [['src/resolve/test-resolve-tables.c',
 165           dns_type_headers,
 166           'src/shared/test-tables.h'],
 167          [libsystemd_resolve_core,
 168           libshared],
 169          [libgcrypt,
 170           libgpg_error,
 171           libm],
 172          'ENABLE_RESOLVE'],
 173
 174         [['src/resolve/test-dns-packet.c',
 175           dns_type_headers],
 176          [libsystemd_resolve_core,
 177           libshared],
 178          [libgcrypt,
 179           libgpg_error,
 180           libm],
 181          'ENABLE_RESOLVE'],
 182
 183         [['src/resolve/test-resolved-packet.c',
 184           dns_type_headers],
 185          [libsystemd_resolve_core,
 186           libshared],
 187          [libgcrypt,
 188           libgpg_error,
 189           libm],
 190          'ENABLE_RESOLVE'],
 191
 192         [['src/resolve/test-dnssec.c',
 193           dns_type_headers],
 194          [libsystemd_resolve_core,
 195           libshared],
 196          [libgcrypt,
 197           libgpg_error,
 198           libm],
 199          'ENABLE_RESOLVE'],
 200
 201         [['src/resolve/test-dnssec-complex.c',
 202           'src/resolve/dns-type.c',
 203           dns_type_headers],
 204          [],
 205          [],
 206          'ENABLE_RESOLVE', 'manual'],
 207 ]