configure.in

   1 dnl
   2 dnl "$Id: configure.in,v 1.74 2001/02/07 01:25:38 mike Exp $"
   3 dnl
   4 dnl   Configuration script for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2001 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636-3111 USA
  19 dnl
  20 dnl       Voice: (301) 373-9603
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 AC_INIT(cups/cups.h)
  26 AC_CONFIG_HEADER(config.h)
  27 AC_PREFIX_DEFAULT(/)
  28
  29 dnl Get the operating system and version number...
  30
  31 uname=`uname`
  32 uversion=`uname -r | sed -e '1,$s/[[^0-9]]//g'`
  33 if test "$uname" = "IRIX64"; then
  34     uname="IRIX"
  35 fi
  36
  37 dnl Clear the debugging and non-shared library options unless the user asks
  38 dnl for them...
  39
  40 OPTIM=""
  41 AC_SUBST(OPTIM)
  42 GSOPTIM=""
  43 AC_SUBST(GSOPTIM)
  44 PICFLAG=1
  45 CFLAGS="${CFLAGS:=}"
  46 CXXFLAGS="${CXXFLAGS:=}"
  47 DSOFLAGS="${DSOFLAGS:=}"
  48 AC_SUBST(DSOFLAGS)
  49
  50 AC_ARG_ENABLE(debug, [  --enable-debug        turn on debugging [default=no]],[if eval "test x$enable_debug = xyes"; then
  51         OPTIM="-g"
  52         GSOPTIM="-g"
  53 fi])
  54 AC_ARG_ENABLE(shared, [  --enable-shared        turn on shared libraries [default=yes]])
  55 AC_ARG_ENABLE(ssl, [  --enable-ssl           turn on SSL/TLS support [default=no]])
  56 AC_ARG_ENABLE(libtool_unsupported, [  --enable-libtool-unsupported=LIBTOOL_PATH
  57                           turn on building with libtool (UNSUPPORTED!) [default=no]],[if eval "test x$enable_libtool_unsupported != xno"; then
  58         LIBTOOL="$enable_libtool_unsupported"
  59         enable_shared=no
  60         echo "WARNING: libtool is not supported or endorsed by Easy Software Products."
  61         echo "         WE DO NOT PROVIDE TECHNICAL SUPPORT FOR LIBTOOL PROBLEMS."
  62         echo "         (even if you have a support contract)"
  63 else
  64         LIBTOOL=""
  65 fi])
  66
  67 if test "$enable_shared" != "no"; then
  68         case "$uname" in
  69                 SunOS* | UNIX_S*)
  70                         LIBCUPS="libcups.so.2"
  71                         LIBCUPSIMAGE="libcupsimage.so.2"
  72                         DSO="\$(CC)"
  73                         DSOFLAGS="$DSOFLAGS -Wl,-h,\$@ -G \$(OPTIM)"
  74                         ;;
  75                 HP-UX*)
  76                         LIBCUPS="libcups.sl.2"
  77                         LIBCUPSIMAGE="libcupsimage.sl.2"
  78                         DSO="ld"
  79                         DSOFLAGS="$DSOFLAGS -b -z +h \$@"
  80                         ;;
  81                 FreeBSD* | NetBSD* | OpenBSD*)
  82                         LIBCUPS="libcups.so.2"
  83                         LIBCUPSIMAGE="libcupsimage.so.2"
  84                         DSO="\$(CC)"
  85                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  86                         ;;
  87                 OSF1* | Linux*)
  88                         LIBCUPS="libcups.so.2"
  89                         LIBCUPSIMAGE="libcupsimage.so.2"
  90                         DSO="\$(CC)"
  91                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  92                         ;;
  93                 IRIX*)
  94                         LIBCUPS="libcups.so.2"
  95                         LIBCUPSIMAGE="libcupsimage.so.2"
  96                         DSO="\$(CC)"
  97                         DSOFLAGS="$DSOFLAGS -soname \$@ -shared \$(OPTIM)"
  98                         ;;
  99                 *)
 100                         echo "Warning: shared libraries may not be supported.  Trying -shared"
 101                         echo "         option with compiler."
 102                         LIBCUPS="libcups.so.2"
 103                         LIBCUPSIMAGE="libcupsimage.so.2"
 104                         DSO="\$(CC)"
 105                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
 106                         ;;
 107         esac
 108 else
 109         PICFLAG=0
 110         LIBCUPS="libcups.a"
 111         LIBCUPSIMAGE="libcupsimage.a"
 112         DSO=":"
 113 fi
 114
 115 if test "$LIBTOOL" != ""; then
 116         LIBCUPS="libcups.la"
 117         LIBCUPSIMAGE="libcupsimage.la"
 118         LINKCUPS="../cups/\$(LIBCUPS)"
 119         LINKCUPSIMAGE="../filter/\$(LIBCUPSIMAGE)"
 120         DSO=":"
 121         DSOFLAGS=""
 122 else
 123         LINKCUPS="-L../cups -lcups"
 124         LINKCUPSIMAGE="-L../filter -lcupsimage"
 125 fi
 126
 127 AC_ARG_ENABLE(pam, [  --enable-pam        turn on PAM support [default=yes]])
 128
 129 AC_ARG_WITH(fontpath, [  --with-fontpath     set font path for pstoraster],fontpath="$withval",fontpath="")
 130
 131 dnl Checks for programs...
 132 AC_PROG_AWK
 133 AC_PROG_CC
 134 AC_PROG_CXX
 135 AC_PROG_CPP
 136 AC_PROG_RANLIB
 137 AC_PATH_PROG(AR,ar)
 138 AC_PATH_PROG(CHMOD,chmod)
 139 AC_PATH_PROG(CHOWN,chown)
 140 AC_PATH_PROG(CP,cp)
 141 AC_PATH_PROG(MV,mv)
 142 AC_PATH_PROG(NROFF,nroff)
 143 if test "$NROFF" = ""; then
 144     AC_PATH_PROG(GROFF,groff)
 145     if test "$GROFF" = ""; then
 146         NROFF="echo"
 147     else
 148         NROFF="$GROFF -T ascii"
 149     fi
 150 fi
 151 AC_PATH_PROG(HTMLDOC,htmldoc)
 152 AC_PATH_PROG(MKDIR,mkdir)
 153 AC_PATH_PROG(RM,rm)
 154 AC_PATH_PROG(SED,sed)
 155
 156 dnl Architecture checks...
 157 AC_C_BIGENDIAN
 158
 159 dnl Check for libraries...
 160 AC_CHECK_LIB(c,crypt,LIBS="$LIBS")
 161 if test "$ac_cv_lib_c_crypt" = "no"; then
 162         AC_CHECK_LIB(crypt,crypt)
 163 fi
 164 AC_CHECK_LIB(sec,getspent)
 165
 166 LIBMALLOC=""
 167 AC_CHECK_LIB(c,mallinfo,LIBS="$LIBS"; AC_DEFINE(HAVE_MALLINFO),LIBS="$LIBS")
 168 if test "$ac_cv_lib_c_mallinfo" = "no"; then
 169         AC_CHECK_LIB(malloc,mallinfo,
 170                      LIBS="$LIBS"
 171                      LIBMALLOC="-lmalloc"
 172                      AC_DEFINE(HAVE_MALLINFO),
 173                      LIBS="$LIBS")
 174 fi
 175 AC_SUBST(LIBMALLOC)
 176
 177 if test "$enable_pam" != "no"; then
 178         OLDLIBS="$LIBS"
 179         AC_CHECK_LIB(dl,dlopen)
 180         AC_CHECK_LIB(pam,pam_start)
 181         if test "$ac_cv_lib_pam_pam_start" != "no"; then
 182                 PAMDIR="/etc/pam.d"
 183         else
 184                 PAMDIR=""
 185                 LIBS="$OLDLIBS"
 186         fi
 187         AC_SUBST(PAMDIR)
 188 fi
 189
 190 NETLIBS=""
 191 AC_SUBST(NETLIBS)
 192 AC_CHECK_LIB(socket,socket,
 193 if test "$uname" != "IRIX"; then
 194         NETLIBS="-lsocket"
 195 else
 196         echo "Not using -lsocket since you are running IRIX."
 197 fi)
 198 AC_CHECK_LIB(nsl,gethostbyaddr,
 199 if test "$uname" != "IRIX"; then
 200         NETLIBS="$NETLIBS -lnsl"
 201 else
 202         echo "Not using -lnsl since you are running IRIX."
 203 fi)
 204
 205 dnl Encryption support...
 206
 207 SSLLIBS=""
 208 AC_SUBST(SSLLIBS)
 209
 210 if test "$enable_ssl" = "yes"; then
 211         dnl Save the current libraries so the crypto stuff isn't always
 212         dnl included...
 213         SAVELIBS="$LIBS"
 214
 215         dnl Some ELF systems can't resolve all the symbols in libcrypto
 216         dnl if libcrypto was linked against RSAREF, and fail to link the
 217         dnl test program correctly, even though a correct installation
 218         dnl of OpenSSL exists.  So we test the linking three times in
 219         dnl case the RSAREF libraries are needed.
 220
 221         for libcrypto in \
 222                 "-lcrypto" \
 223                 "-lcrypto -lrsaref" \
 224                 "-lcrypto -lRSAglue -lrsaref"
 225         do
 226                 AC_CHECK_LIB(ssl,SSL_new,
 227                         [SSLLIBS="-lssl $libcrypto"
 228                          AC_DEFINE(HAVE_LIBSSL)],,
 229                         $libcrypto
 230                 )
 231                 if test "x${SSLLIBS}" != "x"; then
 232                         break
 233                 fi
 234         done
 235
 236         LIBS="$SAVELIBS"
 237 fi
 238
 239 dnl Save the current libraries since we don't want the image libraries
 240 dnl included with every program...
 241 SAVELIBS="$LIBS"
 242
 243 dnl Check for image libraries...
 244 LIBJPEG=""
 245 LIBPNG=""
 246 LIBTIFF=""
 247 LIBZ=""
 248
 249 AC_SUBST(LIBJPEG)
 250 AC_SUBST(LIBPNG)
 251 AC_SUBST(LIBTIFF)
 252 AC_SUBST(LIBZ)
 253
 254 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 255     AC_DEFINE(HAVE_LIBJPEG)
 256     LIBJPEG="-ljpeg"
 257     LIBS="$LIBS -ljpeg")
 258
 259 AC_CHECK_LIB(z, gzgets,
 260     AC_DEFINE(HAVE_LIBZ)
 261     LIBZ="-lz"
 262     LIBS="$LIBS -lz")
 263
 264 dnl PNG library uses math library functions...
 265 AC_CHECK_LIB(m, pow)
 266
 267 AC_CHECK_LIB(png, png_set_tRNS_to_alpha,
 268     AC_DEFINE(HAVE_LIBPNG)
 269     LIBPNG="-lpng")
 270
 271 AC_CHECK_LIB(tiff, TIFFReadScanline,
 272     AC_DEFINE(HAVE_LIBTIFF)
 273     LIBTIFF="-ltiff")
 274
 275 dnl Restore original LIBS settings...
 276 LIBS="$SAVELIBS"
 277
 278 dnl Checks for header files.
 279 AC_HEADER_STDC
 280 AC_HEADER_DIRENT
 281 AC_CHECK_HEADER(crypt.h,AC_DEFINE(HAVE_CRYPT_H))
 282 AC_CHECK_HEADER(malloc.h,AC_DEFINE(HAVE_MALLOC_H))
 283 AC_CHECK_HEADER(shadow.h,AC_DEFINE(HAVE_SHADOW_H))
 284 AC_CHECK_HEADER(stddef.h,AC_DEFINE(HAVE_STDDEF_H))
 285 AC_CHECK_HEADER(stdlib.h,AC_DEFINE(HAVE_STDLIB_H))
 286 AC_CHECK_HEADER(sys/ioctl.h,AC_DEFINE(HAVE_SYS_IOCTL_H))
 287
 288 dnl Checks for string functions.
 289 AC_CHECK_FUNCS(strdup)
 290 AC_CHECK_FUNCS(strcasecmp)
 291 AC_CHECK_FUNCS(strncasecmp)
 292 if test "$uname" = "HP-UX" -a "$uversion" = "1020"; then
 293         echo Forcing snprintf emulation for HP-UX.
 294 else
 295         AC_CHECK_FUNCS(snprintf)
 296         AC_CHECK_FUNCS(vsnprintf)
 297 fi
 298
 299 dnl Check OS version and use appropriate format string for strftime...
 300 AC_MSG_CHECKING(for correct format string to use with strftime)
 301
 302 case "$uname" in
 303         IRIX* | SunOS*)
 304                 # IRIX and SunOS
 305                 AC_MSG_RESULT(NULL)
 306                 AC_DEFINE(CUPS_STRFTIME_FORMAT, NULL)
 307                 ;;
 308         *)
 309                 # All others
 310                 AC_MSG_RESULT("%c")
 311                 AC_DEFINE(CUPS_STRFTIME_FORMAT, "%c")
 312                 ;;
 313 esac
 314
 315 dnl Checks for vsyslog function.
 316 AC_CHECK_FUNCS(vsyslog)
 317
 318 dnl Checks for signal functions.
 319 if test "$uname" != "Linux"; then
 320         AC_CHECK_FUNCS(sigset)
 321 fi
 322
 323 AC_CHECK_FUNCS(sigaction)
 324
 325 dnl Checks for wait functions.
 326 AC_CHECK_FUNCS(waitpid)
 327 AC_CHECK_FUNCS(wait3)
 328
 329 dnl Update compiler options...
 330 if test -n "$GCC"; then
 331         GXX="gcc"
 332
 333         if test -z "$OPTIM"; then
 334                 OPTIM="-O2"
 335                 GSOPTIM="-O1"
 336         fi
 337         if test $PICFLAG = 1; then
 338                 OPTIM="-fPIC $OPTIM"
 339                 GSOPTIM="-fPIC $GSOPTIM"
 340         fi
 341         OPTIM="-Wall $OPTIM"
 342         GSOPTIM="-Wall $GSOPTIM"
 343 else
 344         case $uname in
 345                 IRIX*)
 346                         if test -z "$OPTIM"; then
 347                                 OPTIM="-O2"
 348                                 GSOPTIM="-O1"
 349                         fi
 350                         if test $uversion -ge 62; then
 351                                 OPTIM="$OPTIM -n32 -mips3"
 352                                 GSOPTIM="$GSOPTIM -n32 -mips3"
 353                         fi
 354                         OPTIM="-fullwarn $OPTIM"
 355                         GSOPTIM="-fullwarn $GSOPTIM"
 356                         ;;
 357                 HP-UX*)
 358                         if test -z "$OPTIM"; then
 359                                 OPTIM="+O2"
 360                                 GSOPTIM="+O1"
 361                         fi
 362                         OPTIM="-Ae $OPTIM"
 363                         GSOPTIM="-Ae $GSOPTIM"
 364                         ;;
 365                 SunOS*)
 366                         # Solaris
 367                         if test -z "$OPTIM"; then
 368                                 OPTIM="-xO4"
 369                                 GSOPTIM="-xO2"
 370                         fi
 371                         if test $PICFLAG = 1; then
 372                                 OPTIM="-KPIC $OPTIM"
 373                                 GSOPTIM="-KPIC $GSOPTIM"
 374                         fi
 375                         ;;
 376                 *)
 377                         # Running some other operating system; inform the user they
 378                         # should contribute the necessary options to
 379                         # cups-support@cups.org...
 380                         echo "Building CUPS with default compiler optimizations; contact"
 381                         echo "cups-support@cups.org with uname and compiler options needed"
 382                         echo "for your platform, or set the CFLAGS environment variable"
 383                         echo "before running configure."
 384                         ;;
 385         esac
 386 fi
 387
 388 if test "$DSO" != ":"; then
 389         # When using DSOs the image libraries are linked to libcupsimage.so
 390         # rather than to the executables.  This makes things smaller if you
 391         # are using any static libraries, and it also allows us to distribute
 392         # a single DSO rather than a bunch...unless the linker is dumb.
 393         case $uname in
 394                 NetBSD*)
 395                         # NetBSD's linker won't resolve symbols in a shared
 396                         # libraries unless their enclosing shared libraries
 397                         # are explicitly listed.
 398                         DSOLIBS="\$(LIBJPEG) \$(LIBPNG) \$(LIBTIFF) \$(LIBZ)"
 399                         IMGLIBS="\$(LIBJPEG) \$(LIBPNG) \$(LIBTIFF) \$(LIBZ)"
 400                         ;;
 401                 *)
 402                         DSOLIBS="\$(LIBJPEG) \$(LIBPNG) \$(LIBTIFF) \$(LIBZ)"
 403                         IMGLIBS=""
 404                         ;;
 405         esac
 406
 407         # The *BSD, HP-UX, and Solaris run-time linkers need help when
 408         # deciding where to find a DSO.  Add linker options to tell them
 409         # where to find the DSO (usually in /usr/lib...  duh!)
 410         case $uname in
 411                 HP-UX*)
 412                         # HP-UX
 413                         DSOFLAGS="+b $libdir +fb $DSOFLAGS"
 414                         LDFLAGS="$LDFLAGS -Wl,+b,$libdir,+fb"
 415                         ;;
 416                 SunOS*)
 417                         # Solaris
 418                         DSOFLAGS="-R$libdir $DSOFLAGS"
 419                         LDFLAGS="$LDFLAGS -R$libdir"
 420                         ;;
 421                 FreeBSD* | NetBSD* | OpenBSD*)
 422                         # *BSD
 423                         DSOFLAGS="-Wl,-R$libdir $DSOFLAGS"
 424                         LDFLAGS="$LDFLAGS -Wl,-R$libdir"
 425                         ;;
 426         esac
 427 else
 428         DSOLIBS=""
 429         IMGLIBS="\$(LIBJPEG) \$(LIBPNG) \$(LIBTIFF) \$(LIBZ)"
 430 fi
 431
 432 AC_SUBST(DSO)
 433 AC_SUBST(DSOLIBS)
 434 AC_SUBST(IMGLIBS)
 435 AC_SUBST(LIBCUPS)
 436 AC_SUBST(LIBCUPSIMAGE)
 437 AC_SUBST(LIBTOOL)
 438 AC_SUBST(LINKCUPS)
 439 AC_SUBST(LINKCUPSIMAGE)
 440
 441 dnl Fix "prefix" variable if it hasn't been specified...
 442 if test "$prefix" = "NONE"; then
 443         prefix="/"
 444 fi
 445
 446 dnl Fix "exec_prefix" variable if it hasn't been specified...
 447 if test "$exec_prefix" = "NONE"; then
 448         if test "$prefix" = "/"; then
 449                 exec_prefix="/usr"
 450         else
 451                 exec_prefix="$prefix"
 452         fi
 453 fi
 454
 455 dnl Fix "sharedstatedir" variable if it hasn't been specified...
 456 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
 457         sharedstatedir="/usr/com"
 458 fi
 459
 460 dnl Fix "infodir" variable if it hasn't been specified...
 461 if test "$infodir" = "\${prefix}/info" -a "$prefix" = "/"; then
 462         infodir="/usr/info"
 463 fi
 464
 465 dnl Fix "datadir" variable if it hasn't been specified...
 466 if test "$datadir" = "\${prefix}/share"; then
 467         if test "$prefix" = "/"; then
 468                 datadir="/usr/share"
 469         else
 470                 datadir="$prefix/share"
 471         fi
 472 fi
 473
 474 dnl Fix "includedir" variable if it hasn't been specified...
 475 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
 476         includedir="/usr/include"
 477 fi
 478
 479 dnl Fix "localstatedir" variable if it hasn't been specified...
 480 if test "$localstatedir" = "\${prefix}/var"; then
 481         if test "$prefix" = "/"; then
 482                 localstatedir="/var"
 483         else
 484                 localstatedir="$prefix/var"
 485         fi
 486 fi
 487
 488 dnl Fix "sysconfdir" variable if it hasn't been specified...
 489 if test "$sysconfdir" = "\${prefix}/etc"; then
 490         if test "$prefix" = "/"; then
 491                 sysconfdir="/etc"
 492         else
 493                 sysconfdir="$prefix/etc"
 494         fi
 495 fi
 496
 497 dnl Fix "libdir" variable for IRIX 6.x...
 498 if test "$uname" = "IRIX" -a $uversion -ge 62; then
 499         libdir="$exec_prefix/lib32"
 500 fi
 501
 502 dnl Fix "mandir" variable...
 503 if test "$mandir" = "\${prefix}/man" -a "$prefix" = "/"; then
 504         case "$uname" in
 505                 FreeBSD* | NetBSD* | OpenBSD*)
 506                         # *BSD
 507                         mandir="/usr/share/man"
 508                         ;;
 509                 IRIX*)
 510                         # SGI IRIX
 511                         mandir="/usr/share/catman"
 512                         ;;
 513                 *)
 514                         # All others
 515                         mandir="/usr/man"
 516                         ;;
 517         esac
 518 fi
 519
 520 dnl Fix "fontpath" variable...
 521 if test "x$fontpath" = "x"; then
 522         fontpath="$datadir/cups/fonts"
 523 fi
 524
 525 dnl Setup manpage extensions...
 526 case "$uname" in
 527         FreeBSD* | NetBSD* | OpenBSD*)
 528                 # *BSD
 529                 CAT1EXT=0
 530                 CAT5EXT=0
 531                 CAT8EXT=0
 532                 ;;
 533         IRIX*)
 534                 # SGI IRIX
 535                 CAT1EXT=z
 536                 CAT5EXT=z
 537                 CAT8EXT=z
 538                 ;;
 539         *)
 540                 # All others
 541                 CAT1EXT=1
 542                 CAT5EXT=5
 543                 CAT8EXT=8
 544                 ;;
 545 esac
 546
 547 AC_SUBST(CAT1EXT)
 548 AC_SUBST(CAT5EXT)
 549 AC_SUBST(CAT8EXT)
 550
 551 dnl Setup init.d locations...
 552 case "$uname" in
 553         FreeBSD* | OpenBSD*)
 554                 # FreeBSD and OpenBSD
 555                 INITDIR=""
 556                 INITDDIR=""
 557                 ;;
 558
 559         NetBSD*)
 560                 # NetBSD
 561                 INITDIR=""
 562                 INITDDIR="/etc/rc.d"
 563                 ;;
 564
 565         Linux*)
 566                 # Linux seems to choose an init.d directory at random...
 567                 if test -d /sbin/init.d; then
 568                         # SuSE
 569                         INITDIR="/sbin/init.d"
 570                         INITDDIR=".."
 571                 else
 572                         if test -d /etc/rc.d; then
 573                                 # RedHat
 574                                 INITDIR="/etc/rc.d"
 575                                 INITDDIR="../init.d"
 576                         else
 577                                 # Others
 578                                 INITDIR="/etc"
 579                                 INITDDIR="../init.d"
 580                         fi
 581                 fi
 582                 ;;
 583
 584         OSF1* | HP-UX*)
 585                 INITDIR="/sbin"
 586                 INITDDIR="../init.d"
 587                 ;;
 588
 589         *)
 590                 INITDIR="/etc"
 591                 INITDDIR="../init.d"
 592                 ;;
 593
 594 esac
 595
 596 AC_SUBST(INITDIR)
 597 AC_SUBST(INITDDIR)
 598
 599 dnl Setup default locations...
 600 CUPS_SERVERROOT='${sysconfdir}/cups'
 601 CUPS_LOGDIR='${localstatedir}/log/cups'
 602 CUPS_REQUESTS='${localstatedir}/spool/cups'
 603
 604 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 605 AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 606 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 607
 608 dnl See what directory to put server executables...
 609 case "$uname" in
 610         FreeBSD* | NetBSD* | OpenBSD*)
 611                 # *BSD
 612                 INSTALL_SYSV=""
 613                 CUPS_SERVERBIN='${exec_prefix}/libexec/cups'
 614                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/libexec/cups")
 615                 ;;
 616         *)
 617                 # All others
 618                 INSTALL_SYSV="install-sysv"
 619                 CUPS_SERVERBIN='${exec_prefix}/lib/cups'
 620                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/lib/cups")
 621                 ;;
 622 esac
 623
 624 AC_SUBST(INSTALL_SYSV)
 625 AC_SUBST(CUPS_SERVERROOT)
 626 AC_SUBST(CUPS_SERVERBIN)
 627 AC_SUBST(CUPS_LOGDIR)
 628 AC_SUBST(CUPS_REQUESTS)
 629
 630 dnl Set the CUPS_LOCALE directory...
 631 case "$uname" in
 632         Linux* | FreeBSD* | NetBSD* | OpenBSD*)
 633                 CUPS_LOCALEDIR='${datadir}/locale'
 634                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$datadir/locale")
 635                 ;;
 636
 637         OSF1*)
 638                 CUPS_LOCALEDIR='${exec_prefix}/lib/nls/msg'
 639                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/nls/msg")
 640                 ;;
 641
 642         *)
 643                 # This is the standard System V location...
 644                 CUPS_LOCALEDIR='${exec_prefix}/lib/locale'
 645                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/locale")
 646                 ;;
 647 esac
 648
 649 AC_SUBST(CUPS_LOCALEDIR)
 650
 651 dnl Set the CUPS_DATADIR directory...
 652 CUPS_DATADIR='${datadir}/cups'
 653 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 654 AC_SUBST(CUPS_DATADIR)
 655
 656 dnl Set the CUPS_DOCROOT directory...
 657 CUPS_DOCROOT='${datadir}/doc/cups'
 658 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$datadir/doc/cups")
 659 AC_SUBST(CUPS_DOCROOT)
 660
 661 dnl Set the CUPS_FONTPATH directory...
 662 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$fontpath")
 663
 664 AC_OUTPUT(Makedefs cups.sh)
 665
 666 dnl
 667 dnl End of "$Id: configure.in,v 1.74 2001/02/07 01:25:38 mike Exp $".
 668 dnl