configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com], [],
   4         [https://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.64])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like LT_INIT) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="17-May-2023"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77 # Check whether prefix=/usr
  78 AS_CASE([$prefix],
  79 [NONE | /usr],
  80   [AC_MSG_NOTICE([Default --prefix detected.])
  81    AS_CASE([$localstatedir], [NONE | '${prefix}/var' | "${prefix}"/var ],
  82            [localstatedir=/var; AC_MSG_NOTICE([  --localstatedir defaults to /var])])
  83    AS_CASE([$sysconfdir], [NONE | '${prefix}/etc' | "${prefix}"/etc ],
  84            [sysconfdir=/etc; AC_MSG_NOTICE([  --sysconfdir defaults to /etc])])
  85
  86   ]
  87 )
  88
  89 # default for old versions without $runstatedir
  90 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  91
  92 # our default if $localstatedir unchanged
  93 AS_CASE([$localstatedir:$runstatedir],
  94  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  95    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  96 )
  97
  98 AC_SUBST([runstatedir])
  99
 100
 101 # The original default values of {bin,sbin,lib}dir
 102 usrbin_execdir='${exec_prefix}/bin'
 103 AC_SUBST([usrbin_execdir])
 104
 105 usrsbin_execdir='${exec_prefix}/sbin'
 106 AC_SUBST([usrsbin_execdir])
 107
 108 AS_CASE([$libdir],
 109  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
 110    [usrlib_execdir=$libdir],
 111  [usrlib_execdir='${exec_prefix}'$libdir]
 112 )
 113 AC_SUBST([usrlib_execdir])
 114
 115 # static configuration maintaned by packages (e.g. /usr/lib)
 116 AC_ARG_VAR([SYSCONFSTATICDIR],
 117            [Path to static system configuration, default ${prefix}/lib])
 118 AS_IF([test "x$SYSCONFSTATICDIR" = x],
 119       [sysconfstaticdir='${prefix}/lib'],
 120       [sysconfstaticdir=$SYSCONFSTATICDIR])
 121 AC_SUBST([sysconfstaticdir])
 122
 123 AC_PROG_CC
 124 AM_PROG_CC_C_O
 125 AC_PROG_MKDIR_P
 126 AC_PROG_YACC
 127 AC_CANONICAL_HOST
 128 AC_C_CONST
 129 AC_C_VOLATILE
 130
 131 dnl Compiler warnings
 132 UL_WARN_ADD([-fno-common])
 133 UL_WARN_ADD([-Wall])
 134 UL_WARN_ADD([-Wextra])
 135
 136 UL_WARN_ADD([-Waddress-of-packed-member])
 137 UL_WARN_ADD([-Wdiscarded-qualifiers])
 138 UL_WARN_ADD([-Wembedded-directive])
 139 UL_WARN_ADD([-Wextra-semi])
 140 UL_WARN_ADD([-Wformat-security])
 141 UL_WARN_ADD([-Wimplicit-function-declaration])
 142 UL_WARN_ADD([-Wmissing-declarations])
 143 UL_WARN_ADD([-Wmissing-parameter-type])
 144 UL_WARN_ADD([-Wmissing-prototypes])
 145 UL_WARN_ADD([-Wnested-externs])
 146 UL_WARN_ADD([-Wno-missing-field-initializers])
 147 UL_WARN_ADD([-Wold-style-definition])
 148 UL_WARN_ADD([-Wpointer-arith])
 149 UL_WARN_ADD([-Wredundant-decls])
 150 UL_WARN_ADD([-Wsign-compare])
 151 UL_WARN_ADD([-Wstrict-prototypes])
 152 UL_WARN_ADD([-Wtype-limits])
 153 UL_WARN_ADD([-Wuninitialized])
 154 UL_WARN_ADD([-Wunused-but-set-parameter])
 155 UL_WARN_ADD([-Wunused-but-set-variable])
 156 UL_WARN_ADD([-Wunused-parameter])
 157 UL_WARN_ADD([-Wunused-result])
 158 UL_WARN_ADD([-Wunused-variable])
 159
 160 AC_ARG_ENABLE([werror],
 161   AS_HELP_STRING([--enable-werror], [make all compiler warnings into errors]),
 162   [], [enable_werror=no]
 163 )
 164 AS_IF([test "x$enable_werror" = xyes], [
 165   UL_WARN_ADD([-Werror])
 166 ],[
 167   UL_WARN_ADD([-Werror=sequence-point])
 168 ])
 169
 170 AC_SUBST([WARN_CFLAGS])
 171
 172
 173 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 174 AC_SUBST([BSD_WARN_CFLAGS])
 175
 176 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 177 AC_SUBST([PYTHON_WARN_CFLAGS])
 178
 179 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 180 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 181
 182
 183 AC_ARG_ENABLE([asan],
 184   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 185   [], [enable_asan=no]
 186 )
 187 AS_IF([test "x$enable_asan" = xyes], [
 188   UL_WARN_ADD([-fsanitize=address])
 189   ASAN_LDFLAGS="-fsanitize=address"
 190 ])
 191 AC_SUBST([ASAN_LDFLAGS])
 192
 193 AC_ARG_ENABLE([ubsan],
 194   AS_HELP_STRING([--enable-ubsan], [compile with UBsan]),
 195   [], [enable_ubsan=no]
 196 )
 197 AS_IF([test "x$enable_ubsan" = xyes], [
 198   UL_WARN_ADD([-fsanitize=undefined])
 199   UBSAN_LDFLAGS="-fsanitize=undefined"
 200 ])
 201 AC_SUBST([UBSAN_LDFLAGS])
 202
 203 AC_ARG_ENABLE([fuzzing-engine],
 204   AS_HELP_STRING([--enable-fuzzing-engine], [compile with fuzzing engine]),
 205   [], [enable_fuzzing_engine=no]
 206 )
 207 AS_IF([test "x$enable_fuzzing_engine" = xyes && test "x$LIB_FUZZING_ENGINE" = x], [
 208   UL_WARN_ADD([-fno-omit-frame-pointer])
 209   UL_WARN_ADD([-gline-tables-only])
 210   UL_WARN_ADD([-fsanitize=fuzzer-no-link])
 211   FUZZING_ENGINE_LDFLAGS="-fsanitize=fuzzer-no-link"
 212 ])
 213 AC_SUBST([FUZZING_ENGINE_LDFLAGS])
 214 AC_PROG_CXX
 215 AM_CONDITIONAL([FUZZING_ENGINE], [test "x$enable_fuzzing_engine" = xyes])
 216 AM_CONDITIONAL([OSS_FUZZ], [test "x$LIB_FUZZING_ENGINE" != x])
 217
 218 dnl libtool-2
 219 LT_INIT
 220
 221 dnl check supported linker flags
 222 AX_CHECK_VSCRIPT
 223
 224 m4_ifndef([PKG_PROG_PKG_CONFIG],
 225   [m4_fatal([Could not locate the pkg-config autoconf
 226     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 227     If your macros are in a different location, try setting the
 228     environment variable AL_OPTS="-I/other/macro/dir" before running
 229     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 230 PKG_PROG_PKG_CONFIG
 231 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 232
 233 GTK_DOC_CHECK([1.10])
 234 AC_PATH_PROG([XSLTPROC], [xsltproc])
 235
 236
 237 linux_os=no
 238 bsd_os=no
 239 AS_CASE([${host_os}],
 240   [*linux*],
 241      [linux_os=yes],
 242   [*darwin*],
 243      [darwin_os=yes],
 244   [*bsd*],
 245      [bsd_os=yes])
 246 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 247 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 248 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 249
 250 AS_IF([test  "x$darwin_os" = xyes], [
 251   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 252 ])
 253
 254 dnl define ARCH_<NAME> conditionals
 255 UL_SET_ARCH([I86], [i?86-*])
 256 UL_SET_ARCH([86_64], [x86_64*])
 257 UL_SET_ARCH([IA64], [ia64*])
 258 UL_SET_ARCH([S390], [s390*])
 259 UL_SET_ARCH([SPARC], [sparc*])
 260 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 261 UL_SET_ARCH([M68K], [m68*])
 262 UL_SET_ARCH([MIPS], [mips*])
 263 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 264
 265 AC_SYS_LARGEFILE
 266 AC_HEADER_ASSERT
 267 AC_STRUCT_TIMEZONE
 268
 269 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 270 AM_GNU_GETTEXT_VERSION([0.18.3])
 271 AM_GNU_GETTEXT([external])
 272
 273 AS_IF([test -d "$srcdir/po"], [
 274   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 275 ], [dnl echo $ALL_LINGUAS | sed 's/ /\n/g' | sort -u | column -xc 72 -o ' ' | sed 's/^/\t/'
 276   ALL_LINGUAS="
 277         af      am      ar      as      be      bg      bn      bn_IN   ca
 278         cs      cy      da      de      el      en_GB   es      et      eu_ES
 279         fa      fi      fr      gl      gu      he      hi      hr      hu
 280         hy      id      is      it      ja      ka      kn      ko      ku
 281         lo      lt      lv      mk      ml      mr      ms      my      nb
 282         nl      nn      no      nso     or      pa      pl      pt      pt_BR
 283         ro      ru      si      sk      sl      sq      sr      sr@Latn sv
 284         ta      te      th      tr      uk      ur      vi      zh_CN   zh_TW
 285         zu
 286 "])
 287
 288 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 289 #ifdef HAVE_LINUX_COMPILER_H
 290 #include <linux/compiler.h>
 291 #endif
 292 ])
 293 AC_CHECK_HEADERS([ \
 294         asm-generic/fcntl.h \
 295         asm/fcntl.h \
 296         asm/io.h \
 297         byteswap.h \
 298         endian.h \
 299         err.h \
 300         errno.h \
 301         fcntl.h \
 302         getopt.h \
 303         inttypes.h \
 304         lastlog.h \
 305         libutil.h \
 306         linux/blkzoned.h \
 307         linux/btrfs.h \
 308         linux/capability.h \
 309         linux/cdrom.h \
 310         linux/falloc.h \
 311         linux/fd.h \
 312         linux/fiemap.h \
 313         linux/kcmp.h \
 314         linux/net_namespace.h \
 315         linux/nsfs.h \
 316         linux/pr.h \
 317         linux/raw.h \
 318         linux/stat.h \
 319         linux/securebits.h \
 320         linux/tiocl.h \
 321         linux/version.h \
 322         linux/watchdog.h \
 323         linux/if_alg.h \
 324         locale.h \
 325         mntent.h \
 326         net/if_dl.h \
 327         net/if.h \
 328         netinet/in.h \
 329         paths.h \
 330         pty.h \
 331         security/pam_appl.h \
 332         shadow.h \
 333         stdint.h \
 334         stdio_ext.h \
 335         stdlib.h \
 336         sys/disk.h \
 337         sys/disklabel.h \
 338         sys/endian.h \
 339         sys/file.h \
 340         sys/ioccom.h \
 341         sys/ioctl.h \
 342         sys/io.h \
 343         sys/mkdev.h \
 344         sys/mount.h \
 345         sys/param.h \
 346         sys/pidfd.h \
 347         sys/prctl.h \
 348         sys/resource.h \
 349         sys/sendfile.h \
 350         sys/signalfd.h \
 351         sys/socket.h \
 352         sys/sockio.h \
 353         sys/stat.h \
 354         sys/statfs.h \
 355         sys/swap.h \
 356         sys/syscall.h \
 357         sys/sysmacros.h \
 358         sys/time.h \
 359         sys/timex.h \
 360         sys/ttydefaults.h \
 361         sys/types.h \
 362         sys/ucred.h \
 363         sys/un.h \
 364         sys/vfs.h \
 365         sys/xattr.h \
 366         unistd.h \
 367         utmp.h \
 368         utmpx.h \
 369 ])
 370
 371 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 372 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 373 #
 374 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 375  [#ifdef HAVE_SYS_MOUNT_H
 376    # include <linux/fs.h>
 377    # include <sys/mount.h>
 378   #endif
 379 ])
 380
 381 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 382  [#ifdef LINUX_GSMMUX_H
 383    # include <linux/gsmmux.h>
 384    #endif
 385 ])
 386
 387 AC_CHECK_HEADERS([security/pam_misc.h],
 388                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 389                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 390 #ifdef HAVE_SECURITY_PAM_APPL_H
 391 #include <security/pam_appl.h>
 392 #endif
 393 ])
 394
 395 AC_CHECK_DECLS([BLK_ZONE_REP_CAPACITY], [], [], [
 396         #include <linux/blkzoned.h>
 397 ])
 398
 399 AC_CHECK_DECLS([PR_REP_CAPACITY], [], [], [
 400         #include <linux/pr.h>
 401 ])
 402
 403 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 404 #ifdef HAVE_SECURITY_PAM_APPL_H
 405 #include <security/pam_appl.h>
 406 #endif
 407 ])
 408
 409 AC_CHECK_HEADERS([langinfo.h],
 410                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [true])],
 411                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [false])])
 412
 413 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 414 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 415         #include <langinfo.h>
 416 ]], [[
 417         char *str;
 418         str = nl_langinfo (ALTMON_1);
 419         str = nl_langinfo (ALTMON_2);
 420         str = nl_langinfo (ALTMON_3);
 421         str = nl_langinfo (ALTMON_4);
 422         str = nl_langinfo (ALTMON_5);
 423         str = nl_langinfo (ALTMON_6);
 424         str = nl_langinfo (ALTMON_7);
 425         str = nl_langinfo (ALTMON_8);
 426         str = nl_langinfo (ALTMON_9);
 427         str = nl_langinfo (ALTMON_10);
 428         str = nl_langinfo (ALTMON_11);
 429         str = nl_langinfo (ALTMON_12);
 430 ]])], [
 431         AC_MSG_RESULT([yes])
 432         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 433                 [Define if langinfo.h defines ALTMON_x constants])
 434 ], [
 435         AC_MSG_RESULT([no])
 436 ])
 437
 438
 439 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 440 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 441         #include <langinfo.h>
 442 ]], [[
 443         char *str;
 444         str = nl_langinfo (_NL_ABALTMON_1);
 445         str = nl_langinfo (_NL_ABALTMON_2);
 446         str = nl_langinfo (_NL_ABALTMON_3);
 447         str = nl_langinfo (_NL_ABALTMON_4);
 448         str = nl_langinfo (_NL_ABALTMON_5);
 449         str = nl_langinfo (_NL_ABALTMON_6);
 450         str = nl_langinfo (_NL_ABALTMON_7);
 451         str = nl_langinfo (_NL_ABALTMON_8);
 452         str = nl_langinfo (_NL_ABALTMON_9);
 453         str = nl_langinfo (_NL_ABALTMON_10);
 454         str = nl_langinfo (_NL_ABALTMON_11);
 455         str = nl_langinfo (_NL_ABALTMON_12);
 456 ]])], [
 457         AC_MSG_RESULT([yes])
 458         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 459                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 460 ], [
 461         AC_MSG_RESULT([no])
 462 ])
 463
 464
 465 dnl Convert some ac_cv_header_* variables to have_*
 466 dnl
 467 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 468 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 469 have_linux_capability_h=$ac_cv_header_linux_capability_h
 470 have_linux_kcmp_h=$ac_cv_header_linux_kcmp_h
 471 have_linux_pr_h=$ac_cv_header_linux_pr_h
 472 have_linux_raw_h=$ac_cv_header_linux_raw_h
 473 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 474 have_linux_version_h=$ac_cv_header_linux_version_h
 475 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 476 have_pty_h=$ac_cv_header_pty_h
 477 have_security_openpam_h=$ac_cv_header_security_openpam_h
 478 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 479 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 480 have_shadow_h=$ac_cv_header_shadow_h
 481 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 482 have_utmpx_h=$ac_cv_header_utmpx_h
 483 have_mntent_h=$ac_cv_header_mntent_h
 484
 485 AS_CASE([$linux_os:$have_linux_version_h],
 486   [yes:no],
 487     [AC_MSG_ERROR([kernel headers required on Linux])]
 488 )
 489
 490 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 491 #include <time.h>
 492 #include <unistd.h>
 493 ]], [[
 494     int a = 0;
 495     struct tm *tm = localtime(0);
 496     if (a == -1)  /* false */
 497         sleep(tm->tm_gmtoff);
 498 ]])],
 499 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 500 ])
 501
 502 AC_CHECK_TYPES([struct mount_attr], [], [], [[#include <linux/mount.h>]])
 503 AC_CHECK_TYPES([enum fsconfig_command], [], [], [[#include <linux/mount.h>]])
 504
 505 AC_CHECK_MEMBERS([struct termios.c_line],,,
 506     [[#include <termios.h>]])
 507
 508 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 509         [#include <sys/stat.h>])
 510
 511 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 512
 513 AC_CHECK_DECL([environ],
 514         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 515                 [Define to 1 if have **environ prototype])],
 516 )
 517
 518 AC_CHECK_DECL([strsignal],
 519         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 520                 [Define to 1 if have strsignal function prototype])],
 521 )
 522
 523 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 524               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 525               [#include <sys/ioctl.h>])
 526 AC_CHECK_DECL([SOCK_CLOEXEC],
 527               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 528               [#include <sys/types.h>
 529                #include <sys/socket.h>])
 530 AC_CHECK_DECL([SOCK_NONBLOCK],
 531               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 532               [#include <sys/types.h>
 533                #include <sys/socket.h>])
 534 AC_CHECK_DECL([SO_PASSCRED],
 535               [have_so_passcred=yes], [have_so_passcred=no],
 536               [#include <sys/types.h>
 537                #include <sys/socket.h>])
 538
 539 AC_CHECK_FUNCS([ \
 540         clearenv \
 541         close_range \
 542         eaccess \
 543         err \
 544         errx \
 545         explicit_bzero \
 546         __fpending \
 547         __fpurge \
 548         fpurge \
 549         fnmatch \
 550         fsconfig \
 551         fsmount \
 552         fsopen \
 553         fspick \
 554         fsync \
 555         getdomainname \
 556         getdtablesize \
 557         getexecname \
 558         getmntinfo \
 559         getrandom \
 560         getrlimit \
 561         getsgnam \
 562         getttynam \
 563         inotify_init \
 564         jrand48 \
 565         lchown \
 566         lgetxattr \
 567         llistxattr \
 568         llseek \
 569         newlocale \
 570         mempcpy \
 571         mkostemp \
 572         move_mount \
 573         mount_setattr \
 574         nanosleep \
 575         ntp_gettime \
 576         open_tree \
 577         personality \
 578         pidfd_open \
 579         pidfd_send_signal \
 580         posix_fadvise \
 581         prctl \
 582         qsort_r \
 583         rpmatch \
 584         scandirat \
 585         sched_setattr \
 586         sched_setscheduler \
 587         __secure_getenv \
 588         secure_getenv \
 589         sendfile \
 590         setprogname \
 591         setresgid \
 592         setresuid \
 593         sigqueue \
 594         srandom \
 595         statx \
 596         strnchr \
 597         strndup \
 598         strnlen \
 599         strtod_l \
 600         sysconf \
 601         sysinfo \
 602         timegm \
 603         usleep \
 604         uselocale \
 605         utimensat \
 606         vwarnx \
 607         warn \
 608         warnx \
 609 ])
 610 AC_FUNC_FSEEKO
 611
 612 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 613 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 614 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 615 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 616 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 617 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 618 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 619 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 620
 621 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 622
 623 have_setns_syscall="yes"
 624 UL_CHECK_SYSCALL([setns])
 625 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 626    have_setns_syscall="no"
 627 ])
 628
 629 UL_CHECK_SYSCALL([pidfd_open])
 630 UL_CHECK_SYSCALL([pidfd_send_signal])
 631 UL_CHECK_SYSCALL([close_range])
 632
 633 UL_CHECK_SYSCALL([fsconfig])
 634 UL_CHECK_SYSCALL([fsmount])
 635 UL_CHECK_SYSCALL([fsopen])
 636 UL_CHECK_SYSCALL([fspick])
 637 UL_CHECK_SYSCALL([mount_setattr])
 638 UL_CHECK_SYSCALL([move_mount])
 639 UL_CHECK_SYSCALL([open_tree])
 640
 641 AS_IF([test "x$ul_cv_syscall_fsconfig" = xno ||
 642        test "x$ul_cv_syscall_fsmount" = xno ||
 643        test "x$ul_cv_syscall_fsopen" = xno ||
 644        test "x$ul_cv_syscall_fspick" = xno ||
 645        test "x$ul_cv_syscall_mount_setattr" = xno ||
 646        test "x$ul_cv_syscall_move_mount" = xno ||
 647        test "x$ul_cv_syscall_open_tree" = xno],
 648    [
 649         have_mountfd_api="no"
 650    ],[
 651         have_mountfd_api="yes"
 652         AC_DEFINE([HAVE_MOUNTFD_API], [1], [Define to 1 if you want mount API based on FDs.])
 653    ])
 654
 655
 656 AC_CHECK_FUNCS([isnan], [],
 657         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 658         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 659 )
 660 AC_SUBST([MATH_LIBS])
 661
 662
 663 dnl lib/mononotic.c may require -lrt
 664 AC_CHECK_FUNCS([clock_gettime], [],
 665         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 666 )
 667
 668 have_timer="no"
 669 AC_CHECK_FUNCS([timer_create],
 670         [have_timer="yes"],
 671         [AC_CHECK_LIB([rt], [timer_create], [
 672                 have_timer="yes"
 673                 REALTIME_LIBS="-lrt"
 674                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 675         ],[
 676                 AC_SEARCH_LIBS([timer_create], [rt], [
 677                         AC_MSG_RESULT(yes)
 678                         have_timer="yes"
 679                         REALTIME_LIBS="-lrt -lpthread"
 680                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 681                 ],[], [-lpthread]
 682                 )
 683         ])]
 684 )
 685
 686 AC_SUBST([REALTIME_LIBS])
 687
 688 AS_IF([test x"$have_timer" = xno], [
 689        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 690 ])
 691
 692
 693 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 694         RTAS_LIBS="-lrtas"
 695         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 696 ])
 697 AC_SUBST([RTAS_LIBS])
 698
 699
 700 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 701                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 702         [#include <sys/types.h>
 703          #include <sys/socket.h>])
 704
 705 SOCKET_LIBS=
 706 AC_SEARCH_LIBS([socket], [socket],
 707         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 708                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 709 ])
 710 AC_SUBST([SOCKET_LIBS])
 711
 712
 713 have_dirfd=no
 714 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 715 AS_IF([test x"$have_dirfd" = xno], [
 716         AC_CHECK_DECLS([dirfd],
 717                 [have_dirfd=yes], [have_dirfd=no],
 718                 [#include <sys/types.h>
 719                  #include <dirent.h>])
 720 ])
 721
 722 have_ddfd=no
 723 AS_IF([test x"$have_dirfd" = xno], [
 724         AC_CHECK_MEMBERS([DIR.dd_fd],
 725                 [have_ddfd=yes], [have_ddfd=no],
 726                 [#include <sys/types.h>
 727                  #include <dirent.h>])
 728 ])
 729
 730 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes || test "x$have_ddfd" = xyes])
 731
 732
 733 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 734 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 735         #include <errno.h>
 736 ]], [[
 737         program_invocation_short_name = "test";
 738 ]])], [
 739         AC_MSG_RESULT([yes])
 740         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 741                 [Define if program_invocation_short_name is defined])
 742 ], [
 743         AC_MSG_RESULT([no])
 744 ])
 745
 746
 747 AC_MSG_CHECKING([whether __progname is defined])
 748 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 749            [if (*__progname == 0) return 1;])],
 750            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 751            AC_MSG_RESULT([yes]),
 752            AC_MSG_RESULT([no]))
 753
 754 AC_CHECK_DECL([IOC_OPAL_GET_STATUS],
 755         [AC_DEFINE([HAVE_OPAL_GET_STATUS], [1],
 756                 [Define to 1 if OPAL status ioctl is defined])],,
 757               [#include <linux/sed-opal.h>])
 758
 759 dnl Static compilation
 760 m4_define([UL_STATIC_PROGRAMS], [blkid, fdisk, losetup, mount, nsenter, sfdisk, umount, unshare])
 761
 762 AC_ARG_ENABLE([static-programs],
 763   [AS_HELP_STRING([--enable-static-programs=LIST],
 764       [link static the programs in LIST (comma-separated,
 765       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 766
 767 AS_CASE([$enable_static_programs],
 768   [yes],
 769     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 770   [no],
 771     [enable_static_programs=]
 772 )
 773
 774 dnl Set all the individual AM_CONDITIONALs
 775 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 776   AS_CASE([,$enable_static_programs,],
 777    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 778   )
 779   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 780   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 781     [test "x$static_[]UL_PRG" = xyes])
 782 ])
 783
 784
 785 AC_ARG_ENABLE([all-programs],
 786   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 787   [], [enable_all_programs=undefined]
 788 )
 789
 790 AS_CASE([$enable_all_programs],
 791   [yes], [AC_MSG_WARN([force to build all programs by default])
 792           ul_default_estate=check],
 793   [no],  [AC_MSG_WARN([disable all programs and man pages by default])
 794           ul_default_estate=no]
 795 )
 796
 797
 798 AC_ARG_ENABLE([asciidoc],
 799   AS_HELP_STRING([--disable-asciidoc], [do not generate man pages from asciidoc]),
 800   [], [UL_DEFAULT_ENABLE([asciidoc], [check])]
 801 )
 802 UL_BUILD_INIT([asciidoc])
 803 UL_REQUIRES_PROGRAM([asciidoc], [ASCIIDOCTOR], [asciidoctor], [man pages])
 804 AM_CONDITIONAL([ENABLE_ASCIIDOC], [test "x$build_asciidoc" = xyes])
 805
 806 have_manpages=no
 807 AS_IF([test -f "$srcdir/sys-utils/mount.8"], [
 808    AC_MSG_NOTICE([re-use already generated man-pages.])
 809    have_manpages=yes]
 810 )
 811 AM_CONDITIONAL([HAVE_MANPAGES], [test "x$have_manpages" = xyes])
 812
 813
 814 AC_ARG_ENABLE([poman],
 815   AS_HELP_STRING([--disable-poman], [generate translated man pages]),
 816   [], [UL_DEFAULT_ENABLE([poman], [check])]
 817 )
 818 UL_BUILD_INIT([poman])
 819 UL_REQUIRES_PROGRAM([poman], [PO4A], [po4a], [translated man pages])
 820 AM_CONDITIONAL([ENABLE_POMAN], [test "x$build_poman" = xyes])
 821
 822
 823 AX_CHECK_TLS
 824
 825 have_pty=no
 826 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 827   [], [with_util=auto]
 828 )
 829 AS_IF([test "x$with_util" = xno], [
 830   AM_CONDITIONAL([HAVE_UTIL], [false])
 831   have_util=no
 832 ], [
 833   UL_CHECK_LIB([util], [openpty])
 834 ])
 835
 836 AS_IF([test "x$have_pty_h" = xyes && test "x$have_sys_signalfd_h" = xyes && test "x$have_util" = xyes], [
 837    AM_CONDITIONAL([HAVE_PTY], [true])
 838    AC_DEFINE([HAVE_PTY], [1], [have PTY support])
 839    have_pty=yes
 840 ], [
 841    AM_CONDITIONAL([HAVE_PTY], [false])
 842 ])
 843
 844 AC_CHECK_TYPES([union semun], [], [], [[
 845 #include <sys/sem.h>
 846 ]])
 847 AC_CHECK_TYPES([loff_t])
 848
 849
 850 AC_ARG_ENABLE([widechar],
 851   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 852   [], [enable_widechar=check]
 853 )
 854 UL_BUILD_INIT([widechar])
 855 UL_REQUIRES_COMPILE([widechar], [[
 856   #include <wchar.h>
 857   #include <wctype.h>
 858   #include <stdio.h>
 859   #include <stdlib.h>
 860   ]], [[
 861     wchar_t wc;
 862     wint_t w;
 863     w = fgetwc(stdin);
 864     if (w == WEOF) exit(1);
 865     wc = w;
 866     fputwc(wc,stdout);
 867   ]],
 868   [wchar_t support])
 869
 870 AS_IF([test "x$build_widechar" = xyes ], [
 871   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 872 ])
 873
 874
 875 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 876 #include <sched.h>
 877 ]])
 878
 879 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 880
 881 AC_CHECK_TYPES([sighandler_t], [], [], [[
 882 #include <signal.h>
 883 ]])
 884
 885 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 886 #include <sched.h>
 887 ]])
 888
 889 # on Solaris, you can't mix and match standards, since we use c99
 890 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 891 # check for crypt.h and use that without XOPEN_SOURCE.
 892 have_crypt=no
 893 AC_CHECK_HEADERS([crypt.h])
 894 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 895 #ifdef HAVE_CRYPT_H
 896 #include <crypt.h>
 897 #else
 898 #define _XOPEN_SOURCE
 899 #include <unistd.h>
 900 #endif
 901 ]], [[
 902 char *c = crypt("abc","pw");
 903 ]])],[
 904   have_libcrypt=no
 905   have_crypt=yes
 906 ],[
 907   UL_SET_LIBS([-lcrypt])
 908   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 909   #ifdef HAVE_CRYPT_H
 910   #include <crypt.h>
 911   #else
 912   #define _XOPEN_SOURCE
 913   #include <unistd.h>
 914   #endif
 915   ]], [[
 916   char *c = crypt("abc","pw");
 917   ]])],[
 918   have_libcrypt=yes
 919   have_crypt=yes
 920   ],[
 921   AC_MSG_WARN([crypt() is not available])
 922   ])
 923   UL_RESTORE_LIBS
 924 ])
 925 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 926
 927
 928 AC_ARG_WITH([selinux],
 929   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 930   [], [with_selinux=no]
 931 )
 932
 933 AS_IF([test "x$with_selinux" = xno], [
 934   AM_CONDITIONAL([HAVE_SELINUX], [false])
 935 ], [
 936   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.5], [have_selinux=yes], [have_selinux=no])
 937   AS_CASE([$with_selinux:$have_selinux],
 938     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 939   )
 940   AS_IF([test "x$have_selinux" = xyes], [
 941     AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 942     UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 943     AM_CONDITIONAL([HAVE_SELINUX], [true])
 944
 945     UL_SET_LIBS([$SELINUX_LIBS])
 946     # This function is missing in old libselinux 1.xx versions
 947     AC_CHECK_FUNCS([security_get_initial_context])
 948     UL_RESTORE_LIBS
 949   ])
 950 ])
 951 AC_SUBST([SELINUX_LIBS])
 952 AC_SUBST([SELINUX_LIBS_STATIC])
 953
 954
 955 AC_ARG_WITH([audit],
 956   AS_HELP_STRING([--with-audit], [compile with audit support]),
 957   [], [with_audit=no]
 958 )
 959
 960 AS_IF([test "x$with_audit" = xno], [
 961   AM_CONDITIONAL([HAVE_AUDIT], [false])
 962 ], [
 963   UL_CHECK_LIB([audit], [audit_log_user_message])
 964   AS_CASE([$with_audit:$have_audit],
 965     [yes:no],
 966       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 967   )
 968 ])
 969
 970 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 971   [], [with_udev=auto]
 972 )
 973
 974 AS_IF([test "x$with_udev" = xno], [
 975   AM_CONDITIONAL([HAVE_UDEV], [false])
 976 ], [
 977   UL_CHECK_LIB([udev], [udev_new])
 978   AS_CASE([$with_udev:$have_udev],
 979     [yes:no],
 980       [AC_MSG_ERROR([udev selected but libudev not found])]
 981   )
 982 ])
 983
 984
 985 dnl wide-char ncurses
 986 AC_ARG_WITH([ncursesw],
 987   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 988   [], [with_ncursesw=auto]
 989 )
 990 have_ncursesw=no
 991 have_ncursesw_header=no
 992 AS_IF([test "x$with_ncursesw" != xno], [
 993   UL_NCURSES_CHECK([ncursesw])
 994   AS_IF([test "x$have_ncursesw" = xyes], [
 995     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 996     AC_CHECK_HEADERS([ncursesw/term.h])
 997
 998     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 999     # unsuccessful to avoid too many *_H permitations in config.h
1000     AS_IF([test "x$have_ncursesw_header" = xno], [
1001            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
1002            AC_CHECK_HEADERS([term.h])
1003     ])
1004     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
1005   ])
1006   AS_IF([test "x$have_ncursesw" = xyes], [
1007     CURSES_LIB_NAME="ncursesw"
1008     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
1009   ])
1010 ])
1011 AS_CASE([$with_ncursesw:$have_ncursesw],
1012   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
1013
1014
1015 dnl non-wide ncurses
1016 AC_ARG_WITH([ncurses],
1017   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
1018   [], [with_ncurses=auto]
1019 )
1020 have_ncurses=no
1021 have_ncurses_header=no
1022 AS_CASE([$with_ncurses:$build_widechar],
1023   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
1024
1025 AS_IF([test "x$have_ncursesw" = xno && test "x$with_ncurses" != xno ], [
1026   UL_NCURSES_CHECK([ncurses])
1027   AS_IF([test "x$have_ncurses" = xyes], [
1028     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
1029     AC_CHECK_HEADERS([ncurses/term.h])
1030
1031     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
1032     # unsuccessful to avoid too many *_H permitations in config.h
1033     AS_IF([test "x$have_ncurses_header" = xno], [
1034            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
1035            AC_CHECK_HEADERS([term.h])
1036     ])
1037     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
1038   ])
1039   AS_IF([test "x$have_ncurses" = xyes], [
1040     CURSES_LIB_NAME="ncurses"
1041     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
1042   ])
1043 ])
1044 AS_CASE([$with_ncurses:$have_ncurses],
1045   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
1046
1047 AC_SUBST([NCURSES_CFLAGS])
1048 AC_SUBST([NCURSES_LIBS])
1049 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes])
1050
1051
1052 AC_ARG_WITH([slang],
1053   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
1054   [], [with_slang=no]
1055 )
1056 have_slang=no
1057 AS_IF([test "x$with_slang" = xyes], [
1058   AC_CHECK_HEADERS([slang.h slang/slang.h])
1059   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
1060                    [have_slang=yes], [], [
1061 #ifdef HAVE_SLANG_H
1062 #include <slang.h>
1063 #elif defined(HAVE_SLANG_SLANG_H)
1064 #include <slang/slang.h>
1065 #endif
1066 ])
1067   AS_IF([test "x$have_slang" = xno], [
1068     AC_MSG_ERROR([slang selected but slcurses.h not found])],
1069     [CURSES_LIB_NAME=slang
1070   ])
1071 ])
1072 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
1073
1074
1075 AS_IF([test "x$have_slang" = xyes || test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes], [
1076         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
1077                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
1078                                [Define if curses library has the use_default_colors().])
1079         ])
1080         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
1081                      AC_DEFINE(HAVE_RESIZETERM, 1,
1082                                [Define if curses library has the resizeterm().])
1083         ])
1084 ])
1085
1086
1087 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
1088   [], [with_tinfo=auto]
1089 )
1090 have_tinfo=no
1091 have_tinfow=no
1092 AS_IF([test "x$with_tinfo" != xno], [
1093   AS_IF([test "x$have_ncursesw" = xyes], [
1094     UL_TINFO_CHECK([tinfow])
1095   ])
1096   AS_IF([test "x$have_tinfow" = xno], [
1097     UL_TINFO_CHECK([tinfo])
1098   ])
1099 ])
1100 AC_SUBST([TINFO_LIBS])
1101 AC_SUBST([TINFO_LIBS_STATIC])
1102 AC_SUBST([TINFO_CFLAGS])
1103 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes])
1104 AS_IF([test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes], [
1105   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1106 ])
1107
1108
1109 AC_ARG_WITH([readline],
1110   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1111   [], [with_readline=auto]
1112 )
1113
1114 AS_IF([test "x$with_readline" = xno], [
1115   AM_CONDITIONAL([HAVE_READLINE], [false])
1116 ], [
1117   UL_CHECK_LIB([readline], [readline])
1118   AS_CASE([$with_readline:$have_readline],
1119     [yes:no],
1120       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1121     [*:yes],
1122       [READLINE_LIBS="-lreadline"
1123        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1124   )
1125 ])
1126 AC_SUBST([READLINE_LIBS])
1127 AC_SUBST([READLINE_LIBS_STATIC])
1128
1129
1130 AC_ARG_WITH([utempter],
1131   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1132   [], [with_utempter=no]
1133 )
1134
1135 AS_IF([test "x$with_utempter" = xyes], [
1136   UL_CHECK_LIB([utempter], [utempter_add_record])
1137   AS_IF([test "x$have_utempter" = xno], [
1138     AC_MSG_ERROR([utempter selected but libutempter not found])
1139   ])
1140 ], [
1141   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1142 ])
1143
1144
1145 dnl
1146 dnl libuuid
1147 dnl
1148 AC_ARG_ENABLE([libuuid],
1149   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1150   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1151 )
1152 UL_BUILD_INIT([libuuid])
1153 AC_SUBST([LIBUUID_VERSION])
1154 AC_SUBST([LIBUUID_VERSION_INFO])
1155 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1156
1157 AC_ARG_ENABLE([libuuid-force-uuidd],
1158   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1159   [], [enable_libuuid_force_uuidd=no]
1160 )
1161
1162 AS_IF([test "x$build_libuuid" = xyes], [
1163   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1164 ])
1165
1166 dnl
1167 dnl libblkid
1168 dnl
1169 AC_ARG_ENABLE([libblkid],
1170   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1171   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1172 )
1173 UL_BUILD_INIT([libblkid])
1174 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1175 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1176 AC_SUBST([LIBBLKID_DATE])
1177 AC_SUBST([LIBBLKID_VERSION])
1178 AC_SUBST([LIBBLKID_VERSION_INFO])
1179 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1180 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1181 AS_IF([test "x$build_libblkid" = xyes], [
1182   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1183 ])
1184 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1185 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes && test "x$enable_static" = xyes])
1186
1187 dnl
1188 dnl libmount
1189 dnl
1190 AC_ARG_ENABLE([libmount],
1191   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1192   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1193 )
1194 UL_BUILD_INIT([libmount])
1195 UL_REQUIRES_BUILD([libmount], [libblkid])
1196 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1197 UL_REQUIRES_HAVE([libmount], [mntent_h], [mntent.h header file])
1198 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1199 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes && test "x$enable_static" = xyes])
1200 AS_IF([test "x$build_libmount" = xyes], [
1201   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1202   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1203     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1204   ],[
1205     AC_MSG_WARN([libmount will be compiled without namespaces support])
1206   ])
1207 ])
1208
1209 AC_SUBST([LIBMOUNT_VERSION])
1210 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1211 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1212 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1213 AC_SUBST([LIBMOUNT_VERSION_INFO])
1214 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1215
1216 AC_ARG_ENABLE([libmount-mountfd-support],
1217   AS_HELP_STRING([--disable-libmount-mountfd-support], [do not use new mount API based on FDs]),
1218   [], [enable_libmount_mountfd_support=check]
1219 )
1220 UL_BUILD_INIT([libmount_mountfd_support])
1221 UL_REQUIRES_BUILD([libmount_mountfd_support], [libmount])
1222 UL_REQUIRES_LINUX([libmount_mountfd_support])
1223 UL_REQUIRES_HAVE([libmount_mountfd_support], [mountfd_api], [mount FDs based API])
1224 AS_IF([test "x$build_libmount_mountfd_support" = xyes ], [
1225   AC_DEFINE([USE_LIBMOUNT_MOUNTFD_SUPPORT], [1], [Enable support for new mount FD based kernel API])
1226 ])
1227
1228
1229 dnl
1230 dnl libsmartcols
1231 dnl
1232 AC_ARG_ENABLE([libsmartcols],
1233   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1234   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1235 )
1236 UL_BUILD_INIT([libsmartcols])
1237 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1238
1239 AC_SUBST([LIBSMARTCOLS_VERSION])
1240 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1241 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1242
1243
1244 dnl
1245 dnl libfdisk
1246 dnl
1247 AC_ARG_ENABLE([libfdisk],
1248   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1249   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1250 )
1251 UL_BUILD_INIT([libfdisk])
1252 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1253 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1254 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes && test "x$enable_static" = xyes])
1255
1256 AS_IF([test "x$build_libblkid" = xyes],
1257   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1258 AC_SUBST([LIBFDISK_PC_REQUIRES])
1259
1260 AC_SUBST([LIBFDISK_VERSION])
1261 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1262 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1263 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1264 AC_SUBST([LIBFDISK_VERSION_INFO])
1265 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1266
1267
1268 AC_ARG_ENABLE([fdisks],
1269   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1270   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1271 )
1272 enable_fdisk=$enable_fdisks
1273 enable_sfdisk=$enable_fdisks
1274 enable_cfdisk=$enable_fdisks
1275
1276 UL_BUILD_INIT([fdisk])
1277 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1278 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1279 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1280 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1281 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1282
1283
1284 UL_BUILD_INIT([sfdisk])
1285 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1286 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1287 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1288 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1289 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1290
1291
1292 UL_BUILD_INIT([cfdisk])
1293 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1294 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1295 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1296 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1297 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1298
1299
1300 AC_ARG_ENABLE([mount],
1301   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1302   [], [UL_DEFAULT_ENABLE([mount], [check])]
1303 )
1304 UL_BUILD_INIT([mount])
1305 UL_REQUIRES_LINUX([mount])
1306 UL_REQUIRES_BUILD([mount], [libmount])
1307 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1308
1309
1310 AC_ARG_ENABLE([losetup],
1311   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1312   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1313 )
1314 UL_BUILD_INIT([losetup])
1315 UL_REQUIRES_LINUX([losetup])
1316 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1317 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1318
1319 AC_ARG_ENABLE([zramctl],
1320   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1321   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1322 )
1323 UL_BUILD_INIT([zramctl])
1324 UL_REQUIRES_LINUX([zramctl])
1325 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1326 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1327
1328 AC_ARG_ENABLE([fsck],
1329   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1330   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1331 )
1332 UL_BUILD_INIT([fsck])
1333 UL_REQUIRES_BUILD([fsck], [libmount])
1334 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1335
1336
1337 AC_ARG_ENABLE([partx],
1338   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1339   [], [UL_DEFAULT_ENABLE([partx], [check])]
1340 )
1341 UL_BUILD_INIT([partx])
1342 UL_REQUIRES_LINUX([partx])
1343 UL_REQUIRES_BUILD([partx], [libblkid])
1344 UL_REQUIRES_BUILD([partx], [libsmartcols])
1345 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1346
1347
1348 AC_ARG_ENABLE([uuidd],
1349   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1350   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1351 )
1352 UL_BUILD_INIT([uuidd])
1353 UL_REQUIRES_BUILD([uuidd], [libuuid])
1354 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1355 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1356 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1357   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1358 ])
1359 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1360
1361
1362 AC_ARG_ENABLE([uuidgen],
1363   AS_HELP_STRING([--disable-uuidgen], [do not build uuidgen]),
1364   [], [UL_DEFAULT_ENABLE([uuidgen], [check])]
1365 )
1366 UL_BUILD_INIT([uuidgen])
1367 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1368 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1369
1370 UL_BUILD_INIT([uuidparse], [check])
1371 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1372 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1373 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1374
1375 AC_ARG_ENABLE([blkid],
1376   AS_HELP_STRING([--disable-blkid], [do not build blkid(8)]),
1377   [], [UL_DEFAULT_ENABLE([blkid], [check])]
1378 )
1379 UL_BUILD_INIT([blkid])
1380 UL_REQUIRES_BUILD([blkid], [libblkid])
1381 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1382
1383 UL_BUILD_INIT([findfs], [check])
1384 UL_REQUIRES_BUILD([findfs], [libblkid])
1385 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1386
1387 AC_ARG_ENABLE([wipefs],
1388   AS_HELP_STRING([--disable-wipefs], [do not build wipefs]),
1389   [], [UL_DEFAULT_ENABLE([wipefs], [check])]
1390 )
1391 UL_BUILD_INIT([wipefs])
1392 UL_REQUIRES_BUILD([wipefs], [libblkid])
1393 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1394 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1395
1396 UL_BUILD_INIT([findmnt], [check])
1397 UL_REQUIRES_BUILD([findmnt], [libmount])
1398 UL_REQUIRES_BUILD([findmnt], [libblkid])
1399 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1400 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1401
1402
1403 AC_ARG_ENABLE([mountpoint],
1404   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1405   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1406 )
1407 UL_BUILD_INIT([mountpoint])
1408 UL_REQUIRES_BUILD([mountpoint], [libmount])
1409 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1410
1411
1412 AC_ARG_ENABLE([fallocate],
1413   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1414   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1415 )
1416 UL_BUILD_INIT([fallocate])
1417 UL_REQUIRES_LINUX([fallocate])
1418 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1419 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1420
1421 AS_IF([test "x$build_fallocate" = xyes], [
1422   dnl check for valid fallocate() function
1423   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1424   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1425   dnl and program can't be linked.
1426   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1427   dnl function prototype.
1428   AC_MSG_CHECKING([for valid fallocate() function])
1429   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1430 #ifdef HAVE_UNISTD_H
1431 # include <unistd.h>
1432 #endif
1433 #ifdef HAVE_SYS_TYPES_H
1434 # include <sys/types.h>
1435 #endif
1436 #ifdef HAVE_LINUX_FALLOC_H
1437 # include <linux/falloc.h>
1438 #endif
1439 #ifdef HAVE_FCNTL_H
1440 # include <fcntl.h>
1441 #endif
1442 ]],[[
1443    long ret;
1444    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1445    if (ret != 0) {
1446       return 1;
1447    }
1448    ]])],[
1449   AC_MSG_RESULT([yes])
1450   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1451   AC_MSG_RESULT([no])])
1452 ])
1453
1454 AS_IF([test "x$build_fallocate" = xyes], [
1455   dnl check for valid posix_fallocate() function
1456   AC_MSG_CHECKING([for valid posix_fallocate() function])
1457   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1458 #ifdef HAVE_UNISTD_H
1459 # include <unistd.h>
1460 #endif
1461 #ifdef HAVE_SYS_TYPES_H
1462 # include <sys/types.h>
1463 #endif
1464 #ifdef HAVE_LINUX_FALLOC_H
1465 # include <linux/falloc.h>
1466 #endif
1467 #ifdef HAVE_FCNTL_H
1468 # include <fcntl.h>
1469 #endif
1470 ]],[[
1471    long ret;
1472    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1473    if (ret != 0) {
1474       return 1;
1475    }
1476    ]])],[
1477   AC_MSG_RESULT([yes])
1478   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1479   AC_MSG_RESULT([no])])
1480 ])
1481
1482
1483 AC_ARG_ENABLE([unshare],
1484   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1485   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1486 )
1487 UL_BUILD_INIT([unshare])
1488 UL_REQUIRES_LINUX([unshare])
1489 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1490 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1491 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1492
1493 AC_MSG_CHECKING([for valid unshare() function])
1494 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1495 #include <sched.h>
1496 ]],[[
1497    int ret;
1498    ret = unshare(0);
1499    if (ret != 0) {
1500       return 1;
1501    }
1502    ]])],[
1503   AC_MSG_RESULT([yes])
1504   AC_DEFINE([HAVE_UNSHARE], [1], [Have valid unshare() function])],
1505 [
1506   AC_MSG_RESULT([no])
1507 ])
1508
1509
1510 AC_ARG_ENABLE([nsenter],
1511   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1512   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1513 )
1514 UL_BUILD_INIT([nsenter])
1515 UL_REQUIRES_LINUX([nsenter])
1516 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1517 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1518
1519 AC_MSG_CHECKING([for valid setns() function])
1520 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1521 #include <sched.h>
1522 #include <errno.h>
1523 ]],[[
1524    int ret;
1525    ret = setns(0, 0);
1526    if (ret != EINVAL && ret != EBADF && ret != EPERM) {
1527       return 1;
1528    }
1529    ]])],[
1530   AC_MSG_RESULT([yes])
1531   AC_DEFINE([HAVE_SETNS], [1], [Have valid setns() function])],
1532 [
1533   AC_MSG_RESULT([no])
1534 ])
1535
1536
1537 AC_ARG_WITH([cap_ng],
1538   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1539   [], [with_cap_ng=auto]
1540 )
1541 AS_IF([test "x$with_cap_ng" = xno], [
1542   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1543   have_cap_ng=no
1544 ],[
1545   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1546 ])
1547
1548
1549 AC_ARG_ENABLE([setpriv],
1550   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1551   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1552 )
1553 UL_BUILD_INIT([setpriv])
1554 UL_REQUIRES_LINUX([setpriv])
1555 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1556 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1557 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1558 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1559
1560 AC_ARG_ENABLE([hardlink],
1561   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1562   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1563 )
1564 UL_BUILD_INIT([hardlink])
1565 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1566
1567
1568 AC_ARG_ENABLE([eject],
1569   AS_HELP_STRING([--disable-eject], [do not build eject]),
1570   [], [UL_DEFAULT_ENABLE([eject], [check])]
1571 )
1572 UL_BUILD_INIT([eject])
1573 UL_REQUIRES_LINUX([eject])
1574 UL_REQUIRES_BUILD([eject], [libmount])
1575 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1576
1577
1578 AC_ARG_ENABLE([agetty],
1579   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1580   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1581 )
1582 UL_BUILD_INIT([agetty])
1583 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1584 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1585 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1586 AS_IF([test "x$have_futimens" = xyes && test "x$have_inotify_init1" = xyes ], [
1587   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1588 ],[
1589   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1590 ])
1591
1592
1593 AC_ARG_ENABLE([plymouth_support],
1594   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1595   [], [enable_plymouth_support=check]
1596 )
1597 UL_BUILD_INIT([plymouth_support])
1598 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1599 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1600 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1601 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1602 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1603 AS_IF([test "x$build_plymouth_support" = xyes ], [
1604     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1605 ])
1606
1607
1608 AC_ARG_WITH([libz],
1609   AS_HELP_STRING([--without-libz], [compile without libz]),
1610   [], [with_libz=auto]
1611 )
1612 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1613   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1614 ])
1615
1616 AC_ARG_WITH([libmagic],
1617   AS_HELP_STRING([--without-libmagic], [compile without libmagic]),
1618   [], [with_libmagic=auto]
1619 )
1620 AS_IF([test "x$with_libmagic" = xno], [have_magic=no], [
1621   AC_CHECK_LIB([magic], [magic_open], [
1622     AC_CHECK_HEADER(magic.h, [
1623       AC_DEFINE([HAVE_MAGIC], [1], [Define to 1 if you have the libmagic present.])
1624       MAGIC_LIBS="-lmagic"
1625     ])
1626   ])
1627 ])
1628 AC_SUBST([MAGIC_LIBS])
1629
1630
1631 AC_ARG_ENABLE([cramfs],
1632   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1633   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1634 )
1635 UL_BUILD_INIT([cramfs])
1636 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1637 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1638
1639
1640 AC_ARG_ENABLE([bfs],
1641   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1642   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1643 )
1644 UL_BUILD_INIT([bfs])
1645 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1646
1647
1648 AC_ARG_ENABLE([minix],
1649   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1650   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1651 )
1652 UL_BUILD_INIT([minix])
1653 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1654
1655
1656 AC_ARG_ENABLE([fdformat],
1657   AS_HELP_STRING([--enable-fdformat], [build fdformat]),
1658   [], [UL_DEFAULT_ENABLE([fdformat], [no])]
1659 )
1660 UL_BUILD_INIT([fdformat])
1661 UL_REQUIRES_LINUX([fdformat])
1662 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1663
1664
1665 AC_ARG_ENABLE([hwclock],
1666   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1667   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1668 )
1669 have_linuxdummy=$linux_os
1670
1671 UL_BUILD_INIT([hwclock])
1672 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1673 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1674
1675 AC_ARG_ENABLE([hwclock_cmos],
1676   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1677   [], [enable_hwclock_cmos=check]
1678 )
1679 UL_BUILD_INIT([hwclock_cmos])
1680 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1681 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1682 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1683 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1684     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1685 ])
1686
1687 AC_ARG_ENABLE([hwclock_gplv3],
1688   AS_HELP_STRING([--disable-hwclock-gplv3], [do not use datetime parsing GPLv3 code]),
1689   [], [enable_hwclock_gplv3=yes]
1690 )
1691 AM_CONDITIONAL([USE_HWCLOCK_GPLv3_DATETIME], [test "x$enable_hwclock_gplv3" = xyes])
1692 AS_IF([test "x$enable_hwclock_gplv3" = xyes ], [
1693     AC_DEFINE([USE_HWCLOCK_GPLv3_DATETIME], [1], [use datetime parsing GPLv3 code to hwclock])
1694 ])
1695
1696
1697 AC_ARG_ENABLE([mkfs],
1698   AS_HELP_STRING([--disable-mkfs], [do not build mkfs(8)]),
1699   [], [UL_DEFAULT_ENABLE([mkfs], [check])]
1700 )
1701 UL_BUILD_INIT([mkfs])
1702 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1703
1704 UL_BUILD_INIT([isosize], [yes])
1705 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1706
1707
1708 AC_ARG_ENABLE([fstrim],
1709   AS_HELP_STRING([--disable-fstrim], [do not build fstrim(8)]),
1710   [], [UL_DEFAULT_ENABLE([fstrim], [check])]
1711 )
1712 UL_BUILD_INIT([fstrim])
1713 UL_REQUIRES_LINUX([fstrim])
1714 UL_REQUIRES_BUILD([fstrim], [libmount])
1715 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1716
1717
1718 AC_ARG_ENABLE([swapon],
1719   AS_HELP_STRING([--disable-swapon], [do not build swapon(8) and swapoff(8)]),
1720   [], [UL_DEFAULT_ENABLE([swapon], [check])]
1721 )
1722 UL_BUILD_INIT([swapon])
1723 UL_REQUIRES_LINUX([swapon])
1724 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1725 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1726 UL_REQUIRES_BUILD([swapon], [libblkid])
1727 UL_REQUIRES_BUILD([swapon], [libmount])
1728 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1729 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1730 AC_CHECK_FUNCS([swapon])
1731 AC_CHECK_FUNCS([swapoff])
1732
1733
1734 UL_BUILD_INIT([lsblk], [check])
1735 UL_REQUIRES_LINUX([lsblk])
1736 UL_REQUIRES_BUILD([lsblk], [libblkid])
1737 UL_REQUIRES_BUILD([lsblk], [libmount])
1738 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1739 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1740
1741
1742 AC_ARG_ENABLE([lscpu],
1743   AS_HELP_STRING([--disable-lscpu], [do not build lscpu]),
1744   [], [UL_DEFAULT_ENABLE([lscpu], [check])]
1745 )
1746 UL_BUILD_INIT([lscpu])
1747 UL_REQUIRES_LINUX([lscpu])
1748 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1749 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1750 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1751
1752 AC_ARG_ENABLE([lsfd],
1753   AS_HELP_STRING([--disable-lsfd], [do not build lsfd]),
1754   [], [UL_DEFAULT_ENABLE([lsfd], [check])]
1755 )
1756 UL_BUILD_INIT([lsfd])
1757 UL_REQUIRES_LINUX([lsfd])
1758 UL_REQUIRES_BUILD([lsfd], [libsmartcols])
1759 UL_REQUIRES_HAVE([lsfd], [linux_kcmp_h], [linux/kcmp.h header file])
1760 AM_CONDITIONAL([BUILD_LSFD], [test "x$build_lsfd" = xyes])
1761
1762 AC_ARG_ENABLE([lslogins],
1763   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1764   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1765 )
1766 UL_BUILD_INIT([lslogins])
1767 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1768 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1769 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1770 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1771 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1772
1773
1774 UL_BUILD_INIT([chcpu], [check])
1775 UL_REQUIRES_LINUX([chcpu])
1776 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1777 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1778
1779
1780 AC_ARG_ENABLE([wdctl],
1781   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1782   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1783 )
1784 UL_BUILD_INIT([wdctl])
1785 UL_REQUIRES_LINUX([wdctl])
1786 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1787 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1788 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1789
1790
1791 UL_BUILD_INIT([swaplabel], [check])
1792 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1793 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1794
1795
1796 UL_BUILD_INIT([mkswap], [yes])
1797 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1798 AS_IF([test "x$build_mkswap" = xyes && test "x$build_libuuid" != xyes], [
1799   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1800 ])
1801
1802
1803 AC_ARG_ENABLE([cal],
1804   AS_HELP_STRING([--disable-cal], [do not build cal]),
1805   [], [UL_DEFAULT_ENABLE([cal], [check])]
1806 )
1807 UL_BUILD_INIT([cal])
1808 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1809
1810 AC_ARG_ENABLE([logger],
1811   AS_HELP_STRING([--disable-logger], [do not build logger]),
1812   [], [UL_DEFAULT_ENABLE([logger], [check])]
1813 )
1814 UL_BUILD_INIT([logger])
1815 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1816
1817 UL_BUILD_INIT([look], [yes])
1818 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1819
1820 UL_BUILD_INIT([mcookie], [yes])
1821 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1822
1823 UL_BUILD_INIT([namei], [yes])
1824 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1825
1826 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1827 if test "x$matriplet" != "x"; then
1828   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1829   ["Multi-arch triplet for whereis library search path"])
1830 fi
1831 AC_ARG_ENABLE([whereis],
1832   AS_HELP_STRING([--disable-whereis], [do not build whereis]),
1833   [], [UL_DEFAULT_ENABLE([whereis], [check])]
1834 )
1835 UL_BUILD_INIT([whereis])
1836 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1837
1838 AC_ARG_ENABLE([pipesz],
1839   AS_HELP_STRING([--disable-pipesz], [do not build pipesz]),
1840   [], [UL_DEFAULT_ENABLE([pipesz], [check])]
1841 )
1842 UL_BUILD_INIT([pipesz])
1843 UL_REQUIRES_LINUX([pipesz])
1844 AM_CONDITIONAL([BUILD_PIPESZ], [test "x$build_pipesz" = xyes])
1845
1846 UL_BUILD_INIT([fadvise], [check])
1847 UL_REQUIRES_LINUX([fadvise])
1848 AM_CONDITIONAL([BUILD_FADVISE], [test "x$build_fadvise" = xyes])
1849
1850 AC_ARG_ENABLE([waitpid],
1851   AS_HELP_STRING([--disable-waitpid], [do not build waitpid]),
1852   [], [UL_DEFAULT_ENABLE([waitpidd], [check])]
1853 )
1854 UL_BUILD_INIT([waitpid])
1855 UL_REQUIRES_LINUX([waitpid])
1856 AM_CONDITIONAL([BUILD_WAITPID], [test "x$build_waitpid" = xyes])
1857
1858 UL_BUILD_INIT([enosys], [check])
1859 UL_REQUIRES_LINUX([enosys])
1860 AM_CONDITIONAL([BUILD_ENOSYS], [test "x$build_enosys" = xyes])
1861
1862 UL_BUILD_INIT([getopt], [yes])
1863 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1864
1865
1866 UL_BUILD_INIT([blockdev], [check])
1867 UL_REQUIRES_LINUX([blockdev])
1868 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1869
1870
1871 UL_BUILD_INIT([prlimit], [check])
1872 UL_REQUIRES_LINUX([prlimit])
1873 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1874 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1875 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1876 AS_IF([test "x$build_prlimit" = xyes], [
1877   dnl check for valid prlimit() function
1878   AC_MSG_CHECKING([for valid prlimit() function])
1879   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1880 #include <sys/types.h>
1881 #include <sys/time.h>
1882 #include <sys/resource.h>
1883 #include <stddef.h>
1884 ]],[[
1885    int ret;
1886    ret = prlimit(0, RLIMIT_AS, NULL, NULL);
1887    if (ret != 0) {
1888       return 1;
1889    }
1890    ]])],[
1891   AC_MSG_RESULT([yes])
1892   AC_DEFINE([HAVE_PRLIMIT], [1], [Have valid prlimit() function])],[
1893   AC_MSG_RESULT([no])])
1894 ])
1895
1896
1897
1898 UL_BUILD_INIT([lslocks], [check])
1899 UL_REQUIRES_LINUX([lslocks])
1900 UL_REQUIRES_BUILD([lslocks], [libmount])
1901 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1902 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1903
1904
1905 AC_ARG_ENABLE([switch_root],
1906   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1907   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1908 )
1909 UL_BUILD_INIT([switch_root])
1910 UL_REQUIRES_LINUX([switch_root])
1911 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1912 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1913 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1914
1915
1916 AC_ARG_ENABLE([pivot_root],
1917   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1918   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1919 )
1920 UL_BUILD_INIT([pivot_root])
1921 UL_REQUIRES_LINUX([pivot_root])
1922 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1923 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1924
1925
1926 UL_BUILD_INIT([flock], [check])
1927 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1928 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1929
1930
1931 AC_ARG_ENABLE([lsmem],
1932   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1933   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1934 )
1935 UL_BUILD_INIT([lsmem])
1936 UL_REQUIRES_LINUX([lsmem])
1937 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1938 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1939
1940
1941 AC_ARG_ENABLE([chmem],
1942   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1943   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1944 )
1945 UL_BUILD_INIT([chmem])
1946 UL_REQUIRES_LINUX([chmem])
1947 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1948
1949
1950 AC_ARG_ENABLE([ipcmk],
1951   AS_HELP_STRING([--disable-ipcmk], [do not build ipcmk]),
1952   [], [UL_DEFAULT_ENABLE([ipcmk], [check])]
1953 )
1954 UL_BUILD_INIT([ipcmk])
1955 UL_EXCLUDE_ARCH([ipcmk], [*darwin*])
1956 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1957
1958 AC_ARG_ENABLE([ipcrm],
1959   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1960   [], [UL_DEFAULT_ENABLE([ipcrm], [check])]
1961 )
1962 UL_BUILD_INIT([ipcrm])
1963 UL_EXCLUDE_ARCH([ipcrm], [*darwin*])
1964 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1965
1966 AC_ARG_ENABLE([ipcs],
1967   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1968   [], [UL_DEFAULT_ENABLE([ipcs], [check])]
1969 )
1970 UL_BUILD_INIT([ipcs])
1971 UL_EXCLUDE_ARCH([ipcs], [*darwin*])
1972 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1973
1974
1975 AC_ARG_ENABLE([irqtop],
1976   AS_HELP_STRING([--disable-irqtop], [do not build irqtop]),
1977   [], [UL_DEFAULT_ENABLE([irqtop], [check])]
1978 )
1979 UL_BUILD_INIT([irqtop])
1980 UL_REQUIRES_LINUX([irqtop])
1981 UL_REQUIRES_BUILD([irqtop], [libsmartcols])
1982 UL_REQUIRES_HAVE([irqtop], [open_memstream], [open_memstream function])
1983 UL_REQUIRES_HAVE([irqtop], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1984 AM_CONDITIONAL([BUILD_IRQTOP], [test "x$build_irqtop" = xyes])
1985
1986 AC_ARG_ENABLE([lsirq],
1987   AS_HELP_STRING([--disable-lsirq], [do not build lsirq]),
1988   [], [UL_DEFAULT_ENABLE([lsirq], [check])]
1989 )
1990 UL_BUILD_INIT([lsirq])
1991 UL_REQUIRES_LINUX([lsirq])
1992 UL_REQUIRES_BUILD([lsirq], [libsmartcols])
1993 AM_CONDITIONAL([BUILD_LSIRQ], [test "x$build_lsirq" = xyes])
1994
1995
1996 UL_BUILD_INIT([choom], [check])
1997 UL_REQUIRES_LINUX([choom])
1998 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1999
2000 UL_BUILD_INIT([lsipc], [check])
2001 UL_REQUIRES_LINUX([lsipc])
2002 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
2003 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
2004
2005 AC_ARG_ENABLE([lsns],
2006   AS_HELP_STRING([--disable-lsns], [do not build lsns]),
2007   [], [UL_DEFAULT_ENABLE([lsns], [check])]
2008 )
2009 UL_BUILD_INIT([lsns])
2010 UL_REQUIRES_LINUX([lsns])
2011 UL_REQUIRES_BUILD([lsns], [libsmartcols])
2012 UL_REQUIRES_BUILD([lsns], [libmount])
2013 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
2014
2015 UL_BUILD_INIT([renice], [yes])
2016 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
2017
2018
2019 AC_ARG_ENABLE([rfkill],
2020   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
2021   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
2022 )
2023 UL_BUILD_INIT([rfkill])
2024 UL_REQUIRES_LINUX([rfkill])
2025 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
2026 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
2027
2028
2029 UL_BUILD_INIT([setsid], [yes])
2030 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
2031
2032 UL_BUILD_INIT([readprofile], [check])
2033 UL_REQUIRES_LINUX([readprofile])
2034 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
2035
2036 UL_BUILD_INIT([dmesg], [check])
2037 UL_REQUIRES_LINUX([dmesg])
2038 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
2039
2040 UL_BUILD_INIT([ctrlaltdel], [check])
2041 UL_REQUIRES_LINUX([ctrlaltdel])
2042 dnl we assume reboot() to be the 1-argument variant, because even considering
2043 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
2044 dnl reboot() with multiple arguments is yet only found in glibc versions
2045 dnl earlier than 2.x.
2046 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
2047 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
2048
2049 UL_BUILD_INIT([fincore], [check])
2050 UL_REQUIRES_LINUX([fincore])
2051 UL_REQUIRES_BUILD([fincore], [libsmartcols])
2052 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
2053
2054 UL_BUILD_INIT([fsfreeze], [check])
2055 UL_REQUIRES_LINUX([fsfreeze])
2056 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
2057
2058 UL_BUILD_INIT([blkdiscard], [check])
2059 UL_REQUIRES_LINUX([blkdiscard])
2060 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
2061
2062 UL_BUILD_INIT([blkzone], [check])
2063 UL_REQUIRES_LINUX([blkzone])
2064 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
2065 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
2066
2067 UL_BUILD_INIT([blkpr], [check])
2068 UL_REQUIRES_LINUX([blkpr])
2069 UL_REQUIRES_HAVE([blkpr], [linux_pr_h], [linux/pr.h header])
2070 AM_CONDITIONAL([BUILD_BLKPR], [test "x$build_blkpr" = xyes])
2071
2072 UL_BUILD_INIT([ldattach], [check])
2073 UL_REQUIRES_LINUX([ldattach])
2074 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
2075
2076 UL_BUILD_INIT([rtcwake], [check])
2077 UL_REQUIRES_LINUX([rtcwake])
2078 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
2079
2080 UL_BUILD_INIT([setarch], [check])
2081 UL_REQUIRES_LINUX([setarch])
2082 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
2083
2084
2085 # build_scriptutils= is just configure-only variable to control
2086 # script, scriptreplay and scriptlive
2087 AC_ARG_ENABLE([scriptutils],
2088   AS_HELP_STRING([--disable-scriptutils], [do not build script, scriptreplay and scriptlive]),
2089   [], [UL_DEFAULT_ENABLE([scriptutils], [check])]
2090 )
2091
2092 UL_ENABLE_ALIAS([script], [scriptutils])
2093 UL_BUILD_INIT([script])
2094 UL_REQUIRES_HAVE([script], [pty], [openpty function (libutil)])
2095 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
2096
2097 UL_ENABLE_ALIAS([scriptreplay], [scriptutils])
2098 UL_BUILD_INIT([scriptreplay])
2099 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
2100
2101 UL_ENABLE_ALIAS([scriptlive], [scriptutils])
2102 UL_BUILD_INIT([scriptlive])
2103 UL_REQUIRES_HAVE([scriptlive], [pty], [openpty function (libutil)])
2104 AM_CONDITIONAL([BUILD_SCRIPTLIVE], [test "x$build_scriptlive" = xyes])
2105
2106
2107 UL_BUILD_INIT([col], [yes])
2108 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
2109
2110 UL_BUILD_INIT([colcrt], [yes])
2111 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
2112
2113 UL_BUILD_INIT([colrm], [yes])
2114 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
2115
2116 UL_BUILD_INIT([column], [check])
2117 UL_REQUIRES_BUILD([column], [libsmartcols])
2118 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
2119
2120 UL_BUILD_INIT([hexdump], [yes])
2121 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
2122
2123 UL_BUILD_INIT([rev], [yes])
2124 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
2125
2126
2127 AC_ARG_ENABLE([tunelp],
2128   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
2129   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
2130 )
2131 UL_BUILD_INIT([tunelp])
2132 UL_REQUIRES_LINUX([tunelp])
2133 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
2134
2135
2136 AC_ARG_ENABLE([kill],
2137   AS_HELP_STRING([--disable-kill], [do not build kill]),
2138   [], [UL_DEFAULT_ENABLE([kill], [check])]
2139 )
2140 UL_BUILD_INIT([kill])
2141 UL_REQUIRES_LINUX([kill])
2142 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
2143
2144
2145 AC_ARG_ENABLE([last],
2146   AS_HELP_STRING([--disable-last], [do not build last]),
2147   [], [UL_DEFAULT_ENABLE([last], [check])]
2148 )
2149 UL_BUILD_INIT([last])
2150 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
2151 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
2152 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
2153
2154
2155 AC_ARG_ENABLE([utmpdump],
2156   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
2157   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
2158 )
2159 UL_BUILD_INIT([utmpdump])
2160 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
2161 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
2162 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
2163
2164
2165 AC_ARG_ENABLE([line],
2166   AS_HELP_STRING([--enable-line], [build line]),
2167   [], [UL_DEFAULT_ENABLE([line], [no])]
2168 )
2169 UL_BUILD_INIT([line])
2170 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
2171
2172
2173 AC_ARG_ENABLE([mesg],
2174   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
2175   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
2176 )
2177 UL_BUILD_INIT([mesg])
2178 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
2179
2180
2181 AC_ARG_ENABLE([raw],
2182   AS_HELP_STRING([--disable-raw], [do not build raw]),
2183   [], [UL_DEFAULT_ENABLE([raw], [check])]
2184 )
2185 UL_BUILD_INIT([raw])
2186 UL_REQUIRES_LINUX([raw])
2187 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
2188 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
2189
2190
2191 AC_ARG_ENABLE([rename],
2192   AS_HELP_STRING([--disable-rename], [do not build rename]),
2193   [], [UL_DEFAULT_ENABLE([rename], [yes])]
2194 )
2195 UL_BUILD_INIT([rename])
2196 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
2197
2198
2199 AC_ARG_ENABLE([vipw],
2200   AS_HELP_STRING([--enable-vipw], [build vipw]),
2201   [], [UL_DEFAULT_ENABLE([vipw], [no])]
2202 )
2203 UL_BUILD_INIT([vipw])
2204 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
2205 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
2206
2207
2208 AC_ARG_ENABLE([newgrp],
2209   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
2210   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
2211 )
2212 UL_BUILD_INIT([newgrp])
2213 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
2214 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
2215
2216
2217 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
2218   [], [with_user=check]
2219 )
2220 have_user=no
2221 AS_IF([test "x$with_user" != xno], [
2222   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
2223   AS_CASE([$with_user:$have_user],
2224     [yes:no],
2225       [AC_MSG_ERROR([user selected but libuser not found])],
2226     [*:yes],
2227       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
2228   )
2229   # temporary solution, libuser has stupid .pc where are exported all
2230   # private dependencies to Requires: instead of Requires.private:
2231   AS_IF([test "x$have_user" = xyes], [
2232     LIBUSER_LIBS=-luser
2233   ])
2234 ])
2235 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
2236
2237 AC_ARG_ENABLE([chfn-chsh-password],
2238   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
2239   [], [enable_chfn_chsh_password=yes]
2240 )
2241
2242 AC_ARG_ENABLE([chfn-chsh],
2243   AS_HELP_STRING([--disable-chfn-chsh], [do not build chfn and chsh]),
2244   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
2245 )
2246 UL_BUILD_INIT([chfn_chsh])
2247 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
2248 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
2249
2250 AS_IF([test "x$enable_chfn_chsh_password" = xyes || test "x$have_user" = xyes], [
2251   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
2252   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
2253 ])
2254 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
2255 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
2256
2257 AC_ARG_ENABLE([chsh-only-listed],
2258   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
2259   [], enable_chsh_only_listed=yes
2260 )
2261
2262 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
2263   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
2264 ])
2265
2266
2267 AC_ARG_ENABLE([login],
2268   AS_HELP_STRING([--disable-login], [do not build login]),
2269   [], [UL_DEFAULT_ENABLE([login], [check])]
2270 )
2271 UL_BUILD_INIT([login])
2272 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
2273 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
2274 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
2275 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
2276 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
2277
2278 AC_ARG_ENABLE([login-chown-vcs],
2279   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
2280   [], [enable_login_chown_vcs=no]
2281 )
2282
2283 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2284   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2285 ])
2286
2287 AC_ARG_ENABLE([login-stat-mail],
2288   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2289   [], [enable_login_stat_mail=no]
2290 )
2291
2292 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2293   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2294 ])
2295
2296
2297 AC_ARG_ENABLE([nologin],
2298   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2299   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2300 )
2301 UL_BUILD_INIT([nologin])
2302 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2303
2304
2305 AC_ARG_ENABLE([sulogin],
2306   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2307   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2308 )
2309 UL_BUILD_INIT([sulogin])
2310 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2311 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2312 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2313
2314
2315 AC_ARG_ENABLE([su],
2316   AS_HELP_STRING([--disable-su], [do not build su]),
2317   [], [UL_DEFAULT_ENABLE([su], [check])]
2318 )
2319 UL_BUILD_INIT([su])
2320 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2321 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2322 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2323 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2324
2325
2326 AC_ARG_ENABLE([runuser],
2327   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2328   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2329 )
2330 UL_BUILD_INIT([runuser])
2331 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2332 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2333 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2334 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2335
2336
2337 AC_ARG_ENABLE([ul],
2338   AS_HELP_STRING([--disable-ul], [do not build ul]),
2339   [], [UL_DEFAULT_ENABLE([ul], [check])]
2340 )
2341 UL_BUILD_INIT([ul])
2342 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2343 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2344
2345
2346 AC_ARG_ENABLE([more],
2347   AS_HELP_STRING([--disable-more], [do not build more]),
2348   [], [UL_DEFAULT_ENABLE([more], [check])]
2349 )
2350 UL_BUILD_INIT([more])
2351 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2352 UL_REQUIRES_LINUX([more])
2353 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2354
2355
2356 AC_ARG_ENABLE([pg],
2357   AS_HELP_STRING([--enable-pg], [build pg]),
2358   [], [UL_DEFAULT_ENABLE([pg], [no])]
2359 )
2360 UL_BUILD_INIT([pg])
2361 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2362 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2363
2364
2365 AC_ARG_ENABLE([setterm],
2366   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2367   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2368 )
2369 UL_BUILD_INIT([setterm])
2370 UL_REQUIRES_LINUX([setterm])
2371 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2372 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2373
2374 # build_schedutils= is just configure-only variable to control
2375 # ionice, taskset and chrt
2376 AC_ARG_ENABLE([schedutils],
2377   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2378   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2379 )
2380
2381
2382 UL_ENABLE_ALIAS([ionice], [schedutils])
2383 UL_BUILD_INIT([ionice])
2384 UL_REQUIRES_SYSCALL_CHECK([ionice],
2385         [UL_CHECK_SYSCALL([ioprio_set],
2386           [alpha],      [442],
2387           [i*86],       [289],
2388           [ia64*],      [1274],
2389           [powerpc*],   [273],
2390           [s390*],      [282],
2391           [sparc*],     [196],
2392           [sh*],        [288],
2393           [x86_64*],    [251])],
2394         [ioprio_set])
2395
2396 UL_REQUIRES_SYSCALL_CHECK([ionice],
2397         [UL_CHECK_SYSCALL([ioprio_get],
2398           [alpha],      [443],
2399           [i*86],       [290],
2400           [ia64*],      [1275],
2401           [powerpc*],   [274],
2402           [s390*],      [283],
2403           [sparc*],     [218],
2404           [sh*],        [289],
2405           [x86_64*],    [252])],
2406         [ioprio_get])
2407
2408 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2409
2410
2411 UL_ENABLE_ALIAS([taskset], [schedutils])
2412 UL_BUILD_INIT([taskset])
2413 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2414 UL_REQUIRES_SYSCALL_CHECK([taskset],
2415         [UL_CHECK_SYSCALL([sched_getaffinity])],
2416         [sched_getaffinity])
2417 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2418
2419
2420 have_schedsetter=no
2421 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2422       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2423
2424 UL_ENABLE_ALIAS([chrt], [schedutils])
2425 UL_BUILD_INIT([chrt])
2426 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2427 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2428
2429 AS_IF([test "x$build_chrt" = xyes], [
2430         UL_CHECK_SYSCALL([sched_setattr])
2431 ])
2432
2433 UL_ENABLE_ALIAS([uclampset], [schedutils])
2434 UL_BUILD_INIT([uclampset])
2435 UL_REQUIRES_SYSCALL_CHECK([uclampset],
2436         [UL_CHECK_SYSCALL([sched_setattr])], [sched_setattr])
2437 AM_CONDITIONAL([BUILD_UCLAMPSET], [test "x$build_uclampset" = xyes])
2438
2439
2440 AC_ARG_ENABLE([wall],
2441   AS_HELP_STRING([--disable-wall], [do not build wall]),
2442   [], [UL_DEFAULT_ENABLE([wall], [check])]
2443 )
2444 UL_BUILD_INIT([wall])
2445 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2446 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2447
2448
2449 AC_ARG_ENABLE([write],
2450   AS_HELP_STRING([--enable-write], [build write]),
2451   [], [UL_DEFAULT_ENABLE([write], [no])]
2452 )
2453 UL_BUILD_INIT([write])
2454 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2455 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2456 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2457
2458
2459 AC_ARG_WITH([btrfs],
2460   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2461   [], [with_btrfs=check]
2462 )
2463 have_btrfs=no
2464 AS_IF([test "x$with_btrfs" != xno], [
2465   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2466     [yes:no],
2467     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2468     [check:no],
2469        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2470     [*:yes],
2471        [have_btrfs=yes
2472         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2473   )
2474 ])
2475 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2476
2477
2478 AC_ARG_WITH([systemd],
2479   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2480   [], [with_systemd=check]
2481 )
2482
2483 have_systemd=no
2484 AS_IF([test "x$with_systemd" != xno], [
2485   # new version -- all libsystemd-* libs merged into libsystemd
2486   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2487   # old versions
2488   AS_IF([test "x$have_systemd" != "xyes"], [
2489     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2490                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2491     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2492                       [have_systemd_journal=yes], [have_systemd_journal=no])
2493     AS_IF([test "x$have_systemd_daemon" = "xyes" && test "x$have_systemd_journal" = "xyes" ],[
2494            have_systemd=yes])
2495   ])
2496   AS_CASE([$with_systemd:$have_systemd],
2497     [yes:no],
2498       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2499     [*:yes],
2500        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2501        AC_DEFINE([USE_SYSTEMD], [1], [Define if systemd support is wanted ])
2502   )
2503 ])
2504 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2505
2506
2507 AC_ARG_WITH([systemdsystemunitdir],
2508   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2509   [], [
2510   AS_IF([test "x$have_systemd" = xyes], [
2511     PKG_CHECK_VAR([with_systemdsystemunitdir], [systemd], [systemdsystemunitdir],
2512       [],
2513       [with_systemdsystemunitdir=no])
2514   ])
2515 ])
2516 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2517   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2518 ])
2519
2520
2521 AC_ARG_WITH([smack],
2522   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2523   [], [with_smack=no]
2524 )
2525 AS_IF([test "x$with_smack" = xyes], [
2526   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2527 ])
2528
2529 AC_ARG_WITH([econf],
2530   AS_HELP_STRING([--without-econf], [do not use libeconf]),
2531   [], [with_econf=check]
2532 )
2533
2534 have_econf=no
2535 AS_IF([test "x$with_econf" != xno], [
2536   PKG_CHECK_MODULES([ECONF], [libeconf], [have_econf=yes], [have_econf=no])
2537     AS_CASE([$with_econf:$have_econf],
2538     [yes:no],
2539       [AC_MSG_ERROR([libeconf expected but libeconf not found])],
2540     [*:yes],
2541        AC_DEFINE([HAVE_LIBECONF], [1], [Define if libeconf is available])
2542   )
2543 ])
2544 AM_CONDITIONAL([HAVE_ECONF], [test "x$have_econf" = xyes])
2545
2546 AC_ARG_WITH([vendordir],
2547   AS_HELP_STRING([--with-vendordir=DIR], [Directory for distribution provided configuration files]),
2548   [], []
2549 )
2550 AC_SUBST([vendordir], [$with_vendordir])
2551 AM_CONDITIONAL([USE_VENDORDIR], [test "x$with_vendordir" != x])
2552 AS_IF([test "x$with_vendordir" != x], [
2553   AC_DEFINE([USE_VENDORDIR], [1], [Define to 1 to use vendordir])
2554 ])
2555
2556
2557 AC_ARG_ENABLE([bash-completion],
2558   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2559   [], [enable_bash_completion=yes]
2560 )
2561
2562 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2563
2564 AC_ARG_WITH([bashcompletiondir],
2565   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2566   [], [
2567   AS_IF([test "x$enable_bash_completion" = xyes], [
2568     PKG_CHECK_VAR([with_bashcompletiondir], [bash-completion], [completionsdir],
2569       [],
2570       [with_bashcompletiondir=${datadir}/bash-completion/completions])
2571   ])
2572 ])
2573 AS_IF([test "x$enable_bash_completion" = xyes], [
2574   AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2575 ])
2576
2577
2578 AC_ARG_WITH([python],
2579   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2580   [], [with_python=check withval=check]
2581 )
2582
2583 have_python=no
2584 have_libpython=no
2585 AS_IF([test "x$with_python" != xno], [
2586   # We follow distributions default and look for PKG module name "python"
2587   # (minimal version is 2) but if major version is explicitly specified by
2588   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2589   # "python3".
2590   AS_IF([test "x$withval" != xno && test "x$withval" != xyes && test "x$withval" != xcheck],
2591         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2592
2593   # check for python interpreter
2594   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2595   AS_CASE([$with_python:$have_python],
2596     [yes:no],
2597       [AC_MSG_ERROR([python selected but python interpreter not found])],
2598     [check:no],
2599        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2600     [*:yes],
2601        # check for python development stuff
2602        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2603                           [have_libpython=yes], [have_libpython=no])]
2604   )
2605 ])
2606
2607
2608 AC_ARG_ENABLE([pylibmount],
2609   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2610   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2611 )
2612 UL_BUILD_INIT([pylibmount])
2613 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2614 UL_REQUIRES_BUILD([pylibmount], [libmount])
2615 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2616
2617 # We need to introduce a verbatim dependency into the Makefile, without automake
2618 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2619 verbatim_pylibmount_dependency='
2620
2621 # pylibmountexec module must be installed after usrlib_exec libraries,
2622 # otherwise the libtool relink step will fail to find libmount.la and
2623 # will try -lmount which is possibly not available.
2624 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2625
2626 '
2627 AC_SUBST([verbatim_pylibmount_dependency])
2628 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2629
2630 AC_ARG_ENABLE([pg-bell],
2631   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2632   [], [enable_pg_bell=yes]
2633 )
2634
2635 AS_IF([test "x$enable_pg_bell" = xyes], [
2636   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2637 ])
2638
2639
2640 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2641 AC_ARG_ENABLE([fs-paths-default],
2642   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2643   [AS_CASE([$enableval],
2644     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2645     [no],  [fs_paths_defaults=""],
2646     [fs_paths_defaults="$enableval"]
2647   )],
2648   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2649 )
2650 AC_ARG_ENABLE([fs-paths-extra],
2651   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2652   [AS_CASE([$enableval],
2653      [yes|no], [fs_paths_extra=""],
2654      [fs_paths_extra="$enableval"]
2655   )],
2656   [fs_paths_extra=""]
2657 )
2658 fs_paths="$fs_paths_defaults"
2659 AS_IF([test "x$fs_paths_extra" != "x"], [
2660   AS_IF([test "x$fs_paths" != "x"], [
2661     fs_paths="${fs_paths}:"
2662   ])
2663   fs_paths="${fs_paths}${fs_paths_extra}"
2664 ])
2665 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2666
2667
2668 AC_ARG_ENABLE([use-tty-group],
2669   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2670   [], [enable_use_tty_group=yes]
2671 )
2672 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2673
2674 AS_IF([test "x$enable_use_tty_group" = xyes], [
2675   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2676 ])
2677
2678
2679 AC_ARG_ENABLE([sulogin-emergency-mount],
2680   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2681                  [use emergency mount of /dev and /proc for sulogin]),
2682   [], [enable_sulogin_emergency_mount=no]
2683 )
2684
2685 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2686   AS_IF([test "x$linux_os" = xyes], [ ],
2687         [AC_MSG_ERROR([--enable-sulogin-emergency-mount selected for non-linux system])])
2688   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2689             [Should sulogin use an emergency mount of /dev and /proc?])
2690 ])
2691
2692
2693 AC_ARG_ENABLE([usrdir-path],
2694   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2695   [], [enable_usrdir_path=no]
2696 )
2697
2698 AS_IF([test "x$enable_usrdir_path" = xyes], [
2699   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2700 ])
2701
2702
2703 AC_ARG_ENABLE([makeinstall-chown],
2704   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2705   [], [enable_makeinstall_chown=yes]
2706 )
2707 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2708
2709
2710 AC_ARG_ENABLE([makeinstall-setuid],
2711   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2712   [], [enable_makeinstall_setuid=yes]
2713 )
2714 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2715
2716
2717 AC_ARG_ENABLE([colors-default],
2718   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2719   [], [enable_colors_default=yes]
2720 )
2721 AS_IF([test "x$enable_colors_default" = xyes], [
2722   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2723 ])
2724
2725
2726 AC_ARG_WITH([cryptsetup],
2727   AS_HELP_STRING([--with-cryptsetup], [compile with cryptsetup support]),
2728   [], [with_cryptsetup=no]
2729 )
2730
2731 AS_IF([test "x$with_cryptsetup" = xno], [
2732   AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2733   AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2734 ], [
2735   PKG_CHECK_MODULES([CRYPTSETUP], [libcryptsetup],
2736         [AC_DEFINE([HAVE_CRYPTSETUP], [1], [Define if cryptsetup is available])
2737          UL_PKG_STATIC([CRYPTSETUP_LIBS_STATIC], [libcryptsetup])
2738          AM_CONDITIONAL([HAVE_CRYPTSETUP], [true])
2739          SAVE_CFLAGS="$CFLAGS"
2740          CFLAGS="$CRYPTSETUP_CFLAGS $CFLAGS"
2741          SAVE_LIBS="$LIBS"
2742          LIBS="$CRYPTSETUP_LIBS $LIBS"
2743          AC_CHECK_LIB([cryptsetup], [crypt_activate_by_signed_key], [
2744           AC_DEFINE_UNQUOTED([HAVE_CRYPT_ACTIVATE_BY_SIGNED_KEY], [1], [Define if crypt_activate_by_signed_key exist in -lcryptsetup])
2745          ])
2746          AS_IF([test "x$with_cryptsetup" = xdlopen], [
2747           LIBS="-ldl $LIBS"
2748           AC_CHECK_LIB([dl], [dlsym], [
2749             AC_DEFINE([CRYPTSETUP_VIA_DLOPEN], [1], [Define if cryptsetup is to be loaded via dlopen])
2750             AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [true])
2751            ], [AC_MSG_ERROR([libdl required to build with cryptsetup support])])
2752          ], [
2753           AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2754          ])
2755          CFLAGS="$SAVE_CFLAGS"
2756          LIBS="$SAVE_LIBS"
2757          have_cryptsetup=yes],
2758         [have_cryptsetup=no
2759    AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2760    AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2761   ])
2762
2763   AS_CASE([$with_cryptsetup:$have_cryptsetup],
2764     [yes:no], [AC_MSG_WARN([cryptsetup selected but libcryptsetup not found])]
2765   )
2766 ])
2767 AC_SUBST([CRYPTSETUP_LIBS])
2768 AC_SUBST([CRYPTSETUP_LIBS_STATIC])
2769
2770
2771 AC_ARG_VAR([SUID_CFLAGS],
2772            [CFLAGS used for binaries which are usually with the suid bit])
2773 AC_ARG_VAR([SUID_LDFLAGS],
2774            [LDFLAGS used for binaries which are usually with the suid bit])
2775
2776 AC_ARG_VAR([DAEMON_CFLAGS],
2777            [CFLAGS used for binaries which are usually executed as daemons])
2778 AC_ARG_VAR([DAEMON_LDFLAGS],
2779            [LDFLAGS used for binaries which are usually executed as daemons])
2780
2781 AC_ARG_VAR([SOLIB_CFLAGS],
2782            [CFLAGS used for shared libraries])
2783 AC_ARG_VAR([SOLIB_LDFLAGS],
2784            [LDFLAGS used for shared libraries])
2785
2786 AC_ARG_VAR([ADJTIME_PATH],
2787            [Path to hwclock adjtime file, default /etc/adjtime])
2788 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2789 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2790
2791 if test "x${build_alias}" != "x${host_alias}"; then
2792   AC_MSG_NOTICE([setting link_all_deplibs=unknown for libtool])
2793   # work around Debian patch to libtool breaking cross-compiles
2794   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=702737
2795   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=297726
2796   link_all_deplibs=unknown
2797 fi
2798
2799
2800 LIBS=""
2801
2802
2803 AC_CONFIG_HEADERS([config.h])
2804
2805 #
2806 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2807 # more details.
2808 #
2809 AC_CONFIG_FILES([
2810 Makefile
2811 libblkid/docs/Makefile
2812 libblkid/docs/version.xml
2813 libblkid/src/blkid.h
2814 libfdisk/docs/Makefile
2815 libfdisk/docs/version.xml
2816 libfdisk/src/libfdisk.h
2817 libmount/docs/Makefile
2818 libmount/docs/version.xml
2819 libmount/src/libmount.h
2820 libsmartcols/docs/Makefile
2821 libsmartcols/docs/version.xml
2822 libsmartcols/src/libsmartcols.h
2823 po/Makefile.in
2824 po-man/Makefile
2825 ])
2826
2827 AC_OUTPUT
2828
2829 AC_MSG_RESULT([
2830         ${PACKAGE}  ${VERSION}
2831
2832         prefix:                    ${prefix}
2833         exec prefix:               ${exec_prefix}
2834
2835         bindir:                    ${bindir}
2836         sbindir:                   ${sbindir}
2837         libdir:                    ${libdir}
2838         usrbin_execdir:            ${usrbin_execdir}
2839         usrsbin_execdir:           ${usrsbin_execdir}
2840         usrlib_execdir:            ${usrlib_execdir}
2841
2842         localstatedir:             ${localstatedir}
2843         runstatedir:               ${runstatedir}
2844         includedir:                ${includedir}
2845         sysconfdir:                ${sysconfdir}
2846         sysconfstaticdir:          ${sysconfstaticdir}
2847
2848         vendordir:                 ${with_vendordir}
2849
2850         Python:                    ${PYTHON}
2851         Python version:            ${PYTHON_VERSION}
2852         Python libs:               ${pyexecdir}
2853
2854         Bash completions:          ${with_bashcompletiondir}
2855         Systemd support:           ${have_systemd}
2856         Systemd unitdir:           ${with_systemdsystemunitdir}
2857         libeconf support:          ${have_econf}
2858         Btrfs support:             ${have_btrfs}
2859         Wide-char support:         ${build_widechar}
2860         libcryptsetup support:     ${have_cryptsetup}
2861
2862         Manual pages:              ${build_asciidoc}
2863         Manual pages translated:   ${build_poman}
2864
2865         compiler:                  ${CC} / ${CXX}
2866         suid cflags:               ${SUID_CFLAGS}
2867         ldflags:                   ${LDFLAGS}
2868         suid ldflags:              ${SUID_LDFLAGS}
2869         ASAN enabled:              ${enable_asan}
2870         Fuzzing enabled:           ${enable_fuzzing_engine}
2871
2872         cflags:                    ${CFLAGS}
2873
2874         warnings:
2875
2876 ${WARN_CFLAGS}
2877
2878  Type 'make' or 'make <utilname>' to compile.
2879 ])