configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com], [],
   4         [https://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.64])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like LT_INIT) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="17-May-2023"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77 # Check whether prefix=/usr
  78 AS_CASE([$prefix],
  79 [NONE | /usr],
  80   [AC_MSG_NOTICE([Default --prefix detected.])
  81    AS_CASE([$localstatedir], [NONE | '${prefix}/var' | "${prefix}"/var ],
  82            [localstatedir=/var; AC_MSG_NOTICE([  --localstatedir defaults to /var])])
  83    AS_CASE([$sysconfdir], [NONE | '${prefix}/etc' | "${prefix}"/etc ],
  84            [sysconfdir=/etc; AC_MSG_NOTICE([  --sysconfdir defaults to /etc])])
  85
  86   ]
  87 )
  88
  89 # default for old versions without $runstatedir
  90 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  91
  92 # our default if $localstatedir unchanged
  93 AS_CASE([$localstatedir:$runstatedir],
  94  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  95    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  96 )
  97
  98 AC_SUBST([runstatedir])
  99
 100
 101 # The original default values of {bin,sbin,lib}dir
 102 usrbin_execdir='${exec_prefix}/bin'
 103 AC_SUBST([usrbin_execdir])
 104
 105 usrsbin_execdir='${exec_prefix}/sbin'
 106 AC_SUBST([usrsbin_execdir])
 107
 108 AS_CASE([$libdir],
 109  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
 110    [usrlib_execdir=$libdir],
 111  [usrlib_execdir='${exec_prefix}'$libdir]
 112 )
 113 AC_SUBST([usrlib_execdir])
 114
 115 # static configuration maintaned by packages (e.g. /usr/lib)
 116 AC_ARG_VAR([SYSCONFSTATICDIR],
 117            [Path to static system configuration, default ${prefix}/lib])
 118 AS_IF([test "x$SYSCONFSTATICDIR" = x],
 119       [sysconfstaticdir='${prefix}/lib'],
 120       [sysconfstaticdir=$SYSCONFSTATICDIR])
 121 AC_SUBST([sysconfstaticdir])
 122
 123 AC_PROG_CC
 124 AM_PROG_CC_C_O
 125 AC_PROG_MKDIR_P
 126 AC_PROG_YACC
 127 AC_CANONICAL_HOST
 128 AC_C_CONST
 129 AC_C_VOLATILE
 130
 131 dnl Compiler warnings
 132 UL_WARN_ADD([-fno-common])
 133 UL_WARN_ADD([-Wall])
 134 UL_WARN_ADD([-Wextra])
 135
 136 UL_WARN_ADD([-Waddress-of-packed-member])
 137 UL_WARN_ADD([-Wdiscarded-qualifiers])
 138 UL_WARN_ADD([-Wembedded-directive])
 139 UL_WARN_ADD([-Wextra-semi])
 140 UL_WARN_ADD([-Wformat-security])
 141 UL_WARN_ADD([-Wimplicit-function-declaration])
 142 UL_WARN_ADD([-Wmissing-declarations])
 143 UL_WARN_ADD([-Wmissing-parameter-type])
 144 UL_WARN_ADD([-Wmissing-prototypes])
 145 UL_WARN_ADD([-Wnested-externs])
 146 UL_WARN_ADD([-Wno-missing-field-initializers])
 147 UL_WARN_ADD([-Wold-style-definition])
 148 UL_WARN_ADD([-Wpointer-arith])
 149 UL_WARN_ADD([-Wredundant-decls])
 150 UL_WARN_ADD([-Wsign-compare])
 151 UL_WARN_ADD([-Wstrict-prototypes])
 152 UL_WARN_ADD([-Wtype-limits])
 153 UL_WARN_ADD([-Wuninitialized])
 154 UL_WARN_ADD([-Wunused-but-set-parameter])
 155 UL_WARN_ADD([-Wunused-but-set-variable])
 156 UL_WARN_ADD([-Wunused-parameter])
 157 UL_WARN_ADD([-Wunused-result])
 158 UL_WARN_ADD([-Wunused-variable])
 159
 160 AC_ARG_ENABLE([werror],
 161   AS_HELP_STRING([--enable-werror], [make all compiler warnings into errors]),
 162   [], [enable_werror=no]
 163 )
 164 AS_IF([test "x$enable_werror" = xyes], [
 165   UL_WARN_ADD([-Werror])
 166 ],[
 167   UL_WARN_ADD([-Werror=sequence-point])
 168 ])
 169
 170 AC_SUBST([WARN_CFLAGS])
 171
 172
 173 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 174 AC_SUBST([BSD_WARN_CFLAGS])
 175
 176 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 177 AC_SUBST([PYTHON_WARN_CFLAGS])
 178
 179 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 180 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 181
 182
 183 AC_ARG_ENABLE([asan],
 184   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 185   [], [enable_asan=no]
 186 )
 187 AS_IF([test "x$enable_asan" = xyes], [
 188   UL_WARN_ADD([-fsanitize=address])
 189   ASAN_LDFLAGS="-fsanitize=address"
 190 ])
 191 AC_SUBST([ASAN_LDFLAGS])
 192
 193 AC_ARG_ENABLE([ubsan],
 194   AS_HELP_STRING([--enable-ubsan], [compile with UBsan]),
 195   [], [enable_ubsan=no]
 196 )
 197 AS_IF([test "x$enable_ubsan" = xyes], [
 198   UL_WARN_ADD([-fsanitize=undefined])
 199   UBSAN_LDFLAGS="-fsanitize=undefined"
 200 ])
 201 AC_SUBST([UBSAN_LDFLAGS])
 202
 203 AC_ARG_ENABLE([fuzzing-engine],
 204   AS_HELP_STRING([--enable-fuzzing-engine], [compile with fuzzing engine]),
 205   [], [enable_fuzzing_engine=no]
 206 )
 207 AS_IF([test "x$enable_fuzzing_engine" = xyes && test "x$LIB_FUZZING_ENGINE" = x], [
 208   UL_WARN_ADD([-fno-omit-frame-pointer])
 209   UL_WARN_ADD([-gline-tables-only])
 210   UL_WARN_ADD([-fsanitize=fuzzer-no-link])
 211   FUZZING_ENGINE_LDFLAGS="-fsanitize=fuzzer-no-link"
 212 ])
 213 AC_SUBST([FUZZING_ENGINE_LDFLAGS])
 214 AC_PROG_CXX
 215 AM_CONDITIONAL([FUZZING_ENGINE], [test "x$enable_fuzzing_engine" = xyes])
 216 AM_CONDITIONAL([OSS_FUZZ], [test "x$LIB_FUZZING_ENGINE" != x])
 217
 218 AC_ARG_ENABLE([coverage],
 219   AS_HELP_STRING([--enable-coverage], [compile with gcov]),
 220   [], [enable_coverage=no]
 221 )
 222 AS_IF([test "x$enable_coverage" = xyes], [
 223   UL_WARN_ADD([--coverage])
 224   COVERAGE_LDFLAGS="--coverage"
 225 ])
 226 AC_SUBST([COVERAGE_LDFLAGS])
 227 AM_CONDITIONAL([WITH_COVERAGE], [test "x$enable_coverage" = xyes])
 228
 229 dnl libtool-2
 230 LT_INIT
 231
 232 dnl check supported linker flags
 233 AX_CHECK_VSCRIPT
 234
 235 m4_ifndef([PKG_PROG_PKG_CONFIG],
 236   [m4_fatal([Could not locate the pkg-config autoconf
 237     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 238     If your macros are in a different location, try setting the
 239     environment variable AL_OPTS="-I/other/macro/dir" before running
 240     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 241 PKG_PROG_PKG_CONFIG
 242 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 243
 244 GTK_DOC_CHECK([1.10])
 245 AC_PATH_PROG([XSLTPROC], [xsltproc])
 246
 247
 248 linux_os=no
 249 bsd_os=no
 250 AS_CASE([${host_os}],
 251   [*linux*],
 252      [linux_os=yes],
 253   [*darwin*],
 254      [darwin_os=yes],
 255   [*bsd*],
 256      [bsd_os=yes])
 257 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 258 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 259 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 260
 261 AS_IF([test  "x$darwin_os" = xyes], [
 262   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 263 ])
 264
 265 dnl define ARCH_<NAME> conditionals
 266 UL_SET_ARCH([I86], [i?86-*])
 267 UL_SET_ARCH([86_64], [x86_64*])
 268 UL_SET_ARCH([IA64], [ia64*])
 269 UL_SET_ARCH([S390], [s390*])
 270 UL_SET_ARCH([SPARC], [sparc*])
 271 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 272 UL_SET_ARCH([M68K], [m68*])
 273 UL_SET_ARCH([MIPS], [mips*])
 274 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 275
 276 AC_SYS_LARGEFILE
 277 AC_HEADER_ASSERT
 278 AC_STRUCT_TIMEZONE
 279
 280 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 281 AM_GNU_GETTEXT_VERSION([0.18.3])
 282 AM_GNU_GETTEXT([external])
 283
 284 AS_IF([test -d "$srcdir/po"], [
 285   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 286 ], [dnl echo $ALL_LINGUAS | sed 's/ /\n/g' | sort -u | column -xc 72 -o ' ' | sed 's/^/\t/'
 287   ALL_LINGUAS="
 288         af      am      ar      as      be      bg      bn      bn_IN   ca
 289         cs      cy      da      de      el      en_GB   es      et      eu_ES
 290         fa      fi      fr      gl      gu      he      hi      hr      hu
 291         hy      id      is      it      ja      ka      kn      ko      ku
 292         lo      lt      lv      mk      ml      mr      ms      my      nb
 293         nl      nn      no      nso     or      pa      pl      pt      pt_BR
 294         ro      ru      si      sk      sl      sq      sr      sr@Latn sv
 295         ta      te      th      tr      uk      ur      vi      zh_CN   zh_TW
 296         zu
 297 "])
 298
 299 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 300 #ifdef HAVE_LINUX_COMPILER_H
 301 #include <linux/compiler.h>
 302 #endif
 303 ])
 304 AC_CHECK_HEADERS([ \
 305         asm-generic/fcntl.h \
 306         asm/fcntl.h \
 307         asm/io.h \
 308         byteswap.h \
 309         endian.h \
 310         err.h \
 311         errno.h \
 312         fcntl.h \
 313         getopt.h \
 314         inttypes.h \
 315         lastlog.h \
 316         libutil.h \
 317         linux/blkzoned.h \
 318         linux/btrfs.h \
 319         linux/capability.h \
 320         linux/cdrom.h \
 321         linux/falloc.h \
 322         linux/fd.h \
 323         linux/fiemap.h \
 324         linux/kcmp.h \
 325         linux/net_namespace.h \
 326         linux/nsfs.h \
 327         linux/pr.h \
 328         linux/raw.h \
 329         linux/stat.h \
 330         linux/securebits.h \
 331         linux/tiocl.h \
 332         linux/version.h \
 333         linux/watchdog.h \
 334         linux/if_alg.h \
 335         locale.h \
 336         mntent.h \
 337         net/if_dl.h \
 338         net/if.h \
 339         netinet/in.h \
 340         paths.h \
 341         pty.h \
 342         security/pam_appl.h \
 343         shadow.h \
 344         stdint.h \
 345         stdio_ext.h \
 346         stdlib.h \
 347         sys/disk.h \
 348         sys/disklabel.h \
 349         sys/endian.h \
 350         sys/file.h \
 351         sys/ioccom.h \
 352         sys/ioctl.h \
 353         sys/io.h \
 354         sys/mkdev.h \
 355         sys/mount.h \
 356         sys/param.h \
 357         sys/pidfd.h \
 358         sys/prctl.h \
 359         sys/resource.h \
 360         sys/sendfile.h \
 361         sys/signalfd.h \
 362         sys/socket.h \
 363         sys/sockio.h \
 364         sys/stat.h \
 365         sys/statfs.h \
 366         sys/swap.h \
 367         sys/syscall.h \
 368         sys/sysmacros.h \
 369         sys/time.h \
 370         sys/timex.h \
 371         sys/ttydefaults.h \
 372         sys/types.h \
 373         sys/ucred.h \
 374         sys/un.h \
 375         sys/vfs.h \
 376         sys/xattr.h \
 377         unistd.h \
 378         utmp.h \
 379         utmpx.h \
 380 ])
 381
 382 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 383 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 384 #
 385 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 386  [#ifdef HAVE_SYS_MOUNT_H
 387    # include <linux/fs.h>
 388    # include <sys/mount.h>
 389   #endif
 390 ])
 391
 392 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 393  [#ifdef LINUX_GSMMUX_H
 394    # include <linux/gsmmux.h>
 395    #endif
 396 ])
 397
 398 AC_CHECK_HEADERS([security/pam_misc.h],
 399                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 400                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 401 #ifdef HAVE_SECURITY_PAM_APPL_H
 402 #include <security/pam_appl.h>
 403 #endif
 404 ])
 405
 406 AC_CHECK_DECLS([BLK_ZONE_REP_CAPACITY], [], [], [
 407         #include <linux/blkzoned.h>
 408 ])
 409
 410 AC_CHECK_DECLS([PR_REP_CAPACITY], [], [], [
 411         #include <linux/pr.h>
 412 ])
 413
 414 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 415 #ifdef HAVE_SECURITY_PAM_APPL_H
 416 #include <security/pam_appl.h>
 417 #endif
 418 ])
 419
 420 AC_CHECK_HEADERS([langinfo.h],
 421                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [true])],
 422                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [false])])
 423
 424 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 425 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 426         #include <langinfo.h>
 427 ]], [[
 428         char *str;
 429         str = nl_langinfo (ALTMON_1);
 430         str = nl_langinfo (ALTMON_2);
 431         str = nl_langinfo (ALTMON_3);
 432         str = nl_langinfo (ALTMON_4);
 433         str = nl_langinfo (ALTMON_5);
 434         str = nl_langinfo (ALTMON_6);
 435         str = nl_langinfo (ALTMON_7);
 436         str = nl_langinfo (ALTMON_8);
 437         str = nl_langinfo (ALTMON_9);
 438         str = nl_langinfo (ALTMON_10);
 439         str = nl_langinfo (ALTMON_11);
 440         str = nl_langinfo (ALTMON_12);
 441 ]])], [
 442         AC_MSG_RESULT([yes])
 443         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 444                 [Define if langinfo.h defines ALTMON_x constants])
 445 ], [
 446         AC_MSG_RESULT([no])
 447 ])
 448
 449
 450 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 451 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 452         #include <langinfo.h>
 453 ]], [[
 454         char *str;
 455         str = nl_langinfo (_NL_ABALTMON_1);
 456         str = nl_langinfo (_NL_ABALTMON_2);
 457         str = nl_langinfo (_NL_ABALTMON_3);
 458         str = nl_langinfo (_NL_ABALTMON_4);
 459         str = nl_langinfo (_NL_ABALTMON_5);
 460         str = nl_langinfo (_NL_ABALTMON_6);
 461         str = nl_langinfo (_NL_ABALTMON_7);
 462         str = nl_langinfo (_NL_ABALTMON_8);
 463         str = nl_langinfo (_NL_ABALTMON_9);
 464         str = nl_langinfo (_NL_ABALTMON_10);
 465         str = nl_langinfo (_NL_ABALTMON_11);
 466         str = nl_langinfo (_NL_ABALTMON_12);
 467 ]])], [
 468         AC_MSG_RESULT([yes])
 469         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 470                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 471 ], [
 472         AC_MSG_RESULT([no])
 473 ])
 474
 475
 476 dnl Convert some ac_cv_header_* variables to have_*
 477 dnl
 478 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 479 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 480 have_linux_capability_h=$ac_cv_header_linux_capability_h
 481 have_linux_kcmp_h=$ac_cv_header_linux_kcmp_h
 482 have_linux_pr_h=$ac_cv_header_linux_pr_h
 483 have_linux_raw_h=$ac_cv_header_linux_raw_h
 484 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 485 have_linux_version_h=$ac_cv_header_linux_version_h
 486 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 487 have_pty_h=$ac_cv_header_pty_h
 488 have_security_openpam_h=$ac_cv_header_security_openpam_h
 489 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 490 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 491 have_shadow_h=$ac_cv_header_shadow_h
 492 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 493 have_utmpx_h=$ac_cv_header_utmpx_h
 494 have_mntent_h=$ac_cv_header_mntent_h
 495
 496 AS_CASE([$linux_os:$have_linux_version_h],
 497   [yes:no],
 498     [AC_MSG_ERROR([kernel headers required on Linux])]
 499 )
 500
 501 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 502 #include <time.h>
 503 #include <unistd.h>
 504 ]], [[
 505     int a = 0;
 506     struct tm *tm = localtime(0);
 507     if (a == -1)  /* false */
 508         sleep(tm->tm_gmtoff);
 509 ]])],
 510 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 511 ])
 512
 513 AC_CHECK_TYPES([struct mount_attr], [], [], [[#include <linux/mount.h>]])
 514 AC_CHECK_TYPES([enum fsconfig_command], [], [], [[#include <linux/mount.h>]])
 515
 516 AC_CHECK_MEMBERS([struct termios.c_line],,,
 517     [[#include <termios.h>]])
 518
 519 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 520         [#include <sys/stat.h>])
 521
 522 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 523
 524 AC_CHECK_DECL([environ],
 525         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 526                 [Define to 1 if have **environ prototype])],
 527 )
 528
 529 AC_CHECK_DECL([strsignal],
 530         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 531                 [Define to 1 if have strsignal function prototype])],
 532 )
 533
 534 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 535               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 536               [#include <sys/ioctl.h>])
 537 AC_CHECK_DECL([SOCK_CLOEXEC],
 538               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 539               [#include <sys/types.h>
 540                #include <sys/socket.h>])
 541 AC_CHECK_DECL([SOCK_NONBLOCK],
 542               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 543               [#include <sys/types.h>
 544                #include <sys/socket.h>])
 545 AC_CHECK_DECL([SO_PASSCRED],
 546               [have_so_passcred=yes], [have_so_passcred=no],
 547               [#include <sys/types.h>
 548                #include <sys/socket.h>])
 549
 550 AC_CHECK_FUNCS([ \
 551         clearenv \
 552         close_range \
 553         eaccess \
 554         err \
 555         errx \
 556         explicit_bzero \
 557         __fpending \
 558         __fpurge \
 559         fpurge \
 560         fnmatch \
 561         fsconfig \
 562         fsmount \
 563         fsopen \
 564         fspick \
 565         fsync \
 566         getdomainname \
 567         getdtablesize \
 568         getexecname \
 569         getmntinfo \
 570         getrandom \
 571         getrlimit \
 572         getsgnam \
 573         getttynam \
 574         inotify_init \
 575         jrand48 \
 576         lchown \
 577         lgetxattr \
 578         llistxattr \
 579         llseek \
 580         newlocale \
 581         mempcpy \
 582         mkostemp \
 583         move_mount \
 584         mount_setattr \
 585         nanosleep \
 586         ntp_gettime \
 587         open_tree \
 588         personality \
 589         pidfd_open \
 590         pidfd_send_signal \
 591         posix_fadvise \
 592         prctl \
 593         qsort_r \
 594         rpmatch \
 595         scandirat \
 596         sched_setattr \
 597         sched_setscheduler \
 598         __secure_getenv \
 599         secure_getenv \
 600         sendfile \
 601         setprogname \
 602         setresgid \
 603         setresuid \
 604         sigqueue \
 605         srandom \
 606         statx \
 607         strnchr \
 608         strndup \
 609         strnlen \
 610         strtod_l \
 611         sysconf \
 612         sysinfo \
 613         timegm \
 614         usleep \
 615         uselocale \
 616         utimensat \
 617         vwarnx \
 618         warn \
 619         warnx \
 620 ])
 621 AC_FUNC_FSEEKO
 622
 623 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 624 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 625 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 626 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 627 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 628 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 629 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 630 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 631
 632 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 633
 634 have_setns_syscall="yes"
 635 UL_CHECK_SYSCALL([setns])
 636 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 637    have_setns_syscall="no"
 638 ])
 639
 640 UL_CHECK_SYSCALL([pidfd_open])
 641 UL_CHECK_SYSCALL([pidfd_send_signal])
 642 UL_CHECK_SYSCALL([close_range])
 643
 644 UL_CHECK_SYSCALL([fsconfig])
 645 UL_CHECK_SYSCALL([fsmount])
 646 UL_CHECK_SYSCALL([fsopen])
 647 UL_CHECK_SYSCALL([fspick])
 648 UL_CHECK_SYSCALL([mount_setattr])
 649 UL_CHECK_SYSCALL([move_mount])
 650 UL_CHECK_SYSCALL([open_tree])
 651
 652 AS_IF([test "x$ul_cv_syscall_fsconfig" = xno ||
 653        test "x$ul_cv_syscall_fsmount" = xno ||
 654        test "x$ul_cv_syscall_fsopen" = xno ||
 655        test "x$ul_cv_syscall_fspick" = xno ||
 656        test "x$ul_cv_syscall_mount_setattr" = xno ||
 657        test "x$ul_cv_syscall_move_mount" = xno ||
 658        test "x$ul_cv_syscall_open_tree" = xno],
 659    [
 660         have_mountfd_api="no"
 661    ],[
 662         have_mountfd_api="yes"
 663         AC_DEFINE([HAVE_MOUNTFD_API], [1], [Define to 1 if you want mount API based on FDs.])
 664    ])
 665
 666
 667 AC_CHECK_FUNCS([isnan], [],
 668         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 669         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 670 )
 671 AC_SUBST([MATH_LIBS])
 672
 673
 674 dnl lib/mononotic.c may require -lrt
 675 AC_CHECK_FUNCS([clock_gettime], [],
 676         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 677 )
 678
 679 have_timer="no"
 680 AC_CHECK_FUNCS([timer_create],
 681         [have_timer="yes"],
 682         [AC_CHECK_LIB([rt], [timer_create], [
 683                 have_timer="yes"
 684                 REALTIME_LIBS="-lrt"
 685                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 686         ],[
 687                 AC_SEARCH_LIBS([timer_create], [rt], [
 688                         AC_MSG_RESULT(yes)
 689                         have_timer="yes"
 690                         REALTIME_LIBS="-lrt -lpthread"
 691                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 692                 ],[], [-lpthread]
 693                 )
 694         ])]
 695 )
 696
 697 AC_SUBST([REALTIME_LIBS])
 698
 699 AS_IF([test x"$have_timer" = xno], [
 700        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 701 ])
 702
 703
 704 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 705         RTAS_LIBS="-lrtas"
 706         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 707 ])
 708 AC_SUBST([RTAS_LIBS])
 709
 710
 711 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 712                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 713         [#include <sys/types.h>
 714          #include <sys/socket.h>])
 715
 716 SOCKET_LIBS=
 717 AC_SEARCH_LIBS([socket], [socket],
 718         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 719                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 720 ])
 721 AC_SUBST([SOCKET_LIBS])
 722
 723
 724 have_dirfd=no
 725 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 726 AS_IF([test x"$have_dirfd" = xno], [
 727         AC_CHECK_DECLS([dirfd],
 728                 [have_dirfd=yes], [have_dirfd=no],
 729                 [#include <sys/types.h>
 730                  #include <dirent.h>])
 731 ])
 732
 733 have_ddfd=no
 734 AS_IF([test x"$have_dirfd" = xno], [
 735         AC_CHECK_MEMBERS([DIR.dd_fd],
 736                 [have_ddfd=yes], [have_ddfd=no],
 737                 [#include <sys/types.h>
 738                  #include <dirent.h>])
 739 ])
 740
 741 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes || test "x$have_ddfd" = xyes])
 742
 743 MQ_LIBS=
 744 AC_CHECK_LIB([rt], [mq_open], [MQ_LIBS="-lrt"])
 745 AC_SUBST([MQ_LIBS])
 746
 747 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 748 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 749         #include <errno.h>
 750 ]], [[
 751         program_invocation_short_name = "test";
 752 ]])], [
 753         AC_MSG_RESULT([yes])
 754         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 755                 [Define if program_invocation_short_name is defined])
 756 ], [
 757         AC_MSG_RESULT([no])
 758 ])
 759
 760
 761 AC_MSG_CHECKING([whether __progname is defined])
 762 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 763            [if (*__progname == 0) return 1;])],
 764            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 765            AC_MSG_RESULT([yes]),
 766            AC_MSG_RESULT([no]))
 767
 768 AC_CHECK_DECL([IOC_OPAL_GET_STATUS],
 769         [AC_DEFINE([HAVE_OPAL_GET_STATUS], [1],
 770                 [Define to 1 if OPAL status ioctl is defined])],,
 771               [#include <linux/sed-opal.h>])
 772
 773 dnl Static compilation
 774 m4_define([UL_STATIC_PROGRAMS], [blkid, fdisk, losetup, mount, nsenter, sfdisk, umount, unshare])
 775
 776 AC_ARG_ENABLE([static-programs],
 777   [AS_HELP_STRING([--enable-static-programs=LIST],
 778       [link static the programs in LIST (comma-separated,
 779       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 780
 781 AS_CASE([$enable_static_programs],
 782   [yes],
 783     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 784   [no],
 785     [enable_static_programs=]
 786 )
 787
 788 dnl Set all the individual AM_CONDITIONALs
 789 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 790   AS_CASE([,$enable_static_programs,],
 791    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 792   )
 793   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 794   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 795     [test "x$static_[]UL_PRG" = xyes])
 796 ])
 797
 798
 799 AC_ARG_ENABLE([all-programs],
 800   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 801   [], [enable_all_programs=undefined]
 802 )
 803
 804 AS_CASE([$enable_all_programs],
 805   [yes], [AC_MSG_WARN([force to build all programs by default])
 806           ul_default_estate=check],
 807   [no],  [AC_MSG_WARN([disable all programs and man pages by default])
 808           ul_default_estate=no]
 809 )
 810
 811
 812 AC_ARG_ENABLE([asciidoc],
 813   AS_HELP_STRING([--disable-asciidoc], [do not generate man pages from asciidoc]),
 814   [], [UL_DEFAULT_ENABLE([asciidoc], [check])]
 815 )
 816 UL_BUILD_INIT([asciidoc])
 817 UL_REQUIRES_PROGRAM([asciidoc], [ASCIIDOCTOR], [asciidoctor], [man pages])
 818 AM_CONDITIONAL([ENABLE_ASCIIDOC], [test "x$build_asciidoc" = xyes])
 819 have_asciidoctor_failure_level=no
 820 AS_IF([test "x$build_asciidoc" = xyes], [
 821        AC_MSG_CHECKING([whether ${ASCIIDOCTOR} supports --failure-level])
 822        AS_IF([${ASCIIDOCTOR} --help | grep failure-level >/dev/null 2>&1 ], [
 823          AC_MSG_RESULT([yes])
 824          have_asciidoctor_failure_level=yes
 825        ], [
 826          AC_MSG_RESULT([no])
 827        ])
 828 ])
 829 AM_CONDITIONAL([HAVE_ASCIIDOCTOR_FAILURE_LEVEL], [test "x$have_asciidoctor_failure_level" = xyes])
 830
 831 have_manpages=no
 832 AS_IF([test -f "$srcdir/sys-utils/mount.8"], [
 833    AC_MSG_NOTICE([re-use already generated man-pages.])
 834    have_manpages=yes]
 835 )
 836 AM_CONDITIONAL([HAVE_MANPAGES], [test "x$have_manpages" = xyes])
 837
 838
 839 AC_ARG_ENABLE([poman],
 840   AS_HELP_STRING([--disable-poman], [generate translated man pages]),
 841   [], [UL_DEFAULT_ENABLE([poman], [check])]
 842 )
 843 UL_BUILD_INIT([poman])
 844 UL_REQUIRES_PROGRAM([poman], [PO4A], [po4a], [translated man pages])
 845 AM_CONDITIONAL([ENABLE_POMAN], [test "x$build_poman" = xyes])
 846
 847
 848 AX_CHECK_TLS
 849
 850 have_pty=no
 851 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 852   [], [with_util=auto]
 853 )
 854 AS_IF([test "x$with_util" = xno], [
 855   AM_CONDITIONAL([HAVE_UTIL], [false])
 856   have_util=no
 857 ], [
 858   UL_CHECK_LIB([util], [openpty])
 859 ])
 860
 861 AS_IF([test "x$have_pty_h" = xyes && test "x$have_sys_signalfd_h" = xyes && test "x$have_util" = xyes], [
 862    AM_CONDITIONAL([HAVE_PTY], [true])
 863    AC_DEFINE([HAVE_PTY], [1], [have PTY support])
 864    have_pty=yes
 865 ], [
 866    AM_CONDITIONAL([HAVE_PTY], [false])
 867 ])
 868
 869 AC_CHECK_TYPES([union semun], [], [], [[
 870 #include <sys/sem.h>
 871 ]])
 872 AC_CHECK_TYPES([loff_t])
 873
 874
 875 AC_ARG_ENABLE([widechar],
 876   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 877   [], [enable_widechar=check]
 878 )
 879 UL_BUILD_INIT([widechar])
 880 UL_REQUIRES_COMPILE([widechar], [[
 881   #include <wchar.h>
 882   #include <wctype.h>
 883   #include <stdio.h>
 884   #include <stdlib.h>
 885   ]], [[
 886     wchar_t wc;
 887     wint_t w;
 888     w = fgetwc(stdin);
 889     if (w == WEOF) exit(1);
 890     wc = w;
 891     fputwc(wc,stdout);
 892   ]],
 893   [wchar_t support])
 894
 895 AS_IF([test "x$build_widechar" = xyes ], [
 896   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 897 ])
 898
 899
 900 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 901 #include <sched.h>
 902 ]])
 903
 904 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 905
 906 AC_CHECK_TYPES([sighandler_t], [], [], [[
 907 #include <signal.h>
 908 ]])
 909
 910 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 911 #include <sched.h>
 912 ]])
 913
 914 # on Solaris, you can't mix and match standards, since we use c99
 915 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 916 # check for crypt.h and use that without XOPEN_SOURCE.
 917 have_crypt=no
 918 AC_CHECK_HEADERS([crypt.h])
 919 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 920 #ifdef HAVE_CRYPT_H
 921 #include <crypt.h>
 922 #else
 923 #define _XOPEN_SOURCE
 924 #include <unistd.h>
 925 #endif
 926 ]], [[
 927 char *c = crypt("abc","pw");
 928 ]])],[
 929   have_libcrypt=no
 930   have_crypt=yes
 931 ],[
 932   UL_SET_LIBS([-lcrypt])
 933   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 934   #ifdef HAVE_CRYPT_H
 935   #include <crypt.h>
 936   #else
 937   #define _XOPEN_SOURCE
 938   #include <unistd.h>
 939   #endif
 940   ]], [[
 941   char *c = crypt("abc","pw");
 942   ]])],[
 943   have_libcrypt=yes
 944   have_crypt=yes
 945   ],[
 946   AC_MSG_WARN([crypt() is not available])
 947   ])
 948   UL_RESTORE_LIBS
 949 ])
 950 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 951
 952
 953 AC_ARG_WITH([selinux],
 954   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 955   [], [with_selinux=no]
 956 )
 957
 958 AS_IF([test "x$with_selinux" = xno], [
 959   AM_CONDITIONAL([HAVE_SELINUX], [false])
 960 ], [
 961   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.5], [have_selinux=yes], [have_selinux=no])
 962   AS_CASE([$with_selinux:$have_selinux],
 963     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 964   )
 965   AS_IF([test "x$have_selinux" = xyes], [
 966     AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 967     UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 968     AM_CONDITIONAL([HAVE_SELINUX], [true])
 969
 970     UL_SET_LIBS([$SELINUX_LIBS])
 971     # This function is missing in old libselinux 1.xx versions
 972     AC_CHECK_FUNCS([security_get_initial_context])
 973     UL_RESTORE_LIBS
 974   ])
 975 ])
 976 AC_SUBST([SELINUX_LIBS])
 977 AC_SUBST([SELINUX_LIBS_STATIC])
 978
 979
 980 AC_ARG_WITH([audit],
 981   AS_HELP_STRING([--with-audit], [compile with audit support]),
 982   [], [with_audit=no]
 983 )
 984
 985 AS_IF([test "x$with_audit" = xno], [
 986   AM_CONDITIONAL([HAVE_AUDIT], [false])
 987 ], [
 988   UL_CHECK_LIB([audit], [audit_log_user_message])
 989   AS_CASE([$with_audit:$have_audit],
 990     [yes:no],
 991       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 992   )
 993 ])
 994
 995 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 996   [], [with_udev=auto]
 997 )
 998
 999 AS_IF([test "x$with_udev" = xno], [
1000   AM_CONDITIONAL([HAVE_UDEV], [false])
1001 ], [
1002   UL_CHECK_LIB([udev], [udev_new])
1003   AS_CASE([$with_udev:$have_udev],
1004     [yes:no],
1005       [AC_MSG_ERROR([udev selected but libudev not found])]
1006   )
1007 ])
1008
1009
1010 dnl wide-char ncurses
1011 AC_ARG_WITH([ncursesw],
1012   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
1013   [], [with_ncursesw=auto]
1014 )
1015 have_ncursesw=no
1016 have_ncursesw_header=no
1017 AS_IF([test "x$with_ncursesw" != xno], [
1018   UL_NCURSES_CHECK([ncursesw])
1019   AS_IF([test "x$have_ncursesw" = xyes], [
1020     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
1021     AC_CHECK_HEADERS([ncursesw/term.h])
1022
1023     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
1024     # unsuccessful to avoid too many *_H permitations in config.h
1025     AS_IF([test "x$have_ncursesw_header" = xno], [
1026            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
1027            AC_CHECK_HEADERS([term.h])
1028     ])
1029     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
1030   ])
1031   AS_IF([test "x$have_ncursesw" = xyes], [
1032     CURSES_LIB_NAME="ncursesw"
1033     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
1034   ])
1035 ])
1036 AS_CASE([$with_ncursesw:$have_ncursesw],
1037   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
1038
1039
1040 dnl non-wide ncurses
1041 AC_ARG_WITH([ncurses],
1042   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
1043   [], [with_ncurses=auto]
1044 )
1045 have_ncurses=no
1046 have_ncurses_header=no
1047 AS_CASE([$with_ncurses:$build_widechar],
1048   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
1049
1050 AS_IF([test "x$have_ncursesw" = xno && test "x$with_ncurses" != xno ], [
1051   UL_NCURSES_CHECK([ncurses])
1052   AS_IF([test "x$have_ncurses" = xyes], [
1053     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
1054     AC_CHECK_HEADERS([ncurses/term.h])
1055
1056     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
1057     # unsuccessful to avoid too many *_H permitations in config.h
1058     AS_IF([test "x$have_ncurses_header" = xno], [
1059            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
1060            AC_CHECK_HEADERS([term.h])
1061     ])
1062     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
1063   ])
1064   AS_IF([test "x$have_ncurses" = xyes], [
1065     CURSES_LIB_NAME="ncurses"
1066     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
1067   ])
1068 ])
1069 AS_CASE([$with_ncurses:$have_ncurses],
1070   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
1071
1072 AC_SUBST([NCURSES_CFLAGS])
1073 AC_SUBST([NCURSES_LIBS])
1074 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes])
1075
1076
1077 AC_ARG_WITH([slang],
1078   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
1079   [], [with_slang=no]
1080 )
1081 have_slang=no
1082 AS_IF([test "x$with_slang" = xyes], [
1083   AC_CHECK_HEADERS([slang.h slang/slang.h])
1084   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
1085                    [have_slang=yes], [], [
1086 #ifdef HAVE_SLANG_H
1087 #include <slang.h>
1088 #elif defined(HAVE_SLANG_SLANG_H)
1089 #include <slang/slang.h>
1090 #endif
1091 ])
1092   AS_IF([test "x$have_slang" = xno], [
1093     AC_MSG_ERROR([slang selected but slcurses.h not found])],
1094     [CURSES_LIB_NAME=slang
1095   ])
1096 ])
1097 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
1098
1099
1100 AS_IF([test "x$have_slang" = xyes || test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes], [
1101         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
1102                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
1103                                [Define if curses library has the use_default_colors().])
1104         ])
1105         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
1106                      AC_DEFINE(HAVE_RESIZETERM, 1,
1107                                [Define if curses library has the resizeterm().])
1108         ])
1109 ])
1110
1111
1112 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
1113   [], [with_tinfo=auto]
1114 )
1115 have_tinfo=no
1116 have_tinfow=no
1117 AS_IF([test "x$with_tinfo" != xno], [
1118   AS_IF([test "x$have_ncursesw" = xyes], [
1119     UL_TINFO_CHECK([tinfow])
1120   ])
1121   AS_IF([test "x$have_tinfow" = xno], [
1122     UL_TINFO_CHECK([tinfo])
1123   ])
1124 ])
1125 AC_SUBST([TINFO_LIBS])
1126 AC_SUBST([TINFO_LIBS_STATIC])
1127 AC_SUBST([TINFO_CFLAGS])
1128 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes])
1129 AS_IF([test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes], [
1130   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1131 ])
1132
1133
1134 AC_ARG_WITH([readline],
1135   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1136   [], [with_readline=auto]
1137 )
1138
1139 AS_IF([test "x$with_readline" = xno], [
1140   AM_CONDITIONAL([HAVE_READLINE], [false])
1141 ], [
1142   UL_CHECK_LIB([readline], [readline])
1143   AS_CASE([$with_readline:$have_readline],
1144     [yes:no],
1145       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1146     [*:yes],
1147       [READLINE_LIBS="-lreadline"
1148        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1149   )
1150 ])
1151 AC_SUBST([READLINE_LIBS])
1152 AC_SUBST([READLINE_LIBS_STATIC])
1153
1154
1155 AC_ARG_WITH([utempter],
1156   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1157   [], [with_utempter=no]
1158 )
1159
1160 AS_IF([test "x$with_utempter" = xyes], [
1161   UL_CHECK_LIB([utempter], [utempter_add_record])
1162   AS_IF([test "x$have_utempter" = xno], [
1163     AC_MSG_ERROR([utempter selected but libutempter not found])
1164   ])
1165 ], [
1166   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1167 ])
1168
1169
1170 dnl
1171 dnl libuuid
1172 dnl
1173 AC_ARG_ENABLE([libuuid],
1174   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1175   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1176 )
1177 UL_BUILD_INIT([libuuid])
1178 AC_SUBST([LIBUUID_VERSION])
1179 AC_SUBST([LIBUUID_VERSION_INFO])
1180 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1181
1182 AC_ARG_ENABLE([libuuid-force-uuidd],
1183   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1184   [], [enable_libuuid_force_uuidd=no]
1185 )
1186
1187 AS_IF([test "x$build_libuuid" = xyes], [
1188   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1189 ])
1190
1191 dnl
1192 dnl libblkid
1193 dnl
1194 AC_ARG_ENABLE([libblkid],
1195   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1196   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1197 )
1198 UL_BUILD_INIT([libblkid])
1199 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1200 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1201 AC_SUBST([LIBBLKID_DATE])
1202 AC_SUBST([LIBBLKID_VERSION])
1203 AC_SUBST([LIBBLKID_VERSION_INFO])
1204 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1205 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1206 AS_IF([test "x$build_libblkid" = xyes], [
1207   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1208 ])
1209 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1210 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes && test "x$enable_static" = xyes])
1211
1212 dnl
1213 dnl libmount
1214 dnl
1215 AC_ARG_ENABLE([libmount],
1216   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1217   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1218 )
1219 UL_BUILD_INIT([libmount])
1220 UL_REQUIRES_BUILD([libmount], [libblkid])
1221 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1222 UL_REQUIRES_HAVE([libmount], [mntent_h], [mntent.h header file])
1223 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1224 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes && test "x$enable_static" = xyes])
1225 AS_IF([test "x$build_libmount" = xyes], [
1226   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1227   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1228     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1229   ],[
1230     AC_MSG_WARN([libmount will be compiled without namespaces support])
1231   ])
1232 ])
1233
1234 AC_SUBST([LIBMOUNT_VERSION])
1235 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1236 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1237 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1238 AC_SUBST([LIBMOUNT_VERSION_INFO])
1239 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1240
1241 AC_ARG_ENABLE([libmount-mountfd-support],
1242   AS_HELP_STRING([--disable-libmount-mountfd-support], [do not use new mount API based on FDs]),
1243   [], [enable_libmount_mountfd_support=check]
1244 )
1245 UL_BUILD_INIT([libmount_mountfd_support])
1246 UL_REQUIRES_BUILD([libmount_mountfd_support], [libmount])
1247 UL_REQUIRES_LINUX([libmount_mountfd_support])
1248 UL_REQUIRES_HAVE([libmount_mountfd_support], [mountfd_api], [mount FDs based API])
1249 AS_IF([test "x$build_libmount_mountfd_support" = xyes ], [
1250   AC_DEFINE([USE_LIBMOUNT_MOUNTFD_SUPPORT], [1], [Enable support for new mount FD based kernel API])
1251 ])
1252
1253
1254 dnl
1255 dnl libsmartcols
1256 dnl
1257 AC_ARG_ENABLE([libsmartcols],
1258   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1259   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1260 )
1261 UL_BUILD_INIT([libsmartcols])
1262 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1263
1264 AC_SUBST([LIBSMARTCOLS_VERSION])
1265 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1266 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1267
1268
1269 dnl
1270 dnl libfdisk
1271 dnl
1272 AC_ARG_ENABLE([libfdisk],
1273   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1274   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1275 )
1276 UL_BUILD_INIT([libfdisk])
1277 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1278 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1279 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes && test "x$enable_static" = xyes])
1280
1281 AS_IF([test "x$build_libblkid" = xyes],
1282   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1283 AC_SUBST([LIBFDISK_PC_REQUIRES])
1284
1285 AC_SUBST([LIBFDISK_VERSION])
1286 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1287 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1288 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1289 AC_SUBST([LIBFDISK_VERSION_INFO])
1290 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1291
1292
1293 AC_ARG_ENABLE([fdisks],
1294   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1295   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1296 )
1297 enable_fdisk=$enable_fdisks
1298 enable_sfdisk=$enable_fdisks
1299 enable_cfdisk=$enable_fdisks
1300
1301 UL_BUILD_INIT([fdisk])
1302 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1303 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1304 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1305 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1306 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1307
1308
1309 UL_BUILD_INIT([sfdisk])
1310 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1311 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1312 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1313 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1314 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1315
1316
1317 UL_BUILD_INIT([cfdisk])
1318 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1319 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1320 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1321 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1322 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1323
1324
1325 AC_ARG_ENABLE([mount],
1326   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1327   [], [UL_DEFAULT_ENABLE([mount], [check])]
1328 )
1329 UL_BUILD_INIT([mount])
1330 UL_REQUIRES_LINUX([mount])
1331 UL_REQUIRES_BUILD([mount], [libmount])
1332 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1333
1334
1335 AC_ARG_ENABLE([losetup],
1336   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1337   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1338 )
1339 UL_BUILD_INIT([losetup])
1340 UL_REQUIRES_LINUX([losetup])
1341 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1342 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1343
1344 AC_ARG_ENABLE([zramctl],
1345   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1346   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1347 )
1348 UL_BUILD_INIT([zramctl])
1349 UL_REQUIRES_LINUX([zramctl])
1350 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1351 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1352
1353 AC_ARG_ENABLE([fsck],
1354   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1355   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1356 )
1357 UL_BUILD_INIT([fsck])
1358 UL_REQUIRES_BUILD([fsck], [libmount])
1359 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1360
1361
1362 AC_ARG_ENABLE([partx],
1363   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1364   [], [UL_DEFAULT_ENABLE([partx], [check])]
1365 )
1366 UL_BUILD_INIT([partx])
1367 UL_REQUIRES_LINUX([partx])
1368 UL_REQUIRES_BUILD([partx], [libblkid])
1369 UL_REQUIRES_BUILD([partx], [libsmartcols])
1370 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1371
1372
1373 AC_ARG_ENABLE([uuidd],
1374   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1375   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1376 )
1377 UL_BUILD_INIT([uuidd])
1378 UL_REQUIRES_BUILD([uuidd], [libuuid])
1379 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1380 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1381 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1382   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1383 ])
1384 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1385
1386
1387 AC_ARG_ENABLE([uuidgen],
1388   AS_HELP_STRING([--disable-uuidgen], [do not build uuidgen]),
1389   [], [UL_DEFAULT_ENABLE([uuidgen], [check])]
1390 )
1391 UL_BUILD_INIT([uuidgen])
1392 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1393 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1394
1395 UL_BUILD_INIT([uuidparse], [check])
1396 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1397 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1398 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1399
1400 AC_ARG_ENABLE([blkid],
1401   AS_HELP_STRING([--disable-blkid], [do not build blkid(8)]),
1402   [], [UL_DEFAULT_ENABLE([blkid], [check])]
1403 )
1404 UL_BUILD_INIT([blkid])
1405 UL_REQUIRES_BUILD([blkid], [libblkid])
1406 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1407
1408 UL_BUILD_INIT([findfs], [check])
1409 UL_REQUIRES_BUILD([findfs], [libblkid])
1410 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1411
1412 AC_ARG_ENABLE([wipefs],
1413   AS_HELP_STRING([--disable-wipefs], [do not build wipefs]),
1414   [], [UL_DEFAULT_ENABLE([wipefs], [check])]
1415 )
1416 UL_BUILD_INIT([wipefs])
1417 UL_REQUIRES_BUILD([wipefs], [libblkid])
1418 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1419 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1420
1421 UL_BUILD_INIT([findmnt], [check])
1422 UL_REQUIRES_BUILD([findmnt], [libmount])
1423 UL_REQUIRES_BUILD([findmnt], [libblkid])
1424 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1425 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1426
1427
1428 AC_ARG_ENABLE([mountpoint],
1429   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1430   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1431 )
1432 UL_BUILD_INIT([mountpoint])
1433 UL_REQUIRES_BUILD([mountpoint], [libmount])
1434 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1435
1436
1437 AC_ARG_ENABLE([fallocate],
1438   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1439   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1440 )
1441 UL_BUILD_INIT([fallocate])
1442 UL_REQUIRES_LINUX([fallocate])
1443 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1444 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1445
1446 AS_IF([test "x$build_fallocate" = xyes], [
1447   dnl check for valid fallocate() function
1448   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1449   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1450   dnl and program can't be linked.
1451   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1452   dnl function prototype.
1453   AC_MSG_CHECKING([for valid fallocate() function])
1454   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1455 #ifdef HAVE_UNISTD_H
1456 # include <unistd.h>
1457 #endif
1458 #ifdef HAVE_SYS_TYPES_H
1459 # include <sys/types.h>
1460 #endif
1461 #ifdef HAVE_LINUX_FALLOC_H
1462 # include <linux/falloc.h>
1463 #endif
1464 #ifdef HAVE_FCNTL_H
1465 # include <fcntl.h>
1466 #endif
1467 ]],[[
1468    long ret;
1469    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1470    if (ret != 0) {
1471       return 1;
1472    }
1473    ]])],[
1474   AC_MSG_RESULT([yes])
1475   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1476   AC_MSG_RESULT([no])])
1477 ])
1478
1479 AS_IF([test "x$build_fallocate" = xyes], [
1480   dnl check for valid posix_fallocate() function
1481   AC_MSG_CHECKING([for valid posix_fallocate() function])
1482   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1483 #ifdef HAVE_UNISTD_H
1484 # include <unistd.h>
1485 #endif
1486 #ifdef HAVE_SYS_TYPES_H
1487 # include <sys/types.h>
1488 #endif
1489 #ifdef HAVE_LINUX_FALLOC_H
1490 # include <linux/falloc.h>
1491 #endif
1492 #ifdef HAVE_FCNTL_H
1493 # include <fcntl.h>
1494 #endif
1495 ]],[[
1496    long ret;
1497    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1498    if (ret != 0) {
1499       return 1;
1500    }
1501    ]])],[
1502   AC_MSG_RESULT([yes])
1503   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1504   AC_MSG_RESULT([no])])
1505 ])
1506
1507
1508 AC_ARG_ENABLE([unshare],
1509   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1510   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1511 )
1512 UL_BUILD_INIT([unshare])
1513 UL_REQUIRES_LINUX([unshare])
1514 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1515 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1516 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1517
1518 AC_MSG_CHECKING([for valid unshare() function])
1519 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1520 #include <sched.h>
1521 ]],[[
1522    int ret;
1523    ret = unshare(0);
1524    if (ret != 0) {
1525       return 1;
1526    }
1527    ]])],[
1528   AC_MSG_RESULT([yes])
1529   AC_DEFINE([HAVE_UNSHARE], [1], [Have valid unshare() function])],
1530 [
1531   AC_MSG_RESULT([no])
1532 ])
1533
1534
1535 AC_ARG_ENABLE([nsenter],
1536   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1537   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1538 )
1539 UL_BUILD_INIT([nsenter])
1540 UL_REQUIRES_LINUX([nsenter])
1541 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1542 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1543
1544 AC_MSG_CHECKING([for valid setns() function])
1545 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1546 #include <sched.h>
1547 #include <errno.h>
1548 ]],[[
1549    int ret;
1550    ret = setns(0, 0);
1551    if (ret != EINVAL && ret != EBADF && ret != EPERM) {
1552       return 1;
1553    }
1554    ]])],[
1555   AC_MSG_RESULT([yes])
1556   AC_DEFINE([HAVE_SETNS], [1], [Have valid setns() function])],
1557 [
1558   AC_MSG_RESULT([no])
1559 ])
1560
1561
1562 AC_ARG_WITH([cap_ng],
1563   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1564   [], [with_cap_ng=auto]
1565 )
1566 AS_IF([test "x$with_cap_ng" = xno], [
1567   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1568   have_cap_ng=no
1569 ],[
1570   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1571 ])
1572
1573
1574 AC_ARG_ENABLE([setpriv],
1575   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1576   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1577 )
1578 UL_BUILD_INIT([setpriv])
1579 UL_REQUIRES_LINUX([setpriv])
1580 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1581 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1582 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1583 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1584
1585 AC_ARG_ENABLE([hardlink],
1586   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1587   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1588 )
1589 UL_BUILD_INIT([hardlink])
1590 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1591
1592
1593 AC_ARG_ENABLE([eject],
1594   AS_HELP_STRING([--disable-eject], [do not build eject]),
1595   [], [UL_DEFAULT_ENABLE([eject], [check])]
1596 )
1597 UL_BUILD_INIT([eject])
1598 UL_REQUIRES_LINUX([eject])
1599 UL_REQUIRES_BUILD([eject], [libmount])
1600 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1601
1602
1603 AC_ARG_ENABLE([agetty],
1604   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1605   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1606 )
1607 UL_BUILD_INIT([agetty])
1608 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1609 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1610 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1611 AS_IF([test "x$have_futimens" = xyes && test "x$have_inotify_init1" = xyes ], [
1612   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1613 ],[
1614   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1615 ])
1616
1617
1618 AC_ARG_ENABLE([plymouth_support],
1619   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1620   [], [enable_plymouth_support=check]
1621 )
1622 UL_BUILD_INIT([plymouth_support])
1623 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1624 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1625 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1626 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1627 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1628 AS_IF([test "x$build_plymouth_support" = xyes ], [
1629     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1630 ])
1631
1632
1633 AC_ARG_WITH([libz],
1634   AS_HELP_STRING([--without-libz], [compile without libz]),
1635   [], [with_libz=auto]
1636 )
1637 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1638   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1639 ])
1640
1641 AC_ARG_WITH([libmagic],
1642   AS_HELP_STRING([--without-libmagic], [compile without libmagic]),
1643   [], [with_libmagic=auto]
1644 )
1645 AS_IF([test "x$with_libmagic" = xno], [have_magic=no], [
1646   AC_CHECK_LIB([magic], [magic_open], [
1647     AC_CHECK_HEADER(magic.h, [
1648       AC_DEFINE([HAVE_MAGIC], [1], [Define to 1 if you have the libmagic present.])
1649       MAGIC_LIBS="-lmagic"
1650     ])
1651   ])
1652 ])
1653 AC_SUBST([MAGIC_LIBS])
1654
1655
1656 AC_ARG_ENABLE([cramfs],
1657   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1658   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1659 )
1660 UL_BUILD_INIT([cramfs])
1661 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1662 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1663
1664
1665 AC_ARG_ENABLE([bfs],
1666   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1667   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1668 )
1669 UL_BUILD_INIT([bfs])
1670 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1671
1672
1673 AC_ARG_ENABLE([minix],
1674   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1675   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1676 )
1677 UL_BUILD_INIT([minix])
1678 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1679
1680
1681 AC_ARG_ENABLE([fdformat],
1682   AS_HELP_STRING([--enable-fdformat], [build fdformat]),
1683   [], [UL_DEFAULT_ENABLE([fdformat], [no])]
1684 )
1685 UL_BUILD_INIT([fdformat])
1686 UL_REQUIRES_LINUX([fdformat])
1687 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1688
1689
1690 AC_ARG_ENABLE([hwclock],
1691   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1692   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1693 )
1694 have_linuxdummy=$linux_os
1695
1696 UL_BUILD_INIT([hwclock])
1697 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1698 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1699
1700 AC_ARG_ENABLE([hwclock_cmos],
1701   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1702   [], [enable_hwclock_cmos=check]
1703 )
1704 UL_BUILD_INIT([hwclock_cmos])
1705 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1706 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1707 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1708 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1709     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1710 ])
1711
1712 AC_ARG_ENABLE([hwclock_gplv3],
1713   AS_HELP_STRING([--disable-hwclock-gplv3], [do not use datetime parsing GPLv3 code]),
1714   [], [enable_hwclock_gplv3=yes]
1715 )
1716 AM_CONDITIONAL([USE_HWCLOCK_GPLv3_DATETIME], [test "x$enable_hwclock_gplv3" = xyes])
1717 AS_IF([test "x$enable_hwclock_gplv3" = xyes ], [
1718     AC_DEFINE([USE_HWCLOCK_GPLv3_DATETIME], [1], [use datetime parsing GPLv3 code to hwclock])
1719 ])
1720
1721
1722 AC_ARG_ENABLE([mkfs],
1723   AS_HELP_STRING([--disable-mkfs], [do not build mkfs(8)]),
1724   [], [UL_DEFAULT_ENABLE([mkfs], [check])]
1725 )
1726 UL_BUILD_INIT([mkfs])
1727 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1728
1729 UL_BUILD_INIT([isosize], [yes])
1730 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1731
1732
1733 AC_ARG_ENABLE([fstrim],
1734   AS_HELP_STRING([--disable-fstrim], [do not build fstrim(8)]),
1735   [], [UL_DEFAULT_ENABLE([fstrim], [check])]
1736 )
1737 UL_BUILD_INIT([fstrim])
1738 UL_REQUIRES_LINUX([fstrim])
1739 UL_REQUIRES_BUILD([fstrim], [libmount])
1740 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1741
1742
1743 AC_ARG_ENABLE([swapon],
1744   AS_HELP_STRING([--disable-swapon], [do not build swapon(8) and swapoff(8)]),
1745   [], [UL_DEFAULT_ENABLE([swapon], [check])]
1746 )
1747 UL_BUILD_INIT([swapon])
1748 UL_REQUIRES_LINUX([swapon])
1749 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1750 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1751 UL_REQUIRES_BUILD([swapon], [libblkid])
1752 UL_REQUIRES_BUILD([swapon], [libmount])
1753 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1754 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1755 AC_CHECK_FUNCS([swapon])
1756 AC_CHECK_FUNCS([swapoff])
1757
1758
1759 UL_BUILD_INIT([lsblk], [check])
1760 UL_REQUIRES_LINUX([lsblk])
1761 UL_REQUIRES_BUILD([lsblk], [libblkid])
1762 UL_REQUIRES_BUILD([lsblk], [libmount])
1763 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1764 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1765
1766
1767 AC_ARG_ENABLE([lscpu],
1768   AS_HELP_STRING([--disable-lscpu], [do not build lscpu]),
1769   [], [UL_DEFAULT_ENABLE([lscpu], [check])]
1770 )
1771 UL_BUILD_INIT([lscpu])
1772 UL_REQUIRES_LINUX([lscpu])
1773 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1774 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1775 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1776
1777 AC_ARG_ENABLE([lsfd],
1778   AS_HELP_STRING([--disable-lsfd], [do not build lsfd]),
1779   [], [UL_DEFAULT_ENABLE([lsfd], [check])]
1780 )
1781 UL_BUILD_INIT([lsfd])
1782 UL_REQUIRES_LINUX([lsfd])
1783 UL_REQUIRES_BUILD([lsfd], [libsmartcols])
1784 UL_REQUIRES_HAVE([lsfd], [linux_kcmp_h], [linux/kcmp.h header file])
1785 AM_CONDITIONAL([BUILD_LSFD], [test "x$build_lsfd" = xyes])
1786
1787 AC_ARG_ENABLE([lslogins],
1788   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1789   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1790 )
1791 UL_BUILD_INIT([lslogins])
1792 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1793 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1794 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1795 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1796 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1797
1798
1799 UL_BUILD_INIT([chcpu], [check])
1800 UL_REQUIRES_LINUX([chcpu])
1801 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1802 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1803
1804
1805 AC_ARG_ENABLE([wdctl],
1806   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1807   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1808 )
1809 UL_BUILD_INIT([wdctl])
1810 UL_REQUIRES_LINUX([wdctl])
1811 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1812 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1813 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1814
1815
1816 UL_BUILD_INIT([swaplabel], [check])
1817 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1818 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1819
1820
1821 UL_BUILD_INIT([mkswap], [yes])
1822 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1823 AS_IF([test "x$build_mkswap" = xyes && test "x$build_libuuid" != xyes], [
1824   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1825 ])
1826
1827
1828 AC_ARG_ENABLE([cal],
1829   AS_HELP_STRING([--disable-cal], [do not build cal]),
1830   [], [UL_DEFAULT_ENABLE([cal], [check])]
1831 )
1832 UL_BUILD_INIT([cal])
1833 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1834
1835 AC_ARG_ENABLE([logger],
1836   AS_HELP_STRING([--disable-logger], [do not build logger]),
1837   [], [UL_DEFAULT_ENABLE([logger], [check])]
1838 )
1839 UL_BUILD_INIT([logger])
1840 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1841
1842 UL_BUILD_INIT([look], [yes])
1843 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1844
1845 UL_BUILD_INIT([mcookie], [yes])
1846 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1847
1848 UL_BUILD_INIT([namei], [yes])
1849 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1850
1851 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1852 if test "x$matriplet" != "x"; then
1853   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1854   ["Multi-arch triplet for whereis library search path"])
1855 fi
1856 AC_ARG_ENABLE([whereis],
1857   AS_HELP_STRING([--disable-whereis], [do not build whereis]),
1858   [], [UL_DEFAULT_ENABLE([whereis], [check])]
1859 )
1860 UL_BUILD_INIT([whereis])
1861 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1862
1863 AC_ARG_ENABLE([pipesz],
1864   AS_HELP_STRING([--disable-pipesz], [do not build pipesz]),
1865   [], [UL_DEFAULT_ENABLE([pipesz], [check])]
1866 )
1867 UL_BUILD_INIT([pipesz])
1868 UL_REQUIRES_LINUX([pipesz])
1869 AM_CONDITIONAL([BUILD_PIPESZ], [test "x$build_pipesz" = xyes])
1870
1871 UL_BUILD_INIT([fadvise], [check])
1872 UL_REQUIRES_LINUX([fadvise])
1873 AM_CONDITIONAL([BUILD_FADVISE], [test "x$build_fadvise" = xyes])
1874
1875 AC_ARG_ENABLE([waitpid],
1876   AS_HELP_STRING([--disable-waitpid], [do not build waitpid]),
1877   [], [UL_DEFAULT_ENABLE([waitpid], [check])]
1878 )
1879 UL_BUILD_INIT([waitpid])
1880 UL_REQUIRES_LINUX([waitpid])
1881 UL_REQUIRES_SYSCALL_CHECK([waitpid], [UL_CHECK_SYSCALL([pidfd_open])], [pidfd_open])
1882 AM_CONDITIONAL([BUILD_WAITPID], [test "x$build_waitpid" = xyes])
1883
1884 UL_BUILD_INIT([enosys], [check])
1885 UL_REQUIRES_LINUX([enosys])
1886 AS_IF([test "x$build_enosys" = xyes], [
1887   AC_MSG_CHECKING([for valid audit arch])
1888   AC_COMPILE_IFELSE(
1889     [AC_LANG_PROGRAM([[#include "${srcdir}/include/audit-arch.h"]])],
1890     [AC_MSG_RESULT([yes])],
1891     [AC_MSG_RESULT([no])
1892      build_enosys=no
1893     ])
1894 ])
1895 AM_CONDITIONAL([BUILD_ENOSYS], [test "x$build_enosys" = xyes])
1896
1897 UL_BUILD_INIT([lsclocks], [yes])
1898 AM_CONDITIONAL([BUILD_LSCLOCKS], [test "x$build_lsclocks" = xyes])
1899
1900 UL_BUILD_INIT([getopt], [yes])
1901 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1902
1903
1904 UL_BUILD_INIT([blockdev], [check])
1905 UL_REQUIRES_LINUX([blockdev])
1906 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1907
1908
1909 UL_BUILD_INIT([prlimit], [check])
1910 UL_REQUIRES_LINUX([prlimit])
1911 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1912 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1913 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1914 AS_IF([test "x$build_prlimit" = xyes], [
1915   dnl check for valid prlimit() function
1916   AC_MSG_CHECKING([for valid prlimit() function])
1917   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1918 #include <sys/types.h>
1919 #include <sys/time.h>
1920 #include <sys/resource.h>
1921 #include <stddef.h>
1922 ]],[[
1923    int ret;
1924    ret = prlimit(0, RLIMIT_AS, NULL, NULL);
1925    if (ret != 0) {
1926       return 1;
1927    }
1928    ]])],[
1929   AC_MSG_RESULT([yes])
1930   AC_DEFINE([HAVE_PRLIMIT], [1], [Have valid prlimit() function])],[
1931   AC_MSG_RESULT([no])])
1932 ])
1933
1934
1935
1936 UL_BUILD_INIT([lslocks], [check])
1937 UL_REQUIRES_LINUX([lslocks])
1938 UL_REQUIRES_BUILD([lslocks], [libmount])
1939 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1940 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1941
1942
1943 AC_ARG_ENABLE([switch_root],
1944   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1945   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1946 )
1947 UL_BUILD_INIT([switch_root])
1948 UL_REQUIRES_LINUX([switch_root])
1949 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1950 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1951 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1952
1953
1954 AC_ARG_ENABLE([pivot_root],
1955   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1956   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1957 )
1958 UL_BUILD_INIT([pivot_root])
1959 UL_REQUIRES_LINUX([pivot_root])
1960 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1961 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1962
1963
1964 UL_BUILD_INIT([flock], [check])
1965 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1966 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1967
1968
1969 AC_ARG_ENABLE([lsmem],
1970   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1971   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1972 )
1973 UL_BUILD_INIT([lsmem])
1974 UL_REQUIRES_LINUX([lsmem])
1975 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1976 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1977
1978
1979 AC_ARG_ENABLE([chmem],
1980   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1981   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1982 )
1983 UL_BUILD_INIT([chmem])
1984 UL_REQUIRES_LINUX([chmem])
1985 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1986
1987
1988 AC_ARG_ENABLE([ipcmk],
1989   AS_HELP_STRING([--disable-ipcmk], [do not build ipcmk]),
1990   [], [UL_DEFAULT_ENABLE([ipcmk], [check])]
1991 )
1992 UL_BUILD_INIT([ipcmk])
1993 UL_EXCLUDE_ARCH([ipcmk], [*darwin*])
1994 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1995
1996 AC_ARG_ENABLE([ipcrm],
1997   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1998   [], [UL_DEFAULT_ENABLE([ipcrm], [check])]
1999 )
2000 UL_BUILD_INIT([ipcrm])
2001 UL_EXCLUDE_ARCH([ipcrm], [*darwin*])
2002 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
2003
2004 AC_ARG_ENABLE([ipcs],
2005   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
2006   [], [UL_DEFAULT_ENABLE([ipcs], [check])]
2007 )
2008 UL_BUILD_INIT([ipcs])
2009 UL_EXCLUDE_ARCH([ipcs], [*darwin*])
2010 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
2011
2012
2013 AC_ARG_ENABLE([irqtop],
2014   AS_HELP_STRING([--disable-irqtop], [do not build irqtop]),
2015   [], [UL_DEFAULT_ENABLE([irqtop], [check])]
2016 )
2017 UL_BUILD_INIT([irqtop])
2018 UL_REQUIRES_LINUX([irqtop])
2019 UL_REQUIRES_BUILD([irqtop], [libsmartcols])
2020 UL_REQUIRES_HAVE([irqtop], [open_memstream], [open_memstream function])
2021 UL_REQUIRES_HAVE([irqtop], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
2022 AM_CONDITIONAL([BUILD_IRQTOP], [test "x$build_irqtop" = xyes])
2023
2024 AC_ARG_ENABLE([lsirq],
2025   AS_HELP_STRING([--disable-lsirq], [do not build lsirq]),
2026   [], [UL_DEFAULT_ENABLE([lsirq], [check])]
2027 )
2028 UL_BUILD_INIT([lsirq])
2029 UL_REQUIRES_LINUX([lsirq])
2030 UL_REQUIRES_BUILD([lsirq], [libsmartcols])
2031 AM_CONDITIONAL([BUILD_LSIRQ], [test "x$build_lsirq" = xyes])
2032
2033
2034 UL_BUILD_INIT([choom], [check])
2035 UL_REQUIRES_LINUX([choom])
2036 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
2037
2038 UL_BUILD_INIT([lsipc], [check])
2039 UL_REQUIRES_LINUX([lsipc])
2040 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
2041 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
2042
2043 AC_ARG_ENABLE([lsns],
2044   AS_HELP_STRING([--disable-lsns], [do not build lsns]),
2045   [], [UL_DEFAULT_ENABLE([lsns], [check])]
2046 )
2047 UL_BUILD_INIT([lsns])
2048 UL_REQUIRES_LINUX([lsns])
2049 UL_REQUIRES_BUILD([lsns], [libsmartcols])
2050 UL_REQUIRES_BUILD([lsns], [libmount])
2051 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
2052
2053 UL_BUILD_INIT([renice], [yes])
2054 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
2055
2056
2057 AC_ARG_ENABLE([rfkill],
2058   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
2059   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
2060 )
2061 UL_BUILD_INIT([rfkill])
2062 UL_REQUIRES_LINUX([rfkill])
2063 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
2064 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
2065
2066
2067 UL_BUILD_INIT([setsid], [yes])
2068 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
2069
2070 UL_BUILD_INIT([readprofile], [check])
2071 UL_REQUIRES_LINUX([readprofile])
2072 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
2073
2074 UL_BUILD_INIT([dmesg], [check])
2075 UL_REQUIRES_LINUX([dmesg])
2076 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
2077
2078 UL_BUILD_INIT([ctrlaltdel], [check])
2079 UL_REQUIRES_LINUX([ctrlaltdel])
2080 dnl we assume reboot() to be the 1-argument variant, because even considering
2081 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
2082 dnl reboot() with multiple arguments is yet only found in glibc versions
2083 dnl earlier than 2.x.
2084 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
2085 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
2086
2087 UL_BUILD_INIT([fincore], [check])
2088 UL_REQUIRES_LINUX([fincore])
2089 UL_REQUIRES_BUILD([fincore], [libsmartcols])
2090 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
2091
2092 UL_BUILD_INIT([fsfreeze], [check])
2093 UL_REQUIRES_LINUX([fsfreeze])
2094 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
2095
2096 UL_BUILD_INIT([blkdiscard], [check])
2097 UL_REQUIRES_LINUX([blkdiscard])
2098 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
2099
2100 UL_BUILD_INIT([blkzone], [check])
2101 UL_REQUIRES_LINUX([blkzone])
2102 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
2103 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
2104
2105 UL_BUILD_INIT([blkpr], [check])
2106 UL_REQUIRES_LINUX([blkpr])
2107 UL_REQUIRES_HAVE([blkpr], [linux_pr_h], [linux/pr.h header])
2108 AM_CONDITIONAL([BUILD_BLKPR], [test "x$build_blkpr" = xyes])
2109
2110 UL_BUILD_INIT([ldattach], [check])
2111 UL_REQUIRES_LINUX([ldattach])
2112 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
2113
2114 UL_BUILD_INIT([rtcwake], [check])
2115 UL_REQUIRES_LINUX([rtcwake])
2116 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
2117
2118 UL_BUILD_INIT([setarch], [check])
2119 UL_REQUIRES_LINUX([setarch])
2120 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
2121
2122
2123 # build_scriptutils= is just configure-only variable to control
2124 # script, scriptreplay and scriptlive
2125 AC_ARG_ENABLE([scriptutils],
2126   AS_HELP_STRING([--disable-scriptutils], [do not build script, scriptreplay and scriptlive]),
2127   [], [UL_DEFAULT_ENABLE([scriptutils], [check])]
2128 )
2129
2130 UL_ENABLE_ALIAS([script], [scriptutils])
2131 UL_BUILD_INIT([script])
2132 UL_REQUIRES_HAVE([script], [pty], [openpty function (libutil)])
2133 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
2134
2135 UL_ENABLE_ALIAS([scriptreplay], [scriptutils])
2136 UL_BUILD_INIT([scriptreplay])
2137 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
2138
2139 UL_ENABLE_ALIAS([scriptlive], [scriptutils])
2140 UL_BUILD_INIT([scriptlive])
2141 UL_REQUIRES_HAVE([scriptlive], [pty], [openpty function (libutil)])
2142 AM_CONDITIONAL([BUILD_SCRIPTLIVE], [test "x$build_scriptlive" = xyes])
2143
2144
2145 UL_BUILD_INIT([col], [yes])
2146 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
2147
2148 UL_BUILD_INIT([colcrt], [yes])
2149 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
2150
2151 UL_BUILD_INIT([colrm], [yes])
2152 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
2153
2154 UL_BUILD_INIT([column], [check])
2155 UL_REQUIRES_BUILD([column], [libsmartcols])
2156 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
2157
2158 UL_BUILD_INIT([hexdump], [yes])
2159 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
2160
2161 UL_BUILD_INIT([rev], [yes])
2162 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
2163
2164
2165 AC_ARG_ENABLE([tunelp],
2166   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
2167   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
2168 )
2169 UL_BUILD_INIT([tunelp])
2170 UL_REQUIRES_LINUX([tunelp])
2171 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
2172
2173
2174 AC_ARG_ENABLE([kill],
2175   AS_HELP_STRING([--disable-kill], [do not build kill]),
2176   [], [UL_DEFAULT_ENABLE([kill], [check])]
2177 )
2178 UL_BUILD_INIT([kill])
2179 UL_REQUIRES_LINUX([kill])
2180 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
2181
2182
2183 AC_ARG_ENABLE([last],
2184   AS_HELP_STRING([--disable-last], [do not build last]),
2185   [], [UL_DEFAULT_ENABLE([last], [check])]
2186 )
2187 UL_BUILD_INIT([last])
2188 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
2189 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
2190 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
2191
2192
2193 AC_ARG_ENABLE([utmpdump],
2194   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
2195   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
2196 )
2197 UL_BUILD_INIT([utmpdump])
2198 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
2199 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
2200 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
2201
2202
2203 AC_ARG_ENABLE([line],
2204   AS_HELP_STRING([--enable-line], [build line]),
2205   [], [UL_DEFAULT_ENABLE([line], [no])]
2206 )
2207 UL_BUILD_INIT([line])
2208 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
2209
2210
2211 AC_ARG_ENABLE([mesg],
2212   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
2213   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
2214 )
2215 UL_BUILD_INIT([mesg])
2216 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
2217
2218
2219 AC_ARG_ENABLE([raw],
2220   AS_HELP_STRING([--disable-raw], [do not build raw]),
2221   [], [UL_DEFAULT_ENABLE([raw], [check])]
2222 )
2223 UL_BUILD_INIT([raw])
2224 UL_REQUIRES_LINUX([raw])
2225 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
2226 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
2227
2228
2229 AC_ARG_ENABLE([rename],
2230   AS_HELP_STRING([--disable-rename], [do not build rename]),
2231   [], [UL_DEFAULT_ENABLE([rename], [yes])]
2232 )
2233 UL_BUILD_INIT([rename])
2234 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
2235
2236
2237 AC_ARG_ENABLE([vipw],
2238   AS_HELP_STRING([--enable-vipw], [build vipw]),
2239   [], [UL_DEFAULT_ENABLE([vipw], [no])]
2240 )
2241 UL_BUILD_INIT([vipw])
2242 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
2243 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
2244
2245
2246 AC_ARG_ENABLE([newgrp],
2247   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
2248   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
2249 )
2250 UL_BUILD_INIT([newgrp])
2251 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
2252 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
2253
2254
2255 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
2256   [], [with_user=check]
2257 )
2258 have_user=no
2259 AS_IF([test "x$with_user" != xno], [
2260   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
2261   AS_CASE([$with_user:$have_user],
2262     [yes:no],
2263       [AC_MSG_ERROR([user selected but libuser not found])],
2264     [*:yes],
2265       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
2266   )
2267   # temporary solution, libuser has stupid .pc where are exported all
2268   # private dependencies to Requires: instead of Requires.private:
2269   AS_IF([test "x$have_user" = xyes], [
2270     LIBUSER_LIBS=-luser
2271   ])
2272 ])
2273 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
2274
2275 AC_ARG_ENABLE([chfn-chsh-password],
2276   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
2277   [], [enable_chfn_chsh_password=yes]
2278 )
2279
2280 AC_ARG_ENABLE([chfn-chsh],
2281   AS_HELP_STRING([--disable-chfn-chsh], [do not build chfn and chsh]),
2282   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
2283 )
2284 UL_BUILD_INIT([chfn_chsh])
2285 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
2286 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
2287
2288 AS_IF([test "x$enable_chfn_chsh_password" = xyes || test "x$have_user" = xyes], [
2289   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
2290   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
2291 ])
2292 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
2293 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
2294
2295 AC_ARG_ENABLE([chsh-only-listed],
2296   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
2297   [], enable_chsh_only_listed=yes
2298 )
2299
2300 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
2301   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
2302 ])
2303
2304
2305 AC_ARG_ENABLE([login],
2306   AS_HELP_STRING([--disable-login], [do not build login]),
2307   [], [UL_DEFAULT_ENABLE([login], [check])]
2308 )
2309 UL_BUILD_INIT([login])
2310 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
2311 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
2312 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
2313 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
2314 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
2315
2316 AC_ARG_ENABLE([login-chown-vcs],
2317   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
2318   [], [enable_login_chown_vcs=no]
2319 )
2320
2321 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2322   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2323 ])
2324
2325 AC_ARG_ENABLE([login-stat-mail],
2326   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2327   [], [enable_login_stat_mail=no]
2328 )
2329
2330 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2331   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2332 ])
2333
2334
2335 AC_ARG_ENABLE([nologin],
2336   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2337   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2338 )
2339 UL_BUILD_INIT([nologin])
2340 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2341
2342
2343 AC_ARG_ENABLE([sulogin],
2344   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2345   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2346 )
2347 UL_BUILD_INIT([sulogin])
2348 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2349 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2350 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2351
2352
2353 AC_ARG_ENABLE([su],
2354   AS_HELP_STRING([--disable-su], [do not build su]),
2355   [], [UL_DEFAULT_ENABLE([su], [check])]
2356 )
2357 UL_BUILD_INIT([su])
2358 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2359 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2360 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2361 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2362
2363
2364 AC_ARG_ENABLE([runuser],
2365   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2366   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2367 )
2368 UL_BUILD_INIT([runuser])
2369 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2370 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2371 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2372 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2373
2374
2375 AC_ARG_ENABLE([ul],
2376   AS_HELP_STRING([--disable-ul], [do not build ul]),
2377   [], [UL_DEFAULT_ENABLE([ul], [check])]
2378 )
2379 UL_BUILD_INIT([ul])
2380 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2381 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2382
2383
2384 AC_ARG_ENABLE([more],
2385   AS_HELP_STRING([--disable-more], [do not build more]),
2386   [], [UL_DEFAULT_ENABLE([more], [check])]
2387 )
2388 UL_BUILD_INIT([more])
2389 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2390 UL_REQUIRES_LINUX([more])
2391 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2392
2393
2394 AC_ARG_ENABLE([pg],
2395   AS_HELP_STRING([--enable-pg], [build pg]),
2396   [], [UL_DEFAULT_ENABLE([pg], [no])]
2397 )
2398 UL_BUILD_INIT([pg])
2399 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2400 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2401
2402
2403 AC_ARG_ENABLE([setterm],
2404   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2405   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2406 )
2407 UL_BUILD_INIT([setterm])
2408 UL_REQUIRES_LINUX([setterm])
2409 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2410 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2411
2412 # build_schedutils= is just configure-only variable to control
2413 # ionice, taskset and chrt
2414 AC_ARG_ENABLE([schedutils],
2415   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2416   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2417 )
2418
2419
2420 UL_ENABLE_ALIAS([ionice], [schedutils])
2421 UL_BUILD_INIT([ionice])
2422 UL_REQUIRES_SYSCALL_CHECK([ionice],
2423         [UL_CHECK_SYSCALL([ioprio_set],
2424           [alpha],      [442],
2425           [i*86],       [289],
2426           [ia64*],      [1274],
2427           [powerpc*],   [273],
2428           [s390*],      [282],
2429           [sparc*],     [196],
2430           [sh*],        [288],
2431           [x86_64*],    [251])],
2432         [ioprio_set])
2433
2434 UL_REQUIRES_SYSCALL_CHECK([ionice],
2435         [UL_CHECK_SYSCALL([ioprio_get],
2436           [alpha],      [443],
2437           [i*86],       [290],
2438           [ia64*],      [1275],
2439           [powerpc*],   [274],
2440           [s390*],      [283],
2441           [sparc*],     [218],
2442           [sh*],        [289],
2443           [x86_64*],    [252])],
2444         [ioprio_get])
2445
2446 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2447
2448
2449 UL_ENABLE_ALIAS([taskset], [schedutils])
2450 UL_BUILD_INIT([taskset])
2451 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2452 UL_REQUIRES_SYSCALL_CHECK([taskset],
2453         [UL_CHECK_SYSCALL([sched_getaffinity])],
2454         [sched_getaffinity])
2455 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2456
2457
2458 have_schedsetter=no
2459 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2460       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2461
2462 UL_ENABLE_ALIAS([chrt], [schedutils])
2463 UL_BUILD_INIT([chrt])
2464 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2465 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2466
2467 AS_IF([test "x$build_chrt" = xyes], [
2468         UL_CHECK_SYSCALL([sched_setattr])
2469 ])
2470
2471 UL_ENABLE_ALIAS([uclampset], [schedutils])
2472 UL_BUILD_INIT([uclampset])
2473 UL_REQUIRES_SYSCALL_CHECK([uclampset],
2474         [UL_CHECK_SYSCALL([sched_setattr])], [sched_setattr])
2475 AM_CONDITIONAL([BUILD_UCLAMPSET], [test "x$build_uclampset" = xyes])
2476
2477
2478 AC_ARG_ENABLE([wall],
2479   AS_HELP_STRING([--disable-wall], [do not build wall]),
2480   [], [UL_DEFAULT_ENABLE([wall], [check])]
2481 )
2482 UL_BUILD_INIT([wall])
2483 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2484 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2485
2486
2487 AC_ARG_ENABLE([write],
2488   AS_HELP_STRING([--enable-write], [build write]),
2489   [], [UL_DEFAULT_ENABLE([write], [no])]
2490 )
2491 UL_BUILD_INIT([write])
2492 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2493 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2494 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2495
2496
2497 AC_ARG_WITH([btrfs],
2498   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2499   [], [with_btrfs=check]
2500 )
2501 have_btrfs=no
2502 AS_IF([test "x$with_btrfs" != xno], [
2503   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2504     [yes:no],
2505     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2506     [check:no],
2507        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2508     [*:yes],
2509        [have_btrfs=yes
2510         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2511   )
2512 ])
2513 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2514
2515
2516 AC_ARG_WITH([systemd],
2517   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2518   [], [with_systemd=check]
2519 )
2520
2521 have_systemd=no
2522 AS_IF([test "x$with_systemd" != xno], [
2523   # new version -- all libsystemd-* libs merged into libsystemd
2524   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2525   # old versions
2526   AS_IF([test "x$have_systemd" != "xyes"], [
2527     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2528                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2529     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2530                       [have_systemd_journal=yes], [have_systemd_journal=no])
2531     AS_IF([test "x$have_systemd_daemon" = "xyes" && test "x$have_systemd_journal" = "xyes" ],[
2532            have_systemd=yes])
2533   ])
2534   AS_CASE([$with_systemd:$have_systemd],
2535     [yes:no],
2536       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2537     [*:yes],
2538        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2539        AC_DEFINE([USE_SYSTEMD], [1], [Define if systemd support is wanted ])
2540   )
2541 ])
2542 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2543
2544
2545 AC_ARG_WITH([systemdsystemunitdir],
2546   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2547   [], [
2548   AS_IF([test "x$have_systemd" = xyes], [
2549     PKG_CHECK_VAR([with_systemdsystemunitdir], [systemd], [systemdsystemunitdir],
2550       [],
2551       [with_systemdsystemunitdir=no])
2552   ])
2553 ])
2554 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2555   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2556 ])
2557
2558
2559 AC_ARG_WITH([smack],
2560   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2561   [], [with_smack=no]
2562 )
2563 AS_IF([test "x$with_smack" = xyes], [
2564   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2565 ])
2566
2567 AC_ARG_WITH([econf],
2568   AS_HELP_STRING([--without-econf], [do not use libeconf]),
2569   [], [with_econf=check]
2570 )
2571
2572 have_econf=no
2573 AS_IF([test "x$with_econf" != xno], [
2574   PKG_CHECK_MODULES([ECONF], [libeconf], [have_econf=yes], [have_econf=no])
2575     AS_CASE([$with_econf:$have_econf],
2576     [yes:no],
2577       [AC_MSG_ERROR([libeconf expected but libeconf not found])],
2578     [*:yes],
2579        AC_DEFINE([HAVE_LIBECONF], [1], [Define if libeconf is available])
2580   )
2581 ])
2582 AM_CONDITIONAL([HAVE_ECONF], [test "x$have_econf" = xyes])
2583
2584 AC_ARG_WITH([vendordir],
2585   AS_HELP_STRING([--with-vendordir=DIR], [Directory for distribution provided configuration files]),
2586   [], []
2587 )
2588 AC_SUBST([vendordir], [$with_vendordir])
2589 AM_CONDITIONAL([USE_VENDORDIR], [test "x$with_vendordir" != x])
2590 AS_IF([test "x$with_vendordir" != x], [
2591   AC_DEFINE([USE_VENDORDIR], [1], [Define to 1 to use vendordir])
2592 ])
2593
2594
2595 AC_ARG_ENABLE([bash-completion],
2596   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2597   [], [enable_bash_completion=yes]
2598 )
2599
2600 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2601
2602 AC_ARG_WITH([bashcompletiondir],
2603   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2604   [], [
2605   AS_IF([test "x$enable_bash_completion" = xyes], [
2606     PKG_CHECK_VAR([with_bashcompletiondir], [bash-completion], [completionsdir],
2607       [],
2608       [with_bashcompletiondir=${datadir}/bash-completion/completions])
2609   ])
2610 ])
2611 AS_IF([test "x$enable_bash_completion" = xyes], [
2612   AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2613 ])
2614
2615
2616 AC_ARG_WITH([python],
2617   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2618   [], [with_python=check withval=check]
2619 )
2620
2621 have_python=no
2622 have_libpython=no
2623 AS_IF([test "x$with_python" != xno], [
2624   # We follow distributions default and look for PKG module name "python"
2625   # (minimal version is 2) but if major version is explicitly specified by
2626   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2627   # "python3".
2628   AS_IF([test "x$withval" != xno && test "x$withval" != xyes && test "x$withval" != xcheck],
2629         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2630
2631   # check for python interpreter
2632   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2633   AS_CASE([$with_python:$have_python],
2634     [yes:no],
2635       [AC_MSG_ERROR([python selected but python interpreter not found])],
2636     [check:no],
2637        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2638     [*:yes],
2639        # check for python development stuff
2640        [
2641          PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION], [have_libpython=yes], [have_libpython=no])
2642
2643          # https://github.com/util-linux/util-linux/issues/2366
2644          AX_COMPARE_VERSION([$PYTHON_VERSION], [ge], [3.12], [
2645            UL_WARN_ADD([-Wno-error=redundant-decls], [PYTHON_CFLAGS])
2646          ])
2647        ]
2648   )
2649 ])
2650
2651
2652 AC_ARG_ENABLE([pylibmount],
2653   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2654   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2655 )
2656 UL_BUILD_INIT([pylibmount])
2657 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2658 UL_REQUIRES_BUILD([pylibmount], [libmount])
2659 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2660
2661 # We need to introduce a verbatim dependency into the Makefile, without automake
2662 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2663 verbatim_pylibmount_dependency='
2664
2665 # pylibmountexec module must be installed after usrlib_exec libraries,
2666 # otherwise the libtool relink step will fail to find libmount.la and
2667 # will try -lmount which is possibly not available.
2668 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2669
2670 '
2671 AC_SUBST([verbatim_pylibmount_dependency])
2672 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2673
2674 AC_ARG_ENABLE([pg-bell],
2675   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2676   [], [enable_pg_bell=yes]
2677 )
2678
2679 AS_IF([test "x$enable_pg_bell" = xyes], [
2680   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2681 ])
2682
2683
2684 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2685 AC_ARG_ENABLE([fs-paths-default],
2686   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2687   [AS_CASE([$enableval],
2688     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2689     [no],  [fs_paths_defaults=""],
2690     [fs_paths_defaults="$enableval"]
2691   )],
2692   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2693 )
2694 AC_ARG_ENABLE([fs-paths-extra],
2695   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2696   [AS_CASE([$enableval],
2697      [yes|no], [fs_paths_extra=""],
2698      [fs_paths_extra="$enableval"]
2699   )],
2700   [fs_paths_extra=""]
2701 )
2702 fs_paths="$fs_paths_defaults"
2703 AS_IF([test "x$fs_paths_extra" != "x"], [
2704   AS_IF([test "x$fs_paths" != "x"], [
2705     fs_paths="${fs_paths}:"
2706   ])
2707   fs_paths="${fs_paths}${fs_paths_extra}"
2708 ])
2709 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2710
2711
2712 AC_ARG_ENABLE([use-tty-group],
2713   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2714   [], [enable_use_tty_group=yes]
2715 )
2716 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2717
2718 AS_IF([test "x$enable_use_tty_group" = xyes], [
2719   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2720 ])
2721
2722
2723 AC_ARG_ENABLE([sulogin-emergency-mount],
2724   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2725                  [use emergency mount of /dev and /proc for sulogin]),
2726   [], [enable_sulogin_emergency_mount=no]
2727 )
2728
2729 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2730   AS_IF([test "x$linux_os" = xyes], [ ],
2731         [AC_MSG_ERROR([--enable-sulogin-emergency-mount selected for non-linux system])])
2732   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2733             [Should sulogin use an emergency mount of /dev and /proc?])
2734 ])
2735
2736
2737 AC_ARG_ENABLE([usrdir-path],
2738   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2739   [], [enable_usrdir_path=no]
2740 )
2741
2742 AS_IF([test "x$enable_usrdir_path" = xyes], [
2743   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2744 ])
2745
2746
2747 AC_ARG_ENABLE([makeinstall-chown],
2748   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2749   [], [enable_makeinstall_chown=yes]
2750 )
2751 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2752
2753
2754 AC_ARG_ENABLE([makeinstall-setuid],
2755   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2756   [], [enable_makeinstall_setuid=yes]
2757 )
2758 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2759
2760
2761 AC_ARG_ENABLE([colors-default],
2762   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2763   [], [enable_colors_default=yes]
2764 )
2765 AS_IF([test "x$enable_colors_default" = xyes], [
2766   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2767 ])
2768
2769
2770 AC_ARG_WITH([cryptsetup],
2771   AS_HELP_STRING([--with-cryptsetup], [compile with cryptsetup support]),
2772   [], [with_cryptsetup=no]
2773 )
2774
2775 AS_IF([test "x$with_cryptsetup" = xno], [
2776   AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2777   AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2778 ], [
2779   PKG_CHECK_MODULES([CRYPTSETUP], [libcryptsetup],
2780         [AC_DEFINE([HAVE_CRYPTSETUP], [1], [Define if cryptsetup is available])
2781          UL_PKG_STATIC([CRYPTSETUP_LIBS_STATIC], [libcryptsetup])
2782          AM_CONDITIONAL([HAVE_CRYPTSETUP], [true])
2783          SAVE_CFLAGS="$CFLAGS"
2784          CFLAGS="$CRYPTSETUP_CFLAGS $CFLAGS"
2785          SAVE_LIBS="$LIBS"
2786          LIBS="$CRYPTSETUP_LIBS $LIBS"
2787          AC_CHECK_LIB([cryptsetup], [crypt_activate_by_signed_key], [
2788           AC_DEFINE_UNQUOTED([HAVE_CRYPT_ACTIVATE_BY_SIGNED_KEY], [1], [Define if crypt_activate_by_signed_key exist in -lcryptsetup])
2789          ])
2790          AS_IF([test "x$with_cryptsetup" = xdlopen], [
2791           LIBS="-ldl $LIBS"
2792           AC_CHECK_LIB([dl], [dlsym], [
2793             AC_DEFINE([CRYPTSETUP_VIA_DLOPEN], [1], [Define if cryptsetup is to be loaded via dlopen])
2794             AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [true])
2795            ], [AC_MSG_ERROR([libdl required to build with cryptsetup support])])
2796          ], [
2797           AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2798          ])
2799          CFLAGS="$SAVE_CFLAGS"
2800          LIBS="$SAVE_LIBS"
2801          have_cryptsetup=yes],
2802         [have_cryptsetup=no
2803    AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2804    AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2805   ])
2806
2807   AS_CASE([$with_cryptsetup:$have_cryptsetup],
2808     [yes:no], [AC_MSG_WARN([cryptsetup selected but libcryptsetup not found])]
2809   )
2810 ])
2811 AC_SUBST([CRYPTSETUP_LIBS])
2812 AC_SUBST([CRYPTSETUP_LIBS_STATIC])
2813
2814
2815 AC_ARG_VAR([SUID_CFLAGS],
2816            [CFLAGS used for binaries which are usually with the suid bit])
2817 AC_ARG_VAR([SUID_LDFLAGS],
2818            [LDFLAGS used for binaries which are usually with the suid bit])
2819
2820 AC_ARG_VAR([DAEMON_CFLAGS],
2821            [CFLAGS used for binaries which are usually executed as daemons])
2822 AC_ARG_VAR([DAEMON_LDFLAGS],
2823            [LDFLAGS used for binaries which are usually executed as daemons])
2824
2825 AC_ARG_VAR([SOLIB_CFLAGS],
2826            [CFLAGS used for shared libraries])
2827 AC_ARG_VAR([SOLIB_LDFLAGS],
2828            [LDFLAGS used for shared libraries])
2829
2830 AC_ARG_VAR([ADJTIME_PATH],
2831            [Path to hwclock adjtime file, default /etc/adjtime])
2832 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2833 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2834
2835 if test "x${build_alias}" != "x${host_alias}"; then
2836   AC_MSG_NOTICE([setting link_all_deplibs=unknown for libtool])
2837   # work around Debian patch to libtool breaking cross-compiles
2838   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=702737
2839   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=297726
2840   link_all_deplibs=unknown
2841 fi
2842
2843
2844 LIBS=""
2845
2846
2847 AC_CONFIG_HEADERS([config.h])
2848
2849 #
2850 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2851 # more details.
2852 #
2853 AC_CONFIG_FILES([
2854 Makefile
2855 libblkid/docs/Makefile
2856 libblkid/docs/version.xml
2857 libblkid/src/blkid.h
2858 libfdisk/docs/Makefile
2859 libfdisk/docs/version.xml
2860 libfdisk/src/libfdisk.h
2861 libmount/docs/Makefile
2862 libmount/docs/version.xml
2863 libmount/src/libmount.h
2864 libsmartcols/docs/Makefile
2865 libsmartcols/docs/version.xml
2866 libsmartcols/src/libsmartcols.h
2867 po/Makefile.in
2868 po-man/Makefile
2869 ])
2870
2871 AC_OUTPUT
2872
2873 AC_MSG_RESULT([
2874         ${PACKAGE}  ${VERSION}
2875
2876         prefix:                    ${prefix}
2877         exec prefix:               ${exec_prefix}
2878
2879         bindir:                    ${bindir}
2880         sbindir:                   ${sbindir}
2881         libdir:                    ${libdir}
2882         usrbin_execdir:            ${usrbin_execdir}
2883         usrsbin_execdir:           ${usrsbin_execdir}
2884         usrlib_execdir:            ${usrlib_execdir}
2885
2886         localstatedir:             ${localstatedir}
2887         runstatedir:               ${runstatedir}
2888         includedir:                ${includedir}
2889         sysconfdir:                ${sysconfdir}
2890         sysconfstaticdir:          ${sysconfstaticdir}
2891
2892         vendordir:                 ${with_vendordir}
2893
2894         Python:                    ${PYTHON}
2895         Python version:            ${PYTHON_VERSION}
2896         Python libs:               ${pyexecdir}
2897
2898         Bash completions:          ${with_bashcompletiondir}
2899         Systemd support:           ${have_systemd}
2900         Systemd unitdir:           ${with_systemdsystemunitdir}
2901         libeconf support:          ${have_econf}
2902         Btrfs support:             ${have_btrfs}
2903         Wide-char support:         ${build_widechar}
2904         libcryptsetup support:     ${have_cryptsetup}
2905
2906         Manual pages:              ${build_asciidoc}
2907         Manual pages translated:   ${build_poman}
2908
2909         compiler:                  ${CC} / ${CXX}
2910         suid cflags:               ${SUID_CFLAGS}
2911         ldflags:                   ${LDFLAGS}
2912         suid ldflags:              ${SUID_LDFLAGS}
2913         ASAN enabled:              ${enable_asan}
2914         Fuzzing enabled:           ${enable_fuzzing_engine}
2915         Coverage enabled           ${enable_coverage}
2916
2917         cflags:                    ${CFLAGS}
2918
2919         warnings:
2920
2921 ${WARN_CFLAGS}
2922
2923  Type 'make' or 'make <utilname>' to compile.
2924 ])