gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 # Create sub-directories for objects and dependencies.
  48 CONFIG_SRC_SUBDIR="arch"
  49 AC_SUBST(CONFIG_SRC_SUBDIR)
  50
  51 AC_CONFIG_COMMANDS([gdbdepdir],[
  52   for subdir in ${CONFIG_SRC_SUBDIR}
  53   do
  54       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  55   done],
  56   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  57
  58 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  59
  60 gnulib_extra_configure_args=
  61 # If large-file support is disabled, make sure gnulib does the same.
  62 if test "$enable_largefile" = no; then
  63 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  64 fi
  65
  66 # Configure gnulib.  We need to build gnulib under some other
  67 # directory not "gnulib", to avoid the problem of both GDB and
  68 # GDBserver wanting to build it in the same directory, when building
  69 # in the source dir.
  70 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  71                   ["$gnulib_extra_configure_args"])
  72
  73 dnl List of object files and targets accumulated by configure.
  74
  75 CONFIG_OBS=
  76 CONFIG_DEPS=
  77 CONFIG_SRCS=
  78 ENABLE_CFLAGS=
  79
  80 CONFIG_ALL=
  81 CONFIG_CLEAN=
  82 CONFIG_INSTALL=
  83 CONFIG_UNINSTALL=
  84
  85 dnl Set up for gettext.
  86 ZW_GNU_GETTEXT_SISTER_DIR
  87
  88 localedir='${datadir}/locale'
  89 AC_SUBST(localedir)
  90
  91 if test x"$USE_NLS" = xyes; then
  92    CONFIG_ALL="$CONFIG_ALL all-po"
  93    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  94    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  95    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  96 fi
  97
  98 GNULIB=build-gnulib/import
  99
 100 # For Makefile dependencies.
 101 GNULIB_STDINT_H=
 102 if test x"$STDINT_H" != x; then
 103   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 104 fi
 105 AC_SUBST(GNULIB_STDINT_H)
 106
 107 PACKAGE=gdb
 108 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 109 AC_SUBST(PACKAGE)
 110
 111 # We never need to detect it in this sub-configure.
 112 # But preserve it for config.status --recheck.
 113 AC_ARG_VAR(MAKEINFO,
 114   [Parent configure detects if it is of sufficient version.])
 115 AC_ARG_VAR(MAKEINFOFLAGS,
 116   [Parameters for MAKEINFO.])
 117
 118 MAKEINFO_EXTRA_FLAGS=""
 119 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 120   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 121   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 122     gdb_cv_have_makeinfo_click=yes
 123   else
 124     gdb_cv_have_makeinfo_click=no
 125   fi])
 126 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 127   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 128 fi
 129 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 130
 131 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 132     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 133     [${libdir}/debug])
 134
 135 # We can't pass paths as command line arguments.
 136 # Mingw32 tries to be clever and will convert the paths for us.
 137 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 138 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 139 # This breaks GDB's relocatable path conversions since paths passed in
 140 # config.h would not get so translated, the path prefixes no longer match.
 141 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 142
 143 # GDB's datadir relocation
 144
 145 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 146     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 147     [${datadir}/gdb])
 148
 149 AC_ARG_WITH(relocated-sources,
 150 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 151 [reloc_srcdir="${withval}"
 152  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 153               [Relocated directory for source files. ])
 154 ])
 155
 156 AC_MSG_CHECKING([for default auto-load directory])
 157 AC_ARG_WITH(auto-load-dir,
 158 AS_HELP_STRING([--with-auto-load-dir=PATH],
 159   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 160   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 161 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 162 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 163               [Directories from which to load auto-loaded scripts.])
 164 AC_MSG_RESULT([$with_auto_load_dir])
 165
 166 AC_MSG_CHECKING([for default auto-load safe-path])
 167 AC_ARG_WITH(auto-load-safe-path,
 168 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 169   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 170 AS_HELP_STRING([--without-auto-load-safe-path],
 171                [do not restrict auto-loaded files locations]),
 172     [if test "$with_auto_load_safe_path" = "no"; then
 173      with_auto_load_safe_path="/"
 174      fi],
 175 [with_auto_load_safe_path="$with_auto_load_dir"])
 176 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 177 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 178               [Directories safe to hold auto-loaded files.])
 179 AC_MSG_RESULT([$with_auto_load_safe_path])
 180
 181 AC_CONFIG_SUBDIRS(testsuite)
 182
 183 # Check whether to support alternative target configurations
 184 AC_ARG_ENABLE(targets,
 185 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 186 [case "${enableval}" in
 187   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 188             ;;
 189   no)       enable_targets= ;;
 190   *)        enable_targets=$enableval ;;
 191 esac])
 192
 193 # Check whether to enable 64-bit support on 32-bit hosts
 194 AC_ARG_ENABLE(64-bit-bfd,
 195 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 196 [case "${enableval}" in
 197   yes)  want64=true  ;;
 198   no)   want64=false ;;
 199   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 200 esac],[want64=false])dnl
 201
 202 # Provide defaults for some variables set by the per-host and per-target
 203 # configuration.
 204 gdb_host_obs=posix-hdep.o
 205
 206 if test "${target}" = "${host}"; then
 207   gdb_native=yes
 208 else
 209   gdb_native=no
 210 fi
 211
 212 . $srcdir/configure.host
 213
 214 # Add in the common host objects.
 215 . $srcdir/common/common.host
 216 gdb_host_obs="$gdb_host_obs $common_host_obs"
 217
 218 # Accumulate some settings from configure.tgt over all enabled targets
 219
 220 TARGET_OBS=
 221 all_targets=
 222 HAVE_NATIVE_GCORE_TARGET=
 223
 224 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 225 do
 226   if test "$targ_alias" = "all"; then
 227     all_targets=true
 228   else
 229     # Canonicalize the secondary target names.
 230     result=`$ac_config_sub $targ_alias 2>/dev/null`
 231     if test -n "$result"; then
 232         targ=$result
 233     else
 234         targ=$targ_alias
 235     fi
 236
 237     . ${srcdir}/configure.tgt
 238
 239     AS_IF([test -z "${gdb_target_obs}"],
 240       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 241
 242     # Target-specific object files
 243     for i in ${gdb_target_obs}; do
 244         case " $TARGET_OBS " in
 245         *" ${i} "*) ;;
 246         *)
 247           TARGET_OBS="$TARGET_OBS ${i}"
 248           ;;
 249         esac
 250     done
 251
 252     # Check whether this target needs 64-bit CORE_ADDR
 253     if test x${want64} = xfalse; then
 254       . ${srcdir}/../bfd/config.bfd
 255     fi
 256
 257     # Check whether this target is native and supports gcore.
 258     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 259        && $gdb_have_gcore; then
 260       HAVE_NATIVE_GCORE_TARGET=1
 261     fi
 262   fi
 263 done
 264
 265 if test x${all_targets} = xtrue; then
 266
 267   # We want all 64-bit targets if we either:
 268   #  - run on a 64-bit host  or
 269   #  - already require 64-bit support for some other target  or
 270   #  - the --enable-64-bit-bfd option was supplied
 271   # Otherwise we only support all 32-bit targets.
 272   #
 273   # NOTE: This test must be in sync with the corresponding
 274   #       tests in BFD!
 275
 276   if test x${want64} = xfalse; then
 277     AC_CHECK_SIZEOF(long)
 278     if test "x${ac_cv_sizeof_long}" = "x8"; then
 279       want64=true
 280     fi
 281   fi
 282   if test x${want64} = xtrue; then
 283     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 284   else
 285     TARGET_OBS='$(ALL_TARGET_OBS)'
 286   fi
 287 fi
 288
 289 AC_SUBST(TARGET_OBS)
 290 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 291
 292 # For other settings, only the main target counts.
 293 gdb_sim=
 294 gdb_osabi=
 295 build_gdbserver=
 296 targ=$target; . ${srcdir}/configure.tgt
 297
 298 # Fetch the default architecture and default target vector from BFD.
 299 targ=$target; . $srcdir/../bfd/config.bfd
 300
 301 # We only want the first architecture, so strip off the others if
 302 # there is more than one.
 303 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 304
 305 if test "x$targ_archs" != x; then
 306   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 307     [Define to BFD's default architecture. ])
 308 fi
 309 if test "x$targ_defvec" != x; then
 310   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 311     [Define to BFD's default target vector. ])
 312 fi
 313
 314 # The CLI cannot be disabled yet, but may be in the future.
 315
 316 # Enable CLI.
 317 AC_ARG_ENABLE(gdbcli,
 318 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 319   [case $enableval in
 320     yes)
 321       ;;
 322     no)
 323       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 324     *)
 325       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 326   esac],
 327   [enable_gdbcli=yes])
 328 if test x"$enable_gdbcli" = xyes; then
 329   if test -d $srcdir/cli; then
 330     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 331     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 332     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 333     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 334   fi
 335 fi
 336
 337 # Enable MI.
 338 AC_ARG_ENABLE(gdbmi,
 339 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 340   [case $enableval in
 341     yes | no)
 342       ;;
 343     *)
 344       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 345   esac],
 346   [enable_gdbmi=yes])
 347 if test x"$enable_gdbmi" = xyes; then
 348   if test -d $srcdir/mi; then
 349     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 350     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 351     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 352     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 353   fi
 354 fi
 355
 356 # Enable TUI.
 357 AC_ARG_ENABLE(tui,
 358 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 359   [case $enableval in
 360     yes | no | auto)
 361       ;;
 362     *)
 363       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 364   esac],enable_tui=auto)
 365
 366 # Enable gdbtk.
 367 AC_ARG_ENABLE(gdbtk,
 368 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 369   [case $enableval in
 370     yes | no)
 371       ;;
 372     *)
 373       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 374   esac],
 375   [if test -d $srcdir/gdbtk; then
 376     enable_gdbtk=yes
 377   else
 378     enable_gdbtk=no
 379   fi])
 380 # We unconditionally disable gdbtk tests on selected platforms.
 381 case $host_os in
 382   go32* | windows*)
 383     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 384     enable_gdbtk=no ;;
 385 esac
 386
 387 # Libunwind support for ia64.
 388
 389 AC_ARG_WITH(libunwind-ia64,
 390 AS_HELP_STRING([--with-libunwind-ia64],
 391                [use libunwind frame unwinding for ia64 targets]),,
 392             [with_libunwind_ia64=auto])
 393
 394 # Backward compatibility option.
 395 if test "${with_libunwind+set}" = set; then
 396   if test x"$with_libunwind_ia64" != xauto; then
 397     AC_MSG_ERROR(
 398       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 399   fi
 400   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 401   with_libunwind_ia64="$with_libunwind"
 402 fi
 403
 404 case "$with_libunwind_ia64" in
 405   yes | no)
 406     ;;
 407   auto)
 408     AC_CHECK_HEADERS(libunwind-ia64.h)
 409     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 410     ;;
 411   *)
 412     AC_MSG_ERROR(
 413       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 414     ;;
 415 esac
 416
 417 if test x"$with_libunwind_ia64" = xyes; then
 418   AC_CHECK_HEADERS(libunwind-ia64.h)
 419   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 420     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 421   fi
 422   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 423   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 424   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 425 fi
 426
 427 opt_curses=no
 428 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 429
 430 prefer_curses=no
 431 if test "$opt_curses" = "yes"; then
 432   prefer_curses=yes
 433 fi
 434
 435 # Profiling support.
 436 AC_ARG_ENABLE(profiling,
 437 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 438   [case $enableval in
 439     yes | no)
 440       ;;
 441     *)
 442       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 443   esac],
 444  [enable_profiling=no])
 445
 446 AC_CHECK_FUNCS(monstartup _mcleanup)
 447 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 448 [AC_TRY_LINK(
 449 [#include <stdlib.h>
 450 extern char _etext;
 451 ],
 452 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 453 if test $ac_cv_var__etext = yes; then
 454   AC_DEFINE(HAVE__ETEXT, 1,
 455             [Define to 1 if your system has the _etext variable. ])
 456 fi
 457 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 458 [AC_TRY_LINK(
 459 [#include <stdlib.h>
 460 extern char etext;
 461 ],
 462 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 463 if test $ac_cv_var_etext = yes; then
 464   AC_DEFINE(HAVE_ETEXT, 1,
 465             [Define to 1 if your system has the etext variable. ])
 466 fi
 467 if test "$enable_profiling" = yes ; then
 468   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 469     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 470   fi
 471   PROFILE_CFLAGS=-pg
 472   OLD_CFLAGS="$CFLAGS"
 473   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 474
 475   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 476     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 477      ac_cv_cc_supports_pg=no)])
 478
 479   if test $ac_cv_cc_supports_pg = no; then
 480     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 481   fi
 482
 483   CFLAGS="$OLD_CFLAGS"
 484 fi
 485
 486 ACX_PKGVERSION([GDB])
 487 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 488 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 489 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 490
 491 # --------------------- #
 492 # Checks for programs.  #
 493 # --------------------- #
 494
 495 AC_PROG_AWK
 496 AC_PROG_INSTALL
 497 AC_PROG_LN_S
 498 AC_PROG_RANLIB
 499 AC_PROG_YACC
 500
 501 AC_CHECK_TOOL(AR, ar)
 502 AC_CHECK_TOOL(DLLTOOL, dlltool)
 503 AC_CHECK_TOOL(WINDRES, windres)
 504
 505 case $host_os in
 506   gnu*)
 507     # Needed for GNU Hurd hosts.
 508     AC_CHECK_TOOL(MIG, mig)
 509     if test x"$MIG" = x; then
 510       AC_MSG_ERROR([MIG not found but required for $host hosts])
 511     fi
 512     ;;
 513 esac
 514
 515 # ---------------------- #
 516 # Checks for libraries.  #
 517 # ---------------------- #
 518
 519 # We might need to link with -lm; most simulators need it.
 520 AC_CHECK_LIB(m, main)
 521
 522 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 523 AC_SEARCH_LIBS(gethostbyname, nsl)
 524
 525 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 526 AC_SEARCH_LIBS(socketpair, socket)
 527
 528 # Link in zlib if we can.  This allows us to read compressed debug sections.
 529 AM_ZLIB
 530
 531 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 532 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 533 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 534   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 535             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 536
 537 AM_ICONV
 538
 539 # GDB may fork/exec the iconv program to get the list of supported character
 540 # sets.  Allow the user to specify where to find it.
 541 # There are several factors affecting the choice of option name:
 542 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 543 #   the build-time location of libiconv files.
 544 # - The program we need to find is iconv, which comes with glibc.  The user
 545 #   doesn't necessarily have libiconv installed.  Therefore naming this
 546 #   --with-libiconv-foo feels wrong.
 547 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 548 #   defined to work on directories not files (though it really doesn't know
 549 #   the difference).
 550 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 551 #   with --with-libiconv-prefix.
 552 # Putting these together is why the option name is --with-iconv-bin.
 553
 554 AC_ARG_WITH(iconv-bin,
 555 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 556 [iconv_bin="${withval}"
 557  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 558                     [Path of directory of iconv program.])
 559  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 560 ])
 561
 562 # For the TUI, we need enhanced curses functionality.
 563 if test x"$enable_tui" != xno; then
 564   prefer_curses=yes
 565 fi
 566
 567 curses_found=no
 568 if test x"$prefer_curses" = xyes; then
 569   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 570   # curses library because the latter might not provide all the
 571   # functionality we need.  However, this leads to problems on systems
 572   # where the linker searches /usr/local/lib, but the compiler doesn't
 573   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 574   # default installation of ncurses on alpha*-dec-osf* will lead to such
 575   # a situation.
 576   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 577
 578   if test "$ac_cv_search_waddstr" != no; then
 579     curses_found=yes
 580   fi
 581 fi
 582
 583 # Check whether we should enable the TUI, but only do so if we really
 584 # can.
 585 if test x"$enable_tui" != xno; then
 586   if test -d $srcdir/tui; then
 587     if test "$curses_found" != no; then
 588       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 589       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 590       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 591       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 592     else
 593       if test x"$enable_tui" = xyes; then
 594         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 595       else
 596         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 597       fi
 598     fi
 599   fi
 600 fi
 601
 602 # Since GDB uses Readline, we need termcap functionality.  In many
 603 # cases this will be provided by the curses library, but some systems
 604 # have a separate termcap library, or no curses library at all.
 605
 606 case $host_os in
 607   cygwin*)
 608     if test -d $srcdir/libtermcap; then
 609       LIBS="../libtermcap/libtermcap.a $LIBS"
 610       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 611     fi ;;
 612   go32* | *djgpp*)
 613     ac_cv_search_tgetent="none required"
 614     ;;
 615 esac
 616
 617 # These are the libraries checked by Readline.
 618 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncursesw ncurses])
 619
 620 if test "$ac_cv_search_tgetent" = no; then
 621   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 622 fi
 623
 624 AC_ARG_WITH([system-readline],
 625   [AS_HELP_STRING([--with-system-readline],
 626                   [use installed readline library])])
 627
 628 if test "$with_system_readline" = yes; then
 629   READLINE=-lreadline
 630   READLINE_DEPS=
 631   READLINE_CFLAGS=
 632   READLINE_TEXI_INCFLAG=
 633 else
 634   READLINE='$(READLINE_DIR)/libreadline.a'
 635   READLINE_DEPS='$(READLINE)'
 636   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 637   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 638 fi
 639 AC_SUBST(READLINE)
 640 AC_SUBST(READLINE_DEPS)
 641 AC_SUBST(READLINE_CFLAGS)
 642 AC_SUBST(READLINE_TEXI_INCFLAG)
 643
 644 # Generate jit-reader.h
 645
 646 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 647 TARGET_PTR=
 648
 649 AC_CHECK_SIZEOF(unsigned long long)
 650 AC_CHECK_SIZEOF(unsigned long)
 651 AC_CHECK_SIZEOF(unsigned __int128)
 652
 653 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 654   TARGET_PTR="unsigned long"
 655 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 656   TARGET_PTR="unsigned long long"
 657 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 658   TARGET_PTR="unsigned __int128"
 659 else
 660   TARGET_PTR="unsigned long"
 661 fi
 662
 663 AC_SUBST(TARGET_PTR)
 664 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 665
 666 AC_SEARCH_LIBS(dlopen, dl)
 667
 668 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 669                 [directory to load the JIT readers from],
 670                 [${libdir}/gdb])
 671
 672 AC_ARG_WITH(expat,
 673   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 674   [], [with_expat=auto])
 675 AC_MSG_CHECKING([whether to use expat])
 676 AC_MSG_RESULT([$with_expat])
 677
 678 if test "${with_expat}" = no; then
 679   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 680   HAVE_LIBEXPAT=no
 681 else
 682   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 683                         [XML_Parser p = XML_ParserCreate (0);])
 684   if test "$HAVE_LIBEXPAT" != yes; then
 685     if test "$with_expat" = yes; then
 686       AC_MSG_ERROR([expat is missing or unusable])
 687     else
 688       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 689     fi
 690   else
 691     save_LIBS=$LIBS
 692     LIBS="$LIBS $LIBEXPAT"
 693     AC_CHECK_FUNCS(XML_StopParser)
 694     LIBS=$save_LIBS
 695   fi
 696 fi
 697
 698 AC_ARG_WITH(mpfr,
 699   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 700   [], [with_mpfr=auto])
 701 AC_MSG_CHECKING([whether to use MPFR])
 702 AC_MSG_RESULT([$with_mpfr])
 703
 704 if test "${with_mpfr}" = no; then
 705   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 706   HAVE_LIBMPFR=no
 707 else
 708   AC_LIB_HAVE_LINKFLAGS([mpfr], [], [#include <mpfr.h>],
 709                         [mpfr_exp_t exp; mpfr_t x;
 710                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 711   if test "$HAVE_LIBMPFR" != yes; then
 712     if test "$with_mpfr" = yes; then
 713       AC_MSG_ERROR([MPFR is missing or unusable])
 714     else
 715       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 716     fi
 717   fi
 718 fi
 719
 720 # --------------------- #
 721 # Check for libpython.  #
 722 # --------------------- #
 723
 724 dnl Utility to simplify finding libpython.
 725 dnl $1 = pythonX.Y
 726 dnl $2 = the shell variable to assign the result to
 727 dnl      If libpython is found we store $version here.
 728 dnl $3 = additional flags to add to CPPFLAGS
 729 dnl $4 = additional flags to add to LIBS
 730
 731 AC_DEFUN([AC_TRY_LIBPYTHON],
 732 [
 733   version=$1
 734   define([have_libpython_var],$2)
 735   new_CPPFLAGS=$3
 736   new_LIBS=$4
 737   AC_MSG_CHECKING([for ${version}])
 738   save_CPPFLAGS=$CPPFLAGS
 739   save_LIBS=$LIBS
 740   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 741   LIBS="$LIBS $new_LIBS"
 742   found_usable_python=no
 743   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 744                                  [[Py_Initialize ();]]),
 745                  [have_libpython_var=${version}
 746                   found_usable_python=yes
 747                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 748                   PYTHON_LIBS=$new_LIBS])
 749   CPPFLAGS=$save_CPPFLAGS
 750   LIBS=$save_LIBS
 751   AC_MSG_RESULT([${found_usable_python}])
 752 ])
 753
 754 dnl There are several different values for --with-python:
 755 dnl
 756 dnl no -   Don't include python support.
 757 dnl yes -  Include python support, error if it's missing.
 758 dnl        If we find python in $PATH, use it to fetch configure options,
 759 dnl        otherwise assume the compiler can find it with no help from us.
 760 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 761 dnl auto - Same as "yes", but if python is missing from the system,
 762 dnl        fall back to "no".
 763 dnl /path/to/python/exec-prefix -
 764 dnl        Use the python located in this directory.
 765 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 766 dnl        the compilation parameters.  Otherwise use
 767 dnl        -I/path/to/python/exec-prefix/include,
 768 dnl        -L/path/to/python/exec-prefix/lib.
 769 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 770 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 771 dnl        but is deprecated.
 772 dnl /path/to/python/executable -
 773 dnl        Run python-config.py with this version of python to fetch the
 774 dnl        compilation parameters.
 775 dnl        NOTE: This needn't be the real python executable.
 776 dnl        In a cross-compilation scenario (build != host), this could be
 777 dnl        a shell script that provides what python-config.py provides for
 778 dnl        --ldflags, --includes, --exec-prefix.
 779 dnl python-executable -
 780 dnl        Find python-executable in $PATH, and then handle the same as
 781 dnl        /path/to/python/executable.
 782 dnl
 783 dnl If a python program is specified, it is used to run python-config.py and
 784 dnl is passed --ldflags, --includes, --exec-prefix.
 785
 786 AC_ARG_WITH(python,
 787   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 788   [], [with_python=auto])
 789 AC_MSG_CHECKING([whether to use python])
 790 AC_MSG_RESULT([$with_python])
 791
 792 if test "${with_python}" = no; then
 793   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 794   have_libpython=no
 795 else
 796   case "${with_python}" in
 797   [[\\/]]* | ?:[[\\/]]*)
 798     if test -d ${with_python}; then
 799       # Assume the python binary is ${with_python}/bin/python.
 800       python_prog="${with_python}/bin/python"
 801       python_prefix=
 802       # If python does not exit ${with_python}/bin, then try in
 803       # ${with_python}.  On Windows/MinGW, this is where the Python
 804       # executable is.
 805       if test ! -x "${python_prog}"; then
 806         python_prog="${with_python}/python"
 807         python_prefix=
 808       fi
 809       if test ! -x "${python_prog}"; then
 810         # Fall back to gdb 7.0/7.1 behaviour.
 811         python_prog=missing
 812         python_prefix=${with_python}
 813       fi
 814     elif test -x "${with_python}"; then
 815       # While we can't run python compiled for $host (unless host == build),
 816       # the user could write a script that provides the needed information,
 817       # so we support that.
 818       python_prog=${with_python}
 819       python_prefix=
 820     else
 821       AC_ERROR(invalid value for --with-python)
 822     fi
 823     ;;
 824   */*)
 825     # Disallow --with-python=foo/bar.
 826     AC_ERROR(invalid value for --with-python)
 827     ;;
 828   *)
 829     # The user has either specified auto, yes, or the name of the python
 830     # program assumed to be in $PATH.
 831     python_prefix=
 832     case "${with_python}" in
 833     yes | auto)
 834       if test ${build} = ${host}; then
 835         AC_PATH_PROG(python_prog_path, python, missing)
 836         if test "${python_prog_path}" = missing; then
 837           python_prog=missing
 838         else
 839           python_prog=${python_prog_path}
 840         fi
 841       else
 842         # Not much we can do except assume the cross-compiler will find the
 843         # right files.
 844         python_prog=missing
 845       fi
 846       ;;
 847     *)
 848       # While we can't run python compiled for $host (unless host == build),
 849       # the user could write a script that provides the needed information,
 850       # so we support that.
 851       python_prog="${with_python}"
 852       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 853       if test "${python_prog_path}" = missing; then
 854         AC_ERROR(unable to find python program ${python_prog})
 855       fi
 856       ;;
 857     esac
 858   esac
 859
 860   if test "${python_prog}" != missing; then
 861     # We have a python program to use, but it may be too old.
 862     # Don't flag an error for --with-python=auto (the default).
 863     have_python_config=yes
 864     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 865     if test $? != 0; then
 866       have_python_config=failed
 867       if test "${with_python}" != auto; then
 868         AC_ERROR(failure running python-config --includes)
 869       fi
 870     fi
 871     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 872     if test $? != 0; then
 873       have_python_config=failed
 874       if test "${with_python}" != auto; then
 875         AC_ERROR(failure running python-config --ldflags)
 876       fi
 877     fi
 878     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 879     if test $? != 0; then
 880       have_python_config=failed
 881       if test "${with_python}" != auto; then
 882         AC_ERROR(failure running python-config --exec-prefix)
 883       fi
 884     fi
 885   else
 886     # We do not have a python executable we can use to determine where
 887     # to find the Python headers and libs.  We cannot guess the include
 888     # path from the python_prefix either, because that include path
 889     # depends on the Python version.  So, there is nothing much we can
 890     # do except assume that the compiler will be able to find those files.
 891     python_includes=
 892     python_libs=
 893     have_python_config=no
 894   fi
 895
 896   # If we have python-config, only try the configuration it provides.
 897   # Otherwise fallback on the old way of trying different versions of
 898   # python in turn.
 899
 900   have_libpython=no
 901   if test "${have_python_config}" = yes; then
 902     # Determine the Python version by extracting "-lpython<version>"
 903     # part of the python_libs. <version> is usually X.Y with X and Y
 904     # being decimal numbers, but can also be XY (seen on Windows).
 905     #
 906     # The extraction is performed using sed with a regular expression.
 907     # Initially, the regexp used was using the '?' quantifier to make
 908     # the dot in the version number optional.  Unfortunately, this
 909     # does not work with non-GNU versions of sed because, because of
 910     # what looks like a limitation (the '?' quantifier does not work
 911     # with back-references).  We work around this limitation by using
 912     # the '*' quantifier instead.  It means that, in theory, we might
 913     # match unexpected version strings such as "-lpython2..7", but
 914     # this seems unlikely in practice.  And even if that happens,
 915     # an error will be triggered later on, when checking that version
 916     # number.
 917     python_version=`echo " ${python_libs} " \
 918                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 919     case "${python_version}" in
 920     python*)
 921       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 922                        ${python_includes}, ${python_libs})
 923       ;;
 924     *)
 925       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 926       ;;
 927     esac
 928   elif test "${have_python_config}" != failed; then
 929     if test "${have_libpython}" = no; then
 930       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 931                        ${python_includes}, "${python_libs} -lpython2.7")
 932     fi
 933     if test "${have_libpython}" = no; then
 934       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 935                        ${python_includes}, "${python_libs} -lpython2.6")
 936     fi
 937     if test ${have_libpython} = no; then
 938       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 939                        ${python_includes}, "${python_libs} -lpython2.5")
 940     fi
 941     if test ${have_libpython} = no; then
 942       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 943                        ${python_includes}, "${python_libs} -lpython2.4")
 944     fi
 945   fi
 946   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 947     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 948   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 949     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 950   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 951     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 952   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 953     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 954   fi
 955
 956   if test "${have_libpython}" = no; then
 957     case "${with_python}" in
 958     yes)
 959       AC_MSG_ERROR([python is missing or unusable])
 960       ;;
 961     auto)
 962       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 963       ;;
 964     *)
 965       AC_MSG_ERROR([no usable python found at ${with_python}])
 966       ;;
 967     esac
 968   else
 969     if test -n "${python_prefix}"; then
 970       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 971                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 972       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 973     fi
 974   fi
 975 fi
 976
 977 if test "${have_libpython}" != no; then
 978   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 979   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 980   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 981   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 982   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 983   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 984
 985   # Flags needed to compile Python code (taken from python-config --cflags).
 986   # We cannot call python-config directly because it will output whatever was
 987   # used when compiling the Python interpreter itself, including flags which
 988   # would make the python-related objects be compiled differently from the
 989   # rest of GDB (e.g., -O2 and -fPIC).
 990   if test "${GCC}" = yes; then
 991     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 992   fi
 993
 994   if test "x${tentative_python_cflags}" != x; then
 995     AC_MSG_CHECKING(compiler flags for python code)
 996     for flag in ${tentative_python_cflags}; do
 997       # Check that the compiler accepts it
 998       saved_CFLAGS="$CFLAGS"
 999       CFLAGS="$CFLAGS $flag"
1000       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
1001       CFLAGS="$saved_CFLAGS"
1002     done
1003     AC_MSG_RESULT(${PYTHON_CFLAGS})
1004   fi
1005
1006   # On x64 Windows, Python's include headers, and pyconfig.h in
1007   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1008   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1009   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1010   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1011   # The issue was reported to the Python community, but still isn't
1012   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1013
1014   case "$gdb_host" in
1015     mingw64)
1016            if test "${GCC}" = yes; then
1017              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1018            fi
1019            ;;
1020   esac
1021
1022   # Note that "python -m threading" cannot be used to check for
1023   # threading support due to a bug in Python 2.7.3
1024   # (http://bugs.python.org/issue15567).
1025   AC_MSG_CHECKING(whether python supports threads)
1026   saved_CPPFLAGS="${CPPFLAGS}"
1027   CPPFLAGS="${PYTHON_CPPFLAGS}"
1028   # Note that the test is reversed so that python_has_threads=yes on
1029   # unexpected failures.
1030   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1031 #include <Python.h>
1032 #ifdef WITH_THREAD
1033 # error
1034 #endif
1035   ]]), [python_has_threads=no], [python_has_threads=yes])
1036   AC_MSG_RESULT(${python_has_threads})
1037   CPPFLAGS="${saved_CPPFLAGS}"
1038 else
1039   # Even if Python support is not compiled in, we need to have this file
1040   # included so that the "python" command, et.al., still exists.
1041   CONFIG_OBS="$CONFIG_OBS python.o"
1042   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1043 fi
1044
1045 # Work around Python http://bugs.python.org/issue10112.  See also
1046 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1047 # no effect.  Note that the only test after this that uses Python is
1048 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1049 # run without -export-dynamic too.
1050 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1051
1052 AC_SUBST(PYTHON_CFLAGS)
1053 AC_SUBST(PYTHON_CPPFLAGS)
1054 AC_SUBST(PYTHON_LIBS)
1055 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1056
1057 # -------------------- #
1058 # Check for libguile.  #
1059 # -------------------- #
1060
1061 dnl Utility to simplify finding libguile.
1062 dnl $1 = pkg-config-program
1063 dnl $2 = space-separate list of guile versions to try
1064 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1065 dnl $4 = the shell variable to assign the result to
1066 dnl      If libguile is found we store "yes" here.
1067
1068 AC_DEFUN([AC_TRY_LIBGUILE],
1069 [
1070   pkg_config=$1
1071   guile_version_list=$2
1072   flag_errors=$3
1073   define([have_libguile_var],$4)
1074   found_usable_guile=checking
1075   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1076   for guile_version in ${guile_version_list}; do
1077     ${pkg_config} --exists ${guile_version} 2>/dev/null
1078     if test $? != 0; then
1079       continue
1080     fi
1081     dnl pkg-config says the package exists, so if we get an error now,
1082     dnl that's bad.
1083     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1084     if test $? != 0; then
1085       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1086     fi
1087     new_LIBS=`${pkg_config} --libs ${guile_version}`
1088     if test $? != 0; then
1089       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1090     fi
1091     dnl If we get this far, great.
1092     found_usable_guile=${guile_version}
1093     break
1094   done
1095   if test "${found_usable_guile}" = "checking"; then
1096     if test "${flag_errors}" = "yes"; then
1097       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1098     else
1099       found_usable_guile=no
1100     fi
1101   fi
1102   dnl One final sanity check.
1103   dnl The user could have said --with-guile=python-2.7.
1104   if test "${found_usable_guile}" != no; then
1105     save_CPPFLAGS=$CPPFLAGS
1106     save_LIBS=$LIBS
1107     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1108     LIBS="$LIBS $new_LIBS"
1109     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1110                                    [[scm_init_guile ();]]),
1111                    [have_libguile_var=yes
1112                     GUILE_CPPFLAGS=$new_CPPFLAGS
1113                     GUILE_LIBS=$new_LIBS],
1114                    [found_usable_guile=no])
1115     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1116     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1117       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1118                 [Define if Guile supports manual finalization.])
1119     )
1120     CPPFLAGS=$save_CPPFLAGS
1121     LIBS=$save_LIBS
1122     if test "${found_usable_guile}" = no; then
1123       if test "${flag_errors}" = yes; then
1124         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1125       fi
1126     fi
1127   fi
1128   AC_MSG_RESULT([${found_usable_guile}])
1129 ])
1130
1131 dnl There are several different values for --with-guile:
1132 dnl
1133 dnl no -   Don't include guile support.
1134 dnl yes -  Include guile support, error if it's missing.
1135 dnl        The pkg-config program must be in $PATH.
1136 dnl auto - Same as "yes", but if guile is missing from the system,
1137 dnl        fall back to "no".
1138 dnl guile-version [guile-version-choice-2 ...] -
1139 dnl        A space-separated list of guile package versions to try.
1140 dnl        These are passed to pkg-config as-is.
1141 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1142 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1143 dnl /path/to/pkg-config -
1144 dnl        Use this pkg-config program.
1145 dnl        NOTE: This needn't be the "real" pkg-config program.
1146 dnl        It could be a shell script.  It is invoked as:
1147 dnl        pkg-config --exists $version
1148 dnl        pkg-config --cflags $version
1149 dnl        pkg-config --libs $version
1150 dnl        pkg-config --variable guild $version
1151 dnl        The script will be called with $version having each value in
1152 dnl        $try_guile_versions until --exists indicates success.
1153
1154 AC_ARG_WITH(guile,
1155   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1156   [], [with_guile=auto])
1157 AC_MSG_CHECKING([whether to use guile])
1158 AC_MSG_RESULT([$with_guile])
1159
1160 dnl We check guile with pkg-config.
1161 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1162
1163 try_guile_versions="guile-2.0"
1164 have_libguile=no
1165 case "${with_guile}" in
1166 no)
1167   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1168   ;;
1169 auto)
1170   if test "${pkg_config_prog_path}" = "missing"; then
1171     AC_MSG_WARN([pkg-config not found, guile support disabled])
1172   else
1173     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1174   fi
1175   ;;
1176 yes)
1177   if test "${pkg_config_prog_path}" = "missing"; then
1178     AC_MSG_ERROR([pkg-config not found])
1179   fi
1180   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1181   ;;
1182 [[\\/]]* | ?:[[\\/]]*)
1183   if test -x "${with_guile}"; then
1184     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1185   else
1186     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1187   fi
1188   ;;
1189 "" | */*)
1190   # Disallow --with=guile="" and --with-guile=foo/bar.
1191   AC_MSG_ERROR([invalid value for --with-guile])
1192   ;;
1193 *)
1194   # A space separate list of guile versions to try, in order.
1195   if test "${pkg_config_prog_path}" = "missing"; then
1196     AC_MSG_ERROR([pkg-config not found])
1197   fi
1198   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1199   ;;
1200 esac
1201
1202 if test "${have_libguile}" != no; then
1203   dnl Get the name of the 'guild' program.
1204   case "${with_guile}" in
1205   [[\\/]]* | ?:[[\\/]]*)
1206     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1207     ;;
1208   *)
1209     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1210     ;;
1211   esac
1212
1213   dnl Make sure guild can handle this host.
1214   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1215   dnl If not, disable guile support.
1216   if test "$ac_cv_guild_ok" = no; then
1217     have_libguile=no
1218     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1219   fi
1220 fi
1221
1222 if test "${have_libguile}" != no; then
1223   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1224   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1225   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1226   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1227   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1228   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1229
1230   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1231   save_LIBS="$LIBS"
1232   save_CPPFLAGS="$CPPFLAGS"
1233   LIBS="$GUILE_LIBS"
1234   CPPFLAGS="$GUILE_CPPFLAGS"
1235   AC_CHECK_FUNCS([scm_new_smob])
1236   LIBS="$save_LIBS"
1237   CPPFLAGS="$save_CPPFLAGS"
1238 else
1239   # Even if Guile support is not compiled in, we need to have these files
1240   # included.
1241   CONFIG_OBS="$CONFIG_OBS guile.o"
1242   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1243 fi
1244 AC_SUBST(GUILE_CPPFLAGS)
1245 AC_SUBST(GUILE_LIBS)
1246 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1247
1248 # --------------------- #
1249 # Check for libmcheck.  #
1250 # --------------------- #
1251
1252 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1253 # but turn it off if Python is enabled with threads, since -lmcheck is
1254 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1255 # and for releases.
1256 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1257    && $development; then
1258   libmcheck_default=yes
1259 else
1260   libmcheck_default=no
1261 fi
1262 GDB_AC_LIBMCHECK(${libmcheck_default})
1263
1264 if test "$ENABLE_LIBMCHECK" = "yes" \
1265         -a "${have_libpython}" != "no" \
1266         -a "${python_has_threads}" = "yes" ; then
1267   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1268 fi
1269
1270 AC_ARG_WITH(intel_pt,
1271   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1272   [], [with_intel_pt=auto])
1273 AC_MSG_CHECKING([whether to use intel pt])
1274 AC_MSG_RESULT([$with_intel_pt])
1275
1276 if test "${with_intel_pt}" = no; then
1277   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1278   HAVE_LIBIPT=no
1279 else
1280   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1281 #include <linux/perf_event.h>
1282 #ifndef PERF_ATTR_SIZE_VER5
1283 # error
1284 #endif
1285   ]]), [perf_event=yes], [perf_event=no])
1286   if test "$perf_event" != yes; then
1287     if test "$with_intel_pt" = yes; then
1288       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1289     else
1290       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1291     fi
1292   fi
1293
1294   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1295   if test "$HAVE_LIBIPT" != yes; then
1296     if test "$with_intel_pt" = yes; then
1297       AC_MSG_ERROR([libipt is missing or unusable])
1298     else
1299       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1300     fi
1301   else
1302     save_LIBS=$LIBS
1303     LIBS="$LIBS $LIBIPT"
1304     AC_CHECK_FUNCS(pt_insn_event)
1305     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1306                      [#include <intel-pt.h>])
1307     LIBS=$save_LIBS
1308   fi
1309 fi
1310
1311 # ------------------------- #
1312 # Checks for header files.  #
1313 # ------------------------- #
1314
1315 AC_HEADER_STDC
1316 # elf_hp.h is for HP/UX 64-bit shared library support.
1317 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1318                   thread_db.h \
1319                   sys/fault.h \
1320                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1321                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1322                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1323                   termios.h elf_hp.h \
1324                   dlfcn.h])
1325 AC_CHECK_HEADERS(sys/proc.h, [], [],
1326 [#if HAVE_SYS_PARAM_H
1327 # include <sys/param.h>
1328 #endif
1329 ])
1330 AC_CHECK_HEADERS(sys/user.h, [], [],
1331 [#if HAVE_SYS_PARAM_H
1332 # include <sys/param.h>
1333 #endif
1334 ])
1335
1336 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1337 AC_CHECK_HEADERS(term.h, [], [],
1338 [#if HAVE_CURSES_H
1339 # include <curses.h>
1340 #endif
1341 ])
1342
1343 # ------------------------- #
1344 # Checks for declarations.  #
1345 # ------------------------- #
1346
1347 libiberty_INIT
1348
1349 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1350 AM_LC_MESSAGES
1351
1352 # ----------------------- #
1353 # Checks for structures.  #
1354 # ----------------------- #
1355
1356 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1357
1358 # ------------------ #
1359 # Checks for types.  #
1360 # ------------------ #
1361
1362 AC_CHECK_TYPES(socklen_t, [], [],
1363 [#include <sys/types.h>
1364 #include <sys/socket.h>
1365 ])
1366
1367 # ------------------------------------- #
1368 # Checks for compiler characteristics.  #
1369 # ------------------------------------- #
1370
1371 AC_C_CONST
1372 AC_C_INLINE
1373 AC_C_BIGENDIAN
1374
1375 # ------------------------------ #
1376 # Checks for library functions.  #
1377 # ------------------------------ #
1378
1379 AC_FUNC_MMAP
1380 AC_FUNC_VFORK
1381 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1382                 pipe poll pread pread64 pwrite resize_term \
1383                 sbrk setpgid setpgrp setsid \
1384                 sigaction sigprocmask sigsetmask socketpair \
1385                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1386                 setrlimit getrlimit posix_madvise waitpid \
1387                 ptrace64 sigaltstack mkdtemp setns])
1388 AM_LANGINFO_CODESET
1389 GDB_AC_COMMON
1390
1391 # Check the return and argument types of ptrace.
1392 GDB_AC_PTRACE
1393
1394 dnl AC_FUNC_SETPGRP does not work when cross compiling
1395 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1396 if test "$cross_compiling" = no; then
1397   AC_FUNC_SETPGRP
1398 else
1399   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1400     [AC_TRY_COMPILE([
1401 #include <unistd.h>
1402 ], [
1403   if (setpgrp(1,1) == -1)
1404     exit (0);
1405   else
1406     exit (1);
1407 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1408 if test $ac_cv_func_setpgrp_void = yes; then
1409   AC_DEFINE(SETPGRP_VOID, 1)
1410 fi
1411 fi
1412
1413 # Assume we'll default to using the included libiberty regex.
1414 gdb_use_included_regex=yes
1415
1416 # However, if the system regex is GNU regex, then default to *not*
1417 # using the included regex.
1418 AC_CACHE_CHECK(
1419   [for GNU regex],
1420   [gdb_cv_have_gnu_regex],
1421   [AC_TRY_COMPILE(
1422     [#include <gnu-versions.h>],
1423     [#define REGEX_INTERFACE_VERSION 1
1424 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1425 # error "Version mismatch"
1426 #endif],
1427     gdb_cv_have_gnu_regex=yes,
1428     gdb_cv_have_gnu_regex=no)])
1429 if test $gdb_cv_have_gnu_regex = yes; then
1430   gdb_use_included_regex=no
1431 fi
1432
1433 AC_ARG_WITH(included-regex,
1434   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1435   gdb_with_regex=$withval,
1436   gdb_with_regex=$gdb_use_included_regex)
1437 if test "$gdb_with_regex" = yes; then
1438   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1439     [Define to 1 if the regex included in libiberty should be used.])
1440 fi
1441
1442 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1443 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1444 [#include <sys/param.h>
1445 #include <sys/proc.h>
1446 ])
1447
1448 # See if <sys/lwp.h> defines `struct lwp`.
1449 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1450 [AC_TRY_COMPILE([#include <sys/param.h>
1451 #define _KMEMUSER
1452 #include <sys/lwp.h>], [struct lwp l;],
1453 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1454 if test $gdb_cv_struct_lwp = yes; then
1455   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1456             [Define to 1 if your system has struct lwp.])
1457 fi
1458
1459 # See if <machine/reg.h> degines `struct reg'.
1460 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1461 [AC_TRY_COMPILE([#include <sys/types.h>
1462 #include <machine/reg.h>], [struct reg r;],
1463 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1464 if test $gdb_cv_struct_reg = yes; then
1465   AC_DEFINE(HAVE_STRUCT_REG, 1,
1466             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1467 fi
1468
1469 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1470 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1471 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1472                  [#include <sys/types.h>
1473 #include <machine/reg.h>])
1474
1475 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1476 # Older amd64 Linux's don't have the fs_base and gs_base members of
1477 # `struct user_regs_struct'.
1478 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1479                  [], [], [#include <sys/user.h>])
1480
1481 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1482 AC_MSG_CHECKING(for PTRACE_GETREGS)
1483 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1484 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1485                 [PTRACE_GETREGS;],
1486                 [gdb_cv_have_ptrace_getregs=yes],
1487                 [gdb_cv_have_ptrace_getregs=no])])
1488 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1489 if test $gdb_cv_have_ptrace_getregs = yes; then
1490   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1491   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1492 fi
1493
1494 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1495 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1496 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1497 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1498                 [PTRACE_GETFPXREGS;],
1499                 [gdb_cv_have_ptrace_getfpxregs=yes],
1500                 [gdb_cv_have_ptrace_getfpxregs=no])])
1501 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1502 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1503   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1504   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1505 fi
1506
1507 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1508 AC_MSG_CHECKING(for PT_GETDBREGS)
1509 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1510 [AC_TRY_COMPILE([#include <sys/types.h>
1511 #include <sys/ptrace.h>],
1512                 [PT_GETDBREGS;],
1513                 [gdb_cv_have_pt_getdbregs=yes],
1514                 [gdb_cv_have_pt_getdbregs=no])])
1515 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1516 if test $gdb_cv_have_pt_getdbregs = yes; then
1517   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1518   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1519 fi
1520
1521 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1522 AC_MSG_CHECKING(for PT_GETXMMREGS)
1523 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1524 [AC_TRY_COMPILE([#include <sys/types.h>
1525 #include <sys/ptrace.h>],
1526                 [PT_GETXMMREGS;],
1527                 [gdb_cv_have_pt_getxmmregs=yes],
1528                 [gdb_cv_have_pt_getxmmregs=no])])
1529 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1530 if test $gdb_cv_have_pt_getxmmregs = yes; then
1531   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1532   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1533 fi
1534
1535 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1536 # Older FreeBSD versions don't have the pl_tdname member of
1537 # `struct ptrace_lwpinfo'.
1538 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1539                  [#include <sys/ptrace.h>])
1540
1541 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1542 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1543 # FreeBSD 10.3.
1544 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1545                  [#include <sys/ptrace.h>])
1546
1547 # Detect which type of /proc is in use, such as for Solaris.
1548
1549 if test "${target}" = "${host}"; then
1550   case "${host}" in
1551   *-*-sysv4.2* | *-*-sysv5* )
1552       AC_DEFINE(NEW_PROC_API, 1,
1553       [Define if you want to use new multi-fd /proc interface.])
1554       ;;
1555   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1556       AC_DEFINE(NEW_PROC_API, 1,
1557       [Define if you want to use new multi-fd /proc interface.])
1558       ;;
1559   esac
1560 fi
1561
1562 if test "$ac_cv_header_sys_procfs_h" = yes; then
1563   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1564   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1565   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1566   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1567   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1568   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1569   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1570   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1571   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1572   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1573   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1574
1575
1576   dnl Check for broken prfpregset_t type
1577
1578   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1579   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1580   dnl instead of the struct itself).  We detect this here, and work
1581   dnl around it in gdb_proc_service.h.
1582
1583   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1584     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1585     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1586       [AC_TRY_RUN([#include <sys/procfs.h>
1587        int main ()
1588        {
1589          if (sizeof (prfpregset_t) == sizeof (void *))
1590            return 1;
1591          return 0;
1592        }],
1593        gdb_cv_prfpregset_t_broken=no,
1594        gdb_cv_prfpregset_t_broken=yes,
1595        gdb_cv_prfpregset_t_broken=yes)])
1596     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1597     if test $gdb_cv_prfpregset_t_broken = yes; then
1598       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1599       [Define if the prfpregset_t type is broken.])
1600     fi
1601   fi
1602 fi
1603
1604 # Check if the compiler supports the `long long' type.
1605
1606 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1607                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1608 [[extern long long foo;]],
1609 [[switch (foo & 2) { case 0: return 1; }]])],
1610                                   gdb_cv_c_long_long=yes,
1611                                   gdb_cv_c_long_long=no)])
1612 if test $gdb_cv_c_long_long != yes; then
1613   # libdecnumber requires long long.
1614   AC_MSG_ERROR([Compiler must support long long for GDB.])
1615 fi
1616
1617 # Check if the compiler and runtime support printing long longs.
1618
1619 AC_CACHE_CHECK([for long long support in printf],
1620                gdb_cv_printf_has_long_long,
1621                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1622 [[char buf[32];
1623   long long l = 0;
1624   l = (l << 16) + 0x0123;
1625   l = (l << 16) + 0x4567;
1626   l = (l << 16) + 0x89ab;
1627   l = (l << 16) + 0xcdef;
1628   sprintf (buf, "0x%016llx", l);
1629   return (strcmp ("0x0123456789abcdef", buf));]])],
1630                               gdb_cv_printf_has_long_long=yes,
1631                               gdb_cv_printf_has_long_long=no,
1632                               gdb_cv_printf_has_long_long=no)])
1633 if test $gdb_cv_printf_has_long_long = yes; then
1634   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1635             [Define to 1 if the "%ll" format works to print long longs.])
1636 fi
1637
1638 # Check if the compiler and runtime support printing decfloats.
1639
1640 AC_CACHE_CHECK([for decfloat support in printf],
1641                gdb_cv_printf_has_decfloat,
1642                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1643 [[char buf[64];
1644   _Decimal32 d32 = 1.2345df;
1645   _Decimal64 d64 = 1.2345dd;
1646   _Decimal128 d128 = 1.2345dl;
1647   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1648   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1649                               gdb_cv_printf_has_decfloat=yes,
1650                               gdb_cv_printf_has_decfloat=no,
1651                               gdb_cv_printf_has_decfloat=no)])
1652 if test $gdb_cv_printf_has_decfloat = yes; then
1653   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1654             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1655 fi
1656
1657 # Check if the compiler supports the `long double' type.  We can't use
1658 # AC_C_LONG_DOUBLE because that one does additional checks on the
1659 # constants defined in <float.h> that fail on some systems,
1660 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1661
1662 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1663                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1664                                   gdb_cv_c_long_double=yes,
1665                                   gdb_cv_c_long_double=no)])
1666 if test $gdb_cv_c_long_double = yes; then
1667   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1668            [Define to 1 if the compiler supports long double.])
1669 fi
1670
1671 # Check if the compiler and runtime support printing long doubles.
1672
1673 AC_CACHE_CHECK([for long double support in printf],
1674                gdb_cv_printf_has_long_double,
1675                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1676 [[char buf[16];
1677   long double f = 3.141592653;
1678   sprintf (buf, "%Lg", f);
1679   return (strncmp ("3.14159", buf, 7));]])],
1680                               gdb_cv_printf_has_long_double=yes,
1681                               gdb_cv_printf_has_long_double=no,
1682                               gdb_cv_printf_has_long_double=no)])
1683 if test $gdb_cv_printf_has_long_double = yes; then
1684   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1685             [Define to 1 if the "%Lg" format works to print long doubles.])
1686 fi
1687
1688 # Check if the compiler and runtime support scanning long doubles.
1689
1690 AC_CACHE_CHECK([for long double support in scanf],
1691                gdb_cv_scanf_has_long_double,
1692                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1693 [[#include <stdio.h>]],
1694 [[char *buf = "3.141592653";
1695   long double f = 0;
1696   sscanf (buf, "%Lg", &f);
1697   return !(f > 3.14159 && f < 3.14160);]])],
1698                               gdb_cv_scanf_has_long_double=yes,
1699                               gdb_cv_scanf_has_long_double=no,
1700                               gdb_cv_scanf_has_long_double=no)])
1701 if test $gdb_cv_scanf_has_long_double = yes; then
1702   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1703             [Define to 1 if the "%Lg" format works to scan long doubles.])
1704 fi
1705
1706 case ${host_os} in
1707 aix*)
1708   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1709     SAVE_LDFLAGS=$LDFLAGS
1710
1711     case $GCC in
1712     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1713     *) gdb_cv_bigtoc=-bbigtoc ;;
1714     esac
1715
1716     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1717     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1718     LDFLAGS="${SAVE_LDFLAGS}"
1719   ])
1720   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1721   ;;
1722 esac
1723
1724 AC_MSG_CHECKING(for the dynamic export flag)
1725 dynamic_list=false
1726 if test "${gdb_native}" = yes; then
1727    # The dynamically loaded libthread_db needs access to symbols in the gdb
1728    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1729    # may not be supported there.
1730    old_LDFLAGS="$LDFLAGS"
1731    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1732    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1733    LDFLAGS="$LDFLAGS $RDYNAMIC"
1734    if test "${have_libpython}" = no; then
1735      AC_TRY_LINK([], [], [dynamic_list=true])
1736    else
1737      # Workaround http://bugs.python.org/issue4434 where static
1738      # libpythonX.Y.a would get its symbols required for
1739      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1740      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1741
1742      # Note the workaround for Python
1743      # http://bugs.python.org/issue10112 earlier has removed
1744      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1745      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1746      # always pass.
1747      old_CFLAGS="$CFLAGS"
1748      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1749      old_LIBS="$LIBS"
1750      LIBS="$LIBS $PYTHON_LIBS"
1751      old_CPPFLAGS="$CPPFLAGS"
1752      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1753      AC_RUN_IFELSE(
1754        AC_LANG_PROGRAM(
1755          [#include "Python.h"],
1756          [int err;
1757           Py_Initialize ();
1758           err = PyRun_SimpleString ("import itertools\n");
1759           Py_Finalize ();
1760           return err == 0 ? 0 : 1;]),
1761        [dynamic_list=true], [], [true])
1762      LIBS="$old_LIBS"
1763      CFLAGS="$old_CFLAGS"
1764      CPPFLAGS="$old_CPPFLAGS"
1765    fi
1766    LDFLAGS="$old_LDFLAGS"
1767 fi
1768 if $dynamic_list; then
1769   found="-Wl,--dynamic-list"
1770   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1771 else
1772   found="-rdynamic"
1773   RDYNAMIC="-rdynamic"
1774 fi
1775 AC_SUBST(RDYNAMIC)
1776 AC_MSG_RESULT($found)
1777
1778 dnl For certain native configurations, we need to check whether thread
1779 dnl support can be built in or not.
1780 dnl
1781 dnl Note that we only want this if we are both native (host == target),
1782 dnl and not doing a canadian cross build (build == host).
1783
1784 if test ${build} = ${host} -a ${host} = ${target} ; then
1785    case ${host_os} in
1786    aix*)
1787       AC_MSG_CHECKING(for AiX thread debugging library)
1788       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1789                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1790                                    [#ifndef PTHDB_VERSION_3
1791                                     #error
1792                                     #endif],
1793                                    gdb_cv_have_aix_thread_debug=yes,
1794                                    gdb_cv_have_aix_thread_debug=no)])
1795       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1796       if test $gdb_cv_have_aix_thread_debug = yes; then
1797          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1798          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1799          LIBS="$LIBS -lpthdebug"
1800
1801          # Older versions of AIX do not provide the declaration for
1802          # the getthrds function (it appears that it was introduced
1803          # with AIX 6.x).
1804          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1805       fi
1806       ;;
1807    esac
1808    AC_SUBST(CONFIG_LDFLAGS)
1809 fi
1810
1811 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1812 dnl other error codes.
1813 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1814    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1815                   gdb_cv_thread_db_h_has_td_notalloc,
1816      AC_TRY_COMPILE(
1817        [#include <thread_db.h>],
1818        [int i = TD_NOTALLOC;],
1819        gdb_cv_thread_db_h_has_td_notalloc=yes,
1820        gdb_cv_thread_db_h_has_td_notalloc=no
1821      )
1822    )
1823    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1824                   gdb_cv_thread_db_h_has_td_version,
1825      AC_TRY_COMPILE(
1826        [#include <thread_db.h>],
1827        [int i = TD_VERSION;],
1828        gdb_cv_thread_db_h_has_td_version=yes,
1829        gdb_cv_thread_db_h_has_td_version=no
1830      )
1831    )
1832    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1833                   gdb_cv_thread_db_h_has_td_notls,
1834      AC_TRY_COMPILE(
1835        [#include <thread_db.h>],
1836        [int i = TD_NOTLS;],
1837        gdb_cv_thread_db_h_has_td_notls=yes,
1838        gdb_cv_thread_db_h_has_td_notls=no
1839      )
1840    )
1841 fi
1842 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1843   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1844             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1845 fi
1846 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1847   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1848             [Define if <thread_db.h> has the TD_VERSION error code.])
1849 fi
1850 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1851   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1852             [Define if <thread_db.h> has the TD_NOTLS error code.])
1853 fi
1854
1855 dnl Check if we can disable the virtual address space randomization.
1856 dnl The functionality of setarch -R.
1857 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1858 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1859 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1860 #       define ADDR_NO_RANDOMIZE 0x0040000
1861 #      endif
1862        /* Test the flag could be set and stays set.  */
1863        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1864        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1865            return 1])])
1866 AC_RUN_IFELSE([PERSONALITY_TEST],
1867               [have_personality=true],
1868               [have_personality=false],
1869               [AC_LINK_IFELSE([PERSONALITY_TEST],
1870                               [have_personality=true],
1871                               [have_personality=false])])
1872 if $have_personality
1873 then
1874     AC_DEFINE([HAVE_PERSONALITY], 1,
1875               [Define if you support the personality syscall.])
1876 fi
1877
1878 dnl Set the host's .gdbinit filename.
1879 case $host_os in
1880   go32* | *djgpp*)
1881     gdbinit=gdb.ini
1882     ;;
1883   *)
1884     gdbinit=.gdbinit
1885     ;;
1886 esac
1887 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1888
1889 dnl Handle optional features that can be enabled.
1890
1891 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1892 # except that the argument to --with-sysroot is optional.
1893 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1894 if test "x$with_sysroot" = xyes; then
1895   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1896 fi
1897 AC_ARG_WITH(sysroot,
1898   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1899                  [search for usr/lib et al within DIR]),
1900   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1901 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1902               [search for usr/lib et al within DIR])
1903 AC_SUBST(TARGET_SYSTEM_ROOT)
1904 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1905
1906 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1907     [automatically load a system-wide gdbinit file],
1908     [])
1909
1910 AM_GDB_WARNINGS
1911
1912 # In the Cygwin environment, we need some additional flags.
1913 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1914 [AC_EGREP_CPP(^lose$, [
1915 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1916 lose
1917 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1918
1919
1920 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1921 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1922 case ${host} in
1923   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1924   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1925   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1926 esac
1927 AC_SUBST(SER_HARDWIRE)
1928
1929 # libreadline needs libuser32.a in a cygwin environment
1930 WIN32LIBS=
1931 if test x$gdb_cv_os_cygwin = xyes; then
1932     WIN32LIBS="-luser32"
1933     case "${target}" in
1934         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1935         ;;
1936     esac
1937 fi
1938
1939 # The ser-tcp.c module requires sockets.
1940 case ${host} in
1941   *mingw32*)
1942     AC_DEFINE(USE_WIN32API, 1,
1943               [Define if we should use the Windows API, instead of the
1944                POSIX API.  On Windows, we use the Windows API when
1945                building for MinGW, but the POSIX API when building
1946                for Cygwin.])
1947     WIN32LIBS="$WIN32LIBS -lws2_32"
1948     ;;
1949 esac
1950 AC_SUBST(WIN32LIBS)
1951
1952 # Add ELF support to GDB, but only if BFD includes ELF support.
1953 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1954                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1955 if test $gdb_cv_var_elf = yes; then
1956   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1957   AC_DEFINE(HAVE_ELF, 1,
1958             [Define if ELF support should be included.])
1959   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1960   if test "$plugins" = "yes"; then
1961     AC_SEARCH_LIBS(dlopen, dl)
1962   fi
1963 fi
1964
1965 # Add macho support to GDB, but only if BFD includes it.
1966 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1967                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1968 if test $gdb_cv_var_macho = yes; then
1969   CONFIG_OBS="$CONFIG_OBS machoread.o"
1970 fi
1971
1972 # Add any host-specific objects to GDB.
1973 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1974
1975 # If building on ELF, look for lzma support for embedded compressed debug info.
1976 if test $gdb_cv_var_elf = yes; then
1977   AC_ARG_WITH(lzma,
1978     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1979     [], [with_lzma=auto])
1980   AC_MSG_CHECKING([whether to use lzma])
1981   AC_MSG_RESULT([$with_lzma])
1982
1983   if test "${with_lzma}" != no; then
1984     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1985                           [lzma_index_iter iter;
1986                            lzma_index_iter_init (&iter, 0);
1987                            lzma_mf_is_supported (LZMA_MF_HC3);])
1988     if test "$HAVE_LIBLZMA" != yes; then
1989       if test "$with_lzma" = yes; then
1990         AC_MSG_ERROR([missing liblzma for --with-lzma])
1991       fi
1992     fi
1993   fi
1994 fi
1995
1996 LIBGUI="../libgui/src/libgui.a"
1997 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1998 AC_SUBST(LIBGUI)
1999 AC_SUBST(GUI_CFLAGS_X)
2000
2001 WIN32LDAPP=
2002 AC_SUBST(WIN32LIBS)
2003 AC_SUBST(WIN32LDAPP)
2004
2005 case "${host}" in
2006 *-*-cygwin* | *-*-mingw* )
2007     configdir="win"
2008     ;;
2009 *)
2010     configdir="unix"
2011     ;;
2012 esac
2013
2014 GDBTKLIBS=
2015 if test "${enable_gdbtk}" = "yes"; then
2016
2017     # Gdbtk must have an absolute path to srcdir in order to run
2018     # properly when not installed.
2019     here=`pwd`
2020     cd ${srcdir}
2021     GDBTK_SRC_DIR=`pwd`
2022     cd $here
2023
2024     SC_PATH_TCLCONFIG
2025
2026     # If $no_tk is nonempty, then we can't do Tk, and there is no
2027     # point to doing Tcl.
2028     SC_PATH_TKCONFIG
2029
2030     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2031         SC_LOAD_TCLCONFIG
2032
2033         # Check for in-tree tcl
2034         here=`pwd`
2035         cd ${srcdir}/..
2036         topdir=`pwd`
2037         cd ${here}
2038
2039         intree="no"
2040         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2041           intree="yes"
2042         fi
2043
2044         # Find Tcl private headers
2045         if test x"${intree}" = xno; then
2046           CY_AC_TCL_PRIVATE_HEADERS
2047           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2048           TCL_LIBRARY="${TCL_LIB_SPEC}"
2049           TCL_DEPS=""
2050         else
2051           # If building tcl in the same src tree, private headers
2052           # are not needed, but we need to be sure to use the right
2053           # headers library
2054           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2055           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2056           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2057         fi
2058         AC_SUBST(TCL_INCLUDE)
2059         AC_SUBST(TCL_LIBRARY)
2060         AC_SUBST(TCL_DEPS)
2061
2062         SC_LOAD_TKCONFIG
2063
2064         # Check for in-tree Tk
2065         intree="no"
2066         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2067           intree="yes"
2068         fi
2069
2070         # Find Tk private headers
2071         if test x"${intree}" = xno; then
2072           CY_AC_TK_PRIVATE_HEADERS
2073           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2074           TK_LIBRARY=${TK_LIB_SPEC}
2075           TK_DEPS=""
2076         else
2077           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2078           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2079           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2080         fi
2081         AC_SUBST(TK_INCLUDE)
2082         AC_SUBST(TK_LIBRARY)
2083         AC_SUBST(TK_DEPS)
2084         AC_SUBST(TK_XINCLUDES)
2085
2086         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2087
2088         # Include some libraries that Tcl and Tk want.
2089         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2090         # Yes, the ordering seems wrong here.  But it isn't.
2091         # TK_LIBS is the list of libraries that need to be linked
2092         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2093         # were in LIBS then any link tests after this point would
2094         # try to include things like `$(LIBGUI)', which wouldn't work.
2095         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2096
2097         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2098         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2099         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2100         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2101         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2102         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2103         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2104
2105         if test x$gdb_cv_os_cygwin = xyes; then
2106           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2107           WIN32LDAPP="-Wl,--subsystem,console"
2108           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2109         fi
2110
2111         AC_CONFIG_SUBDIRS(gdbtk)
2112     fi
2113 fi
2114
2115 AC_SUBST(X_CFLAGS)
2116 AC_SUBST(X_LDFLAGS)
2117 AC_SUBST(X_LIBS)
2118 AC_SUBST(GDBTKLIBS)
2119 AC_SUBST(GDBTK_CFLAGS)
2120 AC_SUBST(GDBTK_SRC_DIR)
2121
2122 AC_PATH_X
2123
2124 # Unlike the sim directory, whether a simulator is linked is controlled by
2125 # presence of a gdb_sim definition in the target configure.tgt entry.
2126 # This code just checks for a few cases where we'd like to ignore those
2127 # definitions, even when they're present in the '.mt' file.  These cases
2128 # are when --disable-sim is specified, or if the simulator directory is
2129 # not part of the source tree.
2130 #
2131 AC_ARG_ENABLE(sim,
2132 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2133 [echo "enable_sim = $enable_sim";
2134  echo "enableval = ${enableval}";
2135  case "${enableval}" in
2136   yes) ignore_sim=false ;;
2137   no)  ignore_sim=true ;;
2138   *)   ignore_sim=false ;;
2139  esac],
2140 [ignore_sim=false])
2141
2142 if test ! -d "${srcdir}/../sim"; then
2143   ignore_sim=true
2144 fi
2145
2146 SIM=
2147 SIM_OBS=
2148 if test "${ignore_sim}" = "false"; then
2149   if test x"${gdb_sim}" != x ; then
2150     SIM="${gdb_sim}"
2151     SIM_OBS="remote-sim.o"
2152     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2153
2154     # Some tdep code should only be compiled in when the ppc sim is
2155     # built.  PR sim/13418.
2156     case $target in
2157       powerpc*-*-*)
2158         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2159         ;;
2160     esac
2161   fi
2162 fi
2163 AC_SUBST(SIM)
2164 AC_SUBST(SIM_OBS)
2165
2166 AC_SUBST(ENABLE_CFLAGS)
2167 AC_SUBST(PROFILE_CFLAGS)
2168
2169 AC_SUBST(CONFIG_OBS)
2170 AC_SUBST(CONFIG_DEPS)
2171 AC_SUBST(CONFIG_SRCS)
2172 AC_SUBST(CONFIG_ALL)
2173 AC_SUBST(CONFIG_CLEAN)
2174 AC_SUBST(CONFIG_INSTALL)
2175 AC_SUBST(CONFIG_UNINSTALL)
2176
2177 # List of host floatformats.
2178 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2179 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2180 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2181
2182 # target_subdir is used by the testsuite to find the target libraries.
2183 target_subdir=
2184 if test "${host}" != "${target}"; then
2185     target_subdir="${target_alias}/"
2186 fi
2187 AC_SUBST(target_subdir)
2188
2189 # Import nat definitions.
2190 nat_makefile_frag=/dev/null
2191 if test "${gdb_native}" = "yes"; then
2192   . ${srcdir}/configure.nat
2193   nativefile=$NAT_FILE
2194 fi
2195
2196 AC_SUBST(NAT_FILE)
2197 AC_SUBST(NATDEPFILES)
2198 AC_SUBST(NAT_CDEPS)
2199 AC_SUBST(LOADLIBES)
2200 AC_SUBST(MH_CFLAGS)
2201 AC_SUBST(XM_CLIBS)
2202 AC_SUBST(NAT_GENERATED_FILES)
2203 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2204 AC_SUBST_FILE(nat_makefile_frag)
2205
2206 if test x"${gdb_osabi}" != x ; then
2207     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2208                        [Define to the default OS ABI for this configuration.])
2209 fi
2210
2211 # Enable multi-ice-gdb-server.
2212 AC_ARG_ENABLE(multi-ice,
2213 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2214   [case $enableval in
2215     yes | no)
2216       ;;
2217     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2218   esac])
2219 if test "x$enable_multi_ice" = xyes; then
2220    AC_CONFIG_SUBDIRS(multi-ice)
2221 fi
2222
2223 AC_ARG_ENABLE(gdbserver,
2224 AS_HELP_STRING([--enable-gdbserver],
2225                [automatically build gdbserver (yes/no/auto, default is auto)]),
2226 [case "${enableval}" in
2227   yes| no|auto) ;;
2228   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2229 esac],[enable_gdbserver=auto])
2230
2231 # We only build gdbserver automatically in a native configuration, and
2232 # only if the user did not explicitly disable its build.
2233 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2234   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2235   if test "x$build_gdbserver" = xyes; then
2236     AC_MSG_RESULT(yes)
2237     AC_CONFIG_SUBDIRS(gdbserver)
2238     gdbserver_build_enabled=yes
2239   else
2240     AC_MSG_RESULT(no)
2241   fi
2242 fi
2243
2244 # If the user explicitly request the gdbserver to be built, verify that
2245 # we were in fact able to enable it.
2246 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2247   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2248 fi
2249
2250 # Check for babeltrace and babeltrace-ctf
2251 AC_ARG_WITH(babeltrace,
2252   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2253   [], [with_babeltrace=auto])
2254 AC_MSG_CHECKING([whether to use babeltrace])
2255 AC_MSG_RESULT([$with_babeltrace])
2256
2257 if test "x$with_babeltrace" = "xno"; then
2258   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2259 else
2260   # Append -Werror to CFLAGS so that configure can catch the warning
2261   # "assignment from incompatible pointer type", which is related to
2262   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2263   # in GDB, while babeltrace 1.0.3 is broken.
2264   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2265   # safe to save and restore CFLAGS here.
2266   saved_CFLAGS=$CFLAGS
2267   CFLAGS="$CFLAGS -Werror"
2268   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2269                         [#include <babeltrace/babeltrace.h>
2270                          #include <babeltrace/ctf/events.h>
2271                          #include <babeltrace/ctf/iterator.h>],
2272                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2273                         struct bt_ctf_event *event = NULL;
2274                         const struct bt_definition *scope;
2275
2276                         pos->type = BT_SEEK_BEGIN;
2277                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2278                         scope = bt_ctf_get_top_level_scope (event,
2279                                                            BT_STREAM_EVENT_HEADER);
2280                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2281                         ])
2282   CFLAGS=$saved_CFLAGS
2283
2284   if test "$HAVE_LIBBABELTRACE" != yes; then
2285      if test "$with_babeltrace" = yes; then
2286        AC_MSG_ERROR([babeltrace is missing or unusable])
2287      else
2288        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2289      fi
2290   fi
2291 fi
2292
2293 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2294 # empty version.
2295
2296 files=
2297 links=
2298
2299 rm -f nm.h
2300 if test "${nativefile}" != ""; then
2301     case "${nativefile}" in
2302       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2303       * ) GDB_NM_FILE="${nativefile}"
2304     esac
2305     files="${files} ${GDB_NM_FILE}"
2306     links="${links} nm.h"
2307     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2308 fi
2309 AC_SUBST(GDB_NM_FILE)
2310
2311 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2312 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2313 if test "x$USE_MAINTAINER_MODE" = xyes; then
2314   if test "${XSLTPROC}" = missing; then
2315     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2316   fi
2317 fi
2318 AC_SUBST(XSLTPROC)
2319
2320 AC_LINK_FILES($files, $links)
2321
2322 dnl Check for exe extension set on certain hosts (e.g. Win32)
2323 AC_EXEEXT
2324
2325 dnl  Detect the character set used by this host.
2326 dnl  At the moment, we just assume it's UTF-8.
2327 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2328           [Define to be a string naming the default host character set.])
2329
2330 if $development; then
2331   AC_DEFINE(GDB_SELF_TEST, 1,
2332             [Define if self-testing features should be enabled])
2333   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS)"
2334   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS)"
2335 fi
2336
2337 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2338 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2339 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2340 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2341 [
2342 case x$CONFIG_HEADERS in
2343 xconfig.h:config.in)
2344 echo > stamp-h ;;
2345 esac
2346 ])
2347
2348 AC_OUTPUT