gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66 changequote(,)dnl
  67     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  68 changequote([,])dnl
  69
  70     # check for architecture variants
  71     case ${cpu} in
  72       armeb)            cpu_type=arm endian=big ;;
  73       arm*)             cpu_type=arm endian=little ;;
  74       hppa*)            cpu_type=hppa ;;
  75 changequote(,)dnl
  76       i[456]86)         cpu_type=i386 ;;
  77       m680[012346]0)    cpu_type=m68k ;;
  78       m68008)           cpu_type=m68k ;;
  79       m683??)           cpu_type=m68k ;;
  80 changequote([,])dnl
  81       m8*)              cpu_type=m88k ;;
  82       mips*el)          cpu_type=mips endian=little ;;
  83       mips*)            cpu_type=mips endian=big ;;
  84       powerpcle*)       cpu_type=ppc endian=little ;;
  85       powerpc*)         cpu_type=ppc endian=big ;;
  86       rs6000*)          cpu_type=ppc ;;
  87       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  88       sparc*)           cpu_type=sparc ;;
  89       *)                cpu_type=${cpu} ;;
  90     esac
  91
  92     if test ${this_target} = $target ; then
  93       target_cpu_type=${cpu_type}
  94     elif test ${target_cpu_type} != ${cpu_type} ; then
  95       continue
  96     fi
  97
  98     targ=${cpu_type}
  99     generic_target=${cpu_type}-$vendor-$os
 100     dev=no
 101     bfd_gas=no
 102     em=generic
 103
 104     # assign object format
 105     case ${generic_target} in
 106       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 107       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 108       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 109       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 110       a29k-*-vxworks*)      fmt=coff ;;
 111
 112       alpha-*-*vms*)        fmt=evax ;;
 113       alpha-*-netware*)     fmt=ecoff ;;
 114       alpha-*-osf*)         fmt=ecoff ;;
 115       alpha-*-linuxecoff*)  fmt=ecoff ;;
 116       alpha-*-linux*)       fmt=elf em=linux ;;
 117
 118 # start-sanitize-arc
 119       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 120 # end-sanitize-arc
 121
 122       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 123       arm-*-aout)           fmt=aout
 124                             case "$endian" in
 125                               big)      targ=arm-big ;;
 126                               *)        targ=arm-lit ;;
 127                             esac
 128                             ;;
 129       arm-*-coff)           fmt=coff ;;
 130       arm-*-riscix*)        fmt=aout ;;
 131       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 132
 133       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 134 # start-sanitize-d30v
 135       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 136 # end-sanitize-d30v
 137
 138       hppa-*-*elf*)         fmt=elf em=hppa ;;
 139       hppa-*-lites*)        fmt=elf em=hppa ;;
 140       hppa-*-osf*)          fmt=som em=hppa ;;
 141       hppa-*-hpux*)         fmt=som em=hppa ;;
 142       hppa-*-bsd*)          fmt=som em=hppa ;;
 143       hppa-*-hiux*)         fmt=som em=hppa ;;
 144
 145       h8300-*-coff)         fmt=coff ;;
 146
 147       i386-ibm-aix*)        fmt=coff targ=i386coff
 148                              em=i386aix ;;
 149       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 150       i386-*-bsd*)          fmt=aout em=386bsd ;;
 151       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 152       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 153       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 154       i386-*-linux*coff*)   fmt=coff em=linux
 155                              targ=i386coff ;;
 156       i386-*-linux*)        fmt=elf em=linux ;;
 157       i386-*-lynxos*)       fmt=coff targ=i386coff
 158                              em=lynx ;;
 159       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 160                             fmt=elf ;;
 161       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 162       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 163                             fmt=coff targ=i386coff ;;
 164       i386-*-vsta)          fmt=aout ;;
 165       i386-*-go32)          fmt=coff targ=i386coff ;;
 166       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 167       i386-*-gnu*)          fmt=elf ;;
 168       i386-*-mach*)
 169                             fmt=aout em=mach bfd_gas=yes ;;
 170       i386-*-msdos*)        fmt=aout ;;
 171       i386-*-moss*)         fmt=elf ;;
 172       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 173       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 174       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 175       i960-*-bout)          fmt=bout ;;
 176       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 177       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 178       i960-*-nindy*)        fmt=bout ;;
 179       i960-*-vxworks4*)     fmt=bout ;;
 180       i960-*-vxworks5.0)    fmt=bout ;;
 181       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 182       i960-*-vxworks*)      fmt=bout ;;
 183
 184       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 185                             fmt=aout em=sun3 ;;
 186       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 187       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 188       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 189       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 190                             fmt=elf ;;
 191       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 192                             fmt=coff targ=m68kcoff ;;
 193       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 194       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 195       m68k-*-linux*)        fmt=elf em=linux ;;
 196       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 197                              em=lynx ;;
 198       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 199       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 200       m68k-*-psos*)         fmt=elf em=psos;;
 201
 202       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 203       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 204
 205       # don't change em like *-*-bsd does
 206       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 207       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 208       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 209       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 210       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 211       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 212       mips-*-ecoff*)        fmt=ecoff
 213                             case "$endian" in
 214                             big) targ=mips-big ;;
 215                             *)   targ=mips-lit ;;
 216                             esac
 217                             ;;
 218       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 219       mips-*-gnu*)          fmt=aout
 220                             case "$endian" in
 221                             big) targ=mips-big ;;
 222                             *)   targ=mips-lit ;;
 223                             esac
 224                             ;;
 225       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 226       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 227       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 228       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 229       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 230       mips-*-elf* | mips-*-rtems* | mips-*-linux*)
 231                             fmt=elf
 232                             case "$endian" in
 233                             big) targ=mips-big ;;
 234                             *)   targ=mips-lit ;;
 235                             esac
 236                             ;;
 237       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 238       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 239       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 240                             fmt=coff em=pe
 241                             case "$endian" in
 242                             big) targ=ppc-big ;;
 243                             *)   targ=ppc-lit ;;
 244                             esac
 245                             ;;
 246       ppc-*-aix*)           fmt=coff ;;
 247       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 248                             fmt=elf
 249                             case "$endian" in
 250                             big)  targ=ppc-big ;;
 251                             *)    targ=ppc-lit ;;
 252                             esac
 253                             ;;
 254       ppc-*-linux*)         fmt=elf
 255                             case "$endian" in
 256                             big)  targ=ppc-big ;;
 257                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 258                             esac
 259                             ;;
 260       ppc-*-solaris*)       fmt=elf
 261                             case "$endian" in
 262                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 263                             *)    targ=ppc-sol ;;
 264                             esac
 265                             ;;
 266       ppc-*-rtems*)
 267                             fmt=elf
 268                             case "$endian" in
 269                             big)  targ=ppc-big ;;
 270                             *)    targ=ppc-lit ;;
 271                             esac
 272                             ;;
 273       ppc-*-macos* | ppc-*-mpw*)
 274                             fmt=coff em=macos ;;
 275       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 276
 277       sh-*-elf*)            fmt=elf ;;
 278       sh-*-coff*)           fmt=coff ;;
 279
 280       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 281       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 282
 283       sparc-*-rtems*)       fmt=aout ;;
 284       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 285       sparc-*-aout | sparc*-*-vxworks*)
 286                             fmt=aout em=sparcaout ;;
 287       sparc-*-coff)         fmt=coff ;;
 288       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 289       sparc-fujitsu-none)   fmt=aout ;;
 290       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 291                             fmt=elf ;;
 292       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 293
 294 # start-sanitize-tic80
 295       tic80-*-*)            fmt=coff targ=tic80coff;;
 296 # end-sanitize-tic80
 297       v850-*-*)             fmt=elf bfd_gas=yes ;;
 298
 299       vax-*-bsd* | vax-*-ultrix*)
 300                             fmt=aout ;;
 301       vax-*-vms)            fmt=vms ;;
 302
 303       z8k-*-coff | z8k-*-sim)
 304                             fmt=coff ;;
 305
 306       w65-*-*)              fmt=coff ;;
 307
 308       *-*-aout | *-*-scout)
 309                             fmt=aout ;;
 310       *-*-nindy*)
 311                             fmt=bout ;;
 312       *-*-bsd*)
 313                             fmt=aout em=sun3 ;;
 314       *-*-generic)          fmt=generic ;;
 315       *-*-xray | *-*-hms)   fmt=coff ;;
 316       *-*-sim)              fmt=coff ;;
 317       *-*-elf | *-*-sysv4* | *-*-solaris*)
 318                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 319                             fmt=elf dev=yes ;;
 320       *-*-vxworks)          fmt=aout ;;
 321       *-*-netware)          fmt=elf ;;
 322     esac
 323
 324     case ${cpu_type}-${fmt} in
 325       alpha-*)  bfd_gas=yes ;;
 326       arm-*)    bfd_gas=yes ;;
 327     # not yet
 328     # i386-aout)        bfd_gas=preferred ;;
 329       mips-*)   bfd_gas=yes ;;
 330       ns32k-*)  bfd_gas=yes ;;
 331       ppc-*)    bfd_gas=yes ;;
 332       sparc-*)  bfd_gas=yes ;;
 333       *-elf)    bfd_gas=yes ;;
 334       *-ecoff)  bfd_gas=yes ;;
 335       *-som)    bfd_gas=yes ;;
 336       *)                ;;
 337     esac
 338
 339 # Other random stuff.
 340
 341     # do we need the opcodes library?
 342     case ${cpu_type} in
 343       vax | i386)
 344         ;;
 345       *)
 346         need_opcodes=yes
 347         if test "${shared_opcodes}" = "true"; then
 348           # A shared libopcodes must be linked against libbfd.
 349           need_bfd=yes
 350         fi
 351         ;;
 352     esac
 353
 354     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 355
 356     case ${cpu}-${vendor}-${os} in
 357       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 358     esac
 359
 360     case ${cpu_type} in
 361       m68k)
 362         case ${extra_objects} in
 363         *m68k-parse.o*) ;;
 364         *) extra_objects="$extra_objects m68k-parse.o" ;;
 365         esac
 366         ;;
 367     esac
 368
 369 # See if we really can support this configuration with the emulation code.
 370
 371     if test $this_target = $target ; then
 372       primary_bfd_gas=$bfd_gas
 373       obj_format=$fmt
 374       gas_target=$targ
 375       te_file=$em
 376
 377       if test $bfd_gas = no ; then
 378         # Can't support other configurations this way.
 379         break
 380       fi
 381     elif test $bfd_gas = no ; then
 382       # Can't support this configuration.
 383       break
 384     fi
 385
 386 # From target name and format, produce a list of supported emulations.
 387
 388     case ${generic_target}-${fmt} in
 389       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 390       mips-*-*-ecoff)   case "$endian" in
 391                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 392                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 393                         esac ;;
 394       mips-*-*-elf)     case "$endian" in
 395                         big)    emulation="mipsbelf mipslelf mipself" ;;
 396                         *)      emulation="mipslelf mipsbelf mipself" ;;
 397                         esac ;;
 398     esac
 399
 400     emulations="$emulations $emulation"
 401
 402 done
 403
 404 # Assign floating point type.  Most processors with FP support
 405 # IEEE FP.  On those that don't support FP at all, usually IEEE
 406 # is emulated.
 407 case ${target_cpu} in
 408   vax | tahoe ) atof=${target_cpu} ;;
 409   *)            atof=ieee ;;
 410 esac
 411
 412 case "${obj_format}" in
 413   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 414 esac
 415
 416 dnl
 417 dnl Make sure the desired support files exist.
 418 dnl
 419
 420 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 421   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 422 fi
 423
 424 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 425   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 426 fi
 427
 428 # and target makefile frag
 429
 430 target_frag=${srcdir}/config/${gas_target}.mt
 431 if test ! -r ${target_frag}; then
 432   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 433 fi
 434 AC_SUBST_FILE(target_frag)
 435
 436 case ${user_bfd_gas}-${primary_bfd_gas} in
 437   yes-yes | no-no)
 438     # We didn't override user's choice.
 439     ;;
 440   no-yes)
 441     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 442     ;;
 443   no-preferred)
 444     primary_bfd_gas=no
 445     ;;
 446   *-preferred)
 447     primary_bfd_gas=yes
 448     ;;
 449   yes-*)
 450     primary_bfd_gas=yes
 451     ;;
 452   -*)
 453     # User specified nothing.
 454     ;;
 455 esac
 456
 457 # Some COFF configurations want these random other flags set.
 458 case ${obj_format} in
 459   coff)
 460     case ${target_cpu_type} in
 461       i386) AC_DEFINE(I386COFF) ;;
 462       m68k) AC_DEFINE(M68KCOFF) ;;
 463       m88k) AC_DEFINE(M88KCOFF) ;;
 464     esac
 465     ;;
 466 esac
 467
 468 # Getting this done right is going to be a bitch.  Each configuration specified
 469 # with --enable-targets=... should be checked for environment, format, cpu, and
 470 # bfd_gas setting.
 471 #
 472 # For each configuration, the necessary object file support code must be linked
 473 # in.  This might be only one, it might be up to four.  The necessary emulation
 474 # code needs to be provided, too.
 475 #
 476 # And then there's "--enable-targets=all"....
 477 #
 478 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 479
 480 formats="${obj_format}"
 481 emfiles=""
 482 EMULATIONS=""
 483 GAS_UNIQ(emulations)
 484 for em in . $emulations ; do
 485   case $em in
 486     .)  continue ;;
 487     mipsbelf | mipslelf)
 488         fmt=elf   file=mipself ;;
 489     mipsbecoff | mipslecoff)
 490         fmt=ecoff file=mipsecoff ;;
 491   esac
 492   formats="$formats $fmt"
 493   emfiles="$emfiles e-$file.o"
 494   EMULATIONS="$EMULATIONS &$em,"
 495 done
 496 GAS_UNIQ(formats)
 497 GAS_UNIQ(emfiles)
 498 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 499   for fmt in $formats ; do
 500     case $fmt in
 501       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 502       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 503       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 504       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 505       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 506       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 507       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 508       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 509       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 510       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 511     esac
 512     extra_objects="$extra_objects obj-$fmt.o"
 513   done
 514   obj_format=multi
 515 fi
 516 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 517   te_file=multi
 518   extra_objects="$extra_objects $emfiles"
 519   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 520   AC_DEFINE(USE_EMULATIONS)
 521 fi
 522 AC_SUBST(extra_objects)
 523 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 524 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 525
 526 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 527         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 528         config/te-${te_file}.h config/atof-${atof}.c \
 529         $extra_files"
 530 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 531         $extra_links"
 532
 533 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 534   yes-*-coff)   need_bfd=yes ;;
 535   no-*-coff)    need_bfd=yes
 536                 AC_DEFINE(MANY_SEGMENTS) ;;
 537 esac
 538
 539 reject_dev_configs=yes
 540
 541 case ${reject_dev_configs}-${dev} in
 542   yes-yes) # Oops.
 543     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 544     ;;
 545 esac
 546
 547 AC_SUBST(target_cpu_type)
 548 AC_SUBST(obj_format)
 549 AC_SUBST(atof)
 550 dnl AC_SUBST(emulation)
 551
 552 AC_LINK_FILES($files, $links)
 553
 554 case "${primary_bfd_gas}" in
 555   yes)  AC_DEFINE(BFD_ASSEMBLER)
 556         need_bfd=yes ;;
 557 esac
 558
 559 # do we need the opcodes library?
 560 case "${need_opcodes}" in
 561 yes)
 562   OPCODES_DEP=../opcodes/libopcodes.a
 563   OPCODES_LIB='-L../opcodes -lopcodes'
 564
 565   # We need to handle some special cases for shared libraries.
 566   case "${host}" in
 567   *-*-sunos*)
 568     # On SunOS, we must link against the name we are going to install,
 569     # not -lbfd, since SunOS does not support SONAME.
 570     if test "${shared_opcodes}" = "true"; then
 571       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 572     fi
 573     ;;
 574   alpha*-*-osf*)
 575     # On Alpha OSF/1, the native linker searches all the -L
 576     # directories for any LIB.so files, and only then searches for any
 577     # LIB.a files.  That means that if there is an installed
 578     # libbfd.so, but this build is not done with --enable-shared, the
 579     # link will wind up being against the install libbfd.so rather
 580     # than the newly built libbfd.  To avoid this, we must explicitly
 581     # link against libbfd.a when --enable-shared is not used.
 582     if test "${shared_opcodes}" != "true"; then
 583       OPCODES_LIB='../opcodes/libopcodes.a'
 584     fi
 585     ;;
 586   esac
 587   ;;
 588 esac
 589 AC_SUBST(OPCODES_DEP)
 590 AC_SUBST(OPCODES_LIB)
 591
 592 case "${need_bfd}" in
 593 yes)
 594   BFDDEP=../bfd/libbfd.a
 595   BFDLIB='-L../bfd -lbfd'
 596   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 597
 598   # We need to handle some special cases for shared libraries
 599   case "${host}" in
 600   *-*-sunos*)
 601     # On SunOS, we must link against the name we are going to install,
 602     # not -lbfd, since SunOS does not support SONAME.
 603     if test "${shared_bfd}" = "true"; then
 604       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 605     fi
 606     ;;
 607   alpha*-*-osf*)
 608     # On Alpha OSF/1, the native linker searches all the -L
 609     # directories for any LIB.so files, and only then searches for any
 610     # LIB.a files.  That means that if there is an installed
 611     # libbfd.so, but this build is not done with --enable-shared, the
 612     # link will wind up being against the install libbfd.so rather
 613     # than the newly built libbfd.  To avoid this, we must explicitly
 614     # link against libbfd.a when --enable-shared is not used.
 615     if test "${shared_bfd}" != "true"; then
 616       BFDLIB='../bfd/libbfd.a'
 617     fi
 618     ;;
 619   esac
 620   ;;
 621 esac
 622 AC_SUBST(BFDDEP)
 623 AC_SUBST(BFDLIB)
 624 AC_SUBST(ALL_OBJ_DEPS)
 625
 626 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 627 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 628 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 629 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 630 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 631
 632 AC_PROG_CC
 633 AC_PROG_INSTALL
 634
 635 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 636
 637 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 638 # people who are not cross-compiling but are compiling cross-assemblers.
 639 AC_MSG_CHECKING(whether compiling a cross-assembler)
 640 if test "${host}" = "${target}"; then
 641   cross_gas=no
 642 else
 643   cross_gas=yes
 644   AC_DEFINE(CROSS_COMPILE)
 645 fi
 646 AC_MSG_RESULT($cross_gas)
 647
 648 dnl ansidecl.h will deal with const
 649 dnl AC_CONST
 650 AC_FUNC_ALLOCA
 651 AC_C_INLINE
 652
 653 # VMS doesn't have unlink.
 654 AC_CHECK_FUNCS(unlink remove, break)
 655
 656 # Some systems don't have sbrk().
 657 AC_CHECK_FUNCS(sbrk)
 658
 659 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 660 # enough, but on some of those systems, the assert macro relies on requoting
 661 # working properly!
 662 GAS_WORKING_ASSERT
 663
 664 # On some systems, the system header files may not declare malloc, realloc,
 665 # and free.  There are places where gas needs these functions to have been
 666 # declared -- such as when taking their addresses.
 667 gas_test_headers="
 668 #ifdef HAVE_MEMORY_H
 669 #include <memory.h>
 670 #endif
 671 #ifdef HAVE_STRING_H
 672 #include <string.h>
 673 #else
 674 #ifdef HAVE_STRINGS_H
 675 #include <strings.h>
 676 #endif
 677 #endif
 678 #ifdef HAVE_STDLIB_H
 679 #include <stdlib.h>
 680 #endif
 681 #ifdef HAVE_UNISTD_H
 682 #include <unistd.h>
 683 #endif
 684 "
 685 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 686 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 687 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 688 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 689
 690 # Does errno.h declare errno, or do we have to add a separate declaration
 691 # for it?
 692 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 693 #ifdef HAVE_ERRNO_H
 694 #include <errno.h>
 695 #endif
 696 ])
 697
 698 HLDFLAGS=
 699 HLDENV=
 700 RPATH_ENVVAR=LD_LIBRARY_PATH
 701 # If we have shared libraries, try to set rpath reasonably.
 702 if test "${shared}" = "true"; then
 703   case "${host}" in
 704   *-*-hpux*)
 705     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 706     RPATH_ENVVAR=SHLIB_PATH
 707     ;;
 708   *-*-irix5* | *-*-irix6*)
 709     HLDFLAGS='-Wl,-rpath,$(libdir)'
 710     ;;
 711   *-*-linux*aout*)
 712     ;;
 713   *-*-linux*)
 714     HLDFLAGS='-Wl,-rpath,$(libdir)'
 715     ;;
 716   *-*-solaris*)
 717     HLDFLAGS='-R $(libdir)'
 718     ;;
 719   *-*-sysv4*)
 720     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 721     ;;
 722   esac
 723 fi
 724
 725 # On SunOS, if the linker supports the -rpath option, use it to
 726 # prevent ../bfd and ../opcodes from being included in the run time
 727 # search path.
 728 case "${host}" in
 729   *-*-sunos*)
 730     echo 'main () { }' > conftest.c
 731     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 732     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 733       :
 734     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 735       :
 736     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 737       :
 738     elif test "${shared}" = "true"; then
 739       HLDFLAGS='-Wl,-rpath=$(libdir)'
 740     else
 741       HLDFLAGS='-Wl,-rpath='
 742     fi
 743     rm -f conftest.t conftest.c conftest
 744     ;;
 745 esac
 746 AC_SUBST(HLDFLAGS)
 747 AC_SUBST(HLDENV)
 748 AC_SUBST(RPATH_ENVVAR)
 749
 750 dnl This must come last.
 751 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)