gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-netware*)     fmt=ecoff ;;
 111       alpha-*-osf*)         fmt=ecoff ;;
 112       alpha-*-linuxecoff*)  fmt=ecoff ;;
 113       alpha-*-linux*)       fmt=elf em=linux ;;
 114
 115 # start-sanitize-arc
 116       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 117 # end-sanitize-arc
 118
 119       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 120       arm-*-aout)           fmt=aout
 121                             case "$endian" in
 122                               big)      targ=arm-big ;;
 123                               *)        targ=arm-lit ;;
 124                             esac
 125                             ;;
 126       arm-*-coff)           fmt=coff ;;
 127       arm-*-riscix*)        fmt=aout ;;
 128       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 129
 130 # start-sanitize-d10v
 131       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 132 # end-sanitize-d10v
 133
 134       hppa-*-*elf*)         fmt=elf em=hppa ;;
 135       hppa-*-lites*)        fmt=elf em=hppa ;;
 136       hppa-*-osf*)          fmt=som em=hppa ;;
 137       hppa-*-hpux*)         fmt=som em=hppa ;;
 138       hppa-*-bsd*)          fmt=som em=hppa ;;
 139       hppa-*-hiux*)         fmt=som em=hppa ;;
 140
 141       h8300-*-coff)         fmt=coff ;;
 142
 143       i386-ibm-aix*)        fmt=coff targ=i386coff
 144                              em=i386aix ;;
 145       i386-*-bsd*)          fmt=aout em=386bsd ;;
 146       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 147       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 148       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 149       i386-*-linux*coff*)   fmt=coff em=linux
 150                              targ=i386coff ;;
 151       i386-*-linux*)        fmt=elf em=linux ;;
 152       i386-*-lynxos*)       fmt=coff targ=i386coff
 153                              em=lynx ;;
 154       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 155                             fmt=elf ;;
 156       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 157       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 158                             fmt=coff targ=i386coff ;;
 159       i386-*-vsta)          fmt=aout ;;
 160       i386-*-go32)          fmt=coff targ=i386coff ;;
 161       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 162       i386-*-gnu*)          fmt=elf ;;
 163       i386-*-mach*)
 164                             fmt=aout em=mach bfd_gas=yes ;;
 165       i386-*-msdos*)        fmt=aout ;;
 166       i386-*-moss*)         fmt=elf ;;
 167       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 168       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 169       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 170       i960-*-bout)          fmt=bout ;;
 171       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 172       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 173       i960-*-nindy*)        fmt=bout ;;
 174       i960-*-vxworks4*)     fmt=bout ;;
 175       i960-*-vxworks5.0)    fmt=bout ;;
 176       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 177       i960-*-vxworks*)      fmt=bout ;;
 178
 179       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 180                             fmt=aout em=sun3 ;;
 181       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 182       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 183       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 184       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 185                             fmt=elf ;;
 186       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 187                             fmt=coff targ=m68kcoff ;;
 188       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 189       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 190       m68k-*-linux*)        fmt=elf em=linux ;;
 191       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 192                              em=lynx ;;
 193       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 194       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 195       m68k-*-psos*)         fmt=elf em=psos;;
 196
 197       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 198       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 199
 200       # don't change em like *-*-bsd does
 201       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 202       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 203       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 204       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 205       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 206       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 207       mips-*-ecoff*)        fmt=ecoff
 208                             case "$endian" in
 209                             big) targ=mips-big ;;
 210                             *)   targ=mips-lit ;;
 211                             esac
 212                             ;;
 213       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 214       mips-*-gnu*)          fmt=aout
 215                             case "$endian" in
 216                             big) targ=mips-big ;;
 217                             *)   targ=mips-lit ;;
 218                             esac
 219                             ;;
 220       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 221       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 222       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 223       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 224       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 225       mips-*-elf*)          fmt=elf
 226                             case "$endian" in
 227                             big) targ=mips-big ;;
 228                             *)   targ=mips-lit ;;
 229                             esac
 230                             ;;
 231       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 232                             fmt=coff em=pe
 233                             case "$endian" in
 234                             big) targ=ppc-big ;;
 235                             *)   targ=ppc-lit ;;
 236                             esac
 237                             ;;
 238       ppc-*-aix*)           fmt=coff ;;
 239       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 240                             fmt=elf
 241                             case "$endian" in
 242                             big)  targ=ppc-big ;;
 243                             *)    targ=ppc-lit ;;
 244                             esac
 245                             ;;
 246       ppc-*-linux*)         fmt=elf
 247                             case "$endian" in
 248                             big)  targ=ppc-big ;;
 249                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 250                             esac
 251                             ;;
 252       ppc-*-solaris*)       fmt=elf
 253                             case "$endian" in
 254                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 255                             *)    targ=ppc-sol ;;
 256                             esac
 257                             ;;
 258       ppc-*-rtems*)
 259                             fmt=elf
 260                             case "$endian" in
 261                             big)  targ=ppc-big ;;
 262                             *)    targ=ppc-lit ;;
 263                             esac
 264                             ;;
 265       ppc-*-macos* | ppc-*-mpw*)
 266                             fmt=coff em=macos ;;
 267       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 268
 269       sh-*-coff)            fmt=coff ;;
 270
 271       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 272       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 273
 274       sparc-*-rtems*)       fmt=aout ;;
 275       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 276       sparc-*-aout | sparc*-*-vxworks*)
 277                             fmt=aout ;;
 278       sparc-*-coff)         fmt=coff ;;
 279       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 280       sparc-fujitsu-none)   fmt=aout ;;
 281       sparc-*-elf | sparc-*-solaris*)
 282                             fmt=elf ;;
 283       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 284
 285       vax-*-bsd* | vax-*-ultrix*)
 286                             fmt=aout ;;
 287       vax-*-vms)            fmt=vms ;;
 288
 289       z8k-*-coff | z8k-*-sim)
 290                             fmt=coff ;;
 291
 292       w65-*-*)              fmt=coff ;;
 293
 294       *-*-aout | *-*-scout)
 295                             fmt=aout ;;
 296       *-*-nindy*)
 297                             fmt=bout ;;
 298       *-*-bsd*)
 299                             fmt=aout em=sun3 ;;
 300       *-*-generic)          fmt=generic ;;
 301       *-*-xray | *-*-hms)   fmt=coff ;;
 302       *-*-sim)              fmt=coff ;;
 303       *-*-elf | *-*-sysv4* | *-*-solaris*)
 304                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 305                             fmt=elf dev=yes ;;
 306       *-*-vxworks)          fmt=aout ;;
 307       *-*-netware)          fmt=elf ;;
 308     esac
 309
 310     case ${cpu_type}-${fmt} in
 311       alpha-*)  bfd_gas=yes ;;
 312       arm-*)    bfd_gas=yes ;;
 313     # not yet
 314     # i386-aout)        bfd_gas=preferred ;;
 315       mips-*)   bfd_gas=yes ;;
 316       ns32k-*)  bfd_gas=yes ;;
 317       ppc-*)    bfd_gas=yes ;;
 318       sparc-*)  bfd_gas=yes ;;
 319       *-elf)    bfd_gas=yes ;;
 320       *-ecoff)  bfd_gas=yes ;;
 321       *-som)    bfd_gas=yes ;;
 322       *)                ;;
 323     esac
 324
 325 # Other random stuff.
 326
 327     # do we need the opcodes library?
 328     case ${cpu_type} in
 329       vax | i386)
 330         ;;
 331       *)
 332         need_opcodes=yes
 333         if test "${shared_opcodes}" = "true"; then
 334           # A shared libopcodes must be linked against libbfd.
 335           need_bfd=yes
 336         fi
 337         ;;
 338     esac
 339
 340     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 341
 342     case ${cpu}-${vendor}-${os} in
 343       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 344     esac
 345
 346     case ${cpu_type} in
 347       m68k)
 348         case ${extra_objects} in
 349         *m68k-parse.o*) ;;
 350         *) extra_objects="$extra_objects m68k-parse.o" ;;
 351         esac
 352         ;;
 353     esac
 354
 355 # See if we really can support this configuration with the emulation code.
 356
 357     if test $this_target = $target ; then
 358       primary_bfd_gas=$bfd_gas
 359       obj_format=$fmt
 360       gas_target=$targ
 361       te_file=$em
 362
 363       if test $bfd_gas = no ; then
 364         # Can't support other configurations this way.
 365         break
 366       fi
 367     elif test $bfd_gas = no ; then
 368       # Can't support this configuration.
 369       break
 370     fi
 371
 372 # From target name and format, produce a list of supported emulations.
 373
 374     case ${generic_target}-${fmt} in
 375       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 376       mips-*-*-ecoff)   case "$endian" in
 377                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 378                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 379                         esac ;;
 380       mips-*-*-elf)     case "$endian" in
 381                         big)    emulation="mipsbelf mipslelf mipself" ;;
 382                         *)      emulation="mipslelf mipsbelf mipself" ;;
 383                         esac ;;
 384     esac
 385
 386     emulations="$emulations $emulation"
 387
 388 done
 389
 390 # Assign floating point type.  Most processors with FP support
 391 # IEEE FP.  On those that don't support FP at all, usually IEEE
 392 # is emulated.
 393 case ${target_cpu} in
 394   vax | tahoe ) atof=${target_cpu} ;;
 395   *)            atof=ieee ;;
 396 esac
 397
 398 case "${obj_format}" in
 399   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 400 esac
 401
 402 dnl
 403 dnl Make sure the desired support files exist.
 404 dnl
 405
 406 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 407   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 408 fi
 409
 410 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 411   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 412 fi
 413
 414 # and target makefile frag
 415
 416 target_frag=${srcdir}/config/${gas_target}.mt
 417 if test ! -r ${target_frag}; then
 418   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 419 fi
 420 AC_SUBST_FILE(target_frag)
 421
 422 case ${user_bfd_gas}-${primary_bfd_gas} in
 423   yes-yes | no-no)
 424     # We didn't override user's choice.
 425     ;;
 426   no-yes)
 427     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 428     ;;
 429   no-preferred)
 430     primary_bfd_gas=no
 431     ;;
 432   *-preferred)
 433     primary_bfd_gas=yes
 434     ;;
 435   yes-*)
 436     primary_bfd_gas=yes
 437     ;;
 438   -*)
 439     # User specified nothing.
 440     ;;
 441 esac
 442
 443 # Some COFF configurations want these random other flags set.
 444 case ${obj_format} in
 445   coff)
 446     case ${target_cpu_type} in
 447       i386) AC_DEFINE(I386COFF) ;;
 448       m68k) AC_DEFINE(M68KCOFF) ;;
 449       m88k) AC_DEFINE(M88KCOFF) ;;
 450     esac
 451     ;;
 452 esac
 453
 454 # Getting this done right is going to be a bitch.  Each configuration specified
 455 # with --enable-targets=... should be checked for environment, format, cpu, and
 456 # bfd_gas setting.
 457 #
 458 # For each configuration, the necessary object file support code must be linked
 459 # in.  This might be only one, it might be up to four.  The necessary emulation
 460 # code needs to be provided, too.
 461 #
 462 # And then there's "--enable-targets=all"....
 463 #
 464 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 465
 466 formats="${obj_format}"
 467 emfiles=""
 468 EMULATIONS=""
 469 GAS_UNIQ(emulations)
 470 for em in . $emulations ; do
 471   case $em in
 472     .)  continue ;;
 473     mipsbelf | mipslelf)
 474         fmt=elf   file=mipself ;;
 475     mipsbecoff | mipslecoff)
 476         fmt=ecoff file=mipsecoff ;;
 477   esac
 478   formats="$formats $fmt"
 479   emfiles="$emfiles e-$file.o"
 480   EMULATIONS="$EMULATIONS &$em,"
 481 done
 482 GAS_UNIQ(formats)
 483 GAS_UNIQ(emfiles)
 484 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 485   for fmt in $formats ; do
 486     case $fmt in
 487       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 488       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 489       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 490       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 491       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 492       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 493       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 494       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 495       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 496       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 497     esac
 498     extra_objects="$extra_objects obj-$fmt.o"
 499   done
 500   obj_format=multi
 501 fi
 502 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 503   te_file=multi
 504   extra_objects="$extra_objects $emfiles"
 505   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 506   AC_DEFINE(USE_EMULATIONS)
 507 fi
 508 AC_SUBST(extra_objects)
 509 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 510 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 511
 512 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 513         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 514         config/te-${te_file}.h config/atof-${atof}.c \
 515         $extra_files"
 516 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 517         $extra_links"
 518
 519 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 520   yes-*-coff)   need_bfd=yes ;;
 521   no-*-coff)    need_bfd=yes
 522                 AC_DEFINE(MANY_SEGMENTS) ;;
 523 esac
 524
 525 reject_dev_configs=yes
 526
 527 case ${reject_dev_configs}-${dev} in
 528   yes-yes) # Oops.
 529     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 530     ;;
 531 esac
 532
 533 AC_SUBST(target_cpu_type)
 534 AC_SUBST(obj_format)
 535 AC_SUBST(atof)
 536 dnl AC_SUBST(emulation)
 537
 538 AC_LINK_FILES($files, $links)
 539
 540 case "${primary_bfd_gas}" in
 541   yes)  AC_DEFINE(BFD_ASSEMBLER)
 542         need_bfd=yes ;;
 543 esac
 544
 545 # do we need the opcodes library?
 546 case "${need_opcodes}" in
 547 yes)
 548   OPCODES_DEP=../opcodes/libopcodes.a
 549   OPCODES_LIB='-L../opcodes -lopcodes'
 550
 551   # We need to handle some special cases for shared libraries.
 552   case "${host}" in
 553   *-*-sunos*)
 554     # On SunOS, we must link against the name we are going to install,
 555     # not -lbfd, since SunOS does not support SONAME.
 556     if test "${shared_opcodes}" = "true"; then
 557       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 558     fi
 559     ;;
 560   alpha*-*-osf*)
 561     # On Alpha OSF/1, the native linker searches all the -L
 562     # directories for any LIB.so files, and only then searches for any
 563     # LIB.a files.  That means that if there is an installed
 564     # libbfd.so, but this build is not done with --enable-shared, the
 565     # link will wind up being against the install libbfd.so rather
 566     # than the newly built libbfd.  To avoid this, we must explicitly
 567     # link against libbfd.a when --enable-shared is not used.
 568     if test "${shared_opcodes}" != "true"; then
 569       OPCODES_LIB='../opcodes/libopcodes.a'
 570     fi
 571     ;;
 572   esac
 573   ;;
 574 esac
 575 AC_SUBST(OPCODES_DEP)
 576 AC_SUBST(OPCODES_LIB)
 577
 578 case "${need_bfd}" in
 579 yes)
 580   BFDDEP=../bfd/libbfd.a
 581   BFDLIB='-L../bfd -lbfd'
 582   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 583
 584   # We need to handle some special cases for shared libraries
 585   case "${host}" in
 586   *-*-sunos*)
 587     # On SunOS, we must link against the name we are going to install,
 588     # not -lbfd, since SunOS does not support SONAME.
 589     if test "${shared_bfd}" = "true"; then
 590       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 591     fi
 592     ;;
 593   alpha*-*-osf*)
 594     # On Alpha OSF/1, the native linker searches all the -L
 595     # directories for any LIB.so files, and only then searches for any
 596     # LIB.a files.  That means that if there is an installed
 597     # libbfd.so, but this build is not done with --enable-shared, the
 598     # link will wind up being against the install libbfd.so rather
 599     # than the newly built libbfd.  To avoid this, we must explicitly
 600     # link against libbfd.a when --enable-shared is not used.
 601     if test "${shared_bfd}" != "true"; then
 602       BFDLIB='../bfd/libbfd.a'
 603     fi
 604     ;;
 605   esac
 606   ;;
 607 esac
 608 AC_SUBST(BFDDEP)
 609 AC_SUBST(BFDLIB)
 610 AC_SUBST(ALL_OBJ_DEPS)
 611
 612 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 613 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 614 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 615 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 616 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 617
 618 AC_PROG_CC
 619 AC_PROG_INSTALL
 620
 621 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 622
 623 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 624 # people who are not cross-compiling but are compiling cross-assemblers.
 625 AC_MSG_CHECKING(whether compiling a cross-assembler)
 626 if test "${host}" = "${target}"; then
 627   cross_gas=no
 628 else
 629   cross_gas=yes
 630   AC_DEFINE(CROSS_COMPILE)
 631 fi
 632 AC_MSG_RESULT($cross_gas)
 633
 634 dnl ansidecl.h will deal with const
 635 dnl AC_CONST
 636 AC_FUNC_ALLOCA
 637 AC_C_INLINE
 638
 639 # VMS doesn't have unlink.
 640 AC_CHECK_FUNCS(unlink remove, break)
 641
 642 # Some systems don't have sbrk().
 643 AC_CHECK_FUNCS(sbrk)
 644
 645 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 646 # enough, but on some of those systems, the assert macro relies on requoting
 647 # working properly!
 648 GAS_WORKING_ASSERT
 649
 650 # On some systems, the system header files may not declare malloc, realloc,
 651 # and free.  There are places where gas needs these functions to have been
 652 # declared -- such as when taking their addresses.
 653 gas_test_headers="
 654 #ifdef HAVE_MEMORY_H
 655 #include <memory.h>
 656 #endif
 657 #ifdef HAVE_STRING_H
 658 #include <string.h>
 659 #endif
 660 #ifdef HAVE_STDLIB_H
 661 #include <stdlib.h>
 662 #endif
 663 #ifdef HAVE_UNISTD_H
 664 #include <unistd.h>
 665 #endif
 666 "
 667 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 668 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 669
 670 # Does errno.h declare errno, or do we have to add a separate declaration
 671 # for it?
 672 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 673 #ifdef HAVE_ERRNO_H
 674 #include <errno.h>
 675 #endif
 676 ])
 677
 678 HLDFLAGS=
 679 RPATH_ENVVAR=LD_LIBRARY_PATH
 680 # If we have shared libraries, try to set rpath reasonably.
 681 if test "${shared}" = "true"; then
 682   case "${host}" in
 683   *-*-hpux*)
 684     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 685     RPATH_ENVVAR=SHLIB_PATH
 686     ;;
 687   *-*-irix5* | *-*-irix6*)
 688     HLDFLAGS='-Wl,-rpath,$(libdir)'
 689     ;;
 690   *-*-linux*aout*)
 691     ;;
 692   *-*-linux*)
 693     HLDFLAGS='-Wl,-rpath,$(libdir)'
 694     ;;
 695   *-*-sysv4* | *-*-solaris*)
 696     HLDFLAGS='-R $(libdir)'
 697     ;;
 698   esac
 699 fi
 700
 701 # On SunOS, if the linker supports the -rpath option, use it to
 702 # prevent ../bfd and ../opcodes from being included in the run time
 703 # search path.
 704 case "${host}" in
 705   *-*-sunos*)
 706     echo 'main () { }' > conftest.c
 707     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 708     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 709       :
 710     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 711       :
 712     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 713       :
 714     elif test "${shared}" = "true"; then
 715       HLDFLAGS='-Wl,-rpath=$(libdir)'
 716     else
 717       HLDFLAGS='-Wl,-rpath='
 718     fi
 719     rm -f conftest.t conftest.c conftest
 720     ;;
 721 esac
 722 AC_SUBST(HLDFLAGS)
 723 AC_SUBST(RPATH_ENVVAR)
 724
 725 dnl This must come last.
 726 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)