gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_SYS_LARGEFILE
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_PROG_RANLIB
  37
  38 AC_ARG_PROGRAM
  39
  40 AC_HEADER_STDC
  41
  42 # Set the 'development' global.
  43 . $srcdir/../../bfd/development.sh
  44
  45 # Enable -lmcheck by default (it provides cheap-enough memory
  46 # mangling), but turn it off for releases.
  47 if $development; then
  48   libmcheck_default=yes
  49 else
  50   libmcheck_default=no
  51 fi
  52 GDB_AC_LIBMCHECK(${libmcheck_default})
  53
  54 ACX_NONCANONICAL_TARGET
  55 ACX_NONCANONICAL_HOST
  56
  57 # Dependency checking.
  58 ZW_CREATE_DEPDIR
  59 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  60
  61 # Check for the 'make' the user wants to use.
  62 AC_CHECK_PROGS(MAKE, make)
  63 MAKE_IS_GNU=
  64 case "`$MAKE --version 2>&1 | sed 1q`" in
  65   *GNU*)
  66     MAKE_IS_GNU=yes
  67     ;;
  68 esac
  69 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  70 AC_PROG_MAKE_SET
  71
  72 gnulib_extra_configure_args=
  73 # If large-file support is disabled, make sure gnulib does the same.
  74 if test "$enable_largefile" = no; then
  75 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  76 fi
  77
  78 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  79 # to find the the source subdir to be configured directly under
  80 # gdbserver/.  We need to build gnulib under some other directory not
  81 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  82 # build it in the same directory, when building in the source dir.
  83 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  84                   ["$gnulib_extra_configure_args"])
  85
  86 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  87
  88 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  89                  proc_service.h sys/procfs.h linux/elf.h dnl
  90                  fcntl.h signal.h sys/file.h dnl
  91                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  92                  netinet/tcp.h arpa/inet.h)
  93 AC_CHECK_FUNCS(getauxval pread pwrite pread64)
  94
  95 GDB_AC_COMMON
  96
  97 # Check for UST
  98 ustlibs=""
  99 ustinc=""
 100
 101 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 102                           Equivalent to --with-ust-include=PATH/include
 103                           plus --with-ust-lib=PATH/lib])
 104 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 105 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 106
 107 case $with_ust in
 108   no)
 109     ustlibs=
 110     ustinc=
 111     ;;
 112   "" | yes)
 113     ustlibs=" -lust "
 114     ustinc=""
 115     ;;
 116   *)
 117     ustlibs="-L$with_ust/lib -lust"
 118     ustinc="-I$with_ust/include "
 119     ;;
 120 esac
 121 if test "x$with_ust_include" != x; then
 122   ustinc="-I$with_ust_include "
 123 fi
 124 if test "x$with_ust_lib" != x; then
 125   ustlibs="-L$with_ust_lib -lust"
 126 fi
 127
 128 if test "x$with_ust" != "xno"; then
 129   saved_CFLAGS="$CFLAGS"
 130   CFLAGS="$CFLAGS $ustinc"
 131   AC_MSG_CHECKING([for ust])
 132   AC_TRY_COMPILE([
 133 #define CONFIG_UST_GDB_INTEGRATION
 134 #include <ust/ust.h>
 135   ],[],
 136   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 137   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 138   CFLAGS="$saved_CFLAGS"
 139 fi
 140
 141 # Flags needed for UST
 142 AC_SUBST(ustlibs)
 143 AC_SUBST(ustinc)
 144
 145 AC_ARG_ENABLE(werror,
 146   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
 147   [case "${enableval}" in
 148      yes | y) ERROR_ON_WARNING="yes" ;;
 149      no | n)  ERROR_ON_WARNING="no" ;;
 150      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
 151    esac])
 152
 153 # Enable -Werror by default when using gcc.  Turn it off for releases.
 154 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
 155     ERROR_ON_WARNING=yes
 156 fi
 157
 158 WERROR_CFLAGS=""
 159 if test "${ERROR_ON_WARNING}" = yes ; then
 160     WERROR_CFLAGS="-Werror"
 161 fi
 162
 163 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
 164 -Wformat-nonliteral -Wno-char-subscripts -Wempty-body"
 165
 166 WARN_CFLAGS=""
 167 if test "x$GCC" = xyes
 168 then
 169     AC_MSG_CHECKING(compiler warning flags)
 170     # Separate out the -Werror flag as some files just cannot be
 171     # compiled with it enabled.
 172     for w in ${build_warnings}; do
 173         case $w in
 174         -Werr*) WERROR_CFLAGS=-Werror ;;
 175         *) # Check that GCC accepts it
 176             saved_CFLAGS="$CFLAGS"
 177             CFLAGS="$CFLAGS $w"
 178             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 179             CFLAGS="$saved_CFLAGS"
 180         esac
 181     done
 182     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 183 fi
 184 AC_SUBST(WARN_CFLAGS)
 185 AC_SUBST(WERROR_CFLAGS)
 186
 187 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 188 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 189 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 190 dnl augment LIBS.
 191 old_LIBS="$LIBS"
 192 LIBS="$LIBS -ldl"
 193 AC_CHECK_FUNCS(dladdr)
 194 LIBS="$old_LIBS"
 195
 196 libiberty_INIT
 197
 198 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 199
 200 AC_CHECK_TYPES(socklen_t, [], [],
 201 [#include <sys/types.h>
 202 #include <sys/socket.h>
 203 ])
 204
 205 AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 206 #include <elf.h>
 207 )
 208
 209 ACX_PKGVERSION([GDB])
 210 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 211 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 212 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 213
 214 # Check for various supplementary target information (beyond the
 215 # triplet) which might affect the choices in configure.srv.
 216 case "${target}" in
 217 changequote(,)dnl
 218   i[34567]86-*-linux*)
 219 changequote([,])dnl
 220     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 221                    [save_CPPFLAGS="$CPPFLAGS"
 222                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 223                     AC_EGREP_CPP([got it], [
 224 #if __x86_64__
 225 got it
 226 #endif
 227                  ], [gdb_cv_i386_is_x86_64=yes],
 228                     [gdb_cv_i386_is_x86_64=no])
 229                     CPPFLAGS="$save_CPPFLAGS"])
 230     ;;
 231   m68k-*-*)
 232     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 233                    [save_CPPFLAGS="$CPPFLAGS"
 234                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 235                     AC_EGREP_CPP([got it], [
 236 #ifdef __mcoldfire__
 237 got it
 238 #endif
 239                  ], [gdb_cv_m68k_is_coldfire=yes],
 240                     [gdb_cv_m68k_is_coldfire=no])
 241                     CPPFLAGS="$save_CPPFLAGS"])
 242     ;;
 243 esac
 244
 245 . ${srcdir}/configure.srv
 246
 247 # Add in the common host objects.
 248 . ${srcdir}/../common/common.host
 249 srv_host_obs="$common_host_obs"
 250
 251 if test "${srv_mingwce}" = "yes"; then
 252   LIBS="$LIBS -lws2"
 253 elif test "${srv_mingw}" = "yes"; then
 254   LIBS="$LIBS -lws2_32"
 255 elif test "${srv_qnx}" = "yes"; then
 256   LIBS="$LIBS -lsocket"
 257 elif test "${srv_lynxos}" = "yes"; then
 258   LIBS="$LIBS -lnetinet"
 259 fi
 260
 261 if test "${srv_mingw}" = "yes"; then
 262   AC_DEFINE(USE_WIN32API, 1,
 263             [Define if we should use the Windows API, instead of the
 264              POSIX API.  On Windows, we use the Windows API when
 265              building for MinGW, but the POSIX API when building
 266              for Cygwin.])
 267 fi
 268
 269 if test "${srv_linux_usrregs}" = "yes"; then
 270   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 271             [Define if the target supports PTRACE_PEEKUSR for register ]
 272             [access.])
 273 fi
 274
 275 if test "${srv_linux_regsets}" = "yes"; then
 276   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 277             [Define if the target supports register sets.])
 278
 279   AC_MSG_CHECKING(for PTRACE_GETREGS)
 280   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 281   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 282                   [PTRACE_GETREGS;],
 283                   [gdbsrv_cv_have_ptrace_getregs=yes],
 284                   [gdbsrv_cv_have_ptrace_getregs=no])])
 285   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 286   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 287     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 288               [Define if the target supports PTRACE_GETREGS for register ]
 289               [access.])
 290   fi
 291
 292   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 293   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 294   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 295                   [PTRACE_GETFPXREGS;],
 296                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 297                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 298   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 299   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 300     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 301               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 302               [register access.])
 303   fi
 304 fi
 305
 306 if test "${srv_linux_btrace}" = "yes"; then
 307   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 308             [Define if the target supports branch tracing.])
 309 fi
 310
 311 if test "$ac_cv_header_sys_procfs_h" = yes; then
 312   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 313   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 314   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 315   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 316 fi
 317
 318 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 319 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 320   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 321 fi
 322
 323 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 324 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 325   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 326 fi
 327
 328 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 329 dnl needs it (and gdbreplay doesn't).
 330 old_LIBS="$LIBS"
 331 AC_CHECK_LIB(dl, dlopen)
 332 LIBS="$old_LIBS"
 333
 334 srv_thread_depfiles=
 335 srv_libs=
 336
 337 if test "$srv_linux_thread_db" = "yes"; then
 338   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 339     srv_libs="-ldl"
 340     AC_MSG_CHECKING(for the dynamic export flag)
 341     old_LDFLAGS="$LDFLAGS"
 342     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 343     # supported there.
 344     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 345     LDFLAGS="$LDFLAGS $RDYNAMIC"
 346     AC_TRY_LINK([], [],
 347                 [found="-Wl,--dynamic-list"
 348                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 349                 [RDYNAMIC="-rdynamic"
 350                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 351                  AC_TRY_LINK([], [],
 352                              [found="-rdynamic"],
 353                              [found="no"
 354                               RDYNAMIC=""])])
 355     AC_SUBST(RDYNAMIC)
 356     LDFLAGS="$old_LDFLAGS"
 357     AC_MSG_RESULT($found)
 358   else
 359     srv_libs="-lthread_db"
 360   fi
 361
 362   srv_thread_depfiles="thread-db.o proc-service.o"
 363   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 364   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 365   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 366                   [gdbsrv_cv_have_td_version=yes],
 367                   [gdbsrv_cv_have_td_version=no])])
 368   if test $gdbsrv_cv_have_td_version = yes; then
 369     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 370   fi
 371 fi
 372
 373 AC_ARG_WITH(libthread-db,
 374 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 375 [srv_libthread_db_path="${withval}"
 376   srv_libs="$srv_libthread_db_path"
 377 ])
 378
 379 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 380   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 381 fi
 382
 383 if test "$srv_xmlfiles" != ""; then
 384   srv_xmlbuiltin="xml-builtin.o"
 385   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 386
 387   tmp_xmlfiles=$srv_xmlfiles
 388   srv_xmlfiles=""
 389   for f in $tmp_xmlfiles; do
 390     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 391   done
 392 fi
 393
 394 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs"
 395 GDBSERVER_LIBS="$srv_libs"
 396
 397 dnl Check whether the target supports __sync_*_compare_and_swap.
 398 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 399                 gdbsrv_cv_have_sync_builtins, [
 400 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 401                 gdbsrv_cv_have_sync_builtins=yes,
 402                 gdbsrv_cv_have_sync_builtins=no)])
 403 if test $gdbsrv_cv_have_sync_builtins = yes; then
 404   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 405     [Define to 1 if the target supports __sync_*_compare_and_swap])
 406 fi
 407
 408 dnl Check for -fvisibility=hidden support in the compiler.
 409 saved_cflags="$CFLAGS"
 410 CFLAGS="$CFLAGS -fvisibility=hidden"
 411 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 412                         [gdbsrv_cv_have_visibility_hidden=yes],
 413                         [gdbsrv_cv_have_visibility_hidden=no])
 414 CFLAGS="$saved_cflags"
 415
 416 dnl Check if we can disable the virtual address space randomization.
 417 dnl The functionality of setarch -R.
 418 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 419 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 420 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 421 #       define ADDR_NO_RANDOMIZE 0x0040000
 422 #      endif
 423        /* Test the flag could be set and stays set.  */
 424        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 425        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 426            return 1])])
 427 AC_RUN_IFELSE([PERSONALITY_TEST],
 428               [gdbsrv_cv_have_personality=true],
 429               [gdbsrv_cv_have_personality=false],
 430               [AC_LINK_IFELSE([PERSONALITY_TEST],
 431                               [gdbsrv_cv_have_personality=true],
 432                               [gdbsrv_cv_have_personality=false])])
 433 if $gdbsrv_cv_have_personality
 434 then
 435     AC_DEFINE([HAVE_PERSONALITY], 1,
 436               [Define if you support the personality syscall.])
 437 fi
 438
 439
 440 IPA_DEPFILES=""
 441 extra_libraries=""
 442
 443 # check whether to enable the inprocess agent
 444 if test "$ipa_obj" != "" \
 445    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 446    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 447    have_ipa=true
 448 else
 449    have_ipa=false
 450 fi
 451
 452 AC_ARG_ENABLE(inprocess-agent,
 453 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 454 [case "$enableval" in
 455   yes) want_ipa=true ;;
 456   no) want_ipa=false ;;
 457   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 458 esac],
 459 [want_ipa=$have_ipa])
 460
 461 if $want_ipa ; then
 462    if $have_ipa ; then
 463      IPA_DEPFILES="$ipa_obj"
 464      extra_libraries="$extra_libraries libinproctrace.so"
 465    else
 466      AC_MSG_ERROR([inprocess agent not supported for this target])
 467    fi
 468 fi
 469
 470 AC_SUBST(GDBSERVER_DEPFILES)
 471 AC_SUBST(GDBSERVER_LIBS)
 472 AC_SUBST(srv_xmlbuiltin)
 473 AC_SUBST(srv_xmlfiles)
 474 AC_SUBST(IPA_DEPFILES)
 475 AC_SUBST(extra_libraries)
 476
 477 GNULIB=build-gnulib-gdbserver/import
 478
 479 GNULIB_STDINT_H=
 480 if test x"$STDINT_H" != x; then
 481   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 482 fi
 483 AC_SUBST(GNULIB_STDINT_H)
 484
 485 AC_OUTPUT(Makefile,
 486 [case x$CONFIG_HEADERS in
 487 xconfig.h:config.in)
 488 echo > stamp-h ;;
 489 esac
 490 ])