gdb/testsuite/lib/cp-support.exp

   1 # This test code is part of GDB, the GNU debugger.
   2
   3 # Copyright 2003, 2004, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Auxiliary function to check for known problems.
  19 #
  20 # EXPECTED_STRING is the string expected by the test.
  21 #
  22 # ACTUAL_STRING is the actual string output by gdb.
  23 #
  24 # ERRATA_TABLE is a list of lines of the form:
  25 #
  26 #  { expected-string broken-string {eval-block} }
  27 #
  28 # If there is a line for the given EXPECTED_STRING, and if the
  29 # ACTUAL_STRING output by gdb is the same as the BROKEN_STRING in the
  30 # table, then I eval the eval-block.
  31
  32 proc cp_check_errata { expected_string actual_string errata_table } {
  33     foreach erratum $errata_table {
  34         if { "$expected_string" == [lindex $erratum 0]
  35         &&   "$actual_string"   == [lindex $erratum 1] } then {
  36             eval [lindex $erratum 2]
  37         }
  38     }
  39 }
  40
  41 # Test ptype of a class.
  42 #
  43 # Different C++ compilers produce different output.  To accommodate all
  44 # the variations listed below, I read the output of "ptype" and process
  45 # each line, matching it to the class description given in the
  46 # parameters.
  47 #
  48 # IN_COMMAND and IN_TESTNAME are the command and testname for
  49 # gdb_test_multiple.  If IN_TESTNAME is the empty string, then it
  50 # defaults to IN_COMMAND.
  51 #
  52 # IN_KEY is "class" or "struct".  For now, I ignore it, and allow either
  53 # "class" or "struct" in the output, as long as the access specifiers all
  54 # work out okay.
  55 #
  56 # IN_TAG is the class tag or structure tag.
  57 #
  58 # IN_CLASS_TABLE is a list of class information.  Each entry contains a
  59 # keyword and some values.  The keywords and their values are:
  60 #
  61 #   { base "base-declaration" }
  62 #
  63 #      the class has a base with the given declaration.
  64 #
  65 #   { vbase "name" }
  66 #
  67 #      the class has a virtual base pointer with the given name.  this
  68 #      is for gcc 2.95.3, which emits ptype entries for the virtual base
  69 #      pointers.  the vbase list includes both indirect and direct
  70 #      virtual base classes (indeed, a virtual base is usually
  71 #      indirect), so this information cannot be derived from the base
  72 #      declarations.
  73 #
  74 #   { field "access" "declaration" }
  75 #
  76 #      the class has a data field with the given access type and the
  77 #      given declaration.
  78 #
  79 #   { method "access" "declaration" }
  80 #
  81 #      the class has a member function with the given access type
  82 #      and the given declaration.
  83 #
  84 # If you test the same class declaration more than once, you can specify
  85 # IN_CLASS_TABLE as "ibid".  "ibid" means: look for a previous class
  86 # table that had the same IN_KEY and IN_TAG, and re-use that table.
  87 #
  88 # IN_TAIL is the expected text after the close brace, specifically the "*"
  89 # in "struct { ... } *".  This is an optional parameter.  The default
  90 # value is "", for no tail.
  91 #
  92 # IN_ERRATA_TABLE is a list of errata entries.  See cp_check_errata for the
  93 # format of the errata table.  Note: the errata entries are not subject to
  94 # demangler syntax adjustment, so you have to make a bigger table
  95 # with lines for each output variation.
  96 #
  97 # gdb can vary the output of ptype in several ways:
  98 #
  99 # . CLASS/STRUCT
 100 #
 101 #   The output can start with either "class" or "struct", depending on
 102 #   what the symbol table reader in gdb decides.  This is usually
 103 #   unrelated to the original source code.
 104 #
 105 #     dwarf-2  debug info distinguishes class/struct, but gdb ignores it
 106 #     stabs+   debug info does not distinguish class/struct
 107 #     hp       debug info distinguishes class/struct, and gdb honors it
 108 #
 109 #   I tried to accommodate this with regular expressions such as
 110 #   "((class|struct) A \{ public:|struct A \{)", but that turns into a
 111 #   hairy mess because of optional private virtual base pointers and
 112 #   optional public synthetic operators.  This is the big reason I gave
 113 #   up on regular expressions and started parsing the output.
 114 #
 115 # . REDUNDANT ACCESS SPECIFIER
 116 #
 117 #   In "class { private: ... }" or "struct { public: ... }", gdb might
 118 #   or might not emit a redundant initial access specifier, depending
 119 #   on the gcc version.
 120 #
 121 # . VIRTUAL BASE POINTERS
 122 #
 123 #   If a class has virtual bases, either direct or indirect, the class
 124 #   will have virtual base pointers.  With gcc 2.95.3, gdb prints lines
 125 #   for these virtual base pointers.  This does not happen with gcc
 126 #   3.3.4, gcc 3.4.1, or hp acc A.03.45.
 127 #
 128 #   I accept these lines.  These lines are optional; but if I see one of
 129 #   these lines, then I expect to see all of them.
 130 #
 131 #   Note: drow considers printing these lines to be a bug in gdb.
 132 #
 133 # . SYNTHETIC METHODS
 134 #
 135 #   A C++ compiler may synthesize some methods: an assignment
 136 #   operator, a copy constructor, a constructor, and a destructor.  The
 137 #   compiler might include debug information for these methods.
 138 #
 139 #     dwarf-2  gdb does not show these methods
 140 #     stabs+   gdb shows these methods
 141 #     hp       gdb does not show these methods
 142 #
 143 #   I accept these methods.  These lines are optional, and any or
 144 #   all of them might appear, mixed in anywhere in the regular methods.
 145 #
 146 #   With gcc v2, the synthetic copy-ctor and ctor have an additional
 147 #   "int" parameter at the beginning, the "in-charge" flag.
 148 #
 149 # . DEMANGLER SYNTAX VARIATIONS
 150 #
 151 #   Different demanglers produce "int foo(void)" versus "int foo()",
 152 #   "const A&" versus "const A &", and so on.
 153 #
 154 # TESTED WITH
 155 #
 156 #   gcc 2.95.3 -gdwarf-2
 157 #   gcc 2.95.3 -gstabs+
 158 #   gcc 3.3.4 -gdwarf-2
 159 #   gcc 3.3.4 -gstabs+
 160 #   gcc 3.4.1 -gdwarf-2
 161 #   gcc 3.4.1 -gstabs+
 162 #   gcc HEAD 20040731 -gdwarf-2
 163 #   gcc HEAD 20040731 -gstabs+
 164 #
 165 # TODO
 166 #
 167 # Tagless structs.
 168 #
 169 # "A*" versus "A *" and "A&" versus "A &" in user methods.
 170 #
 171 # Test with hp ACC.
 172 #
 173 # -- chastain 2004-08-07
 174
 175 proc cp_test_ptype_class { in_command in_testname in_key in_tag in_class_table { in_tail "" } { in_errata_table { } } } {
 176     global gdb_prompt
 177     set wsopt "\[\r\n\t \]*"
 178
 179     # The test name defaults to the command.
 180
 181     if { "$in_testname" == "" } then { set in_testname "$in_command" }
 182
 183     # Save class tables in a history array for reuse.
 184
 185     global cp_class_table_history
 186     if { $in_class_table == "ibid" } then {
 187         if { ! [info exists cp_class_table_history("$in_key,$in_tag") ] } then {
 188             fail "$in_testname // bad ibid"
 189             return
 190         }
 191         set in_class_table $cp_class_table_history("$in_key,$in_tag")
 192     } else {
 193         set cp_class_table_history("$in_key,$in_tag") $in_class_table
 194     }
 195
 196     # Split the class table into separate tables.
 197
 198     set list_bases   { }
 199     set list_vbases  { }
 200     set list_fields  { }
 201     set list_methods { }
 202
 203     foreach class_line $in_class_table {
 204         switch [lindex $class_line 0] {
 205             "base"   { lappend list_bases   [lindex $class_line 1] }
 206             "vbase"  { lappend list_vbases  [lindex $class_line 1] }
 207             "field"  { lappend list_fields  [lrange $class_line 1 2] }
 208             "method" { lappend list_methods [lrange $class_line 1 2] }
 209             default  { fail "$in_testname // bad line in class table: $class_line"; return; }
 210         }
 211     }
 212
 213     # Construct a list of synthetic operators.
 214     # These are: { count ccess-type regular-expression }.
 215
 216     set list_synth { }
 217     lappend list_synth [list 0 "public" "$in_tag & operator=\\($in_tag const ?&\\);"]
 218     lappend list_synth [list 0 "public" "$in_tag\\((int,|) ?$in_tag const ?&\\);"]
 219     lappend list_synth [list 0 "public" "$in_tag\\((int|void|)\\);"]
 220
 221     # Actually do the ptype.
 222
 223     set parse_okay 0
 224     gdb_test_multiple "$in_command" "$in_testname // parse failed" {
 225         -re "type = (struct|class)${wsopt}(\[A-Za-z0-9_\]*)${wsopt}((:\[^\{\]*)?)${wsopt}\{(.*)\}${wsopt}(\[^\r\n\]*)\[\r\n\]+$gdb_prompt $" {
 226             set parse_okay          1
 227             set actual_key          $expect_out(1,string)
 228             set actual_tag          $expect_out(2,string)
 229             set actual_base_string  $expect_out(3,string)
 230             set actual_body         $expect_out(5,string)
 231             set actual_tail         $expect_out(6,string)
 232         }
 233     }
 234     if { ! $parse_okay } then { return }
 235
 236     # Check the actual key.  It would be nice to require that it match
 237     # the input key, but gdb does not support that.  For now, accept any
 238     # $actual_key as long as the access property of each field/method
 239     # matches.
 240
 241     switch "$actual_key" {
 242         "class"  { set access "private" }
 243         "struct" { set access "public"  }
 244         default  {
 245             cp_check_errata "class"  "$actual_key" $in_errata_table
 246             cp_check_errata "struct" "$actual_key" $in_errata_table
 247             fail "$in_testname // wrong key: $actual_key"
 248             return
 249         }
 250     }
 251
 252     # Check the actual tag.
 253
 254     if { "$actual_tag" != "$in_tag" } then {
 255         cp_check_errata "$in_tag" "$actual_tag" $in_errata_table
 256         fail "$in_testname // wrong tag: $actual_tag"
 257         return
 258     }
 259
 260     # Check the actual bases.
 261     # First parse them into a list.
 262
 263     set list_actual_bases { }
 264     if { "$actual_base_string" != "" } then {
 265         regsub "^:${wsopt}" $actual_base_string "" actual_base_string
 266         set list_actual_bases [split $actual_base_string ","]
 267     }
 268
 269     # Check the base count.
 270
 271     if { [llength $list_actual_bases] < [llength $list_bases] } then {
 272         fail "$in_testname // too few bases"
 273         return
 274     }
 275     if { [llength $list_actual_bases] > [llength $list_bases] } then {
 276         fail "$in_testname // too many bases"
 277         return
 278     }
 279
 280     # Check each base.
 281
 282     foreach actual_base $list_actual_bases {
 283         set actual_base [string trim $actual_base]
 284         set base [lindex $list_bases 0]
 285         if { "$actual_base" != "$base" } then {
 286             cp_check_errata "$base" "$actual_base" $in_errata_table
 287             fail "$in_testname // wrong base: $actual_base"
 288             return
 289         }
 290         set list_bases [lreplace $list_bases 0 0]
 291     }
 292
 293     # Parse each line in the body.
 294
 295     set last_was_access 0
 296     set vbase_match 0
 297
 298     foreach actual_line [split $actual_body "\r\n"] {
 299
 300         # Chomp the line.
 301
 302         set actual_line [string trim $actual_line]
 303         if { "$actual_line" == "" } then { continue }
 304
 305         # Access specifiers.
 306
 307         if { [regexp "^(public|protected|private)${wsopt}:\$" "$actual_line" s0 s1] } then {
 308             set access "$s1"
 309             if { $last_was_access } then {
 310                 fail "$in_testname // redundant access specifier"
 311                 return
 312             }
 313             set last_was_access 1
 314             continue
 315         } else {
 316             set last_was_access 0
 317         }
 318
 319         # Optional virtual base pointer.
 320
 321         if { [ llength $list_vbases ] > 0 } then {
 322             set vbase [lindex $list_vbases 0]
 323             if { [ regexp "$vbase \\*(_vb.|_vb\\\$|__vb_)\[0-9\]*$vbase;" $actual_line ] } then {
 324                 if { "$access" != "private" } then {
 325                     cp_check_errata "private" "$access" $in_errata_table
 326                     fail "$in_testname // wrong access specifier for virtual base: $access"
 327                     return
 328                 }
 329                 set list_vbases [lreplace $list_vbases 0 0]
 330                 set vbase_match 1
 331                 continue
 332             }
 333         }
 334
 335         # Data field.
 336
 337         if { [llength $list_fields] > 0 } then {
 338             set field_access [lindex [lindex $list_fields 0] 0]
 339             set field_decl   [lindex [lindex $list_fields 0] 1]
 340             if { "$actual_line" == "$field_decl" } then {
 341                 if { "$access" != "$field_access" } then {
 342                     cp_check_errata "$field_access" "$access" $in_errata_table
 343                     fail "$in_testname // wrong access specifier for field: $access"
 344                     return
 345                 }
 346                 set list_fields [lreplace $list_fields 0 0]
 347                 continue
 348             }
 349
 350             # Data fields must appear before synths and methods.
 351             cp_check_errata "$field_decl" "$actual_line" $in_errata_table
 352             fail "$in_testname // unrecognized line type 1: $actual_line"
 353             return
 354         }
 355
 356         # Method function.
 357
 358         if { [llength $list_methods] > 0 } then {
 359             set method_access [lindex [lindex $list_methods 0] 0]
 360             set method_decl   [lindex [lindex $list_methods 0] 1]
 361             if { "$actual_line" == "$method_decl" } then {
 362                 if { "$access" != "$method_access" } then {
 363                     cp_check_errata "$method_access" "$access" $in_errata_table
 364                     fail "$in_testname // wrong access specifier for method: $access"
 365                     return
 366                 }
 367                 set list_methods [lreplace $list_methods 0 0]
 368                 continue
 369             }
 370
 371             # gcc 2.95.3 shows "foo()" as "foo(void)".
 372             regsub -all "\\(\\)" $method_decl "(void)" method_decl
 373             if { "$actual_line" == "$method_decl" } then {
 374                 if { "$access" != "$method_access" } then {
 375                     cp_check_errata "$method_access" "$access" $in_errata_table
 376                     fail "$in_testname // wrong access specifier for method: $access"
 377                     return
 378                 }
 379                 set list_methods [lreplace $list_methods 0 0]
 380                 continue
 381             }
 382         }
 383
 384         # Synthetic operators.  These are optional and can be mixed in
 385         # with the methods in any order, but duplicates are wrong.
 386         #
 387         # This test must come after the user methods, so that a user
 388         # method which matches a synth-method pattern is treated
 389         # properly as a user method.
 390
 391         set synth_match 0
 392         for { set isynth 0 } { $isynth < [llength $list_synth] } { incr isynth } {
 393             set synth         [lindex $list_synth $isynth]
 394             set synth_count   [lindex $synth 0]
 395             set synth_access  [lindex $synth 1]
 396             set synth_re      [lindex $synth 2]
 397
 398             if { [ regexp "$synth_re" "$actual_line" ] } then {
 399
 400                 if { "$access" != "$synth_access" } then {
 401                     cp_check_errata "$synth_access" "$access" $in_errata_table
 402                     fail "$in_testname // wrong access specifier for synthetic operator: $access"
 403                     return
 404                 }
 405
 406                 if { $synth_count > 0 } then {
 407                     cp_check_errata "$actual_line" "$actual_line" $in_errata_table
 408                     fail "$in_testname // duplicate synthetic operator: $actual_line"
 409                 }
 410
 411                 # Update the count in list_synth.
 412
 413                 incr synth_count
 414                 set synth [list $synth_count $synth_access "$synth_re"]
 415                 set list_synth [lreplace $list_synth $isynth $isynth $synth]
 416
 417                 # Match found.
 418
 419                 set synth_match 1
 420                 break
 421             }
 422         }
 423         if { $synth_match } then { continue }
 424
 425         # Unrecognized line.
 426
 427         if { [llength $list_methods] > 0 } then {
 428             set method_decl [lindex [lindex $list_methods 0] 1]
 429             cp_check_errata "$method_decl" "$actual_line" $in_errata_table
 430         }
 431
 432         fail "$in_testname // unrecognized line type 2: $actual_line"
 433         return
 434     }
 435
 436     # Check for missing elements.
 437
 438     if { $vbase_match } then {
 439         if { [llength $list_vbases] > 0 } then {
 440             fail "$in_testname // missing virtual base pointers"
 441             return
 442         }
 443     }
 444
 445     if { [llength $list_fields] > 0 } then {
 446         fail "$in_testname // missing fields"
 447         return
 448     }
 449
 450     if { [llength $list_methods] > 0 } then {
 451         fail "$in_testname // missing methods"
 452         return
 453     }
 454
 455     # Check the tail.
 456
 457     set actual_tail [string trim $actual_tail]
 458     if { "$actual_tail" != "$in_tail" } then {
 459         cp_check_errata "$in_tail" "$actual_tail" $in_errata_table
 460         fail "$in_testname // wrong tail: $actual_tail"
 461         return
 462     }
 463
 464     # It all worked!
 465
 466     pass "$in_testname"
 467     return
 468 }