config-scripts/cups-pam.m4

   1 dnl
   2 dnl "$Id: cups-pam.m4,v 1.7 2002/12/17 18:56:39 swdev Exp $"
   3 dnl
   4 dnl   PAM stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2003 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636-3111 USA
  19 dnl
  20 dnl       Voice: (301) 373-9603
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 AC_ARG_ENABLE(pam, [  --enable-pam            turn on PAM support, default=yes])
  26
  27 dnl Don't use PAM with AIX...
  28 if test $uname = AIX; then
  29         enable_pam=no
  30 fi
  31
  32 PAMDIR=""
  33 PAMLIBS=""
  34 PAMMOD="pam_unknown.so"
  35
  36 if test x$enable_pam != xno; then
  37         SAVELIBS="$LIBS"
  38
  39         AC_CHECK_LIB(dl,dlopen)
  40         AC_CHECK_LIB(pam,pam_start)
  41         AC_CHECK_HEADER(pam/pam_appl.h,AC_DEFINE(HAVE_PAM_PAM_APPL_H))
  42
  43         if test x$ac_cv_lib_pam_pam_start != xno; then
  44                 if test x$ac_cv_lib_dl_dlopen != xno; then
  45                         PAMLIBS="-lpam -ldl"
  46                 else
  47                         PAMLIBS="-lpam"
  48                 fi
  49                 if test -d /etc/pam.d; then
  50                         PAMDIR="/etc/pam.d"
  51                 fi
  52         fi
  53
  54         LIBS="$SAVELIBS"
  55
  56         # This test might need to be updated as Linux distributors move
  57         # things around...
  58         for mod in pam_unix2.so pam_unix.so pam_pwdb.so; do
  59                 if test -f /lib/security/$mod; then
  60                         PAMMOD="$mod"
  61                 fi
  62         done
  63 fi
  64
  65 AC_SUBST(PAMDIR)
  66 AC_SUBST(PAMLIBS)
  67 AC_SUBST(PAMMOD)
  68
  69 dnl
  70 dnl End of "$Id: cups-pam.m4,v 1.7 2002/12/17 18:56:39 swdev Exp $".
  71 dnl