units/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4
   5 units = [
   6         ['basic.target',                        ''],
   7         ['bluetooth.target',                    ''],
   8         ['cryptsetup-pre.target',               'HAVE_LIBCRYPTSETUP'],
   9         ['cryptsetup.target',                   'HAVE_LIBCRYPTSETUP',
  10          'sysinit.target.wants/'],
  11         ['dev-hugepages.mount',                 '',
  12          'sysinit.target.wants/'],
  13         ['dev-mqueue.mount',                    '',
  14          'sysinit.target.wants/'],
  15         ['emergency.target',                    ''],
  16         ['exit.target',                         ''],
  17         ['final.target',                        ''],
  18         ['getty.target',                        '',
  19          'multi-user.target.wants/'],
  20         ['getty-pre.target',                    ''],
  21         ['graphical.target',                    '',
  22          'runlevel5.target default.target'],
  23         ['halt.target',                         ''],
  24         ['hibernate.target',                    'ENABLE_HIBERNATE'],
  25         ['hybrid-sleep.target',                 'ENABLE_HIBERNATE'],
  26         ['suspend-then-hibernate.target',         'ENABLE_HIBERNATE'],
  27         ['initrd-fs.target',                    ''],
  28         ['initrd-root-device.target',           ''],
  29         ['initrd-root-fs.target',               ''],
  30         ['initrd-switch-root.target',           ''],
  31         ['initrd.target',                       ''],
  32         ['kexec.target',                        ''],
  33         ['ldconfig.service',                    'ENABLE_LDCONFIG',
  34          'sysinit.target.wants/'],
  35         ['local-fs-pre.target',                 ''],
  36         ['local-fs.target',                     ''],
  37         ['machine.slice',                       'ENABLE_MACHINED'],
  38         ['machines.target',                     'ENABLE_MACHINED',
  39          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
  40         ['multi-user.target',                   '',
  41          'runlevel2.target runlevel3.target runlevel4.target'],
  42         ['network-online.target',               ''],
  43         ['network-pre.target',                  ''],
  44         ['network.target',                      ''],
  45         ['nss-lookup.target',                   ''],
  46         ['nss-user-lookup.target',              ''],
  47         ['paths.target',                        ''],
  48         ['poweroff.target',                     '',
  49          'runlevel0.target'],
  50         ['printer.target',                      ''],
  51         ['proc-sys-fs-binfmt_misc.automount',   'ENABLE_BINFMT',
  52          'sysinit.target.wants/'],
  53         ['proc-sys-fs-binfmt_misc.mount',       'ENABLE_BINFMT'],
  54         ['reboot.target',                       '',
  55          'runlevel6.target ctrl-alt-del.target'],
  56         ['remote-cryptsetup.target',            'HAVE_LIBCRYPTSETUP',
  57          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
  58         ['remote-fs-pre.target',                ''],
  59         ['remote-fs.target',                    '',
  60          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
  61         ['rescue.target',                       '',
  62          'runlevel1.target'],
  63         ['rpcbind.target',                      ''],
  64         ['shutdown.target',                     ''],
  65         ['sigpwr.target',                       ''],
  66         ['sleep.target',                        ''],
  67         ['slices.target',                       ''],
  68         ['smartcard.target',                    ''],
  69         ['sockets.target',                      ''],
  70         ['sound.target',                        ''],
  71         ['suspend.target',                      ''],
  72         ['swap.target',                         ''],
  73         ['sys-fs-fuse-connections.mount',       '',
  74          'sysinit.target.wants/'],
  75         ['sys-kernel-config.mount',             '',
  76          'sysinit.target.wants/'],
  77         ['sys-kernel-debug.mount',              '',
  78          'sysinit.target.wants/'],
  79         ['sysinit.target',                      ''],
  80         ['syslog.socket',                       ''],
  81         ['system-update.target',                ''],
  82         ['systemd-ask-password-console.path',   '',
  83          'sysinit.target.wants/'],
  84         ['systemd-ask-password-wall.path',      '',
  85          'multi-user.target.wants/'],
  86         ['systemd-coredump.socket',             'ENABLE_COREDUMP',
  87          'sockets.target.wants/'],
  88         ['systemd-initctl.socket',              '',
  89          'sockets.target.wants/'],
  90         ['systemd-journal-gatewayd.socket',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
  91         ['systemd-journal-remote.socket',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
  92         ['systemd-journald-audit.socket',       '',
  93          'sockets.target.wants/'],
  94         ['systemd-journald-dev-log.socket',     '',
  95          'sockets.target.wants/'],
  96         ['systemd-journald.socket',             '',
  97          'sockets.target.wants/'],
  98         ['systemd-networkd.socket',             'ENABLE_NETWORKD',
  99          join_paths(pkgsysconfdir, 'system/sockets.target.wants/')],
 100         ['systemd-rfkill.socket',               'ENABLE_RFKILL'],
 101         ['systemd-tmpfiles-clean.timer',        '',
 102          'timers.target.wants/'],
 103         ['systemd-udevd-control.socket',        '',
 104          'sockets.target.wants/'],
 105         ['systemd-udevd-kernel.socket',         '',
 106          'sockets.target.wants/'],
 107         ['time-sync.target',                    ''],
 108         ['timers.target',                       ''],
 109         ['tmp.mount',                           '',
 110          'local-fs.target.wants/'],
 111         ['umount.target',                       ''],
 112         ['user.slice',                          ''],
 113         ['var-lib-machines.mount',              'ENABLE_MACHINED',
 114          'remote-fs.target.wants/ machines.target.wants/'],
 115 ]
 116
 117 in_units = [
 118         ['debug-shell.service',                  ''],
 119         ['emergency.service',                    ''],
 120         ['halt-local.service',                   'HAVE_SYSV_COMPAT'],
 121         ['initrd-cleanup.service',               ''],
 122         ['initrd-parse-etc.service',             ''],
 123         ['initrd-switch-root.service',           ''],
 124         ['initrd-udevadm-cleanup-db.service',    ''],
 125         ['kmod-static-nodes.service',            'HAVE_KMOD ENABLE_TMPFILES',
 126          'sysinit.target.wants/'],
 127         ['quotaon.service',                      'ENABLE_QUOTACHECK'],
 128         ['rc-local.service',                     'HAVE_SYSV_COMPAT'],
 129         ['rescue.service',                       ''],
 130         ['system-update-cleanup.service',        ''],
 131         ['systemd-ask-password-console.service', ''],
 132         ['systemd-ask-password-wall.service',    ''],
 133         ['systemd-backlight@.service',           'ENABLE_BACKLIGHT'],
 134         ['systemd-binfmt.service',               'ENABLE_BINFMT',
 135          'sysinit.target.wants/'],
 136         ['systemd-coredump@.service',            'ENABLE_COREDUMP'],
 137         ['systemd-exit.service',                 ''],
 138         ['systemd-firstboot.service',            'ENABLE_FIRSTBOOT',
 139          'sysinit.target.wants/'],
 140         ['systemd-fsck-root.service',            ''],
 141         ['systemd-fsck@.service',                ''],
 142         ['systemd-halt.service',                 ''],
 143         ['systemd-hibernate-resume@.service',    'ENABLE_HIBERNATE'],
 144         ['systemd-hibernate.service',            'ENABLE_HIBERNATE'],
 145         ['systemd-hybrid-sleep.service',         'ENABLE_HIBERNATE'],
 146         ['systemd-suspend-then-hibernate.service', 'ENABLE_HIBERNATE'],
 147         ['systemd-hostnamed.service',            'ENABLE_HOSTNAMED',
 148          'dbus-org.freedesktop.hostname1.service'],
 149         ['systemd-hwdb-update.service',          'ENABLE_HWDB',
 150          'sysinit.target.wants/'],
 151         ['systemd-importd.service',              'ENABLE_IMPORTD',
 152          'dbus-org.freedesktop.import1.service'],
 153         ['systemd-initctl.service',               ''],
 154         ['systemd-journal-catalog-update.service', '',
 155          'sysinit.target.wants/'],
 156         ['systemd-journal-flush.service',         '',
 157          'sysinit.target.wants/'],
 158         ['systemd-journal-gatewayd.service',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
 159         ['systemd-journal-remote.service',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
 160         ['systemd-journal-upload.service',       'ENABLE_REMOTE HAVE_LIBCURL'],
 161         ['systemd-journald.service',             '',
 162          'sysinit.target.wants/'],
 163         ['systemd-kexec.service',                ''],
 164         ['systemd-localed.service',              'ENABLE_LOCALED',
 165          'dbus-org.freedesktop.locale1.service'],
 166         ['systemd-logind.service',               'ENABLE_LOGIND',
 167          'multi-user.target.wants/ dbus-org.freedesktop.login1.service'],
 168         ['systemd-machine-id-commit.service',    '',
 169          'sysinit.target.wants/'],
 170         ['systemd-machined.service',             'ENABLE_MACHINED',
 171          'dbus-org.freedesktop.machine1.service'],
 172         ['systemd-modules-load.service',         'HAVE_KMOD',
 173          'sysinit.target.wants/'],
 174         ['systemd-networkd.service',             'ENABLE_NETWORKD',
 175          join_paths(pkgsysconfdir, 'system/dbus-org.freedesktop.network1.service') + ' ' +
 176          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
 177         ['systemd-networkd-wait-online.service', 'ENABLE_NETWORKD',
 178          join_paths(pkgsysconfdir, 'system/network-online.target.wants/')],
 179         ['systemd-nspawn@.service',              ''],
 180         ['systemd-poweroff.service',             ''],
 181         ['systemd-quotacheck.service',           'ENABLE_QUOTACHECK'],
 182         ['systemd-random-seed.service',          'ENABLE_RANDOMSEED',
 183          'sysinit.target.wants/'],
 184         ['systemd-reboot.service',               ''],
 185         ['systemd-remount-fs.service',           '',
 186          'local-fs.target.wants/'],
 187         ['systemd-resolved.service',             'ENABLE_RESOLVE',
 188          join_paths(pkgsysconfdir, 'system/dbus-org.freedesktop.resolve1.service') + ' ' +
 189          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
 190         ['systemd-rfkill.service',               'ENABLE_RFKILL'],
 191         ['systemd-suspend.service',              ''],
 192         ['systemd-sysctl.service',               '',
 193          'sysinit.target.wants/'],
 194         ['systemd-sysusers.service',             'ENABLE_SYSUSERS',
 195          'sysinit.target.wants/'],
 196         ['systemd-timedated.service',            'ENABLE_TIMEDATED',
 197          'dbus-org.freedesktop.timedate1.service'],
 198         ['systemd-timesyncd.service',            'ENABLE_TIMESYNCD',
 199          join_paths(pkgsysconfdir, 'system/sysinit.target.wants/')],
 200         ['systemd-time-wait-sync.service', '',
 201          join_paths(pkgsysconfdir, 'system/sysinit.target.wants/')],
 202         ['systemd-tmpfiles-clean.service',       'ENABLE_TMPFILES'],
 203         ['systemd-tmpfiles-setup-dev.service',   'ENABLE_TMPFILES',
 204          'sysinit.target.wants/'],
 205         ['systemd-tmpfiles-setup.service',       'ENABLE_TMPFILES',
 206          'sysinit.target.wants/'],
 207         ['systemd-udev-settle.service',          ''],
 208         ['systemd-udev-trigger.service',         '',
 209          'sysinit.target.wants/'],
 210         ['systemd-udevd.service',                '',
 211          'sysinit.target.wants/'],
 212         ['systemd-update-done.service',          '',
 213          'sysinit.target.wants/'],
 214         ['systemd-update-utmp-runlevel.service', 'ENABLE_UTMP HAVE_SYSV_COMPAT',
 215          'multi-user.target.wants/ graphical.target.wants/ rescue.target.wants/'],
 216         ['systemd-update-utmp.service',          'ENABLE_UTMP',
 217          'sysinit.target.wants/'],
 218         ['systemd-user-sessions.service',        'HAVE_PAM',
 219          'multi-user.target.wants/'],
 220         ['systemd-vconsole-setup.service',       'ENABLE_VCONSOLE'],
 221         ['systemd-volatile-root.service',        ''],
 222         ['user@.service',                        ''],
 223 ]
 224
 225 m4_units = [
 226         ['getty@.service',                     '',
 227          'autovt@.service ' +
 228          join_paths(pkgsysconfdir, 'system/getty.target.wants/getty@tty1.service')],
 229         ['serial-getty@.service',              ''],
 230 ]
 231
 232 m4_in_units = [
 233         ['console-getty.service',              ''],
 234         ['container-getty@.service',           ''],
 235 ]
 236
 237 foreach tuple : m4_in_units
 238         file = tuple[0]
 239
 240         gen = configure_file(
 241                 input : file + '.m4.in',
 242                 output : file + '.m4',
 243                 configuration : substs)
 244
 245         m4_units += [[file, tuple.get(1, ''), tuple.get(2, ''), gen]]
 246 endforeach
 247
 248 foreach tuple : in_units
 249         file = tuple[0]
 250
 251         # we do this here because install_data does not accept custom_target output
 252         conds = tuple[1].split(' ')
 253         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 254                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 255
 256         gen1 = configure_file(
 257                 input : file + '.in',
 258                 output : file + '.tmp',
 259                 configuration : substs)
 260         gen2 = custom_target(
 261                 file,
 262                 input : gen1,
 263                 output : file,
 264                 command : [sed, '/^## /d', '@INPUT@'],
 265                 capture : true,
 266                 install : install,
 267                 install_dir : systemunitdir)
 268
 269         if install and tuple.length() > 2
 270                 foreach target : tuple[2].split()
 271                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 272                 endforeach
 273         endif
 274 endforeach
 275
 276 foreach tuple : m4_units
 277         file = tuple[0]
 278         input = tuple.get(3, file + '.m4')
 279
 280         # we do this here because install_data does not accept custom_target output
 281         conds = tuple[1].split(' ')
 282         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 283                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 284
 285         custom_target(
 286                 file,
 287                 input : input,
 288                 output: file,
 289                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
 290                 capture : true,
 291                 install : install,
 292                 install_dir : systemunitdir)
 293
 294         if tuple.length() > 2 and install
 295                 foreach target : tuple[2].split()
 296                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 297                 endforeach
 298         endif
 299 endforeach
 300
 301 foreach tuple : units
 302         file = tuple[0]
 303         input = tuple.get(3, file)
 304
 305         conds = tuple[1].split(' ')
 306         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 307                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 308
 309         if install
 310                 install_data(input,
 311                              install_dir : systemunitdir)
 312
 313                 if tuple.length() > 2
 314                         foreach target : tuple[2].split()
 315                                 meson.add_install_script(
 316                                         'meson-add-wants.sh', systemunitdir, target, file)
 317                         endforeach
 318                 endif
 319         endif
 320 endforeach
 321
 322 ############################################################
 323
 324 meson.add_install_script(meson_make_symlink,
 325                          join_paths(pkgsysconfdir, 'user'),
 326                          join_paths(sysconfdir, 'xdg/systemd/user'))
 327 meson.add_install_script(meson_make_symlink,
 328                          join_paths(dbussystemservicedir, 'org.freedesktop.systemd1.service'),
 329                          join_paths(dbussessionservicedir, 'org.freedesktop.systemd1.service'))
 330 if conf.get('HAVE_SYSV_COMPAT') == 1
 331         foreach i : [1, 2, 3, 4, 5]
 332                 meson.add_install_script(
 333                         'sh', '-c',
 334                         mkdir_p
 335                         .format(join_paths(systemunitdir, 'runlevel@0@.target.wants'.format(i))))
 336         endforeach
 337 endif
 338
 339 subdir('user')