gdb/testsuite/gdb.base/index-cache.exp

   1 #   Copyright 2018 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # This test checks that the index-cache feature generates the expected files at
  17 # the expected location.
  18
  19 standard_testfile
  20
  21 if { [prepare_for_testing "failed to prepare" $testfile $srcfile] } {
  22     return
  23 }
  24
  25 # List the files in DIR on the host (where GDB-under-test runs).
  26 # Return a list of two elements:
  27 #   - 0 on success, -1 on failure
  28 #   - the list of files on success, empty on failure
  29
  30 proc ls_host { dir } {
  31     lassign [remote_exec host ls "-1 $dir"] ret output
  32
  33     if { $ret != 0 } {
  34         fail "failed to list files on host in $dir"
  35         return -1
  36     }
  37
  38     # ls -1 returns a list separated by \r\n.  split will return a bunch of
  39     # empty entries (it treats a sequence of split characters as separate
  40     # fields, plus there is a \r\n at the end of the result).  Ignore empty
  41     # list elements.
  42     set filtered {}
  43     set files [split $output \r\n]
  44
  45     foreach file $files {
  46         if { $file != "" } {
  47             lappend filtered $file
  48         }
  49     }
  50
  51     return "0 $filtered"
  52 }
  53
  54 # Execute "show index-cache stats" and verify the output against expected
  55 # values.
  56
  57 proc check_cache_stats { expected_hits expected_misses } {
  58     set re [multi_line \
  59         "  Cache hits .this session.: $expected_hits" \
  60         "Cache misses .this session.: $expected_misses" \
  61     ]
  62
  63     gdb_test "show index-cache stats" $re "check index-cache stats"
  64 }
  65
  66 # Run CODE using a fresh GDB configured based on the other parameters.
  67
  68 proc run_test_with_flags { cache_dir cache_enabled code } {
  69     global GDBFLAGS testfile
  70
  71     save_vars { GDBFLAGS } {
  72         set GDBFLAGS "$GDBFLAGS -iex \"set index-cache directory $cache_dir\""
  73         set GDBFLAGS "$GDBFLAGS -iex \"set index-cache $cache_enabled\""
  74
  75         clean_restart ${testfile}
  76
  77         uplevel 1 $code
  78     }
  79 }
  80
  81 # Test administrative stuff.
  82
  83 proc_with_prefix test_basic_stuff { } {
  84     global testfile
  85
  86     clean_restart ${testfile}
  87
  88     # Check that the index cache is disabled by default.
  89     gdb_test \
  90         "show index-cache" \
  91         " is currently disabled." \
  92         "index-cache is disabled by default"
  93
  94     # Test that we can enable it and "show index-cache" reflects that.
  95     gdb_test_no_output "set index-cache on" "enable index cache"
  96     gdb_test \
  97         "show index-cache" \
  98         " is currently enabled." \
  99         "index-cache is now enabled"
 100
 101     # Test the "set/show index-cache directory" commands.
 102     gdb_test "set index-cache directory" "Argument required.*" "set index-cache directory without arg"
 103     gdb_test_no_output "set index-cache directory /tmp" "change the index cache directory"
 104     gdb_test \
 105         "show index-cache directory" \
 106         "The directory of the index cache is \"/tmp\"."  \
 107         "show index cache directory"
 108 }
 109
 110 # Test loading a binary with the cache disabled.  No file should be created.
 111
 112 proc_with_prefix test_cache_disabled { cache_dir } {
 113     lassign [ls_host $cache_dir] ret files_before
 114
 115     run_test_with_flags $cache_dir off {
 116         lassign [ls_host $cache_dir] ret files_after
 117
 118         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 119         gdb_assert "$nfiles_created == 0" "no files were created"
 120
 121         check_cache_stats 0 0
 122     }
 123 }
 124
 125 # Test with the cache enabled, we expect to have exactly one file created.
 126
 127 proc_with_prefix test_cache_enabled_miss { cache_dir } {
 128     global testfile
 129
 130     lassign [ls_host $cache_dir] ret files_before
 131
 132     run_test_with_flags $cache_dir on {
 133
 134         lassign [ls_host $cache_dir] ret files_after
 135         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 136         gdb_assert "$nfiles_created > 0" "at least one file was created"
 137
 138         set build_id [get_build_id  [standard_output_file ${testfile}]]
 139         if { $build_id == "" } {
 140             fail "couldn't get executable build id"
 141             return
 142         }
 143
 144         set expected_created_file [list "${build_id}.gdb-index"]
 145         set found_idx [lsearch -exact $files_after $expected_created_file]
 146         gdb_assert "$found_idx >= 0" "expected file is there"
 147
 148         remote_exec host rm "-f $cache_dir/$expected_created_file"
 149
 150         check_cache_stats 0 1
 151     }
 152 }
 153
 154
 155 # Test with the cache enabled, this time we should have one file (the
 156 # same), but one cache read hit.
 157
 158 proc_with_prefix test_cache_enabled_hit { cache_dir } {
 159     # Just to populate the cache.
 160     run_test_with_flags $cache_dir on {}
 161
 162     lassign [ls_host $cache_dir] ret files_before
 163
 164     run_test_with_flags $cache_dir on {
 165         lassign [ls_host $cache_dir] ret files_after
 166         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 167         gdb_assert "$nfiles_created == 0" "no files were created"
 168
 169         check_cache_stats 1 0
 170     }
 171 }
 172
 173 test_basic_stuff
 174
 175 # The cache dir should be on the host (possibly remote), so we can't use the
 176 # standard output directory for that (it's on the build machine).
 177 lassign [remote_exec host mktemp -d] ret cache_dir
 178
 179 if { $ret != 0 } {
 180     fail "couldn't create temporary cache dir"
 181     return
 182 }
 183
 184 # The ouput of mktemp contains an end of line, remove it.
 185 set cache_dir [string trimright $cache_dir \r\n]
 186
 187 test_cache_disabled $cache_dir
 188 test_cache_enabled_miss $cache_dir
 189 test_cache_enabled_hit $cache_dir
 190
 191 # Test again with the cache disabled, now that it is populated.
 192 test_cache_disabled $cache_dir
 193