gdb/testsuite/gdb.base/maint-print-frame-id.exp

   1 # Copyright 2022-2023 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test the 'maint print frame-id' command.
  17
  18 standard_testfile
  19
  20 if {[prepare_for_testing "failed to prepare" $testfile \
  21          $srcfile {debug}]} {
  22     return -1
  23 }
  24
  25 if {![runto_main]} {
  26     return -1
  27 }
  28
  29 gdb_breakpoint foo
  30 gdb_continue_to_breakpoint "run to foo"
  31
  32 proc get_frame_id { level } {
  33     set id "**unknown**"
  34
  35     gdb_test_multiple "maint print frame-id ${level}" "" {
  36         -re "^maint print frame-id\[^\r\n\]+\r\n" {
  37             exp_continue
  38         }
  39
  40         -wrap -re "^frame-id for frame #\[0-9\]+: (\[^\r\n\]+)" {
  41             set id $expect_out(1,string)
  42             pass $gdb_test_name
  43         }
  44     }
  45
  46     return $id
  47 }
  48
  49 # Get the frame-id for each frame using the frame level.
  50 array set ids {}
  51 with_test_prefix "get id by level" {
  52     for { set i 0 } { $i < 4 } { incr i } {
  53         set ids($i) [get_frame_id $i]
  54     }
  55 }
  56
  57 # Now get the frame-id of the currently selected frame, and check it
  58 # matches the frame-id we got earlier.  Then move up the stack,
  59 # selecting a new frame.
  60 for { set i 0 } { $i < 4 } { incr i } {
  61     with_test_prefix "frame $i is current" {
  62         set id [get_frame_id ""]
  63         gdb_assert { [string equal $id $ids($i)] } \
  64             "check frame-id matches"
  65     }
  66     gdb_test "up" ".*" \
  67         "move up from frame $i"
  68 }