lib/meson.build

   1 lib_common_sources = '''
   2         blkdev.c
   3         buffer.c
   4         canonicalize.c
   5         color-names.c
   6         crc32.c
   7         crc32c.c
   8         crc64.c
   9         c_strtod.c
  10         encode.c
  11         env.c
  12         fileutils.c
  13         idcache.c
  14         jsonwrt.c
  15         mangle.c
  16         match.c
  17         mbsalign.c
  18         mbsedit.c
  19         md5.c
  20         procfs.c
  21         pwdutils.c
  22         randutils.c
  23         sha1.c
  24         sha256.c
  25         signames.c
  26         strutils.c
  27         strv.c
  28         timeutils.c
  29         ttyutils.c
  30         xxhash.c
  31 '''.split()
  32
  33 idcache_c = files('idcache.c')
  34 randutils_c = files('randutils.c')
  35 md5_c = files('md5.c')
  36 sha1_c = files('sha1.c')
  37 strutils_c = files('strutils.c')
  38 strv_c = files('strv.c')
  39 pager_c = files('pager.c')
  40
  41 lib_common_sources += [idcache_c,
  42                        randutils_c,
  43                        md5_c,
  44                        sha1_c,
  45                        strutils_c,
  46                        strv_c]
  47
  48 monotonic_c = files('monotonic.c')
  49 timer_c = files('timer.c')
  50 swapprober_c = files('swapprober.c')
  51 pty_session_c = files('pty-session.c')
  52 ismounted_c = files('ismounted.c')
  53 exec_shell_c = files('exec_shell.c')
  54 fileeq_c = files('fileeq.c')
  55 logindefs_c = static_library('logindefs',
  56   sources : ['logindefs.c'],
  57   include_directories : dir_include,
  58   dependencies : lib_econf,
  59 )
  60 selinux_utils_c = files('selinux-utils.c')
  61
  62 if LINUX
  63   lib_common_sources += '''
  64     caputils.c
  65     linux_version.c
  66     loopdev.c
  67 '''.split()
  68 endif
  69
  70 if build_plymouth_support
  71   lib_common_sources += '''
  72         plymouth-ctrl.c
  73 '''.split()
  74 endif
  75
  76 if conf.get('HAVE_LANGINFO_H') not in [1]
  77   lib_common_sources += 'langinfo.c'
  78 endif
  79
  80 if conf.get('HAVE_CPU_SET_T') in [1]
  81   lib_common_sources += 'cpuset.c'
  82 endif
  83
  84 if conf.get('HAVE_OPENAT') in [1] and conf.get('HAVE_DIRFD') in [1]
  85   lib_common_sources += '''
  86     path.c
  87     procfs.c
  88     sysfs.c
  89 '''.split()
  90 endif
  91
  92 lib_common = static_library(
  93   'common',
  94   lib_common_sources,
  95   include_directories : dir_include)
  96
  97
  98 lib_color_sources = files('''
  99   colors.c
 100   color-names.c
 101 '''.split())
 102 # colors.h include/color-names.h
 103
 104 lib_tcolors = static_library(
 105   'tcolors',
 106   lib_color_sources,
 107   include_directories : dir_include,
 108   dependencies : curses_libs)