gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_SYS_LARGEFILE
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_PROG_RANLIB
  37
  38 AC_ARG_PROGRAM
  39
  40 AC_HEADER_STDC
  41
  42 # Set the 'development' global.
  43 . $srcdir/../../bfd/development.sh
  44
  45 # Enable -lmcheck by default (it provides cheap-enough memory
  46 # mangling), but turn it off for releases.
  47 if $development; then
  48   libmcheck_default=yes
  49 else
  50   libmcheck_default=no
  51 fi
  52 GDB_AC_LIBMCHECK(${libmcheck_default})
  53
  54 ACX_NONCANONICAL_TARGET
  55 ACX_NONCANONICAL_HOST
  56
  57 # Dependency checking.
  58 ZW_CREATE_DEPDIR
  59 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  60
  61 # Check for the 'make' the user wants to use.
  62 AC_CHECK_PROGS(MAKE, make)
  63 MAKE_IS_GNU=
  64 case "`$MAKE --version 2>&1 | sed 1q`" in
  65   *GNU*)
  66     MAKE_IS_GNU=yes
  67     ;;
  68 esac
  69 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  70 AC_PROG_MAKE_SET
  71
  72 gnulib_extra_configure_args=
  73 # If large-file support is disabled, make sure gnulib does the same.
  74 if test "$enable_largefile" = no; then
  75 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  76 fi
  77
  78 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  79 # to find the the source subdir to be configured directly under
  80 # gdbserver/.  We need to build gnulib under some other directory not
  81 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  82 # build it in the same directory, when building in the source dir.
  83 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  84                   ["$gnulib_extra_configure_args"])
  85
  86 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  87
  88 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  89                  proc_service.h sys/procfs.h linux/elf.h dnl
  90                  fcntl.h signal.h sys/file.h dnl
  91                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  92                  netinet/tcp.h arpa/inet.h)
  93 AC_CHECK_FUNCS(getauxval pread pwrite pread64)
  94
  95 GDB_AC_COMMON
  96
  97 # Check for UST
  98 ustlibs=""
  99 ustinc=""
 100
 101 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 102                           Equivalent to --with-ust-include=PATH/include
 103                           plus --with-ust-lib=PATH/lib])
 104 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 105 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 106
 107 case $with_ust in
 108   no)
 109     ustlibs=
 110     ustinc=
 111     ;;
 112   "" | yes)
 113     ustlibs=" -lust "
 114     ustinc=""
 115     ;;
 116   *)
 117     ustlibs="-L$with_ust/lib -lust"
 118     ustinc="-I$with_ust/include "
 119     ;;
 120 esac
 121 if test "x$with_ust_include" != x; then
 122   ustinc="-I$with_ust_include "
 123 fi
 124 if test "x$with_ust_lib" != x; then
 125   ustlibs="-L$with_ust_lib -lust"
 126 fi
 127
 128 if test "x$with_ust" != "xno"; then
 129   saved_CFLAGS="$CFLAGS"
 130   CFLAGS="$CFLAGS $ustinc"
 131   AC_MSG_CHECKING([for ust])
 132   AC_TRY_COMPILE([
 133 #define CONFIG_UST_GDB_INTEGRATION
 134 #include <ust/ust.h>
 135   ],[],
 136   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 137   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 138   CFLAGS="$saved_CFLAGS"
 139 fi
 140
 141 # Flags needed for UST
 142 AC_SUBST(ustlibs)
 143 AC_SUBST(ustinc)
 144
 145 AC_ARG_ENABLE(werror,
 146   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
 147   [case "${enableval}" in
 148      yes | y) ERROR_ON_WARNING="yes" ;;
 149      no | n)  ERROR_ON_WARNING="no" ;;
 150      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
 151    esac])
 152
 153 # Enable -Werror by default when using gcc.  Turn it off for releases.
 154 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
 155     ERROR_ON_WARNING=yes
 156 fi
 157
 158 WERROR_CFLAGS=""
 159 if test "${ERROR_ON_WARNING}" = yes ; then
 160     WERROR_CFLAGS="-Werror"
 161 fi
 162
 163 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
 164 -Wformat-nonliteral -Wno-char-subscripts -Wempty-body"
 165
 166 WARN_CFLAGS=""
 167 if test "x$GCC" = xyes
 168 then
 169     AC_MSG_CHECKING(compiler warning flags)
 170     # Separate out the -Werror flag as some files just cannot be
 171     # compiled with it enabled.
 172     for w in ${build_warnings}; do
 173         case $w in
 174         -Werr*) WERROR_CFLAGS=-Werror ;;
 175         *) # Check that GCC accepts it
 176             saved_CFLAGS="$CFLAGS"
 177             CFLAGS="$CFLAGS $w"
 178             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 179             CFLAGS="$saved_CFLAGS"
 180         esac
 181     done
 182     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 183 fi
 184 AC_SUBST(WARN_CFLAGS)
 185 AC_SUBST(WERROR_CFLAGS)
 186
 187 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 188 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 189 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 190 dnl augment LIBS.
 191 old_LIBS="$LIBS"
 192 LIBS="$LIBS -ldl"
 193 AC_CHECK_FUNCS(dladdr)
 194 LIBS="$old_LIBS"
 195
 196 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 197
 198 AC_CHECK_TYPES(socklen_t, [], [],
 199 [#include <sys/types.h>
 200 #include <sys/socket.h>
 201 ])
 202
 203 AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 204 #include <elf.h>
 205 )
 206
 207 ACX_PKGVERSION([GDB])
 208 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 209 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 210 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 211
 212 # Check for various supplementary target information (beyond the
 213 # triplet) which might affect the choices in configure.srv.
 214 case "${target}" in
 215 changequote(,)dnl
 216   i[34567]86-*-linux*)
 217 changequote([,])dnl
 218     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 219                    [save_CPPFLAGS="$CPPFLAGS"
 220                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 221                     AC_EGREP_CPP([got it], [
 222 #if __x86_64__
 223 got it
 224 #endif
 225                  ], [gdb_cv_i386_is_x86_64=yes],
 226                     [gdb_cv_i386_is_x86_64=no])
 227                     CPPFLAGS="$save_CPPFLAGS"])
 228     ;;
 229   m68k-*-*)
 230     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 231                    [save_CPPFLAGS="$CPPFLAGS"
 232                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 233                     AC_EGREP_CPP([got it], [
 234 #ifdef __mcoldfire__
 235 got it
 236 #endif
 237                  ], [gdb_cv_m68k_is_coldfire=yes],
 238                     [gdb_cv_m68k_is_coldfire=no])
 239                     CPPFLAGS="$save_CPPFLAGS"])
 240     ;;
 241 esac
 242
 243 . ${srcdir}/configure.srv
 244
 245 # Add in the common host objects.
 246 . ${srcdir}/../common/common.host
 247 srv_host_obs="$common_host_obs"
 248
 249 if test "${srv_mingwce}" = "yes"; then
 250   LIBS="$LIBS -lws2"
 251 elif test "${srv_mingw}" = "yes"; then
 252   LIBS="$LIBS -lws2_32"
 253 elif test "${srv_qnx}" = "yes"; then
 254   LIBS="$LIBS -lsocket"
 255 elif test "${srv_lynxos}" = "yes"; then
 256   LIBS="$LIBS -lnetinet"
 257 fi
 258
 259 if test "${srv_mingw}" = "yes"; then
 260   AC_DEFINE(USE_WIN32API, 1,
 261             [Define if we should use the Windows API, instead of the
 262              POSIX API.  On Windows, we use the Windows API when
 263              building for MinGW, but the POSIX API when building
 264              for Cygwin.])
 265 fi
 266
 267 if test "${srv_linux_usrregs}" = "yes"; then
 268   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 269             [Define if the target supports PTRACE_PEEKUSR for register ]
 270             [access.])
 271 fi
 272
 273 if test "${srv_linux_regsets}" = "yes"; then
 274   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 275             [Define if the target supports register sets.])
 276
 277   AC_MSG_CHECKING(for PTRACE_GETREGS)
 278   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 279   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 280                   [PTRACE_GETREGS;],
 281                   [gdbsrv_cv_have_ptrace_getregs=yes],
 282                   [gdbsrv_cv_have_ptrace_getregs=no])])
 283   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 284   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 285     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 286               [Define if the target supports PTRACE_GETREGS for register ]
 287               [access.])
 288   fi
 289
 290   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 291   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 292   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 293                   [PTRACE_GETFPXREGS;],
 294                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 295                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 296   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 297   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 298     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 299               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 300               [register access.])
 301   fi
 302 fi
 303
 304 if test "${srv_linux_btrace}" = "yes"; then
 305   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 306             [Define if the target supports branch tracing.])
 307 fi
 308
 309 if test "$ac_cv_header_sys_procfs_h" = yes; then
 310   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 311   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 312   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 313   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 314 fi
 315
 316 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 317 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 318   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 319 fi
 320
 321 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 322 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 323   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 324 fi
 325
 326 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 327 dnl needs it (and gdbreplay doesn't).
 328 old_LIBS="$LIBS"
 329 AC_CHECK_LIB(dl, dlopen)
 330 LIBS="$old_LIBS"
 331
 332 srv_thread_depfiles=
 333 srv_libs=
 334
 335 if test "$srv_linux_thread_db" = "yes"; then
 336   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 337     srv_libs="-ldl"
 338     AC_MSG_CHECKING(for the dynamic export flag)
 339     old_LDFLAGS="$LDFLAGS"
 340     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 341     # supported there.
 342     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 343     LDFLAGS="$LDFLAGS $RDYNAMIC"
 344     AC_TRY_LINK([], [],
 345                 [found="-Wl,--dynamic-list"
 346                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 347                 [RDYNAMIC="-rdynamic"
 348                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 349                  AC_TRY_LINK([], [],
 350                              [found="-rdynamic"],
 351                              [found="no"
 352                               RDYNAMIC=""])])
 353     AC_SUBST(RDYNAMIC)
 354     LDFLAGS="$old_LDFLAGS"
 355     AC_MSG_RESULT($found)
 356   else
 357     srv_libs="-lthread_db"
 358   fi
 359
 360   srv_thread_depfiles="thread-db.o proc-service.o"
 361   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 362   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 363   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 364                   [gdbsrv_cv_have_td_version=yes],
 365                   [gdbsrv_cv_have_td_version=no])])
 366   if test $gdbsrv_cv_have_td_version = yes; then
 367     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 368   fi
 369 fi
 370
 371 AC_ARG_WITH(libthread-db,
 372 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 373 [srv_libthread_db_path="${withval}"
 374   srv_libs="$srv_libthread_db_path"
 375 ])
 376
 377 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 378   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 379 fi
 380
 381 if test "$srv_xmlfiles" != ""; then
 382   srv_xmlbuiltin="xml-builtin.o"
 383   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 384
 385   tmp_xmlfiles=$srv_xmlfiles
 386   srv_xmlfiles=""
 387   for f in $tmp_xmlfiles; do
 388     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 389   done
 390 fi
 391
 392 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs"
 393 GDBSERVER_LIBS="$srv_libs"
 394
 395 dnl Check whether the target supports __sync_*_compare_and_swap.
 396 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 397                 gdbsrv_cv_have_sync_builtins, [
 398 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 399                 gdbsrv_cv_have_sync_builtins=yes,
 400                 gdbsrv_cv_have_sync_builtins=no)])
 401 if test $gdbsrv_cv_have_sync_builtins = yes; then
 402   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 403     [Define to 1 if the target supports __sync_*_compare_and_swap])
 404 fi
 405
 406 dnl Check for -fvisibility=hidden support in the compiler.
 407 saved_cflags="$CFLAGS"
 408 CFLAGS="$CFLAGS -fvisibility=hidden"
 409 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 410                         [gdbsrv_cv_have_visibility_hidden=yes],
 411                         [gdbsrv_cv_have_visibility_hidden=no])
 412 CFLAGS="$saved_cflags"
 413
 414 dnl Check if we can disable the virtual address space randomization.
 415 dnl The functionality of setarch -R.
 416 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 417 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 418 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 419 #       define ADDR_NO_RANDOMIZE 0x0040000
 420 #      endif
 421        /* Test the flag could be set and stays set.  */
 422        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 423        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 424            return 1])])
 425 AC_RUN_IFELSE([PERSONALITY_TEST],
 426               [gdbsrv_cv_have_personality=true],
 427               [gdbsrv_cv_have_personality=false],
 428               [AC_LINK_IFELSE([PERSONALITY_TEST],
 429                               [gdbsrv_cv_have_personality=true],
 430                               [gdbsrv_cv_have_personality=false])])
 431 if $gdbsrv_cv_have_personality
 432 then
 433     AC_DEFINE([HAVE_PERSONALITY], 1,
 434               [Define if you support the personality syscall.])
 435 fi
 436
 437
 438 IPA_DEPFILES=""
 439 extra_libraries=""
 440
 441 # check whether to enable the inprocess agent
 442 if test "$ipa_obj" != "" \
 443    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 444    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 445    have_ipa=true
 446 else
 447    have_ipa=false
 448 fi
 449
 450 AC_ARG_ENABLE(inprocess-agent,
 451 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 452 [case "$enableval" in
 453   yes) want_ipa=true ;;
 454   no) want_ipa=false ;;
 455   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 456 esac],
 457 [want_ipa=$have_ipa])
 458
 459 if $want_ipa ; then
 460    if $have_ipa ; then
 461      IPA_DEPFILES="$ipa_obj"
 462      extra_libraries="$extra_libraries libinproctrace.so"
 463    else
 464      AC_MSG_ERROR([inprocess agent not supported for this target])
 465    fi
 466 fi
 467
 468 AC_SUBST(GDBSERVER_DEPFILES)
 469 AC_SUBST(GDBSERVER_LIBS)
 470 AC_SUBST(srv_xmlbuiltin)
 471 AC_SUBST(srv_xmlfiles)
 472 AC_SUBST(IPA_DEPFILES)
 473 AC_SUBST(extra_libraries)
 474
 475 GNULIB=build-gnulib-gdbserver/import
 476
 477 GNULIB_STDINT_H=
 478 if test x"$STDINT_H" != x; then
 479   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 480 fi
 481 AC_SUBST(GNULIB_STDINT_H)
 482
 483 AC_OUTPUT(Makefile,
 484 [case x$CONFIG_HEADERS in
 485 xconfig.h:config.in)
 486 echo > stamp-h ;;
 487 esac
 488 ])