libsmartcols/meson.build

   1 dir_libsmartcols = include_directories('.', 'src')
   2
   3 defs = configuration_data()
   4 defs.set('LIBSMARTCOLS_VERSION', pc_version)
   5
   6 libsmartcols_h = configure_file(
   7   input : 'src/libsmartcols.h.in',
   8   output : 'libsmartcols.h',
   9   configuration : defs,
  10   install : build_libsmartcols,
  11   install_dir : join_paths(get_option('includedir'), 'libsmartcols'),
  12 )
  13
  14 lib_smartcols_sources = '''
  15   src/smartcolsP.h
  16   src/iter.c
  17   src/symbols.c
  18   src/cell.c
  19   src/column.c
  20   src/line.c
  21   src/table.c
  22   src/print.c
  23   src/print-api.c
  24   src/version.c
  25   src/calculate.c
  26   src/grouping.c
  27   src/walk.c
  28   src/init.c
  29 '''.split()
  30
  31 libsmartcols_sym = 'src/libsmartcols.sym'
  32 libsmartcols_sym_path = '@0@/@1@'.format(meson.current_source_dir(), libsmartcols_sym)
  33
  34 lib_smartcols = both_libraries(
  35   'smartcols',
  36   list_h,
  37   lib_smartcols_sources,
  38   include_directories : [dir_include, dir_libsmartcols],
  39   link_depends : libsmartcols_sym,
  40   version : libsmartcols_version,
  41   link_args : ['-Wl,--version-script=@0@'.format(libsmartcols_sym_path)],
  42   link_with : lib_common,
  43   dependencies : build_libsmartcols ? [] : disabler(),
  44   install : build_libsmartcols)
  45
  46 lib_smartcols_static = lib_smartcols.get_static_lib()
  47
  48 if build_libsmartcols
  49   pkgconfig.generate(lib_smartcols,
  50                      description : 'table or tree library',
  51                      subdirs : 'libsmartcols',
  52                      version : pc_version)
  53 endif