configure.ac

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include <dirpaths.h>])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=$(echo $DATE | awk -F- '{print $1}' | sed -e '/^[[1-9]]$/s/^/0/')
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP.$date_spec"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 dnl
  67 dnl Use diet libc
  68 dnl
  69 WITH_DIET_LIBC=
  70 AC_ARG_WITH([diet-libc],
  71 [  --with-diet-libc        use diet libc],
  72 CC="diet cc -nostdinc"
  73 WITH_DIET_LIBC=yes
  74 if test -z "$LIBS"
  75 then
  76         LIBS="-lcompat"
  77 else
  78         LIBS="$LIBS -lcompat"
  79 fi
  80 AC_MSG_RESULT(CC=$CC))dnl
  81 dnl
  82 AC_CANONICAL_HOST
  83 dnl
  84 dnl Check to see if libdl exists for the sake of dlopen
  85 dnl
  86 DLOPEN_LIB=''
  87 AC_CHECK_LIB(dl, dlopen,
  88 [DLOPEN_LIB=-ldl
  89 AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if dlopen/libdl exists])])
  90 AC_SUBST(DLOPEN_LIB)
  91 dnl
  92 AC_ARG_WITH([cc],
  93 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  94 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  95 dnl
  96 AC_ARG_WITH([ccopts],
  97 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  98 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  99 dnl
 100 AC_ARG_WITH([ldopts],
 101 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 102 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 103 dnl
 104 AC_PROG_CC
 105 if test "$GCC" = yes; then
 106    RDYNAMIC="-rdynamic"
 107    AC_SUBST(RDYNAMIC)
 108 fi
 109 AC_PROG_CPP
 110 dnl
 111 dnl Alpha computers use fast and imprecise floating point code that may
 112 dnl miss exceptions by default. Force sane options if we're using GCC.
 113 AC_MSG_CHECKING(for additional special compiler flags)
 114 if test "$GCC" = yes
 115 then
 116     case "$host_cpu" in
 117         alpha)          addcflags="-mieee" ;;
 118     esac
 119 fi
 120 if test "x$addcflags" != x
 121 then
 122     AC_MSG_RESULT($addcflags)
 123     CFLAGS="$addcflags $CFLAGS"
 124 else
 125     AC_MSG_RESULT([[(none)]])
 126 fi
 127 AC_USE_SYSTEM_EXTENSIONS
 128 dnl
 129 dnl Set default values for library extentions.  Will be dealt with after
 130 dnl parsing configuration opions, which may modify these
 131 dnl
 132 LIB_EXT=.a
 133 STATIC_LIB_EXT=.a
 134 PROFILED_LIB_EXT=.a
 135 dnl
 136 dnl Allow separate `root_prefix' to be specified
 137 dnl
 138 AC_ARG_WITH([root-prefix],
 139 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 140 root_prefix=$withval,
 141 root_prefix=NONE)dnl
 142 dnl
 143 dnl handle --enable-maintainer-mode
 144 dnl
 145 AC_ARG_ENABLE([maintainer-mode],
 146 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 147 if test "$enableval" = "no"
 148 then
 149         MAINTAINER_CMT=#
 150         AC_MSG_RESULT([Disabling maintainer mode])
 151 else
 152         MAINTAINER_CMT=
 153         AC_MSG_RESULT([Enabling maintainer mode])
 154 fi
 155 ,
 156 MAINTAINER_CMT=#
 157 AC_MSG_RESULT([Disabling maintainer mode by default])
 158 )
 159 AC_SUBST(MAINTAINER_CMT)
 160 dnl
 161 dnl handle --enable-symlink-install
 162 dnl
 163 AC_ARG_ENABLE([symlink-install],
 164 [  --enable-symlink-install use symlinks when installing instead of hard links],
 165 if test "$enableval" = "no"
 166 then
 167         LINK_INSTALL_FLAGS=-f
 168         AC_MSG_RESULT([Disabling symlinks for install])
 169 else
 170         LINK_INSTALL_FLAGS=-sf
 171         AC_MSG_RESULT([Enabling symlinks for install])
 172 fi
 173 ,
 174 LINK_INSTALL_FLAGS=-f
 175 AC_MSG_RESULT([Disabling symlinks for install by default])
 176 )
 177 AC_SUBST(LINK_INSTALL_FLAGS)
 178 dnl
 179 dnl handle --enable-relative-symlinks
 180 dnl
 181 relative_symlink_defined=
 182 AC_ARG_ENABLE([relative-symlinks],
 183 [  --enable-relative-symlinks use relative symlinks when installing],
 184 if test "$enableval" = "no"
 185 then
 186         SYMLINK_RELATIVE=
 187         relative_symlink_defined=yes
 188         AC_MSG_RESULT([Disabling relative symlinks for install])
 189 else
 190         SYMLINK_RELATIVE=--relative
 191         relative_symlink_defined=yes
 192         AC_MSG_RESULT([Enabling relative symlinks for install])
 193 fi)
 194 AC_ARG_ENABLE([symlink-relative-symlinks],,
 195 if test "$enableval" = "no"
 196 then
 197         SYMLINK_RELATIVE=yes
 198         AC_MSG_RESULT([Disabling relative symlinks for install])
 199 else
 200         SYMLINK_RELATIVE=--relative
 201         AC_MSG_RESULT([Enabling relative symlinks for install])
 202 fi
 203 ,
 204 if test -z "$relative_symlink_defined"
 205 then
 206         SYMLINK_RELATIVE=
 207 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 208 fi
 209 )
 210 AC_SUBST(SYMLINK_RELATIVE)
 211 dnl
 212 dnl handle --enable-symlink-build
 213 dnl
 214 AC_ARG_ENABLE([symlink-build],
 215 [  --enable-symlink-build  use symlinks while building instead of hard links],
 216 if test "$enableval" = "no"
 217 then
 218         LINK_BUILD_FLAGS=
 219         AC_MSG_RESULT([Disabling symlinks for build])
 220 else
 221         LINK_BUILD_FLAGS=-s
 222         AC_MSG_RESULT([Enabling symlinks for build])
 223 fi
 224 ,
 225 LINK_BUILD_FLAGS=
 226 AC_MSG_RESULT([Disabling symlinks for build by default])
 227 )
 228 AC_SUBST(LINK_BUILD_FLAGS)
 229 dnl
 230 dnl handle --enable-verbose-makecmds
 231 dnl
 232 AC_ARG_ENABLE([verbose-makecmds],
 233 [  --enable-verbose-makecmds enable verbose make command output],
 234 if test "$enableval" = "no"
 235 then
 236         AC_MSG_RESULT([Disabling verbose make commands])
 237         E=@echo
 238         ES=echo
 239         Q=@
 240 else
 241         AC_MSG_RESULT([Enabling verbose make commands])
 242         E=@\\#
 243         ES=\\#
 244         Q=
 245 fi
 246 ,
 247 AC_MSG_RESULT([Disabling verbose make commands])
 248 E=@echo
 249 ES=echo
 250 Q=@
 251 )
 252 AC_SUBST(E)
 253 AC_SUBST(ES)
 254 AC_SUBST(Q)
 255 dnl
 256 dnl This needs to be before all of the --enable-*-shlibs options
 257 dnl
 258 E2_PKG_CONFIG_STATIC=--static
 259 LDFLAG_DYNAMIC=
 260 PRIVATE_LIBS_CMT=
 261 dnl
 262 dnl handle --enable-elf-shlibs
 263 dnl
 264 AC_ARG_ENABLE([elf-shlibs],
 265 [  --enable-elf-shlibs    select ELF shared libraries],
 266 if test "$enableval" = "no"
 267 then
 268         ELF_CMT=#
 269         MAKEFILE_ELF=/dev/null
 270         AC_MSG_RESULT([Disabling ELF shared libraries])
 271 else
 272         E2_PKG_CONFIG_STATIC=
 273         ELF_CMT=
 274         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 275         [case "$host_os" in
 276         solaris2.*)
 277                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 278         ;;
 279         esac]
 280         BINARY_TYPE=elfbin
 281         LIB_EXT=.so
 282         PRIVATE_LIBS_CMT=#
 283         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 284         AC_MSG_RESULT([Enabling ELF shared libraries])
 285 fi
 286 ,
 287 MAKEFILE_ELF=/dev/null
 288 ELF_CMT=#
 289 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 290 )
 291 AC_SUBST(ELF_CMT)
 292 AC_SUBST_FILE(MAKEFILE_ELF)
 293 dnl
 294 dnl handle --enable-bsd-shlibs
 295 dnl
 296 AC_ARG_ENABLE([bsd-shlibs],
 297 [  --enable-bsd-shlibs    select BSD shared libraries],
 298 if test "$enableval" = "no"
 299 then
 300         BSDLIB_CMT=#
 301         MAKEFILE_BSDLIB=/dev/null
 302         AC_MSG_RESULT([Disabling BSD shared libraries])
 303 else
 304         E2_PKG_CONFIG_STATIC=
 305         BSDLIB_CMT=
 306         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 307         LIB_EXT=.so
 308         [case "$host_os" in
 309         darwin*)
 310                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 311                 LIB_EXT=.dylib
 312         ;;
 313         esac]
 314         AC_MSG_RESULT([Enabling BSD shared libraries])
 315 fi
 316 ,
 317 MAKEFILE_BSDLIB=/dev/null
 318 BSDLIB_CMT=#
 319 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 320 )
 321 AC_SUBST(BSDLIB_CMT)
 322 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 323 dnl
 324 dnl handle --enable-profile
 325 dnl
 326 AC_ARG_ENABLE([profile],
 327 [  --enable-profile       build profiling libraries],
 328 if test "$enableval" = "no"
 329 then
 330         PROFILE_CMT=#
 331         MAKEFILE_PROFILE=/dev/null
 332         AC_MSG_RESULT([Disabling profiling libraries])
 333 else
 334         PROFILE_CMT=
 335         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 336         PROFILED_LIB_EXT=_p.a
 337         AC_MSG_RESULT([Building profiling libraries])
 338 fi
 339 ,
 340 PROFILE_CMT=#
 341 MAKEFILE_PROFILE=/dev/null
 342 AC_MSG_RESULT([Disabling profiling libraries by default])
 343 )
 344 AC_SUBST(PROFILE_CMT)
 345 AC_SUBST_FILE(MAKEFILE_PROFILE)
 346 dnl
 347 dnl handle --enable-gcov
 348 dnl
 349 AC_ARG_ENABLE([gcov],
 350 [  --enable-gcov                  build for coverage testing using gcov],
 351 if test "$enableval" = "yes"
 352 then
 353         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 354         LDFLAGS="-fprofile-arcs -ftest-coverage"
 355         AC_MSG_RESULT([Enabling gcov support])
 356 fi
 357 )
 358 dnl
 359 dnl handle --enable-hardening
 360 dnl
 361 CFLAGS_SHLIB="${CFLAGS_SHLIB:-$CFLAGS}"
 362 CFLAGS_STLIB="${CFLAGS_STLIB:-$CFLAGS}"
 363 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
 364 LDFLAGS_STATIC=${LDFLAGS_STATIC:-$LDFLAGS}
 365 AC_ARG_ENABLE([hardening],
 366 [  --enable-hardening             build for coverage testing using gcov],
 367 if test "$enableval" = "yes"
 368 then
 369         HARDEN_CFLAGS="-D_FORTIFY_SOURCE=2 -fstack-protector-strong"
 370         HARDEN_LDFLAGS=["-Wl,-z,relro -Wl,-z,now"]
 371         CFLAGS="$CFLAGS $HARDEN_CFLAGS -fPIE"
 372         CFLAGS_SHLIB="$CFLAGS_SHLIB $HARDEN_CFLAGS"
 373         CFLAGS_STLIB="$CFLAGS_STLIB $HARDEN_CFLAGS -fPIE"
 374         LDFLAGS="$LDFLAGS $HARDEN_LDFLAGS -fPIE -pie"
 375         LDFLAGS_STATIC="$LDFLAGS_STATIC $HARDEN_LDFLAGS"
 376         LDFLAGS_SHLIB="$LDFLAGS_SHLIB $HARDEN_LDFLAGS"
 377         AC_MSG_RESULT([Enabling hardening support])
 378 fi
 379 )
 380 dnl
 381 dnl Substitute library extensions
 382 dnl
 383 AC_SUBST(LIB_EXT)
 384 AC_SUBST(STATIC_LIB_EXT)
 385 AC_SUBST(PROFILED_LIB_EXT)
 386 AC_SUBST(LDFLAG_DYNAMIC)
 387 AC_SUBST(PRIVATE_LIBS_CMT)
 388 dnl
 389 dnl handle --enable-jbd-debug
 390 dnl
 391 AC_ARG_ENABLE([jbd-debug],
 392 [  --enable-jbd-debug     enable journal debugging],
 393 if test "$enableval" = "no"
 394 then
 395         AC_MSG_RESULT([Disabling journal debugging])
 396 else
 397         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 398                 [Define to 1 if debugging ext3/4 journal code])
 399         AC_MSG_RESULT([Enabling journal debugging])
 400 fi
 401 ,
 402 AC_MSG_RESULT([Disabling journal debugging by default])
 403 )
 404 dnl
 405 dnl handle --enable-blkid-debug
 406 dnl
 407 AC_ARG_ENABLE([blkid-debug],
 408 [  --enable-blkid-debug    enable blkid debugging],
 409 if test "$enableval" = "no"
 410 then
 411         AC_MSG_RESULT([Disabling blkid debugging])
 412 else
 413         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 414                 [Define to 1 if debugging the blkid library])
 415         AC_MSG_RESULT([Enabling blkid debugging])
 416 fi
 417 ,
 418 AC_MSG_RESULT([Disabling blkid debugging by default])
 419 )
 420 dnl
 421 dnl handle --enable-testio-debug
 422 dnl
 423 AC_ARG_ENABLE([testio-debug],
 424 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 425 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 426         [Define to 1 if the testio I/O manager should be enabled])
 427 if test "$enableval" = "no"
 428 then
 429         AC_MSG_RESULT([Disabling testio debugging])
 430         TEST_IO_CMT="#"
 431 else
 432         TEST_IO_CMT=
 433         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 434         AC_MSG_RESULT([Enabling testio debugging])
 435 fi
 436 ,
 437 AC_MSG_RESULT([Enabling testio debugging by default])
 438 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 439 TEST_IO_CMT=
 440 )
 441 AC_SUBST(TEST_IO_CMT)
 442 dnl
 443 dnl handle --disable-libuuid
 444 dnl
 445 PKG_PROG_PKG_CONFIG
 446 LIBUUID=
 447 DEPLIBUUID=
 448 STATIC_LIBUUID=
 449 DEPSTATIC_LIBUUID=
 450 PROFILED_LIBUUID=
 451 DEPPROFILED_LIBUUID=
 452 UUID_CMT=
 453 AC_ARG_ENABLE([libuuid],
 454 [  --enable-libuuid       build and use private uuid library],
 455 if test "$enableval" = "no"
 456 then
 457         if test -z "$PKG_CONFIG"; then
 458                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 459         fi
 460
 461         AC_CHECK_LIB(uuid, uuid_generate,
 462                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 463                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 464                 [AC_MSG_ERROR([external uuid library not found])])
 465         PROFILED_LIBUUID=$LIBUUID
 466         UUID_CMT=#
 467         AC_MSG_RESULT([Disabling private uuid library])
 468 else
 469         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 470         DEPLIBUUID=$LIBUUID
 471         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 472         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 473         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 474         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 475         AC_MSG_RESULT([Enabling private uuid library])
 476 fi
 477 ,
 478 if test -n "$PKG_CONFIG"; then
 479         AC_CHECK_LIB(uuid, uuid_generate,
 480                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 481                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`])
 482 fi
 483 if test -n "$LIBUUID"; then
 484         PROFILED_LIBUUID=$LIBUUID
 485         UUID_CMT=#
 486         AC_MSG_RESULT([Using system uuid by default])
 487 else
 488         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 489         DEPLIBUUID=$LIBUUID
 490         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 491         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 492         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 493         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 494         AC_MSG_RESULT([Enabling private uuid library by default])
 495 fi
 496 )
 497 AC_SUBST(LIBUUID)
 498 AC_SUBST(DEPLIBUUID)
 499 AC_SUBST(STATIC_LIBUUID)
 500 AC_SUBST(DEPSTATIC_LIBUUID)
 501 AC_SUBST(PROFILED_LIBUUID)
 502 AC_SUBST(DEPPROFILED_LIBUUID)
 503 AC_SUBST(UUID_CMT)
 504 dnl
 505 dnl handle --disable-libblkid
 506 dnl
 507 PKG_PROG_PKG_CONFIG
 508 LIBBLKID=
 509 DEPLIBBLKID=
 510 STATIC_LIBBLKID=
 511 DEPSTATIC_LIBBLKID=
 512 PROFILED_LIBBLKID=
 513 DEPPROFILED_LIBBLKID=
 514 BLKID_CMT=
 515 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 516 AC_ARG_ENABLE([libblkid],
 517 [  --enable-libblkid      build and use private blkid library],
 518 if test "$enableval" = "no"
 519 then
 520         if test -z "$PKG_CONFIG"; then
 521                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 522         fi
 523
 524         AC_CHECK_LIB(blkid, blkid_get_cache,
 525                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 526                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 527                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 528         BLKID_CMT=#
 529         PROFILED_LIBBLKID=$LIBBLKID
 530         AC_MSG_RESULT([Disabling private blkid library])
 531 else
 532         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 533         DEPLIBBLKID=$LIBBLKID
 534         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 535         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 536         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 537         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 538         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 539         AC_MSG_RESULT([Enabling private blkid library])
 540 fi
 541 ,
 542 if test -n "$PKG_CONFIG"; then
 543         AC_CHECK_LIB(blkid, blkid_get_cache,
 544                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 545                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`])
 546 fi
 547 if test -n "$LIBBLKID"; then
 548         BLKID_CMT=#
 549         PROFILED_LIBBLKID=$LIBBLKID
 550         AC_MSG_RESULT([Using system blkid library by default])
 551 else
 552         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 553         DEPLIBBLKID=$LIBBLKID
 554         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 555         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 556         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 557         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 558         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 559         AC_MSG_RESULT([Enabling private blkid library by default])
 560 fi
 561 )
 562 AC_SUBST(LIBBLKID)
 563 AC_SUBST(DEPLIBBLKID)
 564 AC_SUBST(STATIC_LIBBLKID)
 565 AC_SUBST(DEPSTATIC_LIBBLKID)
 566 AC_SUBST(PROFILED_LIBBLKID)
 567 AC_SUBST(DEPPROFILED_LIBBLKID)
 568 AC_SUBST(BLKID_CMT)
 569 dnl
 570 dnl handle --disable-backtrace
 571 dnl
 572 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 573 AC_ARG_ENABLE([backtrace],
 574 [  --disable-backtrace    disable use backtrace],
 575 if test "$enableval" = "no"
 576 then
 577         AC_MSG_RESULT([Disabling use of backtrace])
 578         AC_DEFINE(DISABLE_BACKTRACE, 1)
 579 else
 580         AC_MSG_RESULT([Enabling use of backtrace])
 581 fi
 582 ,
 583 AC_MSG_RESULT([Enabling use of backtrace by default])
 584 )
 585 dnl
 586 dnl handle --enable-debugfs
 587 dnl
 588 AC_ARG_ENABLE([debugfs],
 589 [  --disable-debugfs      disable support of debugfs program],
 590 if test "$enableval" = "no"
 591 then
 592         AC_MSG_RESULT([Disabling debugfs support])
 593         DEBUGFS_CMT="#"
 594 else
 595         DEBUGFS_CMT=
 596         AC_MSG_RESULT([Enabling debugfs support])
 597 fi
 598 ,
 599 AC_MSG_RESULT([Enabling debugfs support by default])
 600 DEBUGFS_CMT=
 601 )
 602 AC_SUBST(DEBUGFS_CMT)
 603 dnl
 604 dnl handle --enable-imager
 605 dnl
 606 AC_ARG_ENABLE([imager],
 607 [  --disable-imager       disable support of e2image program],
 608 if test "$enableval" = "no"
 609 then
 610         AC_MSG_RESULT([Disabling e2image support])
 611         IMAGER_CMT="#"
 612 else
 613         IMAGER_CMT=
 614         AC_MSG_RESULT([Enabling e2image support])
 615 fi
 616 ,
 617 AC_MSG_RESULT([Enabling e2image support by default])
 618 IMAGER_CMT=
 619 )
 620 AC_SUBST(IMAGER_CMT)
 621 dnl
 622 dnl handle --enable-resizer
 623 dnl
 624 AC_ARG_ENABLE([resizer],
 625 [  --disable-resizer      disable support of e2resize program],
 626 if test "$enableval" = "no"
 627 then
 628         AC_MSG_RESULT([Disabling e2resize support])
 629         RESIZER_CMT="#"
 630 else
 631         RESIZER_CMT=
 632         AC_MSG_RESULT([Enabling e2resize support])
 633 fi
 634 ,
 635 AC_MSG_RESULT([Enabling e2resize support by default])
 636 RESIZER_CMT=
 637 )
 638 AC_SUBST(RESIZER_CMT)
 639 dnl
 640 dnl handle --enable-defrag
 641 dnl
 642 AC_ARG_ENABLE([defrag],
 643 [  --disable-defrag       disable support of e4defrag program],
 644 if test "$enableval" = "no"
 645 then
 646         AC_MSG_RESULT([Disabling e4defrag support])
 647         DEFRAG_CMT="#"
 648 else
 649         DEFRAG_CMT=
 650         AC_MSG_RESULT([Enabling e4defrag support])
 651 fi
 652 ,
 653 if test -z "$WITH_DIET_LIBC"
 654 then
 655         AC_MSG_RESULT([Enabling e4defrag support by default])
 656         DEFRAG_CMT=
 657 else
 658         AC_MSG_RESULT([Disabling e4defrag support by default])
 659         DEFRAG_CMT="#"
 660 fi
 661 )
 662 AC_SUBST(DEFRAG_CMT)
 663 dnl
 664 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 665 dnl
 666 AC_ARG_ENABLE([fsck],
 667 [  --enable-fsck           build fsck wrapper program],
 668 [if test "$enableval" = "no"
 669 then
 670         FSCK_PROG='' FSCK_MAN=''
 671         AC_MSG_RESULT([Not building fsck wrapper])
 672 else
 673         FSCK_PROG=fsck FSCK_MAN=fsck.8
 674         AC_MSG_RESULT([Building fsck wrapper])
 675 fi]
 676 ,
 677 [case "$host_os" in
 678   gnu*)
 679     FSCK_PROG='' FSCK_MAN=''
 680     AC_MSG_RESULT([Not building fsck wrapper by default])
 681     ;;
 682   *)
 683     FSCK_PROG=fsck FSCK_MAN=fsck.8
 684     AC_MSG_RESULT([Building fsck wrapper by default])
 685 esac]
 686 )
 687 AC_SUBST(FSCK_PROG)
 688 AC_SUBST(FSCK_MAN)
 689 dnl
 690 dnl See whether to install the `e2initrd-helper' program
 691 dnl
 692 AC_ARG_ENABLE([e2initrd-helper],
 693 [  --enable-e2initrd-helper build e2initrd-helper program],
 694 [if test "$enableval" = "no"
 695 then
 696         E2INITRD_PROG='' E2INITRD_MAN=''
 697         AC_MSG_RESULT([Not building e2initrd helper])
 698 else
 699         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 700         AC_MSG_RESULT([Building e2initrd helper])
 701 fi]
 702 ,
 703 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 704 AC_MSG_RESULT([Building e2initrd helper by default])
 705 )
 706 AC_SUBST(E2INITRD_PROG)
 707 AC_SUBST(E2INITRD_MAN)
 708 dnl
 709 dnl
 710 dnl
 711 AC_ARG_ENABLE([tls],
 712 [  --disable-tls           disable use of thread local support],
 713 [if test "$enableval" = "no"
 714 then
 715         try_tls=""
 716         AC_MSG_RESULT([Disabling thread local support])
 717 else
 718         try_tls="yes"
 719         AC_MSG_RESULT([Enabling thread local support])
 720 fi]
 721 ,
 722 if test -n "$WITH_DIET_LIBC"
 723 then
 724         try_tls=""
 725         AC_MSG_RESULT([Diet libc does not support thread local support])
 726 else
 727         try_tls="yes"
 728         AC_MSG_RESULT([Try using thread local support by default])
 729 fi
 730 )
 731 if test "$try_tls" = "yes"
 732 then
 733 AX_TLS
 734 fi
 735 dnl
 736 dnl
 737 dnl
 738 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 739 AC_ARG_ENABLE([uuidd],
 740 [  --disable-uuidd         disable building the uuid daemon],
 741 [if test "$enableval" = "no"
 742 then
 743         AC_MSG_RESULT([Not building uuidd])
 744         UUIDD_CMT="#"
 745 else
 746         AC_DEFINE(USE_UUIDD, 1)
 747         UUIDD_CMT=""
 748         AC_MSG_RESULT([Building uuidd])
 749 fi]
 750 ,
 751 AC_DEFINE(USE_UUIDD, 1)
 752 if test -z "$UUID_CMT"
 753 then
 754         UUIDD_CMT=""
 755         AC_MSG_RESULT([Building uuidd by default])
 756 else
 757         UUIDD_CMT="#"
 758         AC_MSG_RESULT([Disabling uuidd by default])
 759 fi
 760 )
 761 AC_SUBST(UUIDD_CMT)
 762 dnl
 763 dnl handle --disable-mmp
 764 dnl
 765 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 766 AC_ARG_ENABLE([mmp],
 767 [  --disable-mmp           disable support mmp, Multi Mount Protection],
 768 if test "$enableval" = "no"
 769 then
 770         AC_MSG_RESULT([Disabling mmp support])
 771 else
 772         AC_MSG_RESULT([Enabling mmp support])
 773         AC_DEFINE(CONFIG_MMP, 1)
 774 fi
 775 ,
 776 AC_MSG_RESULT([Enabling mmp support by default])
 777 AC_DEFINE(CONFIG_MMP, 1)
 778 )
 779 dnl
 780 dnl handle --disable-tdb
 781 dnl
 782 AH_TEMPLATE([CONFIG_TDB], [Define to 1 to enable tdb support])
 783 AC_ARG_ENABLE([tdb],
 784 [  --disable-tdb           disable tdb support],
 785 if test "$enableval" = "no"
 786 then
 787         AC_MSG_RESULT([Disabling tdb support])
 788         TDB_CMT="#"
 789         TDB_MAN_COMMENT='.\"'
 790 else
 791         AC_MSG_RESULT([Enabling tdb support])
 792         AC_DEFINE(CONFIG_TDB, 1)
 793         TDB_CMT=""
 794         TDB_MAN_COMMENT=""
 795 fi
 796 ,
 797 AC_MSG_RESULT([Enabling mmp support by default])
 798 AC_DEFINE(CONFIG_TDB, 1)
 799 TDB_CMT=""
 800 TDB_MAN_COMMENT=""
 801 )
 802 AC_SUBST(TDB_CMT)
 803 AC_SUBST(TDB_MAN_COMMENT)
 804 dnl
 805 dnl handle --disable-bmap-stats
 806 dnl
 807 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 808 AC_ARG_ENABLE([bmap-stats],
 809 [  --disable-bmap-stats    disable collection of bitmap stats.],
 810 if test "$enableval" = "no"
 811 then
 812         AC_MSG_RESULT([Disabling bitmap statistics support])
 813 else
 814         AC_MSG_RESULT([Enabling bitmap statistics support])
 815         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 816 fi
 817 ,
 818 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 819 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 820 )
 821 dnl
 822 dnl handle --enable-bmap-stats-ops
 823 dnl
 824 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 825 AC_ARG_ENABLE([bmap-stats-ops],
 826 [  --enable-bmap-stats-ops enable collection of additional bitmap stats],
 827 if test "$enableval" = "no"
 828 then
 829         AC_MSG_RESULT([Disabling additional bitmap statistics])
 830 else
 831         dnl There has to be a better way!
 832         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 833          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 834
 835         AC_MSG_RESULT([Enabling additional bitmap statistics])
 836         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 837 fi
 838 ,
 839 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 840 )
 841 dnl
 842 dnl
 843 dnl
 844 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 845 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 846 dnl
 847 dnl Add internationalization support, using gettext.
 848 dnl
 849 GETTEXT_PACKAGE=e2fsprogs
 850 PACKAGE=e2fsprogs
 851 VERSION="$E2FSPROGS_VERSION"
 852 VERSION=0.14.1
 853 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 854 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 855 AC_SUBST(GETTEXT_PACKAGE)
 856 AC_SUBST(PACKAGE)
 857 AC_SUBST(VERSION)
 858
 859 AM_GNU_GETTEXT
 860 dnl
 861 dnl End of configuration options
 862 dnl
 863 AC_SUBST(BINARY_TYPE)
 864 AC_PROG_MAKE_SET
 865 CHECK_GNU_MAKE
 866 AC_PATH_PROG(LN, ln, ln)
 867 AC_PROG_LN_S
 868 AC_PATH_PROG(MV, mv, mv)
 869 AC_PATH_PROG(CP, cp, cp)
 870 AC_PATH_PROG(RM, rm, rm)
 871 AC_PATH_PROG(CHMOD, chmod, :)
 872 AC_PROG_AWK
 873 AC_PROG_EGREP
 874 AC_PATH_PROG(SED, sed, sed)
 875 AC_PATH_PROG(PERL, perl, perl)
 876 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 877 AC_CHECK_TOOL(AR, ar, ar)
 878 AC_CHECK_TOOL(RANLIB, ranlib, :)
 879 AC_CHECK_TOOL(STRIP, strip, :)
 880 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 881 if test "_$MAKEINFO" = "_"; then
 882     MAKEINFO="@echo Makeinfo is missing. Info documentation will not be built.;true"
 883 else
 884     case "$MAKEINFO" in
 885       */missing.*)
 886         AC_MSG_WARN([
 887 *** Makeinfo is missing. Info documentation will not be built.])
 888         ;;
 889       *)
 890         ;;
 891     esac
 892 fi
 893 AC_SUBST(MAKEINFO)
 894 AC_PROG_INSTALL
 895 # See if we need a separate native compiler.
 896 if test $cross_compiling = no; then
 897   BUILD_CC="$CC"
 898   AC_SUBST(BUILD_CC)
 899 else
 900   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 901 fi
 902 AC_CHECK_HEADERS(m4_flatten([
 903         dirent.h
 904         errno.h
 905         execinfo.h
 906         getopt.h
 907         malloc.h
 908         mntent.h
 909         paths.h
 910         semaphore.h
 911         setjmp.h
 912         signal.h
 913         stdarg.h
 914         stdint.h
 915         stdlib.h
 916         termios.h
 917         termio.h
 918         unistd.h
 919         utime.h
 920         attr/xattr.h
 921         linux/falloc.h
 922         linux/fd.h
 923         linux/major.h
 924         linux/loop.h
 925         net/if_dl.h
 926         netinet/in.h
 927         sys/acl.h
 928         sys/disklabel.h
 929         sys/disk.h
 930         sys/file.h
 931         sys/ioctl.h
 932         sys/key.h
 933         sys/mkdev.h
 934         sys/mman.h
 935         sys/mount.h
 936         sys/prctl.h
 937         sys/resource.h
 938         sys/select.h
 939         sys/socket.h
 940         sys/sockio.h
 941         sys/stat.h
 942         sys/syscall.h
 943         sys/sysctl.h
 944         sys/sysmacros.h
 945         sys/time.h
 946         sys/types.h
 947         sys/un.h
 948         sys/wait.h
 949 ]))
 950 AC_CHECK_HEADERS(net/if.h,,,
 951 [[
 952 #if HAVE_SYS_TYPES_H
 953 #include <sys/types.h>
 954 #endif
 955 #if HAVE_SYS_SOCKET
 956 #include <sys/socket.h>
 957 #endif
 958 ]])
 959 AC_FUNC_VPRINTF
 960 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 961 dnl is not decleared.
 962 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 963                        [Define to 1 if dirent has d_reclen])],,
 964                 [#include <dirent.h>])
 965 AC_CHECK_MEMBERS([struct stat.st_atim])
 966 dnl Check to see if ssize_t was declared
 967 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
 968                 [Define to 1 if ssize_t declared])],,
 969               [#include <sys/types.h>])
 970 dnl
 971 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
 972 dnl it is, and on others it isn't..... Thank you glibc developers....
 973 dnl
 974 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
 975                         [Define to 1 if llseek declared in unistd.h])],,
 976               [#include <unistd.h>])
 977 dnl
 978 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
 979 dnl are so convoluted that I can't tell whether it will always be defined,
 980 dnl and if it isn't defined while lseek64 is defined in the library,
 981 dnl disaster will strike.
 982 dnl
 983 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
 984 dnl
 985 dnl
 986 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
 987                         [Define to 1 if lseek64 declared in unistd.h])],,
 988                 [#define _LARGEFILE_SOURCE
 989                  #define _LARGEFILE64_SOURCE
 990                  #include <unistd.h>])
 991 dnl
 992 dnl Word sizes...
 993 dnl
 994 AC_CHECK_SIZEOF(short)
 995 AC_CHECK_SIZEOF(int)
 996 AC_CHECK_SIZEOF(long)
 997 AC_CHECK_SIZEOF(long long)
 998 AC_CHECK_SIZEOF(off_t)
 999 AC_CHECK_SIZEOF(time_t)
1000 SIZEOF_SHORT=$ac_cv_sizeof_short
1001 SIZEOF_INT=$ac_cv_sizeof_int
1002 SIZEOF_LONG=$ac_cv_sizeof_long
1003 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1004 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1005 SIZEOF_TIME_T=$ac_cv_sizeof_time_t
1006 AC_SUBST(SIZEOF_SHORT)
1007 AC_SUBST(SIZEOF_INT)
1008 AC_SUBST(SIZEOF_LONG)
1009 AC_SUBST(SIZEOF_LONG_LONG)
1010 AC_SUBST(SIZEOF_OFF_T)
1011 AC_SUBST(SIZEOF_TIME_T)
1012 AC_C_BIGENDIAN
1013 if test $cross_compiling = no; then
1014   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1015 else
1016   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1017 fi
1018 ASM_TYPES_HEADER=./asm_types.h
1019 AC_SUBST_FILE(ASM_TYPES_HEADER)
1020 dnl
1021 dnl Save the configuration #defines needed for the public ext2fs.h
1022 dnl header file
1023 dnl
1024 echo "/* These defines are needed for the public ext2fs.h header file */" \
1025      > public_config.h
1026 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1027   uniq tmp_config.$$ >> public_config.h
1028 else
1029   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1030 fi
1031 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1032   uniq tmp_config.$$ >> public_config.h
1033 else
1034   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1035 fi
1036 rm -f tmp_config.$$
1037 PUBLIC_CONFIG_HEADER=./public_config.h
1038 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1039 dnl
1040 dnl See if we have inttypes.h and if intptr_t is defined
1041 dnl
1042 AC_CHECK_HEADERS([inttypes.h])
1043 AC_CHECK_TYPES(intptr_t)
1044 dnl
1045 dnl See if struct stat has a st_flags field, in which case we can get file
1046 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1047 dnl
1048 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1049 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1050         AC_TRY_COMPILE([#include <sys/stat.h>],
1051                 [struct stat stat; stat.st_flags = 0;],
1052                 [e2fsprogs_cv_struct_st_flags=yes],
1053                 [e2fsprogs_cv_struct_st_flags=no]))
1054 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1055 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1056   AC_MSG_CHECKING(whether st_flags field is useful)
1057   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1058         AC_TRY_COMPILE([#include <sys/stat.h>],
1059                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1060                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1061                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1062   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1063   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1064           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1065                 [Define to 1 if struct stat has st_flags])
1066   fi
1067 fi
1068 dnl
1069 dnl Check for the presence of SA_LEN
1070 dnl
1071 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1072                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1073                         [Define to 1 if if struct sockaddr contains sa_len]),,
1074         [#include <sys/types.h>
1075          #include <sys/socket.h>])
1076 dnl
1077 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1078 dnl the system-provided blkid library
1079 dnl
1080 if test -n "$BLKID_CMT"; then
1081   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1082 fi
1083 dnl
1084 AC_CHECK_FUNCS(m4_flatten([
1085         __secure_getenv
1086         add_key
1087         backtrace
1088         blkid_probe_get_topology
1089         blkid_probe_enable_partitions
1090         chflags
1091         fadvise64
1092         fallocate
1093         fallocate64
1094         fchown
1095         fdatasync
1096         fstat64
1097         ftruncate64
1098         futimes
1099         getcwd
1100         getdtablesize
1101         getmntinfo
1102         getpwuid_r
1103         getrlimit
1104         getrusage
1105         jrand48
1106         keyctl
1107         llistxattr
1108         llseek
1109         lseek64
1110         mallinfo
1111         mbstowcs
1112         memalign
1113         mempcpy
1114         mmap
1115         msync
1116         nanosleep
1117         open64
1118         pathconf
1119         posix_fadvise
1120         posix_fadvise64
1121         posix_memalign
1122         prctl
1123         pread
1124         pwrite
1125         pread64
1126         pwrite64
1127         secure_getenv
1128         setmntent
1129         setresgid
1130         setresuid
1131         snprintf
1132         srandom
1133         stpcpy
1134         strcasecmp
1135         strdup
1136         strnlen
1137         strptime
1138         strtoull
1139         sync_file_range
1140         sysconf
1141         usleep
1142         utime
1143         utimes
1144         valloc
1145 ]))
1146 dnl
1147 dnl Check to see if -lsocket is required (solaris) to make something
1148 dnl that uses socket() to compile; this is needed for the UUID library
1149 dnl
1150 SOCKET_LIB=''
1151 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1152 AC_SUBST(SOCKET_LIB)
1153 dnl
1154 dnl See if libmagic exists
1155 dnl
1156 AC_CHECK_LIB(magic, magic_file, [MAGIC_LIB=-lmagic
1157 AC_CHECK_HEADERS([magic.h])])
1158 if test "$ac_cv_lib_dl_dlopen" = yes ; then
1159    MAGIC_LIB=$DLOPEN_LIB
1160 fi
1161 AC_SUBST(MAGIC_LIB)
1162 dnl
1163 dnl Check to see if the FUSE library is -lfuse or -losxfuse
1164 dnl
1165 FUSE_CMT=
1166 FUSE_LIB=
1167 dnl osxfuse.dylib supersedes fuselib.dylib
1168 AC_ARG_ENABLE([fuse2fs],
1169 [  --disable-fuse2fs      do not build fuse2fs],
1170 if test "$enableval" = "no"
1171 then
1172         FUSE_CMT="#"
1173         AC_MSG_RESULT([Disabling fuse2fs])
1174 else
1175         AC_CHECK_HEADERS([pthread.h fuse.h], [],
1176 [AC_MSG_FAILURE([Cannot find fuse2fs headers.])],
1177 [#define _FILE_OFFSET_BITS      64
1178 #define FUSE_USE_VERSION 29])
1179
1180         AC_PREPROC_IFELSE(
1181 [AC_LANG_PROGRAM([[#define FUSE_USE_VERSION 29
1182 #ifdef __linux__
1183 #include <linux/fs.h>
1184 #include <linux/falloc.h>
1185 #include <linux/xattr.h>
1186 #endif
1187 ]], [])], [], [AC_MSG_FAILURE([Cannot find fuse2fs Linux headers.])])
1188
1189         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1190                 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse],
1191                               [AC_MSG_FAILURE([Cannot find fuse library.])])])
1192         AC_MSG_RESULT([Enabling fuse2fs])
1193 fi
1194 ,
1195 AC_CHECK_HEADERS([pthread.h fuse.h], [], [FUSE_CMT="#"],
1196 [#define _FILE_OFFSET_BITS      64
1197 #define FUSE_USE_VERSION 29
1198 #ifdef __linux__
1199 # include <linux/fs.h>
1200 # include <linux/falloc.h>
1201 # include <linux/xattr.h>
1202 #endif])
1203 if test -z "$FUSE_CMT"
1204 then
1205         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1206 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse], [FUSE_CMT="#"])])
1207 fi
1208 if test -z "$FUSE_CMT"
1209 then
1210         AC_MSG_RESULT([Enabling fuse2fs by default.])
1211 fi
1212 )
1213 AC_SUBST(FUSE_LIB)
1214 AC_SUBST(FUSE_CMT)
1215 dnl
1216 dnl See if optreset exists
1217 dnl
1218 AC_MSG_CHECKING(for optreset)
1219 AC_CACHE_VAL(ac_cv_have_optreset,
1220 [AC_EGREP_HEADER(optreset, unistd.h,
1221   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1222 AC_MSG_RESULT($ac_cv_have_optreset)
1223 if test $ac_cv_have_optreset = yes; then
1224   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1225 fi
1226 dnl
1227 dnl Test for sem_init, and which library it might require:
1228 dnl
1229 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1230 SEM_INIT_LIB=''
1231 AC_CHECK_FUNC(sem_init, ,
1232   AC_CHECK_LIB(pthread, sem_init,
1233         AC_DEFINE(HAVE_SEM_INIT, 1)
1234         SEM_INIT_LIB=-lpthread,
1235   AC_CHECK_LIB(rt, sem_init,
1236         AC_DEFINE(HAVE_SEM_INIT, 1)
1237         SEM_INIT_LIB=-lrt,
1238   AC_CHECK_LIB(posix4, sem_init,
1239         AC_DEFINE(HAVE_SEM_INIT, 1)
1240         SEM_INIT_LIB=-lposix4))))dnl
1241 AC_SUBST(SEM_INIT_LIB)
1242 dnl
1243 dnl Check for unified diff
1244 dnl
1245 AC_MSG_CHECKING(for unified diff option)
1246 if diff -u $0 $0 > /dev/null 2>&1 ; then
1247    UNI_DIFF_OPTS=-u
1248 else
1249    UNI_DIFF_OPTS=-c
1250 fi
1251 AC_MSG_RESULT($UNI_DIFF_OPTS)
1252 AC_SUBST(UNI_DIFF_OPTS)
1253 dnl
1254 dnl We use the EXT2 ioctls only under Linux
1255 dnl
1256 case "$host_os" in
1257 linux*)
1258         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1259         ;;
1260 esac
1261 dnl
1262 dnl OS-specific uncomment control
1263 dnl
1264 LINUX_CMT="#"
1265 CYGWIN_CMT="#"
1266 UNIX_CMT=
1267 case "$host_os" in
1268 linux*)
1269         LINUX_CMT=
1270         ;;
1271 cygwin)
1272         CYGWIN_CMT=
1273         UNIX_CMT="#"
1274         ;;
1275 esac
1276 AC_SUBST(LINUX_CMT)
1277 AC_SUBST(CYGWIN_CMT)
1278 AC_SUBST(UNIX_CMT)
1279 dnl
1280 dnl Linux and Hurd places root files in the / by default
1281 dnl
1282 case "$host_os" in
1283 linux* | gnu* | k*bsd*-gnu)
1284         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1285                 root_prefix="";
1286                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1287         fi
1288         ;;
1289 esac
1290 dnl
1291 dnl On Linux/hurd, force the prefix to be /usr
1292 dnl
1293 case "$host_os" in
1294 linux* | gnu* | k*bsd*-gnu)
1295         if test "$prefix" = NONE ; then
1296                 prefix="/usr";
1297                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1298                 if test "$mandir" = '${prefix}/man' ; then
1299                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1300                         mandir=/usr/share/man
1301                 fi
1302         fi
1303 ;;
1304 esac
1305 if test "$root_prefix" = NONE ; then
1306         if test "$prefix" = NONE ; then
1307                 root_prefix="$ac_default_prefix"
1308         else
1309                 root_prefix="$prefix"
1310         fi
1311         root_bindir=$bindir
1312         root_sbindir=$sbindir
1313         root_libdir=$libdir
1314         root_sysconfdir=$sysconfdir
1315 else
1316         root_bindir='${root_prefix}/bin'
1317         root_sbindir='${root_prefix}/sbin'
1318         root_libdir='${root_prefix}/lib'
1319         root_sysconfdir='${root_prefix}/etc'
1320 fi
1321 if test "$bindir" != '${exec_prefix}/bin'; then
1322     root_bindir=$bindir
1323     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1324 fi
1325 if test "$sbindir" != '${exec_prefix}/sbin'; then
1326     root_sbindir=$sbindir
1327     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1328 fi
1329 if test "$libdir" != '${exec_prefix}/lib'; then
1330     root_libdir=$libdir
1331     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1332 fi
1333 if test "$sysconfdir" != '${prefix}/etc'; then
1334     root_sysconfdir=$sysconfdir
1335     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1336 fi
1337 AC_SUBST(root_prefix)
1338 AC_SUBST(root_bindir)
1339 AC_SUBST(root_sbindir)
1340 AC_SUBST(root_libdir)
1341 AC_SUBST(root_sysconfdir)
1342 dnl
1343 dnl Allow specification of the multiarch arch
1344 dnl
1345 AC_ARG_WITH([multiarch],
1346 [  --with-multiarch=ARCH specify the multiarch triplet],
1347 if test "$withval" = "lib64"; then
1348     libdir=/usr/lib64
1349     root_libdir=/lib64
1350 else
1351     libdir=$libdir/$withval
1352     root_libdir=$root_libdir/$withval
1353 fi
1354 )dnl
1355 dnl
1356 dnl See if -static works.  This could fail if the linker does not
1357 dnl support -static, or if required external libraries are not available
1358 dnl in static form.
1359 dnl
1360 AC_MSG_CHECKING([whether we can link with -static])
1361 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1362 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS_STATIC -static"
1363 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1364  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1365 LDFLAGS=$SAVE_LDFLAGS])
1366 dnl
1367 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1368 dnl This is caused by the socket library requiring the nsl library, which
1369 dnl requires the -dl library, which only works for dynamically linked
1370 dnl programs.  It basically means you can't have statically linked programs
1371 dnl which use the network under Solaris.
1372 dnl
1373 case "$host_os" in
1374 solaris2.*)
1375         ac_cv_e2fsprogs_use_static=no
1376 ;;
1377 esac
1378 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1379 if test $ac_cv_e2fsprogs_use_static = yes; then
1380         LDFLAGS_STATIC="$LDFLAGS_STATIC -static"
1381 fi
1382 AC_SUBST(LDFLAGS_STATIC)
1383 dnl
1384 dnl Work around mysterious Darwin / GNU libintl problem
1385 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1386 dnl Apple hacked gcc somehow?)
1387 dnl
1388 case "$host_os" in
1389 darwin*)
1390         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1391         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1392                 [Define to 1 if Apple Darwin libintl workaround is needed])
1393         ;;
1394 esac
1395 dnl
1396 dnl Make the ss and et directories work correctly.
1397 dnl
1398 SS_DIR=`cd ${srcdir}/lib/ss; pwd`
1399 ET_DIR=`cd ${srcdir}/lib/et; pwd`
1400 AC_SUBST(SS_DIR)
1401 AC_SUBST(ET_DIR)
1402 dnl
1403 dnl Only try to run the test suite if we're not cross compiling.
1404 dnl
1405 if test "$cross_compiling" = yes ; then
1406   DO_TEST_SUITE=
1407 else
1408   DO_TEST_SUITE=check
1409 fi
1410 AC_SUBST(DO_TEST_SUITE)
1411 dnl
1412 dnl Only include the intl include files if we're building with them
1413 dnl
1414 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1415 if test -n "$CPPFLAGS" ; then
1416         INCLUDES="$INCLUDES $CPPFLAGS"
1417 fi
1418 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1419         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1420 fi
1421 if test -n "$WITH_DIET_LIBC" ; then
1422         INCLUDES="$INCLUDES -D_REENTRANT"
1423 fi
1424 AC_SUBST(INCLUDES)
1425 AM_MKINSTALLDIRS
1426 dnl
1427 dnl Build CFLAGS
1428 dnl
1429 if test $cross_compiling = no; then
1430    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1431    BUILD_LDFLAGS="$LDFLAGS"
1432 fi
1433 AC_SUBST(BUILD_CFLAGS)
1434 AC_SUBST(BUILD_LDFLAGS)
1435 dnl
1436 dnl Define CFLAGS and LDFLAGS for shared libraries
1437 dnl
1438 CFLAGS_SHLIB=${CFLAGS_SHLIB:-$CFLAGS}
1439 CFLAGS_STLIB=${CFLAGS_STLIB:-$CFLAGS}
1440 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
1441 AC_SUBST(CFLAGS_SHLIB)
1442 AC_SUBST(CFLAGS_STLIB)
1443 AC_SUBST(LDFLAGS_SHLIB)
1444 dnl
1445 dnl Make our output files, being sure that we create the some miscellaneous
1446 dnl directories
1447 dnl
1448 test -d lib || mkdir lib
1449 test -d include || mkdir include
1450 test -d include/linux || mkdir include/linux
1451 test -d include/asm || mkdir include/asm
1452 if test -z "$UUID_CMT" ; then
1453         uuid_out_list="lib/uuid/Makefile lib/uuid/uuid.pc \
1454                 lib/uuid/uuid_types.h"
1455 fi
1456 if test -z "$BLKID_CMT" ; then
1457         blkid_out_list="lib/blkid/Makefile lib/blkid/blkid.pc \
1458                 lib/blkid/blkid_types.h"
1459 fi
1460 for i in MCONFIG Makefile e2fsprogs.spec \
1461         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1462         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1463         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1464         $uuid_out_list $blkid_out_list lib/support/Makefile \
1465         lib/ss/ss.pc lib/et/com_err.pc lib/e2p/e2p.pc lib/ext2fs/ext2fs.pc \
1466         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1467         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1468         resize/Makefile doc/Makefile intl/Makefile \
1469         intl/libgnuintl.h po/Makefile.in ; do
1470         if test -d `dirname ${srcdir}/$i` ; then
1471                 outlist="$outlist $i"
1472         fi
1473 done
1474 AC_OUTPUT($outlist)
1475 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi