bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.90)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AM_BINUTILS_WARNINGS
  55
  56 AM_CONFIG_HEADER(config.h:config.in)
  57
  58 if test -z "$target" ; then
  59     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  60 fi
  61
  62 AM_MAINTAINER_MODE
  63 AM_INSTALL_LIBBFD
  64 AC_EXEEXT
  65
  66 host64=false
  67 target64=false
  68 bfd_default_target_size=32
  69
  70 # host stuff:
  71
  72 AC_PROG_CC
  73 AC_GNU_SOURCE
  74
  75 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw"
  76 CY_GNU_GETTEXT
  77
  78 # Permit host specific settings.
  79 . ${srcdir}/configure.host
  80
  81 AC_SUBST(HDEFINES)
  82 AC_PROG_INSTALL
  83
  84 BFD_HOST_64BIT_LONG=0
  85 BFD_HOST_LONG_LONG=0
  86 BFD_HOST_64_BIT_DEFINED=0
  87 BFD_HOST_64_BIT=
  88 BFD_HOST_U_64_BIT=
  89
  90 AC_MSG_CHECKING([for long long])
  91 AC_CACHE_VAL(bfd_cv_has_long_long,
  92 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
  93 AC_MSG_RESULT($bfd_cv_has_long_long)
  94 if test $bfd_cv_has_long_long = yes; then
  95   BFD_HOST_LONG_LONG=1
  96   AC_CHECK_SIZEOF(long long)
  97 fi
  98
  99 AC_CHECK_SIZEOF(long)
 100 if test "x${ac_cv_sizeof_long}" = "x8"; then
 101   host64=true
 102   BFD_HOST_64BIT_LONG=1
 103   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 104   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 105 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 106   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 107   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 108 fi
 109
 110 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 111   BFD_HOST_64_BIT_DEFINED=1
 112   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 113   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 114 fi
 115
 116 AC_SUBST(BFD_HOST_64BIT_LONG)
 117 AC_SUBST(BFD_HOST_LONG_LONG)
 118 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 119 AC_SUBST(BFD_HOST_64_BIT)
 120 AC_SUBST(BFD_HOST_U_64_BIT)
 121
 122 BFD_CC_FOR_BUILD
 123
 124 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 125 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 126 AC_HEADER_TIME
 127 AC_HEADER_DIRENT
 128 ACX_HEADER_STRING
 129 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 130 AC_CHECK_FUNCS(strtoull)
 131
 132 AC_CHECK_DECLS(basename)
 133 AC_CHECK_DECLS(ftello)
 134 AC_CHECK_DECLS(ftello64)
 135 AC_CHECK_DECLS(fseeko)
 136 AC_CHECK_DECLS(fseeko64)
 137
 138 BFD_BINARY_FOPEN
 139
 140 AC_CHECK_DECLS(ffs)
 141 AC_CHECK_DECLS(free)
 142 AC_CHECK_DECLS(getenv)
 143 AC_CHECK_DECLS(malloc)
 144 AC_CHECK_DECLS(realloc)
 145 AC_CHECK_DECLS(stpcpy)
 146 AC_CHECK_DECLS(strstr)
 147
 148 # If we are configured native, pick a core file support file.
 149 COREFILE=
 150 COREFLAG=
 151 TRAD_HEADER=
 152 if test "${target}" = "${host}"; then
 153   case "${host}" in
 154   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 155         COREFILE=''
 156         ;;
 157   alpha*-*-linux-*)
 158         COREFILE=trad-core.lo
 159         TRAD_HEADER='"hosts/alphalinux.h"'
 160         ;;
 161   alpha*-*-netbsd* | alpha*-*-openbsd*)
 162         COREFILE=netbsd-core.lo
 163         ;;
 164   alpha*-*-*)           COREFILE=osf-core.lo ;;
 165   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 166                         COREFILE='' ;;
 167   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 168   arm-*-riscix)         COREFILE=trad-core.lo ;;
 169   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 170   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 171   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 172   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 173                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 174   hppa*-*-netbsd* | hppa*-*-openbsd*)
 175         COREFILE=netbsd-core.lo
 176         ;;
 177
 178   i370-*-*)
 179         COREFILE=trad-core.lo
 180         TRAD_HEADER='"hosts/i370linux.h"'
 181         ;;
 182
 183 changequote(,)dnl
 184   i[3-7]86-sequent-bsd*)
 185 changequote([,])dnl
 186         COREFILE=trad-core.lo
 187         TRAD_HEADER='"hosts/symmetry.h"'
 188         ;;
 189 changequote(,)dnl
 190   i[3-7]86-sequent-sysv4*) ;;
 191   i[3-7]86-sequent-sysv*)
 192 changequote([,])dnl
 193         COREFILE=trad-core.lo
 194         TRAD_HEADER='"hosts/symmetry.h"'
 195         ;;
 196 changequote(,)dnl
 197   i[3-7]86-*-bsdi)
 198 changequote([,])dnl
 199         COREFILE=
 200         ;;
 201 changequote(,)dnl
 202   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 203 changequote([,])dnl
 204         COREFILE=trad-core.lo
 205         TRAD_HEADER='"hosts/i386bsd.h"'
 206         ;;
 207 changequote(,)dnl
 208   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 209 changequote([,])dnl
 210         COREFILE=''
 211         TRAD_HEADER='"hosts/i386bsd.h"'
 212         ;;
 213 changequote(,)dnl
 214   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 215 changequote([,])dnl
 216         COREFILE=netbsd-core.lo
 217         ;;
 218 changequote(,)dnl
 219   i[3-7]86-esix-sysv3*)
 220 changequote([,])dnl
 221         COREFILE=trad-core.lo
 222         TRAD_HEADER='"hosts/esix.h"'
 223         ;;
 224 changequote(,)dnl
 225   i[3-7]86-*-sco3.2v5*)
 226 changequote([,])dnl
 227         COREFILE=sco5-core.lo
 228         ;;
 229 changequote(,)dnl
 230   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 231 changequote([,])dnl
 232         COREFILE=trad-core.lo
 233         TRAD_HEADER='"hosts/i386sco.h"'
 234         ;;
 235 changequote(,)dnl
 236   i[3-7]86-*-mach3*)
 237 changequote([,])dnl
 238         COREFILE=trad-core.lo
 239         TRAD_HEADER='"hosts/i386mach3.h"'
 240         ;;
 241 changequote(,)dnl
 242   i[3-7]86-*-linux-*)
 243 changequote([,])dnl
 244         COREFILE=trad-core.lo
 245         TRAD_HEADER='"hosts/i386linux.h"'
 246         ;;
 247 changequote(,)dnl
 248   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 249   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 250 changequote([,])dnl
 251   i860-*-mach3* | i860-*-osf1*)
 252         COREFILE=trad-core.lo
 253         TRAD_HEADER='"hosts/i860mach3.h"'
 254         ;;
 255   mips-*-netbsd* | mips*-*-openbsd*)
 256         COREFILE=netbsd-core.lo
 257         ;;
 258   mips-dec-*)
 259         COREFILE=trad-core.lo
 260         TRAD_HEADER='"hosts/decstation.h"'
 261         ;;
 262   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 263   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 264   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 265   mips-*-sysv4*)        ;;
 266   mips-*-sysv* | mips-*-riscos*)
 267         COREFILE=trad-core.lo
 268         TRAD_HEADER='"hosts/riscos.h"'
 269         ;;
 270   mips-sony-bsd*)
 271         COREFILE=trad-core.lo
 272         TRAD_HEADER='"hosts/news-mips.h"'
 273         ;;
 274   m68*-bull*-sysv*)
 275         COREFILE=trad-core.lo
 276         TRAD_HEADER='"hosts/dpx2.h"'
 277         ;;
 278   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 279   m68*-hp-bsd*)
 280         COREFILE=trad-core.lo
 281         TRAD_HEADER='"hosts/hp300bsd.h"'
 282         ;;
 283   m68*-*-linux-*)
 284         COREFILE=trad-core.lo
 285         TRAD_HEADER='"hosts/m68klinux.h"'
 286         ;;
 287   m68*-motorola-sysv*)
 288         COREFILE=trad-core.lo
 289         TRAD_HEADER='"hosts/delta68.h"'
 290         ;;
 291   m68*-sony-*)
 292         COREFILE=trad-core.lo
 293         TRAD_HEADER='"hosts/news.h"'
 294         ;;
 295   m68*-*-netbsd* | m68*-*-openbsd*)
 296         COREFILE=netbsd-core.lo
 297         ;;
 298   m68*-apple-aux*)
 299         COREFILE=trad-core.lo
 300         TRAD_HEADER='"hosts/m68kaux.h"'
 301         ;;
 302   m88*-*-sysv4*)
 303         ;;
 304   m88*-motorola-sysv*)
 305         COREFILE=ptrace-core.lo
 306         ;;
 307   m88*-*-mach3*)
 308         COREFILE=trad-core.lo
 309         TRAD_HEADER='"hosts/m88kmach3.h"'
 310         ;;
 311   m88*-*-openbsd*)
 312         COREFILE=netbsd-core.lo
 313         ;;
 314   ns32k-pc532-mach)
 315         COREFILE=trad-core.lo
 316         TRAD_HEADER='"hosts/pc532mach.h"'
 317         ;;
 318   ns32k-*-netbsd* | ns32k-*-openbsd*)
 319         COREFILE=netbsd-core.lo
 320         ;;
 321   rs6000-*-lynx*)
 322         COREFILE=lynx-core.lo
 323         ;;
 324   rs6000-*-aix5.* | powerpc-*-aix5.*)
 325         COREFILE=rs6000-core.lo
 326         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 327         ;;
 328 changequote(,)dnl
 329   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 330 changequote([,])dnl
 331         COREFILE=rs6000-core.lo
 332         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 333         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 334         # have c_impl as a member of struct core_dumpx
 335         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 336         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 337             [Define if struct core_dumpx has member c_impl])
 338           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 339         ;;
 340   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 341   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 342   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 343   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 344   powerpc-*-beos*)      ;;
 345   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 346                         COREFILE='' ;;
 347   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 348   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 349   s390*-*-*)            COREFILE=trad-core.lo ;;
 350   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 351   sparc-*-netbsd* | sparc*-*-openbsd*)
 352         COREFILE=netbsd-core.lo
 353         ;;
 354   tahoe-*-*)
 355         COREFILE=trad-core.lo
 356         TRAD_HEADER='"hosts/tahoe.h"'
 357         ;;
 358   vax-*-netbsd* | vax-*-openbsd*)
 359         COREFILE=netbsd-core.lo
 360         ;;
 361   vax-*-ultrix2*)
 362         COREFILE=trad-core.lo
 363         TRAD_HEADER='"hosts/vaxult2.h"'
 364         ;;
 365   vax-*-ultrix*)
 366         COREFILE=trad-core.lo
 367         TRAD_HEADER='"hosts/vaxult2.h"'
 368         ;;
 369   vax-*-linux-*)
 370         COREFILE=trad-core.lo
 371         TRAD_HEADER='"hosts/vaxlinux.h"'
 372         ;;
 373   vax-*-*)
 374         COREFILE=trad-core.lo
 375         TRAD_HEADER='"hosts/vaxbsd.h"'
 376         ;;
 377   x86_64-*-netbsd* | x86_64-*-openbsd*)
 378         COREFILE=netbsd-core.lo
 379         ;;
 380   esac
 381
 382   case "$COREFILE" in
 383   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 384   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 385   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 386   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 387   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 388   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 389   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 390   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 391   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 392   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 393   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 394   esac
 395
 396   # ELF corefile support has several flavors, but all of
 397   # them use something called <sys/procfs.h>
 398   AC_CHECK_HEADERS(sys/procfs.h)
 399   if test "$ac_cv_header_sys_procfs_h" = yes; then
 400     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 401     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 402     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 403     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 404     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 405     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 407     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 408     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 409     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 410     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 411     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 412     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 413     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 414     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 415     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 416   fi
 417 fi
 418 AC_SUBST(COREFILE)
 419 AC_SUBST(COREFLAG)
 420 if test -n "$TRAD_HEADER"; then
 421   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 422     [Name of host specific header file to include in trad-core.c.])
 423 fi
 424
 425 # Horrible hacks to build DLLs on Windows.
 426 WIN32LDFLAGS=
 427 WIN32LIBADD=
 428 case "${host}" in
 429 *-*-cygwin*)
 430   if test "$enable_shared" = "yes"; then
 431     WIN32LDFLAGS="-no-undefined"
 432     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 433   fi
 434   ;;
 435 *-*-linux*)
 436   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 437   # libiberty.a.
 438   case "${host}" in
 439   mips*-*-linux*)
 440     # Linux/MIPS uses PIC by default.
 441     if test "$enable_shared" = "yes"; then
 442       WIN32LIBADD="-L../libiberty -liberty"
 443     fi
 444     ;;
 445   *)
 446 changequote(,)dnl
 447     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 448 changequote([,])dnl
 449     if test -n "$x"; then
 450       WIN32LIBADD="-L../libiberty/pic -liberty"
 451     fi
 452   ;;
 453   esac
 454   ;;
 455 esac
 456 AC_SUBST(WIN32LDFLAGS)
 457 AC_SUBST(WIN32LIBADD)
 458
 459 # target stuff:
 460
 461 # Canonicalize the secondary target names.
 462 if test -n "$enable_targets" ; then
 463     for targ in `echo $enable_targets | sed 's/,/ /g'`
 464     do
 465         result=`$ac_config_sub $targ 2>/dev/null`
 466         if test -n "$result" ; then
 467             canon_targets="$canon_targets $result"
 468         else
 469             # Allow targets that config.sub doesn't recognize, like "all".
 470             canon_targets="$canon_targets $targ"
 471         fi
 472     done
 473 fi
 474
 475 all_targets=false
 476 defvec=
 477 selvecs=
 478 assocvecs=
 479 selarchs=
 480 TDEFINES=
 481 for targ in $target $canon_targets
 482 do
 483     if test "x$targ" = "xall"; then
 484         all_targets=true
 485         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 486     else
 487         . $srcdir/config.bfd
 488         if test "x$targ" = "x$target"; then
 489             defvec=$targ_defvec
 490         fi
 491         selvecs="$selvecs $targ_defvec $targ_selvecs"
 492         selarchs="$selarchs $targ_archs"
 493         TDEFINES="$TDEFINES $targ_cflags"
 494     fi
 495 done
 496 AC_SUBST(TDEFINES)
 497
 498 # This processing still needs to be done if we're to decide properly whether
 499 # 64-bit support needs to be compiled in.  Currently, it will be included if
 500 # the default or any other explicitly requested target requires it; it
 501 # will not be included on a 32-bit host if no 64-bit target is requested, and
 502 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 503 # used.
 504
 505 # uniq the default and selected vectors in all the configured targets.
 506 f=""
 507 for i in $selvecs ; do
 508     case " $f " in
 509     *" $i "*) ;;
 510     *) f="$f $i" ;;
 511     esac
 512 done
 513 selvecs="$f"
 514
 515
 516 # uniq the associated vectors in all the configured targets.
 517 f=""
 518 for i in $assocvecs ; do
 519     case " $f " in
 520     *" $i "*) ;;
 521     *) f="$f $i" ;;
 522     esac
 523 done
 524 assocvecs="$f"
 525
 526
 527 # uniq the architectures in all the configured targets.
 528 f=""
 529 for i in $selarchs ; do
 530     case " $f " in
 531     *" $i "*) ;;
 532     *) f="$f $i" ;;
 533     esac
 534 done
 535 selarchs="$f"
 536
 537 # Target backend .o files.
 538 tb=
 539
 540 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 541
 542 for vec in $selvecs
 543 do
 544     target_size=32
 545     case "$vec" in
 546     # This list is alphabetized to make it easy to compare
 547     # with the two vector lists in targets.c.  For the same reason,
 548     # use one entry per line, even though this leads to long lines.
 549     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 550     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 551     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 552     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 553     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 554     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 555     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 556     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 557     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 558     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 559     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 560     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 561     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 562     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 563     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 564     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 565     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 566     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 567     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 568     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 569     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 570     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 571     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 572     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 573     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 574     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 575     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 576     bfd_elf32_bigarm_symbian_vec)
 577                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 578     bfd_elf32_bigarm_vxworks_vec)
 579                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 580     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 581     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 582     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 583     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 584     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 585     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 586     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 587     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 588     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 589     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 590     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 591     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 592     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 593     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 594     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 595     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 596     bfd_elf32_i386_vxworks_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 597     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 598     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 599     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 600     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 601     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 602     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 603     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 604     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 605     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 606     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 607     bfd_elf32_littlearm_symbian_vec)
 608                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 609     bfd_elf32_littlearm_vxworks_vec)
 610                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 611     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 612     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 613     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 614     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 615     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 616     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 617     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 618     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 619     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 620     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 621     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 622     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 623     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 624     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 625     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 626     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 627     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 628     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 629     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 630     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 631     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 632     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 633     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 634     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 635     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 636     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 637     # FIXME: We include cofflink.lo not because it's needed for
 638     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 639     # which needs it but does not list it.  Should be fixed in right place.
 640     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 641     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 642     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 643     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 644     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 645     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 646     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 647     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 648     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 649     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 650     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 651     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 652     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 653     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf32.lo $elf" ;;
 654     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 655     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 656     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 657     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 658     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 659     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 660     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 661     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 662     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 663     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 664     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 665     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 666     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 667     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 668     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 669     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 670     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 671     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 672     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 673     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 674     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 675     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 676     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 677     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 678     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 679     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 680     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 681     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 682     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 683     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf64.lo $elf"; target_size=64 ;;
 684     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 685     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 686     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 687     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 688     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 689     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 690     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 691     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 692     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 693     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 694     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 695     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 696     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 697     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 698     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 699     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 700     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 701     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 702     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 703     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 704     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 705     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 706     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 707     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 708     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 709     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 710     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 711     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 712     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 713     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 714     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 715     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 716     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 717     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 718     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 719     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 720     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 721     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 722     ieee_vec)                   tb="$tb ieee.lo" ;;
 723     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 724     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 725     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 726     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 727     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 728     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 729     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 730     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 731     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 732     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 733     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 734     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 735     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 736     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 737     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 738     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 739     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 740     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 741     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 742     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 743     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 744     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 745     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 746     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 747     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 748     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 749     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 750     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 751     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 752     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 753     pef_vec)                    tb="$tb pef.lo" ;;
 754     pef_xlib_vec)               tb="$tb pef.lo" ;;
 755     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 756     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 757     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 758     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 759     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 760     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 761     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 762     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 763     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 764     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 765     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 766     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 767     som_vec)                    tb="$tb som.lo" ;;
 768     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 769     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 770     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 771     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 772     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 773     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 774     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 775     sym_vec)                    tb="$tb xsym.lo" ;;
 776     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 777     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 778     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 779     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 780     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 781     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 782     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 783     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 784     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 785     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 786     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 787     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 788     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 789     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 790     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 791     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 792     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 793     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 794     versados_vec)               tb="$tb versados.lo" ;;
 795     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 796     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 797     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 798     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 799     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 800
 801     # These appear out of order in targets.c
 802     srec_vec)                   tb="$tb srec.lo" ;;
 803     symbolsrec_vec)             tb="$tb srec.lo" ;;
 804     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 805     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 806     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 807
 808     "")                 ;;
 809     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 810     esac
 811
 812     if test ${target_size} = 64; then
 813         target64=true
 814     fi
 815     if test x"${vec}" = x"${defvec}"; then
 816         bfd_default_target_size=${target_size}
 817     fi
 818 done
 819
 820 # Target architecture .o files.
 821 # A couple of CPUs use shorter file names to avoid problems on DOS
 822 # filesystems.
 823 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 824
 825 # Weed out duplicate .o files.
 826 f=""
 827 for i in $tb ; do
 828     case " $f " in
 829     *" $i "*) ;;
 830     *) f="$f $i" ;;
 831     esac
 832 done
 833 tb="$f"
 834
 835 f=""
 836 for i in $ta ; do
 837     case " $f " in
 838     *" $i "*) ;;
 839     *) f="$f $i" ;;
 840     esac
 841 done
 842 ta="$f"
 843
 844 bfd_backends="$tb"
 845 bfd_machines="$ta"
 846
 847 if test x${all_targets} = xtrue ; then
 848   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 849   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 850   selvecs=
 851   havevecs=
 852   selarchs=
 853   test -n "$assocvecs" &&
 854     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 855 else    # all_targets is true
 856   # Only set these if they will be nonempty, for the clever echo.
 857   havevecs=
 858   assocvecs=
 859   test -n "$selvecs" &&
 860     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 861   test -n "$selvecs" &&
 862     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 863   test -n "$selarchs" &&
 864     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 865 fi      # all_targets is true
 866
 867 case ${host64}-${target64}-${want64} in
 868   *true*)
 869     wordsize=64
 870     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 871     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 872     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 873       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 874       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 875     fi
 876     if test -n "$GCC" ; then
 877        bad_64bit_gcc=no;
 878        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 879        # Add more tests for gcc versions with non-working 64-bit support here.
 880        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 881                     bad_64bit_gcc=yes;
 882                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 883                     AC_MSG_RESULT(no))
 884        if test $bad_64bit_gcc = yes ; then
 885          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 886        fi
 887     fi
 888     ;;
 889   false-false-false)
 890     wordsize=32
 891     bfd_libs='$(BFD32_LIBS)'
 892     all_backends='$(BFD32_BACKENDS)'
 893     ;;
 894 esac
 895
 896 AC_SUBST(wordsize)
 897 AC_SUBST(bfd_libs)
 898 AC_SUBST(all_backends)
 899 AC_SUBST(bfd_backends)
 900 AC_SUBST(bfd_machines)
 901 AC_SUBST(bfd_default_target_size)
 902
 903 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 904 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 905 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 906 # Hopefully a reasonable assumption since fseeko et.al. should be
 907 # upward compatible.
 908 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 909 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 910     AC_CHECK_SIZEOF(off_t)
 911 fi
 912 AC_MSG_CHECKING([file_ptr type])
 913 bfd_file_ptr="long"
 914 bfd_ufile_ptr="unsigned long"
 915 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 916         -o x"${ac_cv_sizeof_off_t}" = x8; then
 917     bfd_file_ptr=BFD_HOST_64_BIT
 918     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 919 fi
 920 AC_MSG_RESULT($bfd_file_ptr)
 921 AC_SUBST(bfd_file_ptr)
 922 AC_SUBST(bfd_ufile_ptr)
 923
 924
 925 tdefaults=""
 926 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 927 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 928 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 929 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 930 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 931 AC_SUBST(tdefaults)
 932
 933 dnl AC_CHECK_HEADERS(sys/mman.h)
 934 AC_FUNC_MMAP
 935 AC_CHECK_FUNCS(madvise mprotect)
 936 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 937   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 938 esac
 939
 940 rm -f doc/config.status
 941 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 942 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 943 AC_OUTPUT
 944