gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-netware*)     fmt=ecoff ;;
 111       alpha-*-osf*)         fmt=ecoff ;;
 112       alpha-*-linuxecoff*)  fmt=ecoff ;;
 113       alpha-*-linux*)       fmt=elf em=linux ;;
 114
 115 # start-sanitize-arc
 116       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 117 # end-sanitize-arc
 118
 119       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 120       arm-*-aout)           fmt=aout
 121                             case "$endian" in
 122                               big)      targ=arm-big ;;
 123                               *)        targ=arm-lit ;;
 124                             esac
 125                             ;;
 126       arm-*-coff)           fmt=coff ;;
 127       arm-*-riscix*)        fmt=aout ;;
 128       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 129
 130 # start-sanitize-d10v
 131       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 132 # end-sanitize-d10v
 133
 134       hppa-*-*elf*)         fmt=elf em=hppa ;;
 135       hppa-*-lites*)        fmt=elf em=hppa ;;
 136       hppa-*-osf*)          fmt=som em=hppa ;;
 137       hppa-*-hpux*)         fmt=som em=hppa ;;
 138       hppa-*-bsd*)          fmt=som em=hppa ;;
 139       hppa-*-hiux*)         fmt=som em=hppa ;;
 140
 141       h8300-*-coff)         fmt=coff ;;
 142
 143       i386-ibm-aix*)        fmt=coff targ=i386coff
 144                              em=i386aix ;;
 145       i386-*-bsd*)          fmt=aout em=386bsd ;;
 146       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 147       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 148       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 149       i386-*-linux*coff*)   fmt=coff em=linux
 150                              targ=i386coff ;;
 151       i386-*-linux*)        fmt=elf em=linux ;;
 152       i386-*-lynxos*)       fmt=coff targ=i386coff
 153                              em=lynx ;;
 154       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 155                             fmt=elf ;;
 156       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 157       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 158                             fmt=coff targ=i386coff ;;
 159       i386-*-vsta)          fmt=aout ;;
 160       i386-*-go32)          fmt=coff targ=i386coff ;;
 161       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 162       i386-*-gnu*)          fmt=elf ;;
 163       i386-*-mach*)
 164                             fmt=aout em=mach bfd_gas=yes ;;
 165       i386-*-msdos*)        fmt=aout ;;
 166       i386-*-moss*)         fmt=elf ;;
 167       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 168       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 169       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 170       i960-*-bout)          fmt=bout ;;
 171       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 172       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 173       i960-*-nindy*)        fmt=bout ;;
 174       i960-*-vxworks4*)     fmt=bout ;;
 175       i960-*-vxworks5.0)    fmt=bout ;;
 176       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 177       i960-*-vxworks*)      fmt=bout ;;
 178
 179       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 180                             fmt=aout em=sun3 ;;
 181       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 182       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 183       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 184       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 185                             fmt=elf ;;
 186       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 187                             fmt=coff targ=m68kcoff ;;
 188       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 189       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 190       m68k-*-linux*)        fmt=elf em=linux ;;
 191       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 192                              em=lynx ;;
 193       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 194       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 195       m68k-*-psos*)         fmt=elf em=psos;;
 196
 197       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 198       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 199
 200       # don't change em like *-*-bsd does
 201       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 202       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 203       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 204       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 205       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 206       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 207       mips-*-ecoff*)        fmt=ecoff
 208                             case "$endian" in
 209                             big) targ=mips-big ;;
 210                             *)   targ=mips-lit ;;
 211                             esac
 212                             ;;
 213       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 214       mips-*-gnu*)          fmt=aout
 215                             case "$endian" in
 216                             big) targ=mips-big ;;
 217                             *)   targ=mips-lit ;;
 218                             esac
 219                             ;;
 220       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 221       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 222       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 223       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 224       mips-*-elf*)          fmt=elf
 225                             case "$endian" in
 226                             big) targ=mips-big ;;
 227                             *)   targ=mips-lit ;;
 228                             esac
 229                             ;;
 230       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 231                             fmt=coff em=pe
 232                             case "$endian" in
 233                             big) targ=ppc-big ;;
 234                             *)   targ=ppc-lit ;;
 235                             esac
 236                             ;;
 237       ppc-*-aix*)           fmt=coff ;;
 238       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 239                             fmt=elf
 240                             case "$endian" in
 241                             big)  targ=ppc-big ;;
 242                             *)    targ=ppc-lit ;;
 243                             esac
 244                             ;;
 245       ppc-*-linux*)         fmt=elf
 246                             case "$endian" in
 247                             big)  targ=ppc-big ;;
 248                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 249                             esac
 250                             ;;
 251       ppc-*-solaris*)       fmt=elf
 252                             case "$endian" in
 253                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 254                             *)    targ=ppc-sol ;;
 255                             esac
 256                             ;;
 257       ppc-*-rtems*)
 258                             fmt=elf
 259                             case "$endian" in
 260                             big)  targ=ppc-big ;;
 261                             *)    targ=ppc-lit ;;
 262                             esac
 263                             ;;
 264       ppc-*-macos* | ppc-*-mpw*)
 265                             fmt=coff em=macos ;;
 266       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 267
 268       sh-*-coff)            fmt=coff ;;
 269
 270       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 271       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 272
 273       sparc-*-rtems*)       fmt=aout ;;
 274       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 275       sparc-*-aout | sparc*-*-vxworks*)
 276                             fmt=aout ;;
 277       sparc-*-coff)         fmt=coff ;;
 278       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 279       sparc-fujitsu-none)   fmt=aout ;;
 280       sparc-*-elf | sparc-*-solaris*)
 281                             fmt=elf ;;
 282       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 283
 284       vax-*-bsd* | vax-*-ultrix*)
 285                             fmt=aout ;;
 286       vax-*-vms)            fmt=vms ;;
 287
 288       z8k-*-coff | z8k-*-sim)
 289                             fmt=coff ;;
 290
 291       w65-*-*)              fmt=coff ;;
 292
 293       *-*-aout | *-*-scout)
 294                             fmt=aout ;;
 295       *-*-nindy*)
 296                             fmt=bout ;;
 297       *-*-bsd*)
 298                             fmt=aout em=sun3 ;;
 299       *-*-generic)          fmt=generic ;;
 300       *-*-xray | *-*-hms)   fmt=coff ;;
 301       *-*-sim)              fmt=coff ;;
 302       *-*-elf | *-*-sysv4* | *-*-solaris*)
 303                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 304                             fmt=elf dev=yes ;;
 305       *-*-vxworks)          fmt=aout ;;
 306       *-*-netware)          fmt=elf ;;
 307     esac
 308
 309     case ${cpu_type}-${fmt} in
 310       alpha-*)  bfd_gas=yes ;;
 311       arm-*)    bfd_gas=yes ;;
 312     # not yet
 313     # i386-aout)        bfd_gas=preferred ;;
 314       mips-*)   bfd_gas=yes ;;
 315       ns32k-*)  bfd_gas=yes ;;
 316       ppc-*)    bfd_gas=yes ;;
 317       sparc-*)  bfd_gas=yes ;;
 318       *-elf)    bfd_gas=yes ;;
 319       *-ecoff)  bfd_gas=yes ;;
 320       *-som)    bfd_gas=yes ;;
 321       *)                ;;
 322     esac
 323
 324 # Other random stuff.
 325
 326     # do we need the opcodes library?
 327     case ${cpu_type} in
 328       vax | i386)
 329         ;;
 330       *)
 331         need_opcodes=yes
 332         if test "${shared_opcodes}" = "true"; then
 333           # A shared libopcodes must be linked against libbfd.
 334           need_bfd=yes
 335         fi
 336         ;;
 337     esac
 338
 339     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 340
 341     case ${cpu}-${vendor}-${os} in
 342       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 343     esac
 344
 345     case ${cpu_type} in
 346       m68k)
 347         case ${extra_objects} in
 348         *m68k-parse.o*) ;;
 349         *) extra_objects="$extra_objects m68k-parse.o" ;;
 350         esac
 351         ;;
 352     esac
 353
 354 # See if we really can support this configuration with the emulation code.
 355
 356     if test $this_target = $target ; then
 357       primary_bfd_gas=$bfd_gas
 358       obj_format=$fmt
 359       gas_target=$targ
 360       te_file=$em
 361
 362       if test $bfd_gas = no ; then
 363         # Can't support other configurations this way.
 364         break
 365       fi
 366     elif test $bfd_gas = no ; then
 367       # Can't support this configuration.
 368       break
 369     fi
 370
 371 # From target name and format, produce a list of supported emulations.
 372
 373     case ${generic_target}-${fmt} in
 374       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 375       mips-*-*-ecoff)   case "$endian" in
 376                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 377                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 378                         esac ;;
 379       mips-*-*-elf)     case "$endian" in
 380                         big)    emulation="mipsbelf mipslelf mipself" ;;
 381                         *)      emulation="mipslelf mipsbelf mipself" ;;
 382                         esac ;;
 383     esac
 384
 385     emulations="$emulations $emulation"
 386
 387 done
 388
 389 # Assign floating point type.  Most processors with FP support
 390 # IEEE FP.  On those that don't support FP at all, usually IEEE
 391 # is emulated.
 392 case ${target_cpu} in
 393   vax | tahoe ) atof=${target_cpu} ;;
 394   *)            atof=ieee ;;
 395 esac
 396
 397 case "${obj_format}" in
 398   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 399 esac
 400
 401 dnl
 402 dnl Make sure the desired support files exist.
 403 dnl
 404
 405 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 406   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 407 fi
 408
 409 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 410   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 411 fi
 412
 413 # and target makefile frag
 414
 415 target_frag=${srcdir}/config/${gas_target}.mt
 416 if test ! -r ${target_frag}; then
 417   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 418 fi
 419 AC_SUBST_FILE(target_frag)
 420
 421 case ${user_bfd_gas}-${primary_bfd_gas} in
 422   yes-yes | no-no)
 423     # We didn't override user's choice.
 424     ;;
 425   no-yes)
 426     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 427     ;;
 428   no-preferred)
 429     primary_bfd_gas=no
 430     ;;
 431   *-preferred)
 432     primary_bfd_gas=yes
 433     ;;
 434   yes-*)
 435     primary_bfd_gas=yes
 436     ;;
 437   -*)
 438     # User specified nothing.
 439     ;;
 440 esac
 441
 442 # Some COFF configurations want these random other flags set.
 443 case ${obj_format} in
 444   coff)
 445     case ${target_cpu_type} in
 446       i386) AC_DEFINE(I386COFF) ;;
 447       m68k) AC_DEFINE(M68KCOFF) ;;
 448       m88k) AC_DEFINE(M88KCOFF) ;;
 449     esac
 450     ;;
 451 esac
 452
 453 # Getting this done right is going to be a bitch.  Each configuration specified
 454 # with --enable-targets=... should be checked for environment, format, cpu, and
 455 # bfd_gas setting.
 456 #
 457 # For each configuration, the necessary object file support code must be linked
 458 # in.  This might be only one, it might be up to four.  The necessary emulation
 459 # code needs to be provided, too.
 460 #
 461 # And then there's "--enable-targets=all"....
 462 #
 463 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 464
 465 formats="${obj_format}"
 466 emfiles=""
 467 EMULATIONS=""
 468 GAS_UNIQ(emulations)
 469 for em in . $emulations ; do
 470   case $em in
 471     .)  continue ;;
 472     mipsbelf | mipslelf)
 473         fmt=elf   file=mipself ;;
 474     mipsbecoff | mipslecoff)
 475         fmt=ecoff file=mipsecoff ;;
 476   esac
 477   formats="$formats $fmt"
 478   emfiles="$emfiles e-$file.o"
 479   EMULATIONS="$EMULATIONS &$em,"
 480 done
 481 GAS_UNIQ(formats)
 482 GAS_UNIQ(emfiles)
 483 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 484   for fmt in $formats ; do
 485     case $fmt in
 486       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 487       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 488       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 489       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 490       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 491       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 492       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 493       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 494       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 495       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 496     esac
 497     extra_objects="$extra_objects obj-$fmt.o"
 498   done
 499   obj_format=multi
 500 fi
 501 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 502   te_file=multi
 503   extra_objects="$extra_objects $emfiles"
 504   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 505   AC_DEFINE(USE_EMULATIONS)
 506 fi
 507 AC_SUBST(extra_objects)
 508 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 509 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 510
 511 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 512         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 513         config/te-${te_file}.h config/atof-${atof}.c \
 514         $extra_files"
 515 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 516         $extra_links"
 517
 518 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 519   yes-*-coff)   need_bfd=yes ;;
 520   no-*-coff)    need_bfd=yes
 521                 AC_DEFINE(MANY_SEGMENTS) ;;
 522 esac
 523
 524 reject_dev_configs=yes
 525
 526 case ${reject_dev_configs}-${dev} in
 527   yes-yes) # Oops.
 528     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 529     ;;
 530 esac
 531
 532 AC_SUBST(target_cpu_type)
 533 AC_SUBST(obj_format)
 534 AC_SUBST(atof)
 535 dnl AC_SUBST(emulation)
 536
 537 AC_LINK_FILES($files, $links)
 538
 539 case "${primary_bfd_gas}" in
 540   yes)  AC_DEFINE(BFD_ASSEMBLER)
 541         need_bfd=yes ;;
 542 esac
 543
 544 # do we need the opcodes library?
 545 case "${need_opcodes}" in
 546 yes)
 547   OPCODES_DEP=../opcodes/libopcodes.a
 548   OPCODES_LIB='-L../opcodes -lopcodes'
 549
 550   # We need to handle some special cases for shared libraries.
 551   case "${host}" in
 552   *-*-sunos*)
 553     # On SunOS, we must link against the name we are going to install,
 554     # not -lbfd, since SunOS does not support SONAME.
 555     if test "${shared_opcodes}" = "true"; then
 556       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 557     fi
 558     ;;
 559   alpha*-*-osf*)
 560     # On Alpha OSF/1, the native linker searches all the -L
 561     # directories for any LIB.so files, and only then searches for any
 562     # LIB.a files.  That means that if there is an installed
 563     # libbfd.so, but this build is not done with --enable-shared, the
 564     # link will wind up being against the install libbfd.so rather
 565     # than the newly built libbfd.  To avoid this, we must explicitly
 566     # link against libbfd.a when --enable-shared is not used.
 567     if test "${shared_opcodes}" != "true"; then
 568       OPCODES_LIB='../opcodes/libopcodes.a'
 569     fi
 570     ;;
 571   esac
 572   ;;
 573 esac
 574 AC_SUBST(OPCODES_DEP)
 575 AC_SUBST(OPCODES_LIB)
 576
 577 case "${need_bfd}" in
 578 yes)
 579   BFDDEP=../bfd/libbfd.a
 580   BFDLIB='-L../bfd -lbfd'
 581   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 582
 583   # We need to handle some special cases for shared libraries
 584   case "${host}" in
 585   *-*-sunos*)
 586     # On SunOS, we must link against the name we are going to install,
 587     # not -lbfd, since SunOS does not support SONAME.
 588     if test "${shared_bfd}" = "true"; then
 589       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 590     fi
 591     ;;
 592   alpha*-*-osf*)
 593     # On Alpha OSF/1, the native linker searches all the -L
 594     # directories for any LIB.so files, and only then searches for any
 595     # LIB.a files.  That means that if there is an installed
 596     # libbfd.so, but this build is not done with --enable-shared, the
 597     # link will wind up being against the install libbfd.so rather
 598     # than the newly built libbfd.  To avoid this, we must explicitly
 599     # link against libbfd.a when --enable-shared is not used.
 600     if test "${shared_bfd}" != "true"; then
 601       BFDLIB='../bfd/libbfd.a'
 602     fi
 603     ;;
 604   esac
 605   ;;
 606 esac
 607 AC_SUBST(BFDDEP)
 608 AC_SUBST(BFDLIB)
 609 AC_SUBST(ALL_OBJ_DEPS)
 610
 611 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 612 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 613 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 614 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 615 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 616
 617 AC_PROG_CC
 618 AC_PROG_INSTALL
 619
 620 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 621
 622 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 623 # people who are not cross-compiling but are compiling cross-assemblers.
 624 AC_MSG_CHECKING(whether compiling a cross-assembler)
 625 if test "${host}" = "${target}"; then
 626   cross_gas=no
 627 else
 628   cross_gas=yes
 629   AC_DEFINE(CROSS_COMPILE)
 630 fi
 631 AC_MSG_RESULT($cross_gas)
 632
 633 dnl ansidecl.h will deal with const
 634 dnl AC_CONST
 635 AC_FUNC_ALLOCA
 636 AC_C_INLINE
 637
 638 # VMS doesn't have unlink.
 639 AC_CHECK_FUNCS(unlink remove, break)
 640
 641 # Some systems don't have sbrk().
 642 AC_CHECK_FUNCS(sbrk)
 643
 644 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 645 # enough, but on some of those systems, the assert macro relies on requoting
 646 # working properly!
 647 GAS_WORKING_ASSERT
 648
 649 # On some systems, the system header files may not declare malloc, realloc,
 650 # and free.  There are places where gas needs these functions to have been
 651 # declared -- such as when taking their addresses.
 652 gas_test_headers="
 653 #ifdef HAVE_MEMORY_H
 654 #include <memory.h>
 655 #endif
 656 #ifdef HAVE_STRING_H
 657 #include <string.h>
 658 #endif
 659 #ifdef HAVE_STDLIB_H
 660 #include <stdlib.h>
 661 #endif
 662 #ifdef HAVE_UNISTD_H
 663 #include <unistd.h>
 664 #endif
 665 "
 666 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 667 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 668
 669 # Does errno.h declare errno, or do we have to add a separate declaration
 670 # for it?
 671 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 672 #ifdef HAVE_ERRNO_H
 673 #include <errno.h>
 674 #endif
 675 ])
 676
 677 HLDFLAGS=
 678 RPATH_ENVVAR=LD_LIBRARY_PATH
 679 # If we have shared libraries, try to set rpath reasonably.
 680 if test "${shared}" = "true"; then
 681   case "${host}" in
 682   *-*-hpux*)
 683     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 684     RPATH_ENVVAR=SHLIB_PATH
 685     ;;
 686   *-*-irix5*)
 687     HLDFLAGS='-Wl,-rpath,$(libdir)'
 688     ;;
 689   *-*-linux*aout*)
 690     ;;
 691   *-*-linux*)
 692     HLDFLAGS='-Wl,-rpath,$(libdir)'
 693     ;;
 694   *-*-sysv4* | *-*-solaris*)
 695     HLDFLAGS='-R $(libdir)'
 696     ;;
 697   esac
 698 fi
 699
 700 # On SunOS, if the linker supports the -rpath option, use it to
 701 # prevent ../bfd and ../opcodes from being included in the run time
 702 # search path.
 703 case "${host}" in
 704   *-*-sunos*)
 705     echo 'main () { }' > conftest.c
 706     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 707     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 708       :
 709     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 710       :
 711     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 712       :
 713     elif test "${shared}" = "true"; then
 714       HLDFLAGS='-Wl,-rpath=$(libdir)'
 715     else
 716       HLDFLAGS='-Wl,-rpath='
 717     fi
 718     rm -f conftest.t conftest.c conftest
 719     ;;
 720 esac
 721 AC_SUBST(HLDFLAGS)
 722 AC_SUBST(RPATH_ENVVAR)
 723
 724 dnl This must come last.
 725 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)