gdb/testsuite/configure.in

   1 dnl Process this file file with autoconf to produce a configure script.
   2 dnl This file is a shell script fragment that supplies the information
   3 dnl necessary to tailor a template configure script into the configure
   4 dnl script appropriate for this directory.  For more information, check
   5 dnl any existing configure script.
   6
   7 AC_PREREQ(2.12.1)
   8 AC_INIT(gdb.base)
   9
  10 CC=${CC-cc}
  11 AC_SUBST(CC)
  12 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/../..)
  13 AC_CANONICAL_SYSTEM
  14
  15 # Directories to use in all configurations.
  16 configdirs="gdb.arch \
  17             gdb.asm \
  18             gdb.base \
  19             gdb.c++ \
  20             gdb.java \
  21             gdb.disasm \
  22             gdb.chill \
  23             gdb.mi \
  24             gdb.threads \
  25             gdb.trace"
  26
  27
  28 # Directories to use for a configuration which uses stabs.
  29 stabsdirs="gdb.stabs"
  30
  31         # this section is for targets that use stabs
  32 # add stabs tests for appropriate targets
  33 case "${target}" in
  34         powerpc-*-aix*) configdirs="${configdirs} ${stabsdirs}" ;;
  35         rs6000-*-aix*)  configdirs="${configdirs} ${stabsdirs}" ;;
  36         *-*-bsd*)       configdirs="${configdirs} ${stabsdirs}" ;;
  37         *-*-go32*)      configdirs="${configdirs} ${stabsdirs}" ;;
  38         *-*-linux*)     configdirs="${configdirs} ${stabsdirs}" ;;
  39         *-*-lynxos*)    configdirs="${configdirs} ${stabsdirs}" ;;
  40         *-sun-*)        configdirs="${configdirs} ${stabsdirs}" ;;
  41         hppa*-*-*)      configdirs="${configdirs} ${stabsdirs}" ;;
  42         *-*-elf*)       configdirs="${configdirs} ${stabsdirs}" ;;
  43         *)              if test "x${with_stabs}" = x"yes" ; then
  44                           configdirs="${configdirs} ${stabsdirs}"
  45                         fi ;;
  46 esac
  47
  48 # Directory with HP specific tests. They will run only with HP's compilers.
  49 # These tests will not work on other platforms and compilers.
  50
  51 hpdir="gdb.hp"
  52
  53 case "${target}" in
  54  hppa*-*-hpux*) configdirs="${configdirs} ${hpdir}" ;;
  55 esac
  56
  57
  58 # Begin stuff to support --enable-shared
  59 AC_ARG_ENABLE(shared,
  60 [  --enable-shared         use shared libraries],
  61 [case "${enableval}" in
  62   yes) shared=true ;;
  63   no)  shared=false ;;
  64   *) shared=true ;;
  65 esac])dnl
  66 RPATH_ENVVAR=LD_LIBRARY_PATH
  67 # If we have shared libraries, try to set RPATH_ENVVAR reasonably.
  68 if test "${shared}" = "true"; then
  69   case "${host}" in
  70   *-*-hpux*)
  71     RPATH_ENVVAR=SHLIB_PATH
  72     ;;
  73   esac
  74 fi
  75 AC_SUBST(RPATH_ENVVAR)
  76 # End stuff to support --enable-shared
  77 # Start stuff to support --enable-gdbtk
  78 AC_ARG_ENABLE(gdbtk,
  79 [  --enable-gdbtk ],
  80 [case "${enableval}" in
  81     yes)
  82         case "$host" in
  83         *go32*)
  84             enable_gdbtk=no ;;
  85         *windows*)
  86             enable_gdbtk=no ;;
  87         *)
  88             enable_gdbtk=yes ;;
  89         esac ;;
  90     no)
  91         enable_gdbtk=no  ;;
  92     *)
  93         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
  94 esac],
  95 [
  96 # Default is on for everything but go32 and windows
  97 case "$host" in
  98     *go32* | *windows*)
  99         ;;
 100     *)
 101         enable_gdbtk=yes ;;
 102     esac
 103 ])
 104
 105 if test "${enable_gdbtk}" = "yes"; then
 106     configdirs="${configdirs} gdb.gdbtk"
 107 fi
 108 # End stuff to support --enable-shared
 109
 110 dnl Check for exe extension set on certain hosts (e.g. Win32)
 111 AC_EXEEXT
 112
 113 # configure the subdirectories too
 114 AC_CONFIG_SUBDIRS($configdirs)
 115
 116 dnl AC_SUBST(gdb_target_cpu)
 117 AC_OUTPUT(Makefile)