gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(server.cc)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_GNU_SOURCE
  29 AC_SYS_LARGEFILE
  30 AM_PROG_INSTALL_STRIP
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_PROG_RANLIB
  37
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 AC_HEADER_STDC
  45
  46 GDB_AC_COMMON
  47 # This is set by GDB_AC_COMMON.
  48 AC_SUBST(WIN32APILIBS)
  49
  50 GDB_AC_SELFTEST
  51
  52 ACX_NONCANONICAL_TARGET
  53 ACX_NONCANONICAL_HOST
  54
  55 # Dependency checking.
  56 ZW_CREATE_DEPDIR
  57
  58 dnl Set up for gettext.
  59 ZW_GNU_GETTEXT_SISTER_DIR
  60
  61 # Create sub-directories for objects and dependencies.
  62 CONFIG_SRC_SUBDIR="arch gdbsupport nat target"
  63 AC_SUBST(CONFIG_SRC_SUBDIR)
  64
  65 AC_CONFIG_COMMANDS([gdbdepdir],[
  66   for subdir in ${CONFIG_SRC_SUBDIR}
  67   do
  68       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  69   done],
  70   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  71
  72 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  73
  74 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  75                  sys/procfs.h linux/elf.h dnl
  76                  fcntl.h signal.h sys/file.h dnl
  77                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  78                  netinet/tcp.h arpa/inet.h)
  79 AC_FUNC_FORK
  80 AC_CHECK_FUNCS(pread pwrite pread64)
  81
  82 # Check the return and argument types of ptrace.
  83 GDB_AC_PTRACE
  84
  85 # Check for UST
  86 ustlibs=""
  87 ustinc=""
  88
  89 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  90                           Equivalent to --with-ust-include=PATH/include
  91                           plus --with-ust-lib=PATH/lib])
  92 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
  93 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
  94
  95 case $with_ust in
  96   no)
  97     ustlibs=
  98     ustinc=
  99     ;;
 100   "" | yes)
 101     ustlibs=" -lust "
 102     ustinc=""
 103     ;;
 104   *)
 105     ustlibs="-L$with_ust/lib -lust"
 106     ustinc="-I$with_ust/include "
 107     ;;
 108 esac
 109 if test "x$with_ust_include" != x; then
 110   ustinc="-I$with_ust_include "
 111 fi
 112 if test "x$with_ust_lib" != x; then
 113   ustlibs="-L$with_ust_lib -lust"
 114 fi
 115
 116 if test "x$with_ust" != "xno"; then
 117   saved_CFLAGS="$CFLAGS"
 118   CFLAGS="$CFLAGS $ustinc"
 119   AC_MSG_CHECKING([for ust])
 120   AC_TRY_COMPILE([
 121 #define CONFIG_UST_GDB_INTEGRATION
 122 #include <ust/ust.h>
 123   ],[],
 124   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 125   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 126   CFLAGS="$saved_CFLAGS"
 127 fi
 128
 129 # Flags needed for UST
 130 AC_SUBST(ustlibs)
 131 AC_SUBST(ustinc)
 132
 133 AM_GDB_WARNINGS
 134
 135 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 136 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 137 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 138 dnl augment LIBS.
 139 old_LIBS="$LIBS"
 140 LIBS="$LIBS -ldl"
 141 AC_CHECK_FUNCS(dladdr)
 142 LIBS="$old_LIBS"
 143
 144 libiberty_INIT
 145
 146 AC_CHECK_DECLS([perror, vasprintf, vsnprintf])
 147
 148 AC_CHECK_TYPES(socklen_t, [], [],
 149 [#include <sys/types.h>
 150 #include <sys/socket.h>
 151 ])
 152
 153 case "${target}" in
 154   *-android*)
 155     # Starting with NDK version 9, <elf.h> actually includes definitions
 156     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 157     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 158     # leading to conflicts with the defintions from <linux/elf.h>.
 159     # This makes it impossible for us to include both <elf.h> and
 160     # <linux/elf.h>, which means that, in practice, we do not have
 161     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 162     # Therefore, do not try to auto-detect availability, as it would
 163     # get it wrong on this platform.
 164     ;;
 165   *)
 166     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 167     #include <elf.h>
 168     )
 169 esac
 170
 171 ACX_PKGVERSION([GDB])
 172 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 173 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 174 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 175
 176 # Check for various supplementary target information (beyond the
 177 # triplet) which might affect the choices in configure.srv.
 178 case "${target}" in
 179 changequote(,)dnl
 180   i[34567]86-*-linux*)
 181 changequote([,])dnl
 182     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 183                    [save_CPPFLAGS="$CPPFLAGS"
 184                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 185                     AC_EGREP_CPP([got it], [
 186 #if __x86_64__
 187 got it
 188 #endif
 189                  ], [gdb_cv_i386_is_x86_64=yes],
 190                     [gdb_cv_i386_is_x86_64=no])
 191                     CPPFLAGS="$save_CPPFLAGS"])
 192     ;;
 193
 194   x86_64-*-linux*)
 195     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 196                    [save_CPPFLAGS="$CPPFLAGS"
 197                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 198                     AC_EGREP_CPP([got it], [
 199 #if __x86_64__ && __ILP32__
 200 got it
 201 #endif
 202                  ], [gdb_cv_x86_is_x32=yes],
 203                     [gdb_cv_x86_is_x32=no])
 204                     CPPFLAGS="$save_CPPFLAGS"])
 205     ;;
 206
 207   m68k-*-*)
 208     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 209                    [save_CPPFLAGS="$CPPFLAGS"
 210                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 211                     AC_EGREP_CPP([got it], [
 212 #ifdef __mcoldfire__
 213 got it
 214 #endif
 215                  ], [gdb_cv_m68k_is_coldfire=yes],
 216                     [gdb_cv_m68k_is_coldfire=no])
 217                     CPPFLAGS="$save_CPPFLAGS"])
 218     ;;
 219 esac
 220
 221 . ${srcdir}/configure.srv
 222
 223 if test "${srv_mingwce}" = "yes"; then
 224   LIBS="$LIBS -lws2"
 225 elif test "${srv_mingw}" = "yes"; then
 226   # WIN32APILIBS is set by GDB_AC_COMMON.
 227   LIBS="$LIBS $WIN32APILIBS"
 228 fi
 229
 230 if test "${srv_linux_usrregs}" = "yes"; then
 231   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 232             [Define if the target supports PTRACE_PEEKUSR for register ]
 233             [access.])
 234 fi
 235
 236 if test "${srv_linux_regsets}" = "yes"; then
 237   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 238             [Define if the target supports register sets.])
 239
 240   AC_MSG_CHECKING(for PTRACE_GETREGS)
 241   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 242   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 243                   [PTRACE_GETREGS;],
 244                   [gdbsrv_cv_have_ptrace_getregs=yes],
 245                   [gdbsrv_cv_have_ptrace_getregs=no])])
 246   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 247   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 248     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 249               [Define if the target supports PTRACE_GETREGS for register ]
 250               [access.])
 251   fi
 252
 253   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 254   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 255   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 256                   [PTRACE_GETFPXREGS;],
 257                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 258                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 259   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 260   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 261     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 262               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 263               [register access.])
 264   fi
 265 fi
 266
 267 if test "${srv_linux_btrace}" = "yes"; then
 268   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 269             [Define if the target supports branch tracing.])
 270 fi
 271
 272 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 273 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 274   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 275 fi
 276
 277 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 278 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 279   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 280 fi
 281
 282 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 283 dnl needs it (and gdbreplay doesn't).
 284 old_LIBS="$LIBS"
 285 AC_CHECK_LIB(dl, dlopen)
 286 LIBS="$old_LIBS"
 287
 288 srv_thread_depfiles=
 289 srv_libs=
 290
 291 if test "$srv_linux_thread_db" = "yes"; then
 292   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 293     srv_libs="-ldl"
 294     AC_MSG_CHECKING(for the dynamic export flag)
 295     old_LDFLAGS="$LDFLAGS"
 296     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 297     # supported there.
 298     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 299     LDFLAGS="$LDFLAGS $RDYNAMIC"
 300     AC_TRY_LINK([], [],
 301                 [found="-Wl,--dynamic-list"
 302                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 303                 [RDYNAMIC="-rdynamic"
 304                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 305                  AC_TRY_LINK([], [],
 306                              [found="-rdynamic"],
 307                              [found="no"
 308                               RDYNAMIC=""])])
 309     AC_SUBST(RDYNAMIC)
 310     LDFLAGS="$old_LDFLAGS"
 311     AC_MSG_RESULT($found)
 312   else
 313     srv_libs="-lthread_db"
 314   fi
 315
 316   srv_thread_depfiles="thread-db.o proc-service.o"
 317   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 318   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 319   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 320                   [gdbsrv_cv_have_td_version=yes],
 321                   [gdbsrv_cv_have_td_version=no])])
 322   if test "$gdbsrv_cv_have_td_version" = yes; then
 323     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 324   fi
 325 fi
 326
 327 AC_ARG_WITH(libthread-db,
 328 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 329 [srv_libthread_db_path="${withval}"
 330   srv_libs="$srv_libthread_db_path"
 331 ])
 332
 333 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 334   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 335 fi
 336
 337 if test "$srv_xmlfiles" != ""; then
 338   srv_xmlbuiltin="xml-builtin.o"
 339   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 340
 341   tmp_xmlfiles=$srv_xmlfiles
 342   srv_xmlfiles=""
 343   for f in $tmp_xmlfiles; do
 344     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 345   done
 346 fi
 347
 348 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
 349 GDBSERVER_LIBS="$srv_libs"
 350
 351 dnl Check whether the target supports __sync_*_compare_and_swap.
 352 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 353                 gdbsrv_cv_have_sync_builtins, [
 354 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 355                 gdbsrv_cv_have_sync_builtins=yes,
 356                 gdbsrv_cv_have_sync_builtins=no)])
 357 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
 358   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 359     [Define to 1 if the target supports __sync_*_compare_and_swap])
 360 fi
 361
 362 dnl Check for -fvisibility=hidden support in the compiler.
 363 saved_cflags="$CFLAGS"
 364 CFLAGS="$CFLAGS -fvisibility=hidden"
 365 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 366                         [gdbsrv_cv_have_visibility_hidden=yes],
 367                         [gdbsrv_cv_have_visibility_hidden=no])
 368 CFLAGS="$saved_cflags"
 369
 370 IPA_DEPFILES=""
 371 extra_libraries=""
 372
 373 # check whether to enable the inprocess agent
 374 if test "$ipa_obj" != "" \
 375    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 376    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 377    have_ipa=true
 378 else
 379    have_ipa=false
 380 fi
 381
 382 AC_ARG_ENABLE(inprocess-agent,
 383 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 384 [case "$enableval" in
 385   yes) want_ipa=true ;;
 386   no) want_ipa=false ;;
 387   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 388 esac],
 389 [want_ipa=$have_ipa])
 390
 391 if $want_ipa ; then
 392    if $have_ipa ; then
 393      IPA_DEPFILES="$ipa_obj"
 394      extra_libraries="$extra_libraries libinproctrace.so"
 395    else
 396      AC_MSG_ERROR([inprocess agent not supported for this target])
 397    fi
 398 fi
 399
 400 AC_SUBST(GDBSERVER_DEPFILES)
 401 AC_SUBST(GDBSERVER_LIBS)
 402 AC_SUBST(srv_xmlbuiltin)
 403 AC_SUBST(srv_xmlfiles)
 404 AC_SUBST(IPA_DEPFILES)
 405 AC_SUBST(extra_libraries)
 406
 407 GNULIB=../gnulib/import
 408
 409 GNULIB_STDINT_H=
 410 if test x"$STDINT_H" != x; then
 411   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 412 fi
 413 AC_SUBST(GNULIB_STDINT_H)
 414
 415 AC_CONFIG_FILES([Makefile])
 416
 417 AC_OUTPUT