config/cfgroot/network-functions.pl

   1 #!/usr/bin/perl -w
   2 ############################################################################
   3 #                                                                          #
   4 # This file is part of the IPFire Firewall.                                #
   5 #                                                                          #
   6 # IPFire is free software; you can redistribute it and/or modify           #
   7 # it under the terms of the GNU General Public License as published by     #
   8 # the Free Software Foundation; either version 2 of the License, or        #
   9 # (at your option) any later version.                                      #
  10 #                                                                          #
  11 # IPFire is distributed in the hope that it will be useful,                #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of           #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the            #
  14 # GNU General Public License for more details.                             #
  15 #                                                                          #
  16 # You should have received a copy of the GNU General Public License        #
  17 # along with IPFire; if not, write to the Free Software                    #
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA #
  19 #                                                                          #
  20 # Copyright (C) 2014 IPFire Team <info@ipfire.org>.                        #
  21 #                                                                          #
  22 ############################################################################
  23
  24 package Network;
  25
  26 require "/var/ipfire/general-functions.pl";
  27
  28 use Socket;
  29
  30 my %PREFIX2NETMASK = (
  31         32 => "255.255.255.255",
  32         31 => "255.255.255.254",
  33         30 => "255.255.255.252",
  34         29 => "255.255.255.248",
  35         28 => "255.255.255.240",
  36         27 => "255.255.255.224",
  37         26 => "255.255.255.192",
  38         25 => "255.255.255.128",
  39         24 => "255.255.255.0",
  40         23 => "255.255.254.0",
  41         22 => "255.255.252.0",
  42         21 => "255.255.248.0",
  43         20 => "255.255.240.0",
  44         19 => "255.255.224.0",
  45         18 => "255.255.192.0",
  46         17 => "255.255.128.0",
  47         16 => "255.255.0.0",
  48         15 => "255.254.0.0",
  49         14 => "255.252.0.0",
  50         13 => "255.248.0.0",
  51         12 => "255.240.0.0",
  52         11 => "255.224.0.0",
  53         10 => "255.192.0.0",
  54          9 => "255.128.0.0",
  55          8 => "255.0.0.0",
  56          7 => "254.0.0.0",
  57          6 => "252.0.0.0",
  58          5 => "248.0.0.0",
  59          4 => "240.0.0.0",
  60          3 => "224.0.0.0",
  61          2 => "192.0.0.0",
  62          1 => "128.0.0.0",
  63          0 => "0.0.0.0"
  64 );
  65
  66 my %NETMASK2PREFIX = reverse(%PREFIX2NETMASK);
  67
  68 # Takes an IP address in dotted decimal notation and
  69 # returns a 32 bit integer representing that IP addresss.
  70 # Will return undef for invalid inputs.
  71 sub ip2bin($) {
  72         my $address = shift;
  73
  74         # This function returns undef for undefined input.
  75         if (!defined $address) {
  76                 return undef;
  77         }
  78
  79         my $address_bin = &Socket::inet_pton(AF_INET, $address);
  80         if ($address_bin) {
  81                 $address_bin = unpack('N', $address_bin);
  82         }
  83
  84         return $address_bin;
  85 }
  86
  87 # Does the reverse of ip2bin().
  88 # Will return undef for invalid inputs.
  89 sub bin2ip($) {
  90         my $address_bin = shift;
  91
  92         # This function returns undef for undefined input.
  93         if (!defined $address_bin) {
  94                 return undef;
  95         }
  96
  97         my $address = pack('N', $address_bin);
  98         if ($address) {
  99                 $address = &Socket::inet_ntop(AF_INET, $address);
 100         }
 101
 102         return $address;
 103 }
 104
 105 # Takes a network in either a.b.c.d/a.b.c.d or a.b.c.d/e notation
 106 # and will return an 32 bit integer representing the start
 107 # address and an other one representing the network mask.
 108 sub network2bin($) {
 109         my $network = shift;
 110
 111         my ($address, $netmask) = split(/\//, $network, 2);
 112
 113         if (&check_prefix($netmask)) {
 114                 $netmask = &convert_prefix2netmask($netmask);
 115         }
 116
 117         my $address_bin = &ip2bin($address);
 118         my $netmask_bin = &ip2bin($netmask);
 119
 120         my $network_start = $address_bin & $netmask_bin;
 121
 122         return ($network_start, $netmask_bin);
 123 }
 124
 125 # Deletes leading zeros in ip address
 126 sub ip_remove_zero{
 127         my $address = shift;
 128         my @ip = split (/\./, $address);
 129
 130         foreach my $octet (@ip) {
 131                 $octet = int($octet);
 132         }
 133
 134         $address = join (".", @ip);
 135
 136         return $address;
 137 }
 138 # Returns True for all valid IP addresses
 139 sub check_ip_address($) {
 140         my $address = shift;
 141
 142         # Normalise the IP address and compare the result with
 143         # the input - which should obviously the same.
 144         my $normalised_address = &_normalise_ip_address($address);
 145
 146         return ((defined $normalised_address) && ($address eq $normalised_address));
 147 }
 148
 149 # Returns True for all valid prefixes.
 150 sub check_prefix($) {
 151         my $prefix = shift;
 152
 153         return (exists $PREFIX2NETMASK{$prefix});
 154 }
 155
 156 # Returns True for all valid subnet masks.
 157 sub check_netmask($) {
 158         my $netmask = shift;
 159
 160         return (exists $NETMASK2PREFIX{$netmask});
 161 }
 162
 163 # Returns True for all valid inputs like a.b.c.d/a.b.c.d.
 164 sub check_ip_address_and_netmask($$) {
 165         my $network = shift;
 166
 167         my ($address, $netmask) = split(/\//, $network, 2);
 168
 169         # Check if the IP address is fine.
 170         #
 171         my $result = &check_ip_address($address);
 172         unless ($result) {
 173                 return $result;
 174         }
 175
 176         return &check_netmask($netmask);
 177 }
 178
 179 # Returns True for all valid subnets like a.b.c.d/e or a.b.c.d/a.b.c.d
 180 sub check_subnet($) {
 181         my $subnet = shift;
 182
 183         my ($address, $network) = split(/\//, $subnet, 2);
 184
 185         # Check if the IP address is fine.
 186         my $result = &check_ip_address($address);
 187         unless ($result) {
 188                 return $result;
 189         }
 190
 191         return &check_prefix($network) || &check_netmask($network);
 192 }
 193
 194 # For internal use only. Will take an IP address and
 195 # return it in a normalised style. Like 8.8.8.010 -> 8.8.8.8.
 196 sub _normalise_ip_address($) {
 197         my $address = shift;
 198
 199         my $address_bin = &ip2bin($address);
 200         if (!defined $address_bin) {
 201                 return undef;
 202         }
 203
 204         return &bin2ip($address_bin);
 205 }
 206
 207 # Returns the prefix for the given subnet mask.
 208 sub convert_netmask2prefix($) {
 209         my $netmask = shift;
 210
 211         if (exists $NETMASK2PREFIX{$netmask}) {
 212                 return $NETMASK2PREFIX{$netmask};
 213         }
 214
 215         return undef;
 216 }
 217
 218 # Returns the subnet mask for the given prefix.
 219 sub convert_prefix2netmask($) {
 220         my $prefix = shift;
 221
 222         if (exists $PREFIX2NETMASK{$prefix}) {
 223                 return $PREFIX2NETMASK{$prefix};
 224         }
 225
 226         return undef;
 227 }
 228
 229 # Takes an IP address and an offset and
 230 # will return the offset'th IP address.
 231 sub find_next_ip_address($$) {
 232         my $address = shift;
 233         my $offset = shift;
 234
 235         my $address_bin = &ip2bin($address);
 236         $address_bin += $offset;
 237
 238         return &bin2ip($address_bin);
 239 }
 240
 241 # Returns the network address of the given network.
 242 sub get_netaddress($) {
 243         my $network = shift;
 244         my ($network_bin, $netmask_bin) = &network2bin($network);
 245
 246         if (defined $network_bin) {
 247                 return &bin2ip($network_bin);
 248         }
 249
 250         return undef;
 251 }
 252
 253 # Returns the broadcast of the given network.
 254 sub get_broadcast($) {
 255         my $network = shift;
 256         my ($network_bin, $netmask_bin) = &network2bin($network);
 257
 258         return &bin2ip($network_bin ^ ~$netmask_bin);
 259 }
 260
 261 # Returns True if $address is in $network.
 262 sub ip_address_in_network($$) {
 263         my $address = shift;
 264         my $network = shift;
 265
 266         my $address_bin = &ip2bin($address);
 267         return undef unless (defined $address_bin);
 268
 269         my ($network_bin, $netmask_bin) = &network2bin($network);
 270
 271         # Find end address
 272         my $broadcast_bin = $network_bin ^ (~$netmask_bin % 2 ** 32);
 273
 274         return (($address_bin ge $network_bin) && ($address_bin le $broadcast_bin));
 275 }
 276
 277 sub setup_upstream_proxy() {
 278         my %proxysettings = ();
 279         &General::readhash("${General::swroot}/proxy/settings", \%proxysettings);
 280
 281         if ($proxysettings{'UPSTREAM_PROXY'}) {
 282                 my $credentials = "";
 283
 284                 if ($proxysettings{'UPSTREAM_USER'}) {
 285                         $credentials = $proxysettings{'UPSTREAM_USER'};
 286
 287                         if ($proxysettings{'UPSTREAM_PASSWORD'}) {
 288                                 $credentials .= ":" . $proxysettings{'UPSTREAM_PASSWORD'};
 289                         }
 290
 291                         $credentials .= "@";
 292                 }
 293
 294                 my $proxy = "http://" . $credentials . $proxysettings{'UPSTREAM_PROXY'};
 295
 296                 $ENV{'http_proxy'} = $proxy;
 297                 $ENV{'https_proxy'} = $proxy;
 298                 $ENV{'ftp_proxy'} = $proxy;
 299         }
 300 }
 301
 302 1;
 303
 304 # Remove the next line to enable the testsuite
 305 __END__
 306
 307 sub assert($) {
 308         my $ret = shift;
 309
 310         if ($ret) {
 311                 return;
 312         }
 313
 314         print "ASSERTION ERROR";
 315         exit(1);
 316 }
 317
 318 sub testsuite() {
 319         my $result;
 320
 321         my $address1 = &ip2bin("8.8.8.8");
 322         assert($address1 == 134744072);
 323
 324         my $address2 = &bin2ip($address1);
 325         assert($address2 eq "8.8.8.8");
 326
 327         # Check if valid IP addresses are correctly recognised.
 328         foreach my $address ("1.2.3.4", "192.168.180.1", "127.0.0.1") {
 329                 if (!&check_ip_address($address)) {
 330                         print "$address is not correctly recognised as a valid IP address!\n";
 331                         exit 1;
 332                 };
 333         }
 334
 335         # Check if invalid IP addresses are correctly found.
 336         foreach my $address ("456.2.3.4", "192.768.180.1", "127.1", "1", "a.b.c.d", "1.2.3.4.5", "1.2.3.4/12") {
 337                 if (&check_ip_address($address)) {
 338                         print "$address is recognised as a valid IP address!\n";
 339                         exit 1;
 340                 };
 341         }
 342
 343         $result = &check_ip_address_and_netmask("192.168.180.0/255.255.255.0");
 344         assert($result);
 345
 346         $result = &convert_netmask2prefix("255.255.254.0");
 347         assert($result == 23);
 348
 349         $result = &convert_prefix2netmask(8);
 350         assert($result eq "255.0.0.0");
 351
 352         $result = &find_next_ip_address("1.2.3.4", 2);
 353         assert($result eq "1.2.3.6");
 354
 355         $result = &ip_address_in_network("10.0.1.4", "10.0.0.0/8");
 356         assert($result);
 357
 358         $result = &ip_address_in_network("192.168.30.11", "192.168.30.0/255.255.255.0");
 359         assert($result);
 360
 361         return 0;
 362 }
 363
 364 &testsuite();