src/udev/meson.build

   1 udevadm_sources = files('''
   2         udevadm.c
   3         udevadm-info.c
   4         udevadm-control.c
   5         udevadm-monitor.c
   6         udevadm-hwdb.c
   7         udevadm-settle.c
   8         udevadm-trigger.c
   9         udevadm-test.c
  10         udevadm-test-builtin.c
  11         udevadm-util.c
  12         udevadm-util.h
  13 '''.split())
  14
  15 systemd_udevd_sources = files('udevd.c')
  16
  17 libudev_core_sources = '''
  18         udev.h
  19         udev-event.c
  20         udev-watch.c
  21         udev-node.c
  22         udev-rules.c
  23         udev-ctrl.c
  24         udev-builtin.c
  25         udev-builtin-btrfs.c
  26         udev-builtin-hwdb.c
  27         udev-builtin-input_id.c
  28         udev-builtin-keyboard.c
  29         udev-builtin-net_id.c
  30         udev-builtin-net_setup_link.c
  31         udev-builtin-path_id.c
  32         udev-builtin-usb_id.c
  33         net/link-config.c
  34         net/link-config.h
  35         net/ethtool-util.c
  36         net/ethtool-util.h
  37 '''.split()
  38
  39 if conf.get('HAVE_KMOD') == 1
  40         libudev_core_sources += ['udev-builtin-kmod.c']
  41 endif
  42
  43 if conf.get('HAVE_BLKID') == 1
  44         libudev_core_sources += ['udev-builtin-blkid.c']
  45 endif
  46
  47 if conf.get('HAVE_ACL') == 1
  48         libudev_core_sources += ['udev-builtin-uaccess.c',
  49                                  logind_acl_c,
  50                                  sd_login_c]
  51 endif
  52
  53 ############################################################
  54
  55 generate_keyboard_keys_list = find_program('generate-keyboard-keys-list.sh')
  56 keyboard_keys_list_txt = custom_target(
  57         'keyboard-keys-list.txt',
  58         output : 'keyboard-keys-list.txt',
  59         command : [generate_keyboard_keys_list, cpp],
  60         capture : true)
  61
  62 generate_keyboard_keys_gperf = find_program('generate-keyboard-keys-gperf.sh')
  63 fname = 'keyboard-keys-from-name.gperf'
  64 gperf_file = custom_target(
  65         fname,
  66         input : keyboard_keys_list_txt,
  67         output : fname,
  68         command : [generate_keyboard_keys_gperf, '@INPUT@'],
  69         capture : true)
  70
  71 fname = 'keyboard-keys-from-name.h'
  72 keyboard_keys_from_name_h = custom_target(
  73         fname,
  74         input : gperf_file,
  75         output : fname,
  76         command : [gperf,
  77                    '-L', 'ANSI-C', '-t',
  78                    '-N', 'keyboard_lookup_key',
  79                    '-H', 'hash_key_name',
  80                    '-p', '-C',
  81                    '@INPUT@'],
  82         capture : true)
  83
  84 ############################################################
  85
  86 link_config_gperf_c = custom_target(
  87         'link-config-gperf.c',
  88         input : 'net/link-config-gperf.gperf',
  89         output : 'link-config-gperf.c',
  90         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  91
  92 ############################################################
  93
  94 if get_option('link-udev-shared')
  95         udev_link_with = [libshared]
  96         udev_rpath = rootlibexecdir
  97 else
  98         udev_link_with = [libshared_static,
  99                           libsystemd_internal]
 100         udev_rpath = ''
 101 endif
 102
 103 libudev_internal = static_library(
 104         'udev',
 105         libudev_sources,
 106         include_directories : includes,
 107         link_with : udev_link_with)
 108
 109 libudev_core_includes = [includes, include_directories('net')]
 110 libudev_core = static_library(
 111         'udev-core',
 112         libudev_core_sources,
 113         link_config_gperf_c,
 114         keyboard_keys_from_name_h,
 115         include_directories : libudev_core_includes,
 116         link_with : udev_link_with,
 117         dependencies : [libblkid, libkmod])
 118
 119 foreach prog : [['ata_id/ata_id.c'],
 120                 ['cdrom_id/cdrom_id.c'],
 121                 ['collect/collect.c'],
 122                 ['scsi_id/scsi_id.c',
 123                  'scsi_id/scsi_id.h',
 124                  'scsi_id/scsi_serial.c',
 125                  'scsi_id/scsi.h'],
 126                 ['v4l_id/v4l_id.c'],
 127                 ['mtd_probe/mtd_probe.c',
 128                  'mtd_probe/mtd_probe.h',
 129                  'mtd_probe/probe_smartmedia.c']]
 130
 131         executable(prog[0].split('/')[0],
 132                    prog,
 133                    include_directories : includes,
 134                    c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 135                    link_with : [libudev_internal],
 136                    install_rpath : udev_rpath,
 137                    install : true,
 138                    install_dir : udevlibexecdir)
 139 endforeach
 140
 141 install_data('udev.conf',
 142              install_dir : join_paths(sysconfdir, 'udev'))
 143
 144 udev_pc = configure_file(
 145         input : 'udev.pc.in',
 146         output : 'udev.pc',
 147         configuration : substs)
 148 install_data(udev_pc,
 149              install_dir : pkgconfigdatadir)
 150
 151 meson.add_install_script('sh', '-c',
 152                          mkdir_p.format(join_paths(sysconfdir, 'udev/rules.d')))