gdb/testsuite/gdb.threads/access-mem-running-thread-exit.exp

   1 # Copyright (C) 2021-2024 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test that we can access memory while all the threads of the inferior
  17 # are running, and even if:
  18 #
  19 # - the leader thread exits
  20 # - the selected thread exits
  21 #
  22 # This test constantly spawns short lived threads to make sure that on
  23 # systems with debug APIs that require passing down a specific thread
  24 # to work with (e.g., GNU/Linux ptrace and /proc filesystem), GDB
  25 # copes with accessing memory just while the thread it is accessing
  26 # memory through exits.
  27 #
  28 # The test spawns two processes and alternates memory accesses between
  29 # them to force flushing per-process caches.  When the testcase was
  30 # originally written, the Linux backend would access inferior memory
  31 # via /proc/PID/mem, and kept one such file open, as a cache.
  32 # Alternating inferiors would force re-opening such file for a
  33 # different process, which would fail if GDB tried to open the file
  34 # for a thread that exited.  The test thus ensured those reopen/fail
  35 # code paths were exercised.  Nowadays, GDB keeps one /proc/PID/mem
  36 # file open per inferior.
  37
  38 standard_testfile
  39
  40 if {[build_executable "failed to prepare" $testfile $srcfile {debug pthreads}] == -1} {
  41     return -1
  42 }
  43
  44 # The test proper.  NON_STOP indicates whether we're testing in
  45 # non-stop, or all-stop mode.
  46
  47 proc test { non_stop } {
  48     global binfile
  49     global gdb_prompt
  50     global GDBFLAGS
  51
  52     save_vars { GDBFLAGS } {
  53       append GDBFLAGS " -ex \"set non-stop $non_stop\""
  54       clean_restart ${binfile}
  55     }
  56
  57     if ![runto_main] {
  58         return -1
  59     }
  60
  61     # If debugging with target remote, check whether the all-stop variant
  62     # of the RSP is being used.  If so, we can't run the background tests.
  63     if {!$non_stop
  64         && [target_info exists gdb_protocol]
  65         && ([target_info gdb_protocol] == "remote"
  66             || [target_info gdb_protocol] == "extended-remote")} {
  67
  68         if {![is_target_non_stop]} {
  69             unsupported "can't issue commands while target is running"
  70             return 0
  71         }
  72     }
  73
  74     delete_breakpoints
  75
  76     # Start the second inferior.
  77     with_test_prefix "second inferior" {
  78         # With stub targets that do reload on run, if we let the new
  79         # inferior share inferior 1's connection, runto_main would
  80         # fail because GDB is already connected to something, like
  81         # e.g. with --target_board=native-gdbserver:
  82         #
  83         #  (gdb) kill
  84         #  ...
  85         #  (gdb) target remote localhost:2348
  86         #  Already connected to a remote target.  Disconnect? (y or n)
  87         #
  88         # Instead, start the inferior with no connection, and let
  89         # gdb_load/runto_main spawn a new remote connection/gdbserver.
  90         #
  91         # OTOH, with extended-remote, we must let the new inferior
  92         # reuse the current connection, so that runto_main below can
  93         # issue the "run" command, and have the inferior run on the
  94         # remote target.  If we forced no connection, then "run" would
  95         # either fail if "set auto-connect-native-target" is on, like
  96         # the native-extended-gdbserver board enforces, or it would
  97         # run the inferior on the native target, which isn't what is
  98         # being tested.
  99         #
 100         # Since it's reload_on_run targets that need special care, we
 101         # default to reusing the connection on most targets.
 102         if [target_info exists gdb,do_reload_on_run] {
 103             gdb_test "add-inferior -no-connection" "New inferior 2.*"
 104         } else {
 105             gdb_test "add-inferior" "New inferior 2.*"
 106         }
 107         gdb_test "inferior 2" "Switching to inferior 2 .*"
 108
 109         gdb_load $binfile
 110
 111         if ![runto_main] {
 112             return -1
 113         }
 114     }
 115
 116     delete_breakpoints
 117
 118     # These put too much noise in the logs.
 119     gdb_test_no_output "set print thread-events off"
 120
 121     # Continue all threads of both processes.
 122     gdb_test_no_output "set schedule-multiple on"
 123     if {$non_stop == "off"} {
 124         set cmd "continue &"
 125     } else {
 126         set cmd "continue -a &"
 127     }
 128     gdb_test_multiple $cmd "continuing" {
 129         -re "Continuing\.\r\n$gdb_prompt " {
 130             pass $gdb_test_name
 131         }
 132     }
 133
 134     # Like gdb_test, but:
 135     # - don't issue a pass on success.
 136     # - on failure, clear the ok variable in the calling context, and
 137     #   break it.
 138     proc my_gdb_test {cmd pattern message} {
 139         upvar inf inf
 140         upvar iter iter
 141         if {[gdb_test -nopass \
 142                  $cmd $pattern "access mem ($message, inf=$inf, iter=$iter)"] \
 143                 != 0} {
 144             uplevel 1 {set ok 0}
 145             return -code break
 146         }
 147     }
 148
 149     # Hammer away for 5 seconds, alternating between inferiors.
 150     set ::done 0
 151     after 5000 { set ::done 1 }
 152
 153     set inf 1
 154     set ok 1
 155     set iter 0
 156     while {!$::done && $ok} {
 157         incr iter
 158         verbose -log "xxxxx: iteration $iter"
 159         gdb_test -nopass "info threads"
 160
 161         if {$inf == 1} {
 162             set inf 2
 163         } else {
 164             set inf 1
 165         }
 166
 167         my_gdb_test "inferior $inf" ".*" "inferior $inf"
 168
 169         my_gdb_test "print global_var = 555" " = 555" \
 170             "write to global_var"
 171         my_gdb_test "print global_var" " = 555" \
 172             "print global_var after writing"
 173         my_gdb_test "print global_var = 333" " = 333" \
 174             "write to global_var again"
 175         my_gdb_test "print global_var" " = 333" \
 176             "print global_var after writing again"
 177     }
 178
 179    if {$ok} {
 180        pass "access mem"
 181    }
 182 }
 183
 184 foreach non_stop { "off" "on" } {
 185     set stop_mode [expr ($non_stop=="off")?"all-stop":"non-stop"]
 186     with_test_prefix "$stop_mode" {
 187         test $non_stop
 188     }
 189 }