src/udev/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4
   5 udevadm_sources = files('''
   6         udevadm.c
   7         udevadm-info.c
   8         udevadm-control.c
   9         udevadm-monitor.c
  10         udevadm-hwdb.c
  11         udevadm-settle.c
  12         udevadm-trigger.c
  13         udevadm-test.c
  14         udevadm-test-builtin.c
  15         udevadm-util.c
  16         udevadm-util.h
  17 '''.split())
  18
  19 systemd_udevd_sources = files('udevd.c')
  20
  21 libudev_core_sources = '''
  22         udev.h
  23         udev-event.c
  24         udev-watch.c
  25         udev-node.c
  26         udev-rules.c
  27         udev-ctrl.c
  28         udev-builtin.c
  29         udev-builtin-btrfs.c
  30         udev-builtin-hwdb.c
  31         udev-builtin-input_id.c
  32         udev-builtin-keyboard.c
  33         udev-builtin-net_id.c
  34         udev-builtin-net_setup_link.c
  35         udev-builtin-path_id.c
  36         udev-builtin-usb_id.c
  37         net/link-config.c
  38         net/link-config.h
  39         net/ethtool-util.c
  40         net/ethtool-util.h
  41 '''.split()
  42
  43 if conf.get('HAVE_KMOD') == 1
  44         libudev_core_sources += ['udev-builtin-kmod.c']
  45 endif
  46
  47 if conf.get('HAVE_BLKID') == 1
  48         libudev_core_sources += ['udev-builtin-blkid.c']
  49 endif
  50
  51 if conf.get('HAVE_ACL') == 1
  52         libudev_core_sources += ['udev-builtin-uaccess.c',
  53                                  logind_acl_c,
  54                                  sd_login_c]
  55 endif
  56
  57 ############################################################
  58
  59 generate_keyboard_keys_list = find_program('generate-keyboard-keys-list.sh')
  60 keyboard_keys_list_txt = custom_target(
  61         'keyboard-keys-list.txt',
  62         output : 'keyboard-keys-list.txt',
  63         command : [generate_keyboard_keys_list, cpp],
  64         capture : true)
  65
  66 generate_keyboard_keys_gperf = find_program('generate-keyboard-keys-gperf.sh')
  67 fname = 'keyboard-keys-from-name.gperf'
  68 gperf_file = custom_target(
  69         fname,
  70         input : keyboard_keys_list_txt,
  71         output : fname,
  72         command : [generate_keyboard_keys_gperf, '@INPUT@'],
  73         capture : true)
  74
  75 fname = 'keyboard-keys-from-name.h'
  76 keyboard_keys_from_name_h = custom_target(
  77         fname,
  78         input : gperf_file,
  79         output : fname,
  80         command : [gperf,
  81                    '-L', 'ANSI-C', '-t',
  82                    '-N', 'keyboard_lookup_key',
  83                    '-H', 'hash_key_name',
  84                    '-p', '-C',
  85                    '@INPUT@'],
  86         capture : true)
  87
  88 ############################################################
  89
  90 link_config_gperf_c = custom_target(
  91         'link-config-gperf.c',
  92         input : 'net/link-config-gperf.gperf',
  93         output : 'link-config-gperf.c',
  94         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  95
  96 ############################################################
  97
  98 if get_option('link-udev-shared')
  99         udev_link_with = [libshared]
 100         udev_rpath = rootlibexecdir
 101 else
 102         udev_link_with = [libshared_static,
 103                           libsystemd_static]
 104         udev_rpath = ''
 105 endif
 106
 107 libudev_basic = static_library(
 108         'udev-basic',
 109         libudev_sources,
 110         include_directories : includes,
 111         c_args : ['-fvisibility=default'])
 112
 113 libudev_static = static_library(
 114         'udev',
 115         'udev.h',
 116         include_directories : includes,
 117         link_with : udev_link_with,
 118         link_whole : libudev_basic)
 119
 120 libudev = shared_library(
 121         'udev',
 122         'udev.h', # pick a header file at random to work around old meson bug
 123         version : libudev_version,
 124         include_directories : includes,
 125         link_args : ['-shared',
 126                      '-Wl,--version-script=' + libudev_sym_path],
 127         link_with : [libsystemd_static, libshared_static],
 128         link_whole : libudev_basic,
 129         dependencies : [threads],
 130         link_depends : libudev_sym,
 131         install : true,
 132         install_dir : rootlibdir)
 133
 134 libudev_core_includes = [includes, include_directories('net')]
 135 libudev_core = static_library(
 136         'udev-core',
 137         libudev_core_sources,
 138         link_config_gperf_c,
 139         keyboard_keys_from_name_h,
 140         include_directories : libudev_core_includes,
 141         c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 142         link_with : udev_link_with,
 143         dependencies : [libblkid, libkmod])
 144
 145 foreach prog : [['ata_id/ata_id.c'],
 146                 ['cdrom_id/cdrom_id.c'],
 147                 ['collect/collect.c'],
 148                 ['scsi_id/scsi_id.c',
 149                  'scsi_id/scsi_id.h',
 150                  'scsi_id/scsi_serial.c',
 151                  'scsi_id/scsi.h'],
 152                 ['v4l_id/v4l_id.c'],
 153                 ['mtd_probe/mtd_probe.c',
 154                  'mtd_probe/mtd_probe.h',
 155                  'mtd_probe/probe_smartmedia.c']]
 156
 157         executable(prog[0].split('/')[0],
 158                    prog,
 159                    include_directories : includes,
 160                    c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 161                    link_with : [libudev_static],
 162                    install_rpath : udev_rpath,
 163                    install : true,
 164                    install_dir : udevlibexecdir)
 165 endforeach
 166
 167 install_data('udev.conf',
 168              install_dir : join_paths(sysconfdir, 'udev'))
 169
 170 udev_pc = configure_file(
 171         input : 'udev.pc.in',
 172         output : 'udev.pc',
 173         configuration : substs)
 174 install_data(udev_pc,
 175              install_dir : pkgconfigdatadir)
 176
 177 meson.add_install_script('sh', '-c',
 178                          mkdir_p.format(join_paths(sysconfdir, 'udev/rules.d')))