units/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 units = [
   4         ['basic.target',                        ''],
   5         ['bluetooth.target',                    ''],
   6         ['boot-complete.target',                ''],
   7         ['cryptsetup-pre.target',               'HAVE_LIBCRYPTSETUP'],
   8         ['cryptsetup.target',                   'HAVE_LIBCRYPTSETUP',
   9          'sysinit.target.wants/'],
  10         ['dev-hugepages.mount',                 '',
  11          'sysinit.target.wants/'],
  12         ['dev-mqueue.mount',                    '',
  13          'sysinit.target.wants/'],
  14         ['emergency.target',                    ''],
  15         ['exit.target',                         ''],
  16         ['final.target',                        ''],
  17         ['getty.target',                        '',
  18          'multi-user.target.wants/'],
  19         ['getty-pre.target',                    ''],
  20         ['graphical.target',                    '',
  21          'runlevel5.target default.target'],
  22         ['halt.target',                         ''],
  23         ['hibernate.target',                    'ENABLE_HIBERNATE'],
  24         ['hybrid-sleep.target',                 'ENABLE_HIBERNATE'],
  25         ['suspend-then-hibernate.target',       'ENABLE_HIBERNATE'],
  26         ['initrd-fs.target',                    ''],
  27         ['initrd-root-device.target',           ''],
  28         ['initrd-root-fs.target',               ''],
  29         ['initrd-switch-root.target',           ''],
  30         ['initrd.target',                       ''],
  31         ['kexec.target',                        ''],
  32         ['ldconfig.service',                    'ENABLE_LDCONFIG',
  33          'sysinit.target.wants/'],
  34         ['local-fs-pre.target',                 ''],
  35         ['local-fs.target',                     ''],
  36         ['machine.slice',                       'ENABLE_MACHINED'],
  37         ['machines.target',                     'ENABLE_MACHINED'],
  38         ['multi-user.target',                   '',
  39          'runlevel2.target runlevel3.target runlevel4.target'],
  40         ['network-online.target',               ''],
  41         ['network-pre.target',                  ''],
  42         ['network.target',                      ''],
  43         ['nss-lookup.target',                   ''],
  44         ['nss-user-lookup.target',              ''],
  45         ['paths.target',                        ''],
  46         ['poweroff.target',                     '',
  47          'runlevel0.target'],
  48         ['printer.target',                      ''],
  49         ['proc-sys-fs-binfmt_misc.automount',   'ENABLE_BINFMT',
  50          'sysinit.target.wants/'],
  51         ['proc-sys-fs-binfmt_misc.mount',       'ENABLE_BINFMT'],
  52         ['reboot.target',                       '',
  53          'runlevel6.target ctrl-alt-del.target'],
  54         ['remote-cryptsetup.target',            'HAVE_LIBCRYPTSETUP'],
  55         ['remote-fs-pre.target',                ''],
  56         ['remote-fs.target',                    ''],
  57         ['rescue.target',                       '',
  58          'runlevel1.target'],
  59         ['rpcbind.target',                      ''],
  60         ['shutdown.target',                     ''],
  61         ['sigpwr.target',                       ''],
  62         ['sleep.target',                        ''],
  63         ['slices.target',                       ''],
  64         ['smartcard.target',                    ''],
  65         ['sockets.target',                      ''],
  66         ['sound.target',                        ''],
  67         ['suspend.target',                      ''],
  68         ['swap.target',                         ''],
  69         ['sys-fs-fuse-connections.mount',       '',
  70          'sysinit.target.wants/'],
  71         ['sys-kernel-config.mount',             '',
  72          'sysinit.target.wants/'],
  73         ['sys-kernel-debug.mount',              '',
  74          'sysinit.target.wants/'],
  75         ['sysinit.target',                      ''],
  76         ['syslog.socket',                       ''],
  77         ['system-update.target',                ''],
  78         ['system-update-pre.target',            ''],
  79         ['system-update-cleanup.service',       ''],
  80         ['systemd-ask-password-console.path',   '',
  81          'sysinit.target.wants/'],
  82         ['systemd-ask-password-wall.path',      '',
  83          'multi-user.target.wants/'],
  84         ['systemd-coredump.socket',             'ENABLE_COREDUMP',
  85          'sockets.target.wants/'],
  86         ['systemd-exit.service',                 ''],
  87         ['systemd-initctl.socket',              '',
  88          'sockets.target.wants/'],
  89         ['systemd-journal-gatewayd.socket',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
  90         ['systemd-journal-remote.socket',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
  91         ['systemd-journald-audit.socket',       '',
  92          'sockets.target.wants/'],
  93         ['systemd-journald-dev-log.socket',     '',
  94          'sockets.target.wants/'],
  95         ['systemd-journald.socket',             '',
  96          'sockets.target.wants/'],
  97         ['systemd-networkd.socket',             'ENABLE_NETWORKD'],
  98         ['systemd-poweroff.service',             ''],
  99         ['systemd-reboot.service',               ''],
 100         ['systemd-rfkill.socket',               'ENABLE_RFKILL'],
 101         ['systemd-tmpfiles-clean.timer',        '',
 102          'timers.target.wants/'],
 103         ['systemd-udevd-control.socket',        '',
 104          'sockets.target.wants/'],
 105         ['systemd-udevd-kernel.socket',         '',
 106          'sockets.target.wants/'],
 107         ['time-set.target',                     ''],
 108         ['time-sync.target',                    ''],
 109         ['timers.target',                       ''],
 110         ['tmp.mount',                           '',
 111          'local-fs.target.wants/'],
 112         ['umount.target',                       ''],
 113         ['user.slice',                          ''],
 114         ['var-lib-machines.mount',              'ENABLE_MACHINED',
 115          'remote-fs.target.wants/ machines.target.wants/'],
 116 ]
 117
 118 in_units = [
 119         ['debug-shell.service',                  ''],
 120         ['emergency.service',                    ''],
 121         ['initrd-cleanup.service',               ''],
 122         ['initrd-parse-etc.service',             ''],
 123         ['initrd-switch-root.service',           ''],
 124         ['initrd-udevadm-cleanup-db.service',    ''],
 125         ['kmod-static-nodes.service',            'HAVE_KMOD ENABLE_TMPFILES',
 126          'sysinit.target.wants/'],
 127         ['quotaon.service',                      'ENABLE_QUOTACHECK'],
 128         ['rc-local.service',                     'HAVE_SYSV_COMPAT'],
 129         ['rescue.service',                       ''],
 130         ['systemd-ask-password-console.service', ''],
 131         ['systemd-ask-password-wall.service',    ''],
 132         ['systemd-backlight@.service',           'ENABLE_BACKLIGHT'],
 133         ['systemd-binfmt.service',               'ENABLE_BINFMT',
 134          'sysinit.target.wants/'],
 135         ['systemd-bless-boot.service',           'ENABLE_EFI HAVE_BLKID'],
 136         ['systemd-boot-check-no-failures.service', ''],
 137         ['systemd-coredump@.service',            'ENABLE_COREDUMP'],
 138         ['systemd-firstboot.service',            'ENABLE_FIRSTBOOT',
 139          'sysinit.target.wants/'],
 140         ['systemd-fsck-root.service',            ''],
 141         ['systemd-fsck@.service',                ''],
 142         ['systemd-halt.service',                 ''],
 143         ['systemd-hibernate-resume@.service',    'ENABLE_HIBERNATE'],
 144         ['systemd-hibernate.service',            'ENABLE_HIBERNATE'],
 145         ['systemd-hybrid-sleep.service',         'ENABLE_HIBERNATE'],
 146         ['systemd-suspend-then-hibernate.service', 'ENABLE_HIBERNATE'],
 147         ['systemd-hostnamed.service',            'ENABLE_HOSTNAMED',
 148          'dbus-org.freedesktop.hostname1.service'],
 149         ['systemd-hwdb-update.service',          'ENABLE_HWDB',
 150          'sysinit.target.wants/'],
 151         ['systemd-importd.service',              'ENABLE_IMPORTD',
 152          'dbus-org.freedesktop.import1.service'],
 153         ['systemd-initctl.service',               ''],
 154         ['systemd-journal-catalog-update.service', '',
 155          'sysinit.target.wants/'],
 156         ['systemd-journal-flush.service',         '',
 157          'sysinit.target.wants/'],
 158         ['systemd-journal-gatewayd.service',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
 159         ['systemd-journal-remote.service',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
 160         ['systemd-journal-upload.service',       'ENABLE_REMOTE HAVE_LIBCURL'],
 161         ['systemd-journald.service',             '',
 162          'sysinit.target.wants/'],
 163         ['systemd-kexec.service',                ''],
 164         ['systemd-localed.service',              'ENABLE_LOCALED',
 165          'dbus-org.freedesktop.locale1.service'],
 166         ['systemd-logind.service',               'ENABLE_LOGIND',
 167          'multi-user.target.wants/ dbus-org.freedesktop.login1.service'],
 168         ['systemd-machine-id-commit.service',    '',
 169          'sysinit.target.wants/'],
 170         ['systemd-machined.service',             'ENABLE_MACHINED',
 171          'dbus-org.freedesktop.machine1.service'],
 172         ['systemd-modules-load.service',         'HAVE_KMOD',
 173          'sysinit.target.wants/'],
 174         ['systemd-networkd.service',             'ENABLE_NETWORKD'],
 175         ['systemd-networkd-wait-online.service', 'ENABLE_NETWORKD'],
 176         ['systemd-nspawn@.service',              ''],
 177         ['systemd-portabled.service',            'ENABLE_PORTABLED',
 178          'dbus-org.freedesktop.portable1.service'],
 179         ['systemd-quotacheck.service',           'ENABLE_QUOTACHECK'],
 180         ['systemd-random-seed.service',          'ENABLE_RANDOMSEED',
 181          'sysinit.target.wants/'],
 182         ['systemd-remount-fs.service',           ''],
 183         ['systemd-resolved.service',             'ENABLE_RESOLVE'],
 184         ['systemd-rfkill.service',               'ENABLE_RFKILL'],
 185         ['systemd-suspend.service',              ''],
 186         ['systemd-sysctl.service',               '',
 187          'sysinit.target.wants/'],
 188         ['systemd-sysusers.service',             'ENABLE_SYSUSERS',
 189          'sysinit.target.wants/'],
 190         ['systemd-timedated.service',            'ENABLE_TIMEDATED',
 191          'dbus-org.freedesktop.timedate1.service'],
 192         ['systemd-timesyncd.service',            'ENABLE_TIMESYNCD'],
 193         ['systemd-time-wait-sync.service',       'ENABLE_TIMESYNCD'],
 194         ['systemd-tmpfiles-clean.service',       'ENABLE_TMPFILES'],
 195         ['systemd-tmpfiles-setup-dev.service',   'ENABLE_TMPFILES',
 196          'sysinit.target.wants/'],
 197         ['systemd-tmpfiles-setup.service',       'ENABLE_TMPFILES',
 198          'sysinit.target.wants/'],
 199         ['systemd-udev-settle.service',          ''],
 200         ['systemd-udev-trigger.service',         '',
 201          'sysinit.target.wants/'],
 202         ['systemd-udevd.service',                '',
 203          'sysinit.target.wants/'],
 204         ['systemd-update-done.service',          '',
 205          'sysinit.target.wants/'],
 206         ['systemd-update-utmp-runlevel.service', 'ENABLE_UTMP HAVE_SYSV_COMPAT',
 207          'multi-user.target.wants/ graphical.target.wants/ rescue.target.wants/'],
 208         ['systemd-update-utmp.service',          'ENABLE_UTMP',
 209          'sysinit.target.wants/'],
 210         ['systemd-user-sessions.service',        'HAVE_PAM',
 211          'multi-user.target.wants/'],
 212         ['systemd-vconsole-setup.service',       'ENABLE_VCONSOLE'],
 213         ['systemd-volatile-root.service',        ''],
 214         ['user-runtime-dir@.service',            ''],
 215         ['user@.service',                        ''],
 216 ]
 217
 218 m4_units = [
 219         ['console-getty.service',              ''],
 220         ['container-getty@.service',           ''],
 221         ['getty@.service',                     '',
 222          'autovt@.service '],
 223         ['serial-getty@.service',              ''],
 224 ]
 225
 226 foreach tuple : in_units
 227         file = tuple[0]
 228
 229         # we do this here because install_data does not accept custom_target output
 230         conds = tuple[1].split(' ')
 231         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 232                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 233
 234         gen1 = configure_file(
 235                 input : file + '.in',
 236                 output : file + '.tmp',
 237                 configuration : substs)
 238         gen2 = custom_target(
 239                 file,
 240                 input : gen1,
 241                 output : file,
 242                 command : [sed, '/^## /d', '@INPUT@'],
 243                 capture : true,
 244                 install : install,
 245                 install_dir : systemunitdir)
 246
 247         if install and tuple.length() > 2
 248                 foreach target : tuple[2].split()
 249                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 250                 endforeach
 251         endif
 252 endforeach
 253
 254 foreach tuple : m4_units
 255         file = tuple[0]
 256         input = tuple.get(3, file + '.m4')
 257
 258         # we do this here because install_data does not accept custom_target output
 259         conds = tuple[1].split(' ')
 260         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 261                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 262
 263         custom_target(
 264                 file,
 265                 input : input,
 266                 output: file,
 267                 command : [meson_apply_m4, config_h, '@INPUT@'],
 268                 capture : true,
 269                 install : install,
 270                 install_dir : systemunitdir)
 271
 272         if tuple.length() > 2 and install
 273                 foreach target : tuple[2].split()
 274                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 275                 endforeach
 276         endif
 277 endforeach
 278
 279 foreach tuple : units
 280         file = tuple[0]
 281         input = tuple.get(3, file)
 282
 283         conds = tuple[1].split(' ')
 284         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 285                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 286
 287         if install
 288                 install_data(input,
 289                              install_dir : systemunitdir)
 290
 291                 if tuple.length() > 2
 292                         foreach target : tuple[2].split()
 293                                 meson.add_install_script(
 294                                         'meson-add-wants.sh', systemunitdir, target, file)
 295                         endforeach
 296                 endif
 297         endif
 298 endforeach
 299
 300 install_data('user-.slice.d/10-defaults.conf',
 301              install_dir : systemunitdir + '/user-.slice.d')
 302
 303 ############################################################
 304
 305 meson.add_install_script(meson_make_symlink,
 306                          join_paths(pkgsysconfdir, 'user'),
 307                          join_paths(sysconfdir, 'xdg/systemd/user'))
 308 meson.add_install_script(meson_make_symlink,
 309                          join_paths(dbussystemservicedir, 'org.freedesktop.systemd1.service'),
 310                          join_paths(dbussessionservicedir, 'org.freedesktop.systemd1.service'))
 311 if conf.get('HAVE_SYSV_COMPAT') == 1
 312         foreach i : [1, 2, 3, 4, 5]
 313                 meson.add_install_script(
 314                         'sh', '-c',
 315                         mkdir_p
 316                         .format(join_paths(systemunitdir, 'runlevel@0@.target.wants'.format(i))))
 317         endforeach
 318 endif
 319
 320 subdir('user')