units/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 units = [
   4         ['basic.target',                        ''],
   5         ['bluetooth.target',                    ''],
   6         ['cryptsetup-pre.target',               'HAVE_LIBCRYPTSETUP'],
   7         ['cryptsetup.target',                   'HAVE_LIBCRYPTSETUP',
   8          'sysinit.target.wants/'],
   9         ['dev-hugepages.mount',                 '',
  10          'sysinit.target.wants/'],
  11         ['dev-mqueue.mount',                    '',
  12          'sysinit.target.wants/'],
  13         ['emergency.target',                    ''],
  14         ['exit.target',                         ''],
  15         ['final.target',                        ''],
  16         ['getty.target',                        '',
  17          'multi-user.target.wants/'],
  18         ['getty-pre.target',                    ''],
  19         ['graphical.target',                    '',
  20          'runlevel5.target default.target'],
  21         ['halt.target',                         ''],
  22         ['hibernate.target',                    'ENABLE_HIBERNATE'],
  23         ['hybrid-sleep.target',                 'ENABLE_HIBERNATE'],
  24         ['suspend-then-hibernate.target',         'ENABLE_HIBERNATE'],
  25         ['initrd-fs.target',                    ''],
  26         ['initrd-root-device.target',           ''],
  27         ['initrd-root-fs.target',               ''],
  28         ['initrd-switch-root.target',           ''],
  29         ['initrd.target',                       ''],
  30         ['kexec.target',                        ''],
  31         ['ldconfig.service',                    'ENABLE_LDCONFIG',
  32          'sysinit.target.wants/'],
  33         ['local-fs-pre.target',                 ''],
  34         ['local-fs.target',                     ''],
  35         ['machine.slice',                       'ENABLE_MACHINED'],
  36         ['machines.target',                     'ENABLE_MACHINED',
  37          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
  38         ['multi-user.target',                   '',
  39          'runlevel2.target runlevel3.target runlevel4.target'],
  40         ['network-online.target',               ''],
  41         ['network-pre.target',                  ''],
  42         ['network.target',                      ''],
  43         ['nss-lookup.target',                   ''],
  44         ['nss-user-lookup.target',              ''],
  45         ['paths.target',                        ''],
  46         ['poweroff.target',                     '',
  47          'runlevel0.target'],
  48         ['printer.target',                      ''],
  49         ['proc-sys-fs-binfmt_misc.automount',   'ENABLE_BINFMT',
  50          'sysinit.target.wants/'],
  51         ['proc-sys-fs-binfmt_misc.mount',       'ENABLE_BINFMT'],
  52         ['reboot.target',                       '',
  53          'runlevel6.target ctrl-alt-del.target'],
  54         ['remote-cryptsetup.target',            'HAVE_LIBCRYPTSETUP',
  55          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
  56         ['remote-fs-pre.target',                ''],
  57         ['remote-fs.target',                    '',
  58          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
  59         ['rescue.target',                       '',
  60          'runlevel1.target'],
  61         ['rpcbind.target',                      ''],
  62         ['shutdown.target',                     ''],
  63         ['sigpwr.target',                       ''],
  64         ['sleep.target',                        ''],
  65         ['slices.target',                       ''],
  66         ['smartcard.target',                    ''],
  67         ['sockets.target',                      ''],
  68         ['sound.target',                        ''],
  69         ['suspend.target',                      ''],
  70         ['swap.target',                         ''],
  71         ['sys-fs-fuse-connections.mount',       '',
  72          'sysinit.target.wants/'],
  73         ['sys-kernel-config.mount',             '',
  74          'sysinit.target.wants/'],
  75         ['sys-kernel-debug.mount',              '',
  76          'sysinit.target.wants/'],
  77         ['sysinit.target',                      ''],
  78         ['syslog.socket',                       ''],
  79         ['system-update.target',                ''],
  80         ['system-update-pre.target',            ''],
  81         ['system-update-cleanup.service',       ''],
  82         ['systemd-ask-password-console.path',   '',
  83          'sysinit.target.wants/'],
  84         ['systemd-ask-password-wall.path',      '',
  85          'multi-user.target.wants/'],
  86         ['systemd-coredump.socket',             'ENABLE_COREDUMP',
  87          'sockets.target.wants/'],
  88         ['systemd-initctl.socket',              '',
  89          'sockets.target.wants/'],
  90         ['systemd-journal-gatewayd.socket',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
  91         ['systemd-journal-remote.socket',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
  92         ['systemd-journald-audit.socket',       '',
  93          'sockets.target.wants/'],
  94         ['systemd-journald-dev-log.socket',     '',
  95          'sockets.target.wants/'],
  96         ['systemd-journald.socket',             '',
  97          'sockets.target.wants/'],
  98         ['systemd-networkd.socket',             'ENABLE_NETWORKD',
  99          join_paths(pkgsysconfdir, 'system/sockets.target.wants/')],
 100         ['systemd-rfkill.socket',               'ENABLE_RFKILL'],
 101         ['systemd-tmpfiles-clean.timer',        '',
 102          'timers.target.wants/'],
 103         ['systemd-udevd-control.socket',        '',
 104          'sockets.target.wants/'],
 105         ['systemd-udevd-kernel.socket',         '',
 106          'sockets.target.wants/'],
 107         ['time-sync.target',                    ''],
 108         ['timers.target',                       ''],
 109         ['tmp.mount',                           '',
 110          'local-fs.target.wants/'],
 111         ['umount.target',                       ''],
 112         ['user.slice',                          ''],
 113         ['var-lib-machines.mount',              'ENABLE_MACHINED',
 114          'remote-fs.target.wants/ machines.target.wants/'],
 115 ]
 116
 117 in_units = [
 118         ['debug-shell.service',                  ''],
 119         ['emergency.service',                    ''],
 120         ['halt-local.service',                   'HAVE_SYSV_COMPAT'],
 121         ['initrd-cleanup.service',               ''],
 122         ['initrd-parse-etc.service',             ''],
 123         ['initrd-switch-root.service',           ''],
 124         ['initrd-udevadm-cleanup-db.service',    ''],
 125         ['kmod-static-nodes.service',            'HAVE_KMOD ENABLE_TMPFILES',
 126          'sysinit.target.wants/'],
 127         ['quotaon.service',                      'ENABLE_QUOTACHECK'],
 128         ['rc-local.service',                     'HAVE_SYSV_COMPAT'],
 129         ['rescue.service',                       ''],
 130         ['systemd-ask-password-console.service', ''],
 131         ['systemd-ask-password-wall.service',    ''],
 132         ['systemd-backlight@.service',           'ENABLE_BACKLIGHT'],
 133         ['systemd-binfmt.service',               'ENABLE_BINFMT',
 134          'sysinit.target.wants/'],
 135         ['systemd-coredump@.service',            'ENABLE_COREDUMP'],
 136         ['systemd-exit.service',                 ''],
 137         ['systemd-firstboot.service',            'ENABLE_FIRSTBOOT',
 138          'sysinit.target.wants/'],
 139         ['systemd-fsck-root.service',            ''],
 140         ['systemd-fsck@.service',                ''],
 141         ['systemd-halt.service',                 ''],
 142         ['systemd-hibernate-resume@.service',    'ENABLE_HIBERNATE'],
 143         ['systemd-hibernate.service',            'ENABLE_HIBERNATE'],
 144         ['systemd-hybrid-sleep.service',         'ENABLE_HIBERNATE'],
 145         ['systemd-suspend-then-hibernate.service', 'ENABLE_HIBERNATE'],
 146         ['systemd-hostnamed.service',            'ENABLE_HOSTNAMED',
 147          'dbus-org.freedesktop.hostname1.service'],
 148         ['systemd-hwdb-update.service',          'ENABLE_HWDB',
 149          'sysinit.target.wants/'],
 150         ['systemd-importd.service',              'ENABLE_IMPORTD',
 151          'dbus-org.freedesktop.import1.service'],
 152         ['systemd-initctl.service',               ''],
 153         ['systemd-journal-catalog-update.service', '',
 154          'sysinit.target.wants/'],
 155         ['systemd-journal-flush.service',         '',
 156          'sysinit.target.wants/'],
 157         ['systemd-journal-gatewayd.service',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
 158         ['systemd-journal-remote.service',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
 159         ['systemd-journal-upload.service',       'ENABLE_REMOTE HAVE_LIBCURL'],
 160         ['systemd-journald.service',             '',
 161          'sysinit.target.wants/'],
 162         ['systemd-kexec.service',                ''],
 163         ['systemd-localed.service',              'ENABLE_LOCALED',
 164          'dbus-org.freedesktop.locale1.service'],
 165         ['systemd-logind.service',               'ENABLE_LOGIND',
 166          'multi-user.target.wants/ dbus-org.freedesktop.login1.service'],
 167         ['systemd-machine-id-commit.service',    '',
 168          'sysinit.target.wants/'],
 169         ['systemd-machined.service',             'ENABLE_MACHINED',
 170          'dbus-org.freedesktop.machine1.service'],
 171         ['systemd-modules-load.service',         'HAVE_KMOD',
 172          'sysinit.target.wants/'],
 173         ['systemd-networkd.service',             'ENABLE_NETWORKD',
 174          join_paths(pkgsysconfdir, 'system/dbus-org.freedesktop.network1.service') + ' ' +
 175          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
 176         ['systemd-networkd-wait-online.service', 'ENABLE_NETWORKD',
 177          join_paths(pkgsysconfdir, 'system/network-online.target.wants/')],
 178         ['systemd-nspawn@.service',              ''],
 179         ['systemd-portabled.service',            'ENABLE_PORTABLED',
 180          'dbus-org.freedesktop.portable1.service'],
 181         ['systemd-poweroff.service',             ''],
 182         ['systemd-quotacheck.service',           'ENABLE_QUOTACHECK'],
 183         ['systemd-random-seed.service',          'ENABLE_RANDOMSEED',
 184          'sysinit.target.wants/'],
 185         ['systemd-reboot.service',               ''],
 186         ['systemd-remount-fs.service',           '',
 187          'local-fs.target.wants/'],
 188         ['systemd-resolved.service',             'ENABLE_RESOLVE',
 189          join_paths(pkgsysconfdir, 'system/dbus-org.freedesktop.resolve1.service') + ' ' +
 190          join_paths(pkgsysconfdir, 'system/multi-user.target.wants/')],
 191         ['systemd-rfkill.service',               'ENABLE_RFKILL'],
 192         ['systemd-suspend.service',              ''],
 193         ['systemd-sysctl.service',               '',
 194          'sysinit.target.wants/'],
 195         ['systemd-sysusers.service',             'ENABLE_SYSUSERS',
 196          'sysinit.target.wants/'],
 197         ['systemd-timedated.service',            'ENABLE_TIMEDATED',
 198          'dbus-org.freedesktop.timedate1.service'],
 199         ['systemd-timesyncd.service',            'ENABLE_TIMESYNCD',
 200          join_paths(pkgsysconfdir, 'system/sysinit.target.wants/')],
 201         ['systemd-time-wait-sync.service',       'ENABLE_TIMESYNCD'],
 202         ['systemd-tmpfiles-clean.service',       'ENABLE_TMPFILES'],
 203         ['systemd-tmpfiles-setup-dev.service',   'ENABLE_TMPFILES',
 204          'sysinit.target.wants/'],
 205         ['systemd-tmpfiles-setup.service',       'ENABLE_TMPFILES',
 206          'sysinit.target.wants/'],
 207         ['systemd-udev-settle.service',          ''],
 208         ['systemd-udev-trigger.service',         '',
 209          'sysinit.target.wants/'],
 210         ['systemd-udevd.service',                '',
 211          'sysinit.target.wants/'],
 212         ['systemd-update-done.service',          '',
 213          'sysinit.target.wants/'],
 214         ['systemd-update-utmp-runlevel.service', 'ENABLE_UTMP HAVE_SYSV_COMPAT',
 215          'multi-user.target.wants/ graphical.target.wants/ rescue.target.wants/'],
 216         ['systemd-update-utmp.service',          'ENABLE_UTMP',
 217          'sysinit.target.wants/'],
 218         ['systemd-user-sessions.service',        'HAVE_PAM',
 219          'multi-user.target.wants/'],
 220         ['systemd-vconsole-setup.service',       'ENABLE_VCONSOLE'],
 221         ['systemd-volatile-root.service',        ''],
 222         ['user-runtime-dir@.service',            ''],
 223         ['user@.service',                        ''],
 224 ]
 225
 226 m4_units = [
 227         ['console-getty.service',              ''],
 228         ['container-getty@.service',           ''],
 229         ['getty@.service',                     '',
 230          'autovt@.service ' +
 231          join_paths(pkgsysconfdir, 'system/getty.target.wants/getty@tty1.service')],
 232         ['serial-getty@.service',              ''],
 233 ]
 234
 235 foreach tuple : in_units
 236         file = tuple[0]
 237
 238         # we do this here because install_data does not accept custom_target output
 239         conds = tuple[1].split(' ')
 240         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 241                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 242
 243         gen1 = configure_file(
 244                 input : file + '.in',
 245                 output : file + '.tmp',
 246                 configuration : substs)
 247         gen2 = custom_target(
 248                 file,
 249                 input : gen1,
 250                 output : file,
 251                 command : [sed, '/^## /d', '@INPUT@'],
 252                 capture : true,
 253                 install : install,
 254                 install_dir : systemunitdir)
 255
 256         if install and tuple.length() > 2
 257                 foreach target : tuple[2].split()
 258                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 259                 endforeach
 260         endif
 261 endforeach
 262
 263 foreach tuple : m4_units
 264         file = tuple[0]
 265         input = tuple.get(3, file + '.m4')
 266
 267         # we do this here because install_data does not accept custom_target output
 268         conds = tuple[1].split(' ')
 269         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 270                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 271
 272         custom_target(
 273                 file,
 274                 input : input,
 275                 output: file,
 276                 command : [meson_apply_m4, config_h, '@INPUT@'],
 277                 capture : true,
 278                 install : install,
 279                 install_dir : systemunitdir)
 280
 281         if tuple.length() > 2 and install
 282                 foreach target : tuple[2].split()
 283                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 284                 endforeach
 285         endif
 286 endforeach
 287
 288 foreach tuple : units
 289         file = tuple[0]
 290         input = tuple.get(3, file)
 291
 292         conds = tuple[1].split(' ')
 293         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 294                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 295
 296         if install
 297                 install_data(input,
 298                              install_dir : systemunitdir)
 299
 300                 if tuple.length() > 2
 301                         foreach target : tuple[2].split()
 302                                 meson.add_install_script(
 303                                         'meson-add-wants.sh', systemunitdir, target, file)
 304                         endforeach
 305                 endif
 306         endif
 307 endforeach
 308
 309 install_data('user-.slice.d/10-defaults.conf',
 310              install_dir : systemunitdir + '/user-.slice.d')
 311
 312 ############################################################
 313
 314 meson.add_install_script(meson_make_symlink,
 315                          join_paths(pkgsysconfdir, 'user'),
 316                          join_paths(sysconfdir, 'xdg/systemd/user'))
 317 meson.add_install_script(meson_make_symlink,
 318                          join_paths(dbussystemservicedir, 'org.freedesktop.systemd1.service'),
 319                          join_paths(dbussessionservicedir, 'org.freedesktop.systemd1.service'))
 320 if conf.get('HAVE_SYSV_COMPAT') == 1
 321         foreach i : [1, 2, 3, 4, 5]
 322                 meson.add_install_script(
 323                         'sh', '-c',
 324                         mkdir_p
 325                         .format(join_paths(systemunitdir, 'runlevel@0@.target.wants'.format(i))))
 326         endforeach
 327 endif
 328
 329 subdir('user')